qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", "Shotgun");
   3 #else
   4 #ifdef SVQC
   5 void W_Shotgun_Attack (void)
   6 {
   7         float   sc;
   8         float   ammoamount;
   9         float   bullets;
  10         float   d;
  11         float   f;
  12         float   spread;
  13         float   bulletspeed;
  14         float   bulletconstant;
  15         local entity flash;
  16
  17         ammoamount = cvar("g_balance_shotgun_primary_ammo");
  18         bullets = cvar("g_balance_shotgun_primary_bullets");
  19         d = cvar("g_balance_shotgun_primary_damage");
  20         f = cvar("g_balance_shotgun_primary_force");
  21         spread = cvar("g_balance_shotgun_primary_spread");
  22         bulletspeed = cvar("g_balance_shotgun_primary_speed");
  23         bulletconstant = cvar("g_balance_shotgun_primary_bulletconstant");
  24
  25         W_SetupShot (self, cvar("g_antilag_bullets") && bulletspeed >= cvar("g_antilag_bullets"), 5, "weapons/shotgun_fire.wav", cvar("g_balance_shotgun_primary_damage"));
  26         for (sc = 0;sc < bullets;sc = sc + 1)
  27                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  28         endFireBallisticBullet();
  29         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  30                 self.ammo_shells = self.ammo_shells - ammoamount;
  31
  32         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, cvar("g_balance_shotgun_primary_ammo"));
  33
  34         // casing code
  35         if (cvar("g_casings") >= 1)
  36                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  37                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  38
  39         // muzzle flash for 1st person view
  40         flash = spawn();
  41         setmodel(flash, "models/uziflash.md3"); // precision set below
  42         flash.think = SUB_Remove;
  43         flash.nextthink = time + 0.06;
  44         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  45         W_AttachToShotorg(flash, '5 0 0');
  46
  47 }
  48
  49 void W_Shotgun_Attack2 (void)
  50 {
  51         float   sc;
  52         float   ammoamount;
  53         float   bullets;
  54         float   d;
  55         float   f;
  56         float   spread;
  57         float   bulletspeed;
  58         float   bulletconstant;
  59         local entity flash;
  60
  61         ammoamount = cvar("g_balance_shotgun_secondary_ammo");
  62         bullets = cvar("g_balance_shotgun_secondary_bullets");
  63         d = cvar("g_balance_shotgun_secondary_damage");
  64         f = cvar("g_balance_shotgun_secondary_force");
  65         spread = cvar("g_balance_shotgun_secondary_spread");
  66         bulletspeed = cvar("g_balance_shotgun_secondary_speed");
  67         bulletconstant = cvar("g_balance_shotgun_secondary_bulletconstant");
  68
  69         W_SetupShot (self, cvar("g_antilag_bullets") && bulletspeed >= cvar("g_antilag_bullets"), 5, "weapons/shotgun_fire.wav", cvar("g_balance_shotgun_secondary_damage"));
  70         for (sc = 0;sc < bullets;sc = sc + 1)
  71                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN | HITTYPE_SECONDARY, 0, 1, bulletconstant);
  72         endFireBallisticBullet();
  73         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  74                 self.ammo_shells = self.ammo_shells - ammoamount;
  75
  76         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, cvar("g_balance_shotgun_secondary_ammo"));
  77
  78         // casing code
  79         if (cvar("g_casings") >= 1)
  80                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  81                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  82
  83         flash = spawn();
  84         setmodel(flash, "models/uziflash.md3"); // precision set below
  85         flash.scale = 1.2;
  86         flash.think = SUB_Remove;
  87         flash.nextthink = time + 0.06;
  88         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  89         W_AttachToShotorg(flash, '5 0 0');
  90 }
  91
  92 void shotgun_meleethink (void)
  93 {
  94         // store time when we started swinging down inside self.cnt
  95         if(!self.cnt)
  96                 self.cnt = time;
  97
  98         makevectors(self.owner.v_angle);
  99         vector angle;
 100         angle = v_forward;
 101
 102         // perform trace
 103         float f;
 104         f = (self.cnt + cvar("g_balance_shotgun_secondary_melee_time") - time) / cvar("g_balance_shotgun_secondary_melee_time") * 2 - 1;
 105         vector targpos;
 106         targpos = self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_shotgun_secondary_melee_range") + v_right * f * cvar("g_balance_shotgun_secondary_melee_swing") + v_up * f * cvar("g_balance_shotgun_secondary_melee_swing");
 107         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 108
 109         // apply the damage, also remove self
 110         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && trace_ent.classname == "player")
 111         {
 112                 vector force;
 113                 force = angle * cvar("g_balance_shotgun_secondary_force");
 114                 Damage (trace_ent, self.owner, self.owner, cvar("g_balance_shotgun_secondary_damage") * ((f + 1) / 2), WEP_SHOTGUN, self.owner.origin + self.owner.view_ofs, force);
 115                 remove(self);
 116         }
 117         else if(time >= self.cnt + cvar("g_balance_shotgun_secondary_melee_time")) // missed, remove ent
 118                 remove(self);
 119         else // continue swinging the weapon in hope of hitting someone :)
 120                 self.nextthink = time;
 121 }
 122
 123 void W_Shotgun_Attack3 (void)
 124 {
 125         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 126         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), w_ready);
 127
 128         entity meleetemp;
 129         meleetemp = spawn();
 130         meleetemp.owner = self;
 131         meleetemp.think = shotgun_meleethink;
 132         meleetemp.nextthink = time + cvar("g_balance_shotgun_secondary_melee_delay");
 133 }
 134
 135 // weapon frames
 136 void shotgun_fire2_03()
 137 {
 138         W_Shotgun_Attack2();
 139         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), w_ready);
 140 }
 141 void shotgun_fire2_02()
 142 {
 143         W_Shotgun_Attack2();
 144         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), shotgun_fire2_03);
 145 }
 146
 147 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 148
 149 float w_shotgun(float req)
 150 {
 151         if (req == WR_AIM)
 152                 if(vlen(self.origin-self.enemy.origin)>200)
 153                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 154                 else
 155                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 156         else if (req == WR_THINK)
 157         {
 158                 if (self.BUTTON_ATCK)
 159                 if (weapon_prepareattack(0, cvar("g_balance_shotgun_primary_refire")))
 160                 {
 161                         W_Shotgun_Attack();
 162                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_shotgun_primary_animtime"), w_ready);
 163                 }
 164                 if (self.BUTTON_ATCK2 && cvar("g_balance_shotgun_secondary"))
 165                 if (weapon_prepareattack(1, cvar("g_balance_shotgun_secondary_refire")))
 166                 {
 167                         if(cvar("g_balance_shotgun_secondary_melee"))
 168                         {
 169                                 // force playback of the anim by switching to another anim (that we never play) here...
 170                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack3);
 171                         }
 172                         else
 173                         {
 174                                 W_Shotgun_Attack2();
 175                                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), shotgun_fire2_02);
 176                         }
 177                 }
 178         }
 179         else if (req == WR_PRECACHE)
 180         {
 181                 precache_model ("models/uziflash.md3");
 182                 precache_model ("models/weapons/g_shotgun.md3");
 183                 precache_model ("models/weapons/v_shotgun.md3");
 184                 precache_model ("models/weapons/h_shotgun.iqm");
 185                 precache_sound ("misc/itempickup.wav");
 186                 precache_sound ("weapons/shotgun_fire.wav");
 187                 precache_sound ("weapons/shotgun_melee.wav");
 188         }
 189         else if (req == WR_SETUP)
 190                 weapon_setup(WEP_SHOTGUN);
 191         else if (req == WR_CHECKAMMO1)
 192                 return self.ammo_shells >= cvar("g_balance_shotgun_primary_ammo");
 193         else if (req == WR_CHECKAMMO2)
 194         {
 195                 if(cvar("g_balance_shotgun_secondary_melee"))
 196                         return TRUE;
 197                 return self.ammo_shells >= cvar("g_balance_shotgun_secondary_ammo") * 3;
 198         }
 199         return TRUE;
 200 };
 201 #endif
 202 #ifdef CSQC
 203 float w_shotgun(float req)
 204 {
 205         if(req == WR_IMPACTEFFECT)
 206         {
 207                 vector org2;
 208                 org2 = w_org + w_backoff * 2;
 209                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 210                 if(!w_issilent)
 211                 {
 212                         if(w_random < 0.05)
 213                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 214                         else if(w_random < 0.1)
 215                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 216                         else if(w_random < 0.2)
 217                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 218                 }
 219         }
 220         else if(req == WR_PRECACHE)
 221         {
 222                 precache_sound("weapons/ric1.wav");
 223                 precache_sound("weapons/ric2.wav");
 224                 precache_sound("weapons/ric3.wav");
 225         }
 226         else if (req == WR_SUICIDEMESSAGE)
 227                 w_deathtypestring = "did the impossible";
 228         else if (req == WR_KILLMESSAGE)
 229         {
 230                 w_deathtypestring = "was gunned by"; // unchecked: SECONDARY
 231         }
 232         return TRUE;
 233 }
 234 #endif
 235 #endif