qcsrc/server/w_uzi.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ UZI,
   4 /* function  */ w_uzi,
   5 /* ammotype  */ IT_NAILS,
   6 /* impulse   */ 3,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN,
   8 /* rating    */ BOT_PICKUP_RATING_MID,
   9 /* model     */ "uzi",
  10 /* shortname */ "uzi",
  11 /* fullname  */ _("Machine Gun")
  12 );
  13 #else
  14 #ifdef SVQC
  15
  16 // leilei's fancy muzzleflash stuff
  17 void UZI_Flash_Go()
  18 {
  19         self.frame = self.frame + 2;
  20         self.scale = self.scale * 0.5;
  21         self.alpha = self.alpha - 0.25;
  22         self.nextthink = time + 0.05;
  23
  24         if (self.alpha <= 0)
  25         {
  26                 self.think = SUB_Remove;
  27                 self.nextthink = time;
  28                 self.realowner.muzzle_flash = world;
  29                 return;
  30         }
  31
  32 }
  33
  34 void UziFlash()
  35 {
  36         if (self.muzzle_flash == world)
  37                 self.muzzle_flash = spawn();
  38
  39         // muzzle flash for 1st person view
  40         setmodel(self.muzzle_flash, "models/uziflash.md3"); // precision set below
  41
  42         self.muzzle_flash.scale = 0.75;
  43         self.muzzle_flash.think = UZI_Flash_Go;
  44         self.muzzle_flash.nextthink = time + 0.02;
  45         self.muzzle_flash.frame = 2;
  46         self.muzzle_flash.alpha = 0.75;
  47         self.muzzle_flash.angles_z = random() * 180;
  48         self.muzzle_flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  49         self.muzzle_flash.owner = self.muzzle_flash.realowner = self;
  50 }
  51
  52 void W_UZI_Attack (float deathtype)
  53 {
  54         W_SetupShot (self, autocvar_g_antilag_bullets && autocvar_g_balance_uzi_speed >= autocvar_g_antilag_bullets, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, ((self.misc_bulletcounter == 1) ? autocvar_g_balance_uzi_first_damage : autocvar_g_balance_uzi_sustained_damage));
  55
  56         self.punchangle_x = random () - 0.5;
  57         self.punchangle_y = random () - 0.5;
  58
  59         // this attack_finished just enforces a cooldown at the end of a burst
  60         ATTACK_FINISHED(self) = time + autocvar_g_balance_uzi_first_refire * W_WeaponRateFactor();
  61
  62         if (self.misc_bulletcounter == 1)
  63                 fireBallisticBullet(w_shotorg, w_shotdir, autocvar_g_balance_uzi_first_spread, autocvar_g_balance_uzi_speed, 5, autocvar_g_balance_uzi_first_damage, autocvar_g_balance_uzi_first_force, deathtype, 0, 1, autocvar_g_balance_uzi_bulletconstant);
  64         else
  65                 fireBallisticBullet(w_shotorg, w_shotdir, autocvar_g_balance_uzi_sustained_spread, autocvar_g_balance_uzi_speed, 5, autocvar_g_balance_uzi_sustained_damage, autocvar_g_balance_uzi_sustained_force, deathtype, 0, 1, autocvar_g_balance_uzi_bulletconstant);
  66         endFireBallisticBullet();
  67
  68         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  69
  70         UziFlash();
  71         W_AttachToShotorg(self.muzzle_flash, '5 0 0');
  72
  73         // casing code
  74         if (autocvar_g_casings >= 2)
  75                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
  76
  77         if (self.misc_bulletcounter == 1)
  78                 W_DecreaseAmmo(ammo_nails, autocvar_g_balance_uzi_first_ammo, autocvar_g_balance_uzi_reload_ammo);
  79         else
  80                 W_DecreaseAmmo(ammo_nails, autocvar_g_balance_uzi_sustained_ammo, autocvar_g_balance_uzi_reload_ammo);
  81 }
  82
  83 // weapon frames
  84 void uzi_fire1_02()
  85 {
  86         if(self.weapon != self.switchweapon) // abort immediately if switching
  87         {
  88                 w_ready();
  89                 return;
  90         }
  91         if (self.BUTTON_ATCK)
  92         {
  93                 if (!weapon_action(self.weapon, WR_CHECKAMMO2))
  94                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  95                 {
  96                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
  97                         w_ready();
  98                         return;
  99                 }
 100                 self.misc_bulletcounter = self.misc_bulletcounter + 1;
 101                 W_UZI_Attack(WEP_UZI);
 102                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_uzi_sustained_refire, uzi_fire1_02);
 103         }
 104         else
 105                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_uzi_sustained_refire, w_ready);
 106 }
 107
 108
 109 void uzi_mode1_fire_auto()
 110 {
 111         float uzi_spread;
 112
 113         if (!self.BUTTON_ATCK)
 114         {
 115                 w_ready();
 116                 return;
 117         }
 118
 119         if (!weapon_action(self.weapon, WR_CHECKAMMO1))
 120         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 121         {
 122                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 123                 w_ready();
 124                 return;
 125         }
 126
 127         W_DecreaseAmmo(ammo_nails, autocvar_g_balance_uzi_sustained_ammo, autocvar_g_balance_uzi_reload_ammo);
 128
 129         W_SetupShot (self, autocvar_g_antilag_bullets && autocvar_g_balance_uzi_speed >= autocvar_g_antilag_bullets, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, autocvar_g_balance_uzi_sustained_damage);
 130
 131         self.punchangle_x = random () - 0.5;
 132         self.punchangle_y = random () - 0.5;
 133
 134         uzi_spread = bound(autocvar_g_balance_uzi_spread_min, autocvar_g_balance_uzi_spread_min + (autocvar_g_balance_uzi_spread_add * self.misc_bulletcounter), autocvar_g_balance_uzi_spread_max);
 135         fireBallisticBullet(w_shotorg, w_shotdir, uzi_spread, autocvar_g_balance_uzi_speed, 5, autocvar_g_balance_uzi_sustained_damage, autocvar_g_balance_uzi_sustained_force, WEP_UZI, 0, 1, autocvar_g_balance_uzi_bulletconstant);
 136         endFireBallisticBullet();
 137
 138         self.misc_bulletcounter = self.misc_bulletcounter + 1;
 139
 140         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 141
 142         UziFlash();
 143         W_AttachToShotorg(self.muzzle_flash, '5 0 0');
 144
 145         if (autocvar_g_casings >= 2) // casing code
 146                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
 147
 148         ATTACK_FINISHED(self) = time + autocvar_g_balance_uzi_first_refire * W_WeaponRateFactor();
 149         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_uzi_sustained_refire, uzi_mode1_fire_auto);
 150 }
 151
 152 void uzi_mode1_fire_burst()
 153 {
 154         W_SetupShot (self, autocvar_g_antilag_bullets && autocvar_g_balance_uzi_speed >= autocvar_g_antilag_bullets, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, autocvar_g_balance_uzi_sustained_damage);
 155
 156         self.punchangle_x = random () - 0.5;
 157         self.punchangle_y = random () - 0.5;
 158
 159         fireBallisticBullet(w_shotorg, w_shotdir, autocvar_g_balance_uzi_burst_spread, autocvar_g_balance_uzi_speed, 5, autocvar_g_balance_uzi_sustained_damage, autocvar_g_balance_uzi_sustained_force, WEP_UZI, 0, 1, autocvar_g_balance_uzi_bulletconstant);
 160         endFireBallisticBullet();
 161
 162
 163         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 164
 165         UziFlash();
 166         W_AttachToShotorg(self.muzzle_flash, '5 0 0');
 167
 168         if (autocvar_g_casings >= 2) // casing code
 169                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
 170
 171         self.misc_bulletcounter = self.misc_bulletcounter + 1;
 172         if (self.misc_bulletcounter == 0)
 173         {
 174                 ATTACK_FINISHED(self) = time + autocvar_g_balance_uzi_burst_refire2 * W_WeaponRateFactor();
 175                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_uzi_burst_animtime, w_ready);
 176         }
 177         else
 178         {
 179                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_uzi_burst_refire, uzi_mode1_fire_burst);
 180         }
 181
 182 }
 183
 184 void spawnfunc_weapon_machinegun(); // defined in t_items.qc
 185
 186 float w_uzi(float req)
 187 {
 188         float ammo_amount;
 189         if (req == WR_AIM)
 190                 if(vlen(self.origin-self.enemy.origin) < 3000 - bound(0, skill, 10) * 200)
 191                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 192                 else
 193                 {
 194                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 195                 }
 196         else if (req == WR_THINK)
 197         {
 198                 if(autocvar_g_balance_uzi_reload_ammo && self.clip_load < min(max(autocvar_g_balance_uzi_sustained_ammo, autocvar_g_balance_uzi_first_ammo), autocvar_g_balance_uzi_burst_ammo)) // forced reload
 199                         weapon_action(self.weapon, WR_RELOAD);
 200                 else if(autocvar_g_balance_uzi_mode == 1)
 201                 {
 202                         if (self.BUTTON_ATCK)
 203                         if (weapon_prepareattack(0, 0))
 204                         {
 205                                 self.misc_bulletcounter = 0;
 206                                 uzi_mode1_fire_auto();
 207                         }
 208
 209                         if(self.BUTTON_ATCK2)
 210                         if(weapon_prepareattack(1, 0))
 211                         {
 212                                 if (!weapon_action(self.weapon, WR_CHECKAMMO2))
 213                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 214                                 {
 215                                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 216                                         w_ready();
 217                                         return FALSE;
 218                                 }
 219
 220                                 W_DecreaseAmmo(ammo_nails, autocvar_g_balance_uzi_burst_ammo, autocvar_g_balance_uzi_reload_ammo);
 221
 222                                 self.misc_bulletcounter = autocvar_g_balance_uzi_burst * -1;
 223                                 uzi_mode1_fire_burst();
 224                         }
 225                 }
 226                 else
 227                 {
 228
 229                         if (self.BUTTON_ATCK)
 230                         if (weapon_prepareattack(0, 0))
 231                         {
 232                                 self.misc_bulletcounter = 1;
 233                                 W_UZI_Attack(WEP_UZI); // sets attack_finished
 234                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_uzi_sustained_refire, uzi_fire1_02);
 235                         }
 236
 237                         if (self.BUTTON_ATCK2 && autocvar_g_balance_uzi_first)
 238                         if (weapon_prepareattack(1, 0))
 239                         {
 240                                 self.misc_bulletcounter = 1;
 241                                 W_UZI_Attack(WEP_UZI | HITTYPE_SECONDARY); // sets attack_finished
 242                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_uzi_first_refire, w_ready);
 243                         }
 244                 }
 245         }
 246         else if (req == WR_PRECACHE)
 247         {
 248                 precache_model ("models/uziflash.md3");
 249                 precache_model ("models/weapons/g_uzi.md3");
 250                 precache_model ("models/weapons/v_uzi.md3");
 251                 precache_model ("models/weapons/h_uzi.iqm");
 252                 precache_sound ("weapons/uzi_fire.wav");
 253                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 254         }
 255         else if (req == WR_SETUP)
 256         {
 257                 weapon_setup(WEP_UZI);
 258                 self.current_ammo = ammo_nails;
 259         }
 260         else if (req == WR_CHECKAMMO1)
 261         {
 262                 if(autocvar_g_balance_uzi_mode == 1)
 263                         ammo_amount = self.ammo_nails >= autocvar_g_balance_uzi_sustained_ammo;
 264                 else
 265                         ammo_amount = self.ammo_nails >= autocvar_g_balance_uzi_first_ammo;
 266
 267                 if(autocvar_g_balance_uzi_reload_ammo)
 268                 {
 269                         if(autocvar_g_balance_uzi_mode == 1)
 270                                 ammo_amount += self.(weapon_load[WEP_UZI]) >= autocvar_g_balance_uzi_sustained_ammo;
 271                         else
 272                                 ammo_amount += self.(weapon_load[WEP_UZI]) >= autocvar_g_balance_uzi_first_ammo;
 273                 }
 274                 return ammo_amount;
 275         }
 276         else if (req == WR_CHECKAMMO2)
 277         {
 278                 if(autocvar_g_balance_uzi_mode == 1)
 279                         ammo_amount = self.ammo_nails >= autocvar_g_balance_uzi_burst_ammo;
 280                 else
 281                         ammo_amount = self.ammo_nails >= autocvar_g_balance_uzi_first_ammo;
 282
 283                 if(autocvar_g_balance_uzi_reload_ammo)
 284                 {
 285                         if(autocvar_g_balance_uzi_mode == 1)
 286                                 ammo_amount += self.(weapon_load[WEP_UZI]) >= autocvar_g_balance_uzi_burst_ammo;
 287                         else
 288                                 ammo_amount += self.(weapon_load[WEP_UZI]) >= autocvar_g_balance_uzi_first_ammo;
 289                 }
 290                 return ammo_amount;
 291         }
 292         else if (req == WR_RELOAD)
 293         {
 294                 W_Reload(min(max(autocvar_g_balance_uzi_sustained_ammo, autocvar_g_balance_uzi_first_ammo), autocvar_g_balance_uzi_burst_ammo), autocvar_g_balance_uzi_reload_ammo, autocvar_g_balance_uzi_reload_time, "weapons/reload.wav");
 295         }
 296         else if (req == WR_SUICIDEMESSAGE)
 297         {
 298                 return WEAPON_THINKING_WITH_PORTALS;
 299         }
 300         else if (req == WR_KILLMESSAGE)
 301         {
 302                 if(w_deathtype & HITTYPE_SECONDARY)
 303                         return WEAPON_UZI_MURDER_SNIPE;
 304                 else
 305                         return WEAPON_UZI_MURDER_SPRAY;
 306         }
 307         return TRUE;
 308 }
 309 #endif
 310 #ifdef CSQC
 311 float w_uzi(float req)
 312 {
 313         if(req == WR_IMPACTEFFECT)
 314         {
 315                 vector org2;
 316                 org2 = w_org + w_backoff * 2;
 317                 pointparticles(particleeffectnum("machinegun_impact"), org2, w_backoff * 1000, 1);
 318                 if(!w_issilent)
 319                         if(w_random < 0.05)
 320                                 sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 321                         else if(w_random < 0.1)
 322                                 sound(self, CH_SHOTS, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 323                         else if(w_random < 0.2)
 324                                 sound(self, CH_SHOTS, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 325         }
 326         else if(req == WR_PRECACHE)
 327         {
 328                 precache_sound("weapons/ric1.wav");
 329                 precache_sound("weapons/ric2.wav");
 330                 precache_sound("weapons/ric3.wav");
 331         }
 332         return TRUE;
 333 }
 334 #endif
 335 #endif