qcsrc/server/weapons/spawning.qc

   1 #include "spawning.qh"
   2
   3 #include "weaponsystem.qh"
   4 #include "../resources.qh"
   5 #include <server/mutators/_mod.qh>
   6 #include <common/t_items.qh>
   7 #include <server/items.qh>
   8 #include <common/weapons/_all.qh>
   9
  10 .bool m_isreplaced; ///< Holds whether the weapon has been replaced.
  11
  12 string W_Apply_Weaponreplace(string in)
  13 {
  14         string out = "";
  15         FOREACH_WORD(in, true, {
  16                 string replacement = "";
  17                 Weapon w = Weapons_fromstr(it);
  18                 if (w)
  19                 {
  20             replacement = w.weaponreplace;
  21             if (replacement == "") replacement = it;
  22                 }
  23                 if (replacement == "0") continue;
  24                 out = cons(out, replacement);
  25         });
  26         return out;
  27 }
  28
  29 void weapon_defaultspawnfunc(entity this, Weapon e)
  30 {
  31         Weapon wpn = e; // TODO unify wpn and e
  32         e = wpn = wpn.m_spawnfunc_hookreplace(wpn, this);
  33         this.classname = wpn.m_canonical_spawnfunc;
  34         if (!Item_IsLoot(this) && !this.m_isreplaced)
  35         {
  36                 if (e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
  37                 {
  38                         LOG_WARNF("Attempted to spawn a mutator-blocked weapon rejected: prvm_edict server %i", this);
  39                         startitem_failed = true;
  40                         return;
  41                 }
  42
  43                 string s = W_Apply_Weaponreplace(e.netname);
  44                 MUTATOR_CALLHOOK(SetWeaponreplace, this, e, s);
  45                 s = M_ARGV(2, string);
  46                 if (s == "")
  47                 {
  48                         delete(this);
  49                         startitem_failed = true;
  50                         return;
  51                 }
  52                 int t = tokenize_console(s);
  53                 if (t >= 2)
  54                 {
  55                         this.team = --internalteam;
  56                         for (int i = 1; i < t; ++i)
  57                         {
  58                                 s = argv(i);
  59                                 Weapon wep = Weapons_fromstr(s);
  60                                 if(wep != WEP_Null)
  61                                 {
  62                                         entity replacement = spawn();
  63                                         copyentity(this, replacement);
  64                                         replacement.m_isreplaced = true;
  65                                         weapon_defaultspawnfunc(replacement, wep);
  66                                 }
  67                         }
  68                 }
  69                 if (t >= 1) // always the case!
  70                 {
  71                         s = argv(0);
  72                         wpn = Weapons_fromstr(s);
  73                 }
  74                 if (wpn == WEP_Null)
  75                 {
  76                         delete(this);
  77                         startitem_failed = true;
  78                         return;
  79                 }
  80         }
  81
  82         if(!Item_IsLoot(this))
  83                 weaponsInMapAll |= WepSet_FromWeapon(wpn);
  84
  85         if (!Item_IsDefinitionAllowed(wpn.m_pickup))
  86         {
  87                 delete(this);
  88                 startitem_failed = true;
  89                 return;
  90         }
  91
  92         if (!this.respawntime)
  93         {
  94                 if (wpn.spawnflags & WEP_FLAG_SUPERWEAPON)
  95                 {
  96                         this.respawntime = g_pickup_respawntime_superweapon;
  97                         this.respawntimejitter = g_pickup_respawntimejitter_superweapon;
  98                 }
  99                 else
 100                 {
 101                         this.respawntime = g_pickup_respawntime_weapon;
 102                         this.respawntimejitter = g_pickup_respawntimejitter_weapon;
 103                 }
 104         }
 105
 106         if (wpn.spawnflags & WEP_FLAG_SUPERWEAPON)
 107                 if (!this.superweapons_finished)
 108                         this.superweapons_finished = autocvar_g_balance_superweapons_time;
 109
 110         // if we don't already have ammo, give us some ammo
 111         if ((wpn.ammo_type != RES_NONE) && !GetResource(this, wpn.ammo_type))
 112         {
 113                 switch (wpn.ammo_type)
 114                 {
 115                         case RES_SHELLS:  SetResource(this, wpn.ammo_type, cvar("g_pickup_shells_weapon"));  break;
 116                         case RES_BULLETS: SetResource(this, wpn.ammo_type, cvar("g_pickup_nails_weapon"));   break;
 117                         case RES_ROCKETS: SetResource(this, wpn.ammo_type, cvar("g_pickup_rockets_weapon")); break;
 118                         case RES_CELLS:   SetResource(this, wpn.ammo_type, cvar("g_pickup_cells_weapon"));   break;
 119                         case RES_PLASMA:  SetResource(this, wpn.ammo_type, cvar("g_pickup_plasma_weapon"));  break;
 120                         case RES_FUEL:    SetResource(this, wpn.ammo_type, cvar("g_pickup_fuel_weapon"));    break;
 121                 }
 122         }
 123
 124         #if 0 // WEAPONTODO
 125         if (wpn.items)
 126         {
 127                 for (int i = 0, j = 1; i < 24; ++i, j <<= 1)
 128                 {
 129                         if (wpn.items & j)
 130                         {
 131                                 ammotype = Item_CounterField(j);
 132                                 if (!this.ammotype)
 133                                         this.ammotype = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
 134                         }
 135                 }
 136         }
 137         #endif
 138
 139         // pickup anyway
 140         if (g_pickup_weapons_anyway)
 141                 this.pickup_anyway = true;
 142
 143         if(!this.owner)
 144                 this.glowmod = wpn.wpcolor;
 145
 146         GameItem def = wpn.m_pickup;
 147         _StartItem(
 148                 this,
 149                 this.itemdef = def,
 150                 this.respawntime, // defaultrespawntime
 151                 this.respawntimejitter // defaultrespawntimejitter
 152         );
 153         #if 0 // WEAPONTODO
 154         if (this.modelindex) { // don't precache if this was removed
 155                 wpn.wr_init(wpn);
 156         }
 157         #endif
 158 }