qcsrc/server/weapons/throwing.qc

   1 #include "throwing.qh"
   2 #include "../_all.qh"
   3
   4 #include "weaponsystem.qh"
   5 #include "../mutators/mutators_include.qh"
   6 #include "../t_items.qh"
   7 #include "../g_damage.qh"
   8 #include "../../common/mapinfo.qh"
   9 #include "../../common/notifications.qh"
  10 #include "../../common/util.qh"
  11 #include "../../common/weapons/all.qh"
  12
  13 void thrown_wep_think()
  14 {SELFPARAM();
  15         self.nextthink = time;
  16         if(self.oldorigin != self.origin)
  17         {
  18                 self.SendFlags |= ISF_LOCATION;
  19                 self.oldorigin = self.origin;
  20         }
  21         self.owner = world;
  22         float timeleft = self.savenextthink - time;
  23         if(timeleft > 1)
  24                 SUB_SetFade(self, self.savenextthink - 1, 1);
  25         else if(timeleft > 0)
  26                 SUB_SetFade(self, time, timeleft);
  27         else
  28                 SUB_VanishOrRemove(self);
  29 }
  30
  31 // returns amount of ammo used as string, or -1 for failure, or 0 for no ammo count
  32 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo)
  33 {SELFPARAM();
  34         float thisammo, i;
  35         string s;
  36         var .int ammotype = (get_weaponinfo(wpn)).ammo_field;
  37
  38         entity wep = spawn();
  39
  40         setorigin(wep, org);
  41         wep.classname = "droppedweapon";
  42         wep.velocity = velo;
  43         wep.owner = wep.enemy = own;
  44         wep.flags |= FL_TOSSED;
  45         wep.colormap = own.colormap;
  46
  47         W_DropEvent(WR_DROP,own,wpn,wep);
  48
  49         if(WepSet_FromWeapon(wpn) & WEPSET_SUPERWEAPONS)
  50         {
  51                 if(own.items & IT_UNLIMITED_SUPERWEAPONS)
  52                 {
  53                         wep.superweapons_finished = time + autocvar_g_balance_superweapons_time;
  54                 }
  55                 else
  56                 {
  57                         float superweapons = 1;
  58                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  59                                 if(WepSet_FromWeapon(i) & WEPSET_SUPERWEAPONS)
  60                                         if(own.weapons & WepSet_FromWeapon(i))
  61                                                 ++superweapons;
  62                         if(superweapons <= 1)
  63                         {
  64                                 wep.superweapons_finished = own.superweapons_finished;
  65                                 own.superweapons_finished = 0;
  66                         }
  67                         else
  68                         {
  69                                 float timeleft = own.superweapons_finished - time;
  70                                 float weptimeleft = timeleft / superweapons;
  71                                 wep.superweapons_finished = time + weptimeleft;
  72                                 own.superweapons_finished -= weptimeleft;
  73                         }
  74                 }
  75         }
  76
  77         WITH(entity, self, wep, weapon_defaultspawnfunc(wpn));
  78         if(startitem_failed)
  79                 return string_null;
  80         wep.glowmod = own.weaponentity_glowmod;
  81         wep.think = thrown_wep_think;
  82         wep.savenextthink = wep.nextthink;
  83         wep.nextthink = min(wep.nextthink, time + 0.5);
  84         wep.pickup_anyway = true; // these are ALWAYS pickable
  85
  86         //wa = W_AmmoItemCode(wpn);
  87         if(ammotype == ammo_none)
  88         {
  89                 return "";
  90         }
  91         else
  92         {
  93                 s = "";
  94
  95                 if(doreduce && g_weapon_stay == 2)
  96                 {
  97                         // if our weapon is loaded, give its load back to the player
  98                         if(self.(weapon_load[self.weapon]) > 0)
  99                         {
 100                                 own.(ammotype) += self.(weapon_load[self.weapon]);
 101                                 self.(weapon_load[self.weapon]) = -1; // schedule the weapon for reloading
 102                         }
 103
 104                         wep.(ammotype) = 0;
 105                 }
 106                 else if(doreduce)
 107                 {
 108                         // if our weapon is loaded, give its load back to the player
 109                         if(self.(weapon_load[self.weapon]) > 0)
 110                         {
 111                                 own.(ammotype) += self.(weapon_load[self.weapon]);
 112                                 self.(weapon_load[self.weapon]) = -1; // schedule the weapon for reloading
 113                         }
 114
 115                         thisammo = min(own.(ammotype), wep.(ammotype));
 116                         wep.(ammotype) = thisammo;
 117                         own.(ammotype) -= thisammo;
 118
 119                         switch(ammotype)
 120                         {
 121                                 case ammo_shells:  s = sprintf("%s and %d shells", s, thisammo);  break;
 122                                 case ammo_nails:   s = sprintf("%s and %d nails", s, thisammo);   break;
 123                                 case ammo_rockets: s = sprintf("%s and %d rockets", s, thisammo); break;
 124                                 case ammo_cells:   s = sprintf("%s and %d cells", s, thisammo);   break;
 125                                 case ammo_plasma:  s = sprintf("%s and %d plasma", s, thisammo);  break;
 126                                 case ammo_fuel:    s = sprintf("%s and %d fuel", s, thisammo);    break;
 127                         }
 128
 129                         s = substring(s, 5, -1);
 130                 }
 131                 return s;
 132         }
 133 }
 134
 135 float W_IsWeaponThrowable(float w)
 136 {
 137         if (!autocvar_g_pickup_items)
 138                 return 0;
 139         if (g_weaponarena)
 140                 return 0;
 141         if (g_cts)
 142                 return 0;
 143         if (g_nexball && w == WEP_MORTAR.m_id)
 144                 return 0;
 145     if(w == 0)
 146         return 0;
 147
 148         #if 0
 149         if(start_weapons & WepSet_FromWeapon(w))
 150         {
 151                 // start weapons that take no ammo can't be dropped (this prevents dropping the laser, as long as it continues to use no ammo)
 152                 if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 153                         return 0;
 154                 if((get_weaponinfo(w)).ammo_field == ammo_none)
 155                         return 0;
 156         }
 157         return 1;
 158         #else
 159         return (get_weaponinfo(w)).weaponthrowable;
 160         #endif
 161 }
 162
 163 // toss current weapon
 164 void W_ThrowWeapon(vector velo, vector delta, float doreduce)
 165 {SELFPARAM();
 166         float w;
 167         string a;
 168
 169         w = self.weapon;
 170         if (w == 0)
 171                 return; // just in case
 172         if(MUTATOR_CALLHOOK(ForbidThrowCurrentWeapon))
 173                 return;
 174         if(!autocvar_g_weapon_throwable)
 175                 return;
 176         if(self.weaponentity.state != WS_READY)
 177                 return;
 178         if(!W_IsWeaponThrowable(w))
 179                 return;
 180
 181         if(!(self.weapons & WepSet_FromWeapon(w)))
 182                 return;
 183         self.weapons &= ~WepSet_FromWeapon(w);
 184
 185         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 186         a = W_ThrowNewWeapon(self, w, doreduce, self.origin + delta, velo);
 187
 188         if(!a) return;
 189         Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_WEAPON_DROP, a, w);
 190 }
 191
 192 void SpawnThrownWeapon(vector org, float w)
 193 {SELFPARAM();
 194         if(self.weapons & WepSet_FromWeapon(self.weapon))
 195                 if(W_IsWeaponThrowable(self.weapon))
 196                         W_ThrowNewWeapon(self, self.weapon, false, org, randomvec() * 125 + '0 0 200');
 197 }