qcsrc/server/weapons/throwing.qc

   1 #include "throwing.qh"
   2
   3 #include "weaponsystem.qh"
   4 #include "../resources.qh"
   5 #include "../mutators/_mod.qh"
   6 #include <common/t_items.qh>
   7 #include "../g_damage.qh"
   8 #include <common/items/item.qh>
   9 #include <common/mapinfo.qh>
  10 #include <common/notifications/all.qh>
  11 #include <common/triggers/subs.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <common/state.qh>
  15 #include <common/wepent.qh>
  16
  17 void thrown_wep_think(entity this)
  18 {
  19         this.nextthink = time;
  20         if(this.oldorigin != this.origin)
  21         {
  22                 this.SendFlags |= ISF_LOCATION;
  23                 this.oldorigin = this.origin;
  24         }
  25         this.owner = NULL;
  26         float timeleft = this.savenextthink - time;
  27         if(timeleft > 1)
  28                 SUB_SetFade(this, this.savenextthink - 1, 1);
  29         else if(timeleft > 0)
  30                 SUB_SetFade(this, time, timeleft);
  31         else
  32                 SUB_VanishOrRemove(this);
  33 }
  34
  35 // returns amount of ammo used as string, or -1 for failure, or 0 for no ammo count
  36 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo, .entity weaponentity)
  37 {
  38         float thisammo;
  39         string s;
  40         Weapon info = Weapons_from(wpn);
  41         int ammotype = info.ammo_type;
  42
  43         entity wep = new(droppedweapon);
  44
  45         setorigin(wep, org);
  46         wep.velocity = velo;
  47         wep.owner = wep.enemy = own;
  48         wep.flags |= FL_TOSSED;
  49         wep.colormap = own.colormap;
  50         wep.glowmod = weaponentity_glowmod(info, own, own.clientcolors, own.(weaponentity));
  51         navigation_dynamicgoal_init(wep, false);
  52
  53         W_DropEvent(wr_drop,own,wpn,wep,weaponentity);
  54
  55         if(WepSet_FromWeapon(Weapons_from(wpn)) & WEPSET_SUPERWEAPONS)
  56         {
  57                 if(own.items & IT_UNLIMITED_SUPERWEAPONS)
  58                 {
  59                         wep.superweapons_finished = time + autocvar_g_balance_superweapons_time;
  60                 }
  61                 else
  62                 {
  63                         int superweapons = 1;
  64                         FOREACH(Weapons, it != WEP_Null, {
  65                                 WepSet set = it.m_wepset;
  66                                 if((set & WEPSET_SUPERWEAPONS) && (own.weapons & set)) ++superweapons;
  67                         });
  68                         if(superweapons <= 1)
  69                         {
  70                                 wep.superweapons_finished = own.superweapons_finished;
  71                                 own.superweapons_finished = 0;
  72                         }
  73                         else
  74                         {
  75                                 float timeleft = own.superweapons_finished - time;
  76                                 float weptimeleft = timeleft / superweapons;
  77                                 wep.superweapons_finished = time + weptimeleft;
  78                                 own.superweapons_finished -= weptimeleft;
  79                         }
  80                 }
  81         }
  82
  83         weapon_defaultspawnfunc(wep, info);
  84         if(startitem_failed)
  85                 return string_null;
  86         setthink(wep, thrown_wep_think);
  87         wep.savenextthink = wep.nextthink;
  88         wep.nextthink = min(wep.nextthink, time + 0.5);
  89         wep.pickup_anyway = true; // these are ALWAYS pickable
  90
  91         //wa = W_AmmoItemCode(wpn);
  92         if(ammotype == RESOURCE_NONE)
  93         {
  94                 return "";
  95         }
  96         else
  97         {
  98                 s = "";
  99
 100                 if(doreduce && g_weapon_stay == 2)
 101                 {
 102                         // if our weapon is loaded, give its load back to the player
 103                         int i = own.(weaponentity).m_weapon.m_id;
 104                         if(own.(weaponentity).(weapon_load[i]) > 0)
 105                         {
 106                                 GiveResource(own, ammotype, own.(weaponentity).(weapon_load[i]));
 107                                 own.(weaponentity).(weapon_load[i]) = -1; // schedule the weapon for reloading
 108                         }
 109                         SetResourceAmount(wep, ammotype, 0);
 110                 }
 111                 else if(doreduce)
 112                 {
 113                         // if our weapon is loaded, give its load back to the player
 114                         int i = own.(weaponentity).m_weapon.m_id;
 115                         if(own.(weaponentity).(weapon_load[i]) > 0)
 116                         {
 117                                 GiveResource(own, ammotype, own.(weaponentity).(weapon_load[i]));
 118                                 own.(weaponentity).(weapon_load[i]) = -1; // schedule the weapon for reloading
 119                         }
 120
 121                         float ownderammo = GetResourceAmount(own, ammotype);
 122                         thisammo = min(ownderammo, GetResourceAmount(wep, ammotype));
 123                         SetResourceAmount(wep, ammotype, thisammo);
 124                         SetResourceAmount(own, ammotype, ownderammo - thisammo);
 125
 126                         switch (ammotype)
 127                         {
 128                                 case RESOURCE_SHELLS:  s = sprintf("%s and %d shells", s, thisammo);  break;
 129                                 case RESOURCE_BULLETS: s = sprintf("%s and %d nails", s, thisammo);   break;
 130                                 case RESOURCE_ROCKETS: s = sprintf("%s and %d rockets", s, thisammo); break;
 131                                 case RESOURCE_CELLS:   s = sprintf("%s and %d cells", s, thisammo);   break;
 132                                 case RESOURCE_PLASMA:  s = sprintf("%s and %d plasma", s, thisammo);  break;
 133                                 case RESOURCE_FUEL:    s = sprintf("%s and %d fuel", s, thisammo);    break;
 134                         }
 135
 136                         s = substring(s, 5, -1);
 137                 }
 138                 return s;
 139         }
 140 }
 141
 142 bool W_IsWeaponThrowable(entity this, int w)
 143 {
 144         if (MUTATOR_CALLHOOK(ForbidDropCurrentWeapon, this, w))
 145                 return false;
 146         if (!autocvar_g_pickup_items)
 147                 return false;
 148         if (g_weaponarena)
 149                 return 0;
 150     if(w == WEP_Null.m_id)
 151         return false;
 152
 153         #if 0
 154         if(start_weapons & WepSet_FromWeapon(Weapons_from(w)))
 155         {
 156                 // start weapons that take no ammo can't be dropped (this prevents dropping the laser, as long as it continues to use no ammo)
 157                 if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 158                         return false;
 159                 if((Weapons_from(w)).ammo_type == RESOURCE_NONE)
 160                         return false;
 161         }
 162         return true;
 163         #else
 164         return (Weapons_from(w)).weaponthrowable;
 165         #endif
 166 }
 167
 168 // toss current weapon
 169 void W_ThrowWeapon(entity this, .entity weaponentity, vector velo, vector delta, float doreduce)
 170 {
 171         Weapon w = this.(weaponentity).m_weapon;
 172         if (w == WEP_Null)
 173                 return; // just in case
 174         if(MUTATOR_CALLHOOK(ForbidThrowCurrentWeapon, this, this.(weaponentity)))
 175                 return;
 176         if(!autocvar_g_weapon_throwable)
 177                 return;
 178         if(this.(weaponentity).state != WS_READY)
 179                 return;
 180         if(!W_IsWeaponThrowable(this, w.m_id))
 181                 return;
 182
 183         WepSet set = WepSet_FromWeapon(w);
 184         if(!(this.weapons & set)) return;
 185         this.weapons &= ~set;
 186
 187         W_SwitchWeapon_Force(this, w_getbestweapon(this, weaponentity), weaponentity);
 188         string a = W_ThrowNewWeapon(this, w.m_id, doreduce, this.origin + delta, velo, weaponentity);
 189
 190         if(!a) return;
 191         Send_Notification(NOTIF_ONE, this, MSG_MULTI, ITEM_WEAPON_DROP, a, w.m_id);
 192 }
 193
 194 void SpawnThrownWeapon(entity this, vector org, Weapon wep, .entity weaponentity)
 195 {
 196         //entity wep = this.(weaponentity).m_weapon;
 197
 198         if(this.weapons & WepSet_FromWeapon(wep))
 199                 if(W_IsWeaponThrowable(this, wep.m_id))
 200                         W_ThrowNewWeapon(this, wep.m_id, false, org, randomvec() * 125 + '0 0 200', weaponentity);
 201 }