Merge branch 'master' into Mario/wepent_experimental
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / weapons / tracing.qc
1 #include "tracing.qh"
2
3 #include "accuracy.qh"
4 #include "common.qh"
5 #include "hitplot.qh"
6 #include "weaponsystem.qh"
7
8 #include "../g_damage.qh"
9 #include "../g_subs.qh"
10 #include "../antilag.qh"
11
12 #include <common/constants.qh>
13 #include <common/net_linked.qh>
14 #include <common/util.qh>
15
16 #include <common/weapons/_all.qh>
17 #include <common/state.qh>
18
19 #include <lib/warpzone/common.qh>
20
21 // this function calculates w_shotorg and w_shotdir based on the weapon model
22 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
23 // make sure you call makevectors first (FIXME?)
24 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, .entity weaponentity, vector s_forward, vector mi, vector ma, float antilag, float recoil, Sound snd, float chan, float maxdamage, float range)
25 {
26         TC(Sound, snd);
27         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
28         float oldsolid;
29         vector vecs, dv;
30         oldsolid = ent.dphitcontentsmask;
31         if (IS_PLAYER(ent) && ent.(weaponentity).m_weapon == WEP_RIFLE)
32                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
33         else
34                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
35         if(antilag)
36                 WarpZone_traceline_antilag(NULL, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
37                 // passing NULL, because we do NOT want it to touch dphitcontentsmask
38         else
39                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
40         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
41
42         vector vf, vr, vu;
43         vf = v_forward;
44         vr = v_right;
45         vu = v_up;
46         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
47         v_forward = vf;
48         v_right = vr;
49         v_up = vu;
50
51         // un-adjust trueaim if shotend is too close
52         if(vdist(w_shotend - (ent.origin + ent.view_ofs), <, autocvar_g_trueaim_minrange))
53                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
54
55         // track max damage
56         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
57                 accuracy_add(ent, ent.(weaponentity).m_weapon.m_id, maxdamage, 0);
58
59         if(IS_PLAYER(ent))
60                 W_HitPlotAnalysis(ent, weaponentity, v_forward, v_right, v_up);
61
62         vector md = ent.(weaponentity).movedir;
63         if(md.x > 0)
64                 vecs = md;
65         else
66                 vecs = '0 0 0';
67
68         dv = v_right * -vecs.y + v_up * vecs.z;
69         w_shotorg = ent.origin + ent.view_ofs + dv;
70
71         // now move the shotorg forward as much as requested if possible
72         if(antilag)
73         {
74                 if(CS(ent).antilag_debug)
75                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, CS(ent).antilag_debug);
76                 else
77                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
78         }
79         else
80                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent);
81         w_shotorg = trace_endpos - v_forward * nudge;
82         // calculate the shotdir from the chosen shotorg
83         w_shotdir = normalize(w_shotend - w_shotorg);
84
85         //vector prevdir = w_shotdir;
86         //vector prevorg = w_shotorg;
87         //vector prevend = w_shotend;
88
89         if (antilag)
90         if (!ent.cvar_cl_noantilag)
91         {
92                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
93                 {
94                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
95                         if (!trace_ent.takedamage)
96                         {
97                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
98                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
99                                 {
100                                         entity e;
101                                         e = trace_ent;
102                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
103                                         if(trace_ent == e)
104                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
105                                 }
106                         }
107                 }
108                 else if(autocvar_g_antilag == 3) // client side hitscan
109                 {
110                         // this part MUST use prydon cursor
111                         if (ent.cursor_trace_ent)                 // client was aiming at someone
112                         if (ent.cursor_trace_ent != ent)         // just to make sure
113                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
114                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
115                         {
116                                 // verify that the shot would miss without antilag
117                                 // (avoids an issue where guns would always shoot at their origin)
118                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
119                                 if (!trace_ent.takedamage)
120                                 {
121                                         // verify that the shot would hit if altered
122                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
123                                         if (trace_ent == ent.cursor_trace_ent)
124                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
125                                         else
126                                                 LOG_INFO("antilag fail\n");
127                                 }
128                         }
129                 }
130         }
131
132         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
133
134         if (!autocvar_g_norecoil)
135                 ent.punchangle_x = recoil * -1;
136
137         if (snd != SND_Null) {
138                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
139                 W_PlayStrengthSound(ent);
140         }
141
142         // nudge w_shotend so a trace to w_shotend hits
143         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
144         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
145         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
146         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
147 }
148
149 vector W_CalculateProjectileVelocity(entity actor, vector pvelocity, vector mvelocity, float forceAbsolute)
150 {
151         vector mdirection;
152         float mspeed;
153         vector outvelocity;
154
155         mvelocity = mvelocity * W_WeaponSpeedFactor(actor);
156
157         mdirection = normalize(mvelocity);
158         mspeed = vlen(mvelocity);
159
160         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
161
162         return outvelocity;
163 }
164
165 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
166 {
167         if(proj.owner == NULL)
168                 error("Unowned missile");
169
170         dir = dir + upDir * (pUpSpeed / pSpeed);
171         dir.z += pZSpeed / pSpeed;
172         pSpeed *= vlen(dir);
173         dir = normalize(dir);
174
175         #if 0
176         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
177         {
178                 mspercallsum = mspercallcount = 0;
179                 mspercallsstyle = autocvar_g_projectiles_spread_style;
180         }
181         mspercallsum -= gettime(GETTIME_HIRES);
182         #endif
183
184         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
185
186         #if 0
187         mspercallsum += gettime(GETTIME_HIRES);
188         mspercallcount += 1;
189         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
190         #endif
191
192         proj.velocity = W_CalculateProjectileVelocity(proj.owner, proj.owner.velocity, pSpeed * dir, forceAbsolute);
193 }
194
195
196 // ====================
197 //  Ballistics Tracing
198 // ====================
199
200 void FireRailgunBullet (entity this, .entity weaponentity, vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
201 {
202         vector hitloc, force, endpoint, dir;
203         entity ent, endent;
204         float endq3surfaceflags;
205         float totaldmg;
206         entity o;
207
208         float length;
209         vector beampos;
210         string snd;
211         entity pseudoprojectile;
212         float f, ffs;
213
214         pseudoprojectile = NULL;
215
216         dir = normalize(end - start);
217         length = vlen(end - start);
218         force = dir * bforce;
219
220         // go a little bit into the wall because we need to hit this wall later
221         end = end + dir;
222
223         totaldmg = 0;
224
225         // trace multiple times until we hit a wall, each obstacle will be made
226         // non-solid so we can hit the next, while doing this we spawn effects and
227         // note down which entities were hit so we can damage them later
228         o = this;
229         while (1)
230         {
231                 if(CS(this).antilag_debug)
232                         WarpZone_traceline_antilag (this, start, end, false, o, CS(this).antilag_debug);
233                 else
234                         WarpZone_traceline_antilag (this, start, end, false, o, ANTILAG_LATENCY(this));
235                 if(o && WarpZone_trace_firstzone)
236                 {
237                         o = NULL;
238                         continue;
239                 }
240
241                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
242                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, this);
243
244                 // if it is NULL we can't hurt it so stop now
245                 if (trace_ent == NULL || trace_fraction == 1)
246                         break;
247
248                 // make the entity non-solid so we can hit the next one
249                 trace_ent.railgunhit = true;
250                 trace_ent.railgunhitloc = end;
251                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
252                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
253                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
254
255                 // stop if this is a wall
256                 if (trace_ent.solid == SOLID_BSP)
257                         break;
258
259                 // make the entity non-solid
260                 trace_ent.solid = SOLID_NOT;
261         }
262
263         endpoint = trace_endpos;
264         endent = trace_ent;
265         endq3surfaceflags = trace_dphitq3surfaceflags;
266
267         // find all the entities the railgun hit and restore their solid state
268         ent = findfloat(NULL, railgunhit, true);
269         while (ent)
270         {
271                 // restore their solid type
272                 ent.solid = ent.railgunhitsolidbackup;
273                 ent = findfloat(ent, railgunhit, true);
274         }
275
276         // spawn a temporary explosion entity for RadiusDamage calls
277         //explosion = spawn();
278
279         // Find all non-hit players the beam passed close by
280         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id)
281         {
282                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != this, LAMBDA(
283                         if(!it.railgunhit)
284                         if(!(IS_SPEC(it) && it.enemy == this))
285                         {
286                                 msg_entity = it;
287                                 // nearest point on the beam
288                                 beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
289
290                                 f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
291                                 if(f <= 0)
292                                         continue;
293
294                                 snd = SND(NEXWHOOSH_RANDOM());
295
296                                 if(!pseudoprojectile)
297                                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
298                                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, snd, VOL_BASE * f, ATTEN_NONE);
299                         }
300                 ));
301
302                 if(pseudoprojectile)
303                         delete(pseudoprojectile);
304         }
305
306         // find all the entities the railgun hit and hurt them
307         ent = findfloat(NULL, railgunhit, true);
308         while (ent)
309         {
310                 // get the details we need to call the damage function
311                 hitloc = ent.railgunhitloc;
312
313                 f = ExponentialFalloff(mindist, maxdist, halflifedist, ent.railgundistance);
314                 ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, ent.railgundistance);
315
316                 if(accuracy_isgooddamage(this, ent))
317                         totaldmg += bdamage * f;
318
319                 // apply the damage
320                 if (ent.takedamage)
321                         Damage (ent, this, this, bdamage * f, deathtype, hitloc, ent.railgunforce * ffs);
322
323                 // create a small explosion to throw gibs around (if applicable)
324                 //setorigin(explosion, hitloc);
325                 //RadiusDamage (explosion, this, 10, 0, 50, NULL, NULL, 300, deathtype);
326
327                 ent.railgunhitloc = '0 0 0';
328                 ent.railgunhitsolidbackup = SOLID_NOT;
329                 ent.railgunhit = false;
330                 ent.railgundistance = 0;
331
332                 // advance to the next entity
333                 ent = findfloat(ent, railgunhit, true);
334         }
335
336         // calculate hits and fired shots for hitscan
337         accuracy_add(this, this.(weaponentity).m_weapon.m_id, 0, min(bdamage, totaldmg));
338
339         trace_endpos = endpoint;
340         trace_ent = endent;
341         trace_dphitq3surfaceflags = endq3surfaceflags;
342 }
343
344 void fireBullet_trace_callback(vector start, vector hit, vector end)
345 {
346         if(vdist(hit - start, >, 16))
347                 trailparticles(NULL, fireBullet_trace_callback_eff, start, hit);
348         WarpZone_trace_forent = NULL;
349         fireBullet_last_hit = NULL;
350 }
351
352 void fireBullet(entity this, .entity weaponentity, vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, int tracereffects)
353 {
354         vector  end;
355
356         dir = normalize(dir + randomvec() * spread);
357         end = start + dir * MAX_SHOT_DISTANCE;
358
359         fireBullet_last_hit = NULL;
360         float solid_penetration_left = 1;
361         float total_damage = 0;
362
363         if(tracereffects & EF_RED)
364                 fireBullet_trace_callback_eff = EFFECT_RIFLE;
365         else if(tracereffects & EF_BLUE)
366                 fireBullet_trace_callback_eff = EFFECT_RIFLE_WEAK;
367         else
368                 fireBullet_trace_callback_eff = EFFECT_BULLET;
369
370         float lag = ANTILAG_LATENCY(this);
371         if(lag < 0.001)
372                 lag = 0;
373         if (!IS_REAL_CLIENT(this))
374                 lag = 0;
375         if(autocvar_g_antilag == 0 || this.cvar_cl_noantilag)
376                 lag = 0; // only do hitscan, but no antilag
377         if(lag)
378         {
379                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, antilag_takeback(it, CS(it), time - lag));
380                 IL_EACH(g_monsters, it != this,
381                 {
382                         antilag_takeback(it, it, time - lag);
383                 });
384         }
385
386         // change shooter to SOLID_BBOX so the shot can hit corpses
387         int oldsolid = this.dphitcontentsmask;
388         if(this)
389                 this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
390
391         WarpZone_trace_forent = this;
392
393         for (;;)
394         {
395                 // TODO also show effect while tracing
396                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, NULL, fireBullet_trace_callback);
397                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
398                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
399                 start = trace_endpos;
400                 entity hit = trace_ent;
401
402                 // When hitting sky, stop.
403                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
404                         break;
405
406                 // can't use noimpact, as we need to pass through walls
407                 //if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
408                         //break;
409
410                 // if we hit "weapclip", bail out
411                 //
412                 // rationale of this check:
413                 //
414                 // any shader that is solid, nodraw AND trans is meant to clip weapon
415                 // shots and players, but has no other effect!
416                 //
417                 // if it is not trans, it is caulk and should not have this side effect
418                 //
419                 // matching shaders:
420                 //   common/weapclip (intended)
421                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
422                 bool is_weapclip = false;
423                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
424                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
425                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
426                         is_weapclip = true;
427
428                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
429                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, this);
430
431                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
432                 {
433                         fireBullet_last_hit = hit;
434                         yoda = 0;
435                         MUTATOR_CALLHOOK(FireBullet_Hit, this, hit, start, end, damage);
436                         damage = M_ARGV(4, float);
437                         float g = accuracy_isgooddamage(this, hit);
438                         Damage(hit, this, this, damage * solid_penetration_left, dtype, start, force * dir * solid_penetration_left);
439                         // calculate hits for ballistic weapons
440                         if(g)
441                         {
442                                 // do not exceed 100%
443                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
444                                 total_damage += damage * solid_penetration_left;
445                                 accuracy_add(this, this.(weaponentity).m_weapon.m_id, 0, added_damage);
446                         }
447                 }
448
449                 if (is_weapclip && !autocvar_g_ballistics_penetrate_clips)
450                         break;
451
452                 // go through solid!
453                 // outside the world? forget it
454                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
455                         break;
456
457                 float maxdist;
458                 if(max_solid_penetration < 0)
459                         break;
460                 else if(hit.ballistics_density < -1)
461                         break; // -2: no solid penetration, ever
462                 else if(hit.ballistics_density < 0)
463                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
464                 else if(hit.ballistics_density == 0)
465                         maxdist = max_solid_penetration * solid_penetration_left;
466                 else
467                         maxdist = max_solid_penetration * solid_penetration_left * hit.ballistics_density;
468
469                 if(maxdist <= autocvar_g_ballistics_mindistance)
470                         break;
471
472                 // move the entity along its velocity until it's out of solid, then let it resume
473                 // The previously hit entity is ignored here!
474                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
475                 if(trace_fraction == 1) // 1: we never got out of solid
476                         break;
477
478                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
479                 // fraction_used_of_what_is_left = dist_taken / maxdist
480                 // solid_penetration_left = solid_penetration_left - solid_penetration_left * fraction_used_of_what_is_left
481                 solid_penetration_left *= 1 - dist_taken / maxdist;
482                 solid_penetration_left = max(solid_penetration_left, 0);
483
484                 // Only show effect when going through a player (invisible otherwise)
485                 if (hit && (hit.solid != SOLID_BSP))
486                         if(vdist(trace_endpos - start, >, 4))
487                                 trailparticles(this, fireBullet_trace_callback_eff, start, trace_endpos);
488
489                 start = trace_endpos;
490
491                 if(hit.solid == SOLID_BSP)
492                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, this);
493         }
494
495         if(lag)
496         {
497                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, antilag_restore(it, CS(it)));
498                 IL_EACH(g_monsters, it != this,
499                 {
500                         antilag_restore(it, it);
501                 });
502         }
503
504         // restore shooter solid type
505         if(this)
506                 this.dphitcontentsmask = oldsolid;
507 }