31d72f821f0e5ba8822f00638b77ccf60d27a2da
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / weapons / tracing.qc
1 #include "tracing.qh"
2
3 #include "accuracy.qh"
4 #include "common.qh"
5 #include "hitplot.qh"
6 #include "weaponsystem.qh"
7
8 #include "../g_damage.qh"
9 #include "../g_subs.qh"
10 #include "../antilag.qh"
11
12 #include "../../common/constants.qh"
13 #include "../../common/util.qh"
14
15 #include "../../common/weapons/all.qh"
16
17 #include "../../lib/warpzone/common.qh"
18
19 // this function calculates w_shotorg and w_shotdir based on the weapon model
20 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
21 // make sure you call makevectors first (FIXME?)
22 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
23 {
24         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
25         float oldsolid;
26         vector vecs, dv;
27         oldsolid = ent.dphitcontentsmask;
28         if (IS_PLAYER(ent) && PS(ent).m_weapon == WEP_RIFLE)
29                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
30         else
31                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
32         if(antilag)
33                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
34                 // passing world, because we do NOT want it to touch dphitcontentsmask
35         else
36                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
37         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
38
39         vector vf, vr, vu;
40         vf = v_forward;
41         vr = v_right;
42         vu = v_up;
43         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
44         v_forward = vf;
45         v_right = vr;
46         v_up = vu;
47
48         // un-adjust trueaim if shotend is too close
49         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
50                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
51
52         // track max damage
53         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
54                 accuracy_add(ent, PS(ent).m_weapon.m_id, maxdamage, 0);
55
56         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
57
58         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
59         vector md = ent.(weaponentity).movedir;
60         if(md.x > 0)
61                 vecs = md;
62         else
63                 vecs = '0 0 0';
64
65         dv = v_right * -vecs.y + v_up * vecs.z;
66         w_shotorg = ent.origin + ent.view_ofs + dv;
67
68         // now move the shotorg forward as much as requested if possible
69         if(antilag)
70         {
71                 if(ent.antilag_debug)
72                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
73                 else
74                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
75         }
76         else
77                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent);
78         w_shotorg = trace_endpos - v_forward * nudge;
79         // calculate the shotdir from the chosen shotorg
80         w_shotdir = normalize(w_shotend - w_shotorg);
81
82         //vector prevdir = w_shotdir;
83         //vector prevorg = w_shotorg;
84         //vector prevend = w_shotend;
85
86         if (antilag)
87         if (!ent.cvar_cl_noantilag)
88         {
89                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
90                 {
91                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
92                         if (!trace_ent.takedamage)
93                         {
94                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
95                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
96                                 {
97                                         entity e;
98                                         e = trace_ent;
99                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
100                                         if(trace_ent == e)
101                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
102                                 }
103                         }
104                 }
105                 else if(autocvar_g_antilag == 3) // client side hitscan
106                 {
107                         // this part MUST use prydon cursor
108                         if (ent.cursor_trace_ent)                 // client was aiming at someone
109                         if (ent.cursor_trace_ent != ent)         // just to make sure
110                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
111                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
112                         {
113                                 // verify that the shot would miss without antilag
114                                 // (avoids an issue where guns would always shoot at their origin)
115                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
116                                 if (!trace_ent.takedamage)
117                                 {
118                                         // verify that the shot would hit if altered
119                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
120                                         if (trace_ent == ent.cursor_trace_ent)
121                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
122                                         else
123                                                 LOG_INFO("antilag fail\n");
124                                 }
125                         }
126                 }
127         }
128
129         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
130
131         if (!autocvar_g_norecoil)
132                 ent.punchangle_x = recoil * -1;
133
134         if (snd != "")
135         {
136                 _sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
137                 W_PlayStrengthSound(ent);
138         }
139
140         // nudge w_shotend so a trace to w_shotend hits
141         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
142         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
143         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
144         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
145 }
146
147 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
148 {
149         vector mdirection;
150         float mspeed;
151         vector outvelocity;
152
153         mvelocity = mvelocity * W_WeaponSpeedFactor();
154
155         mdirection = normalize(mvelocity);
156         mspeed = vlen(mvelocity);
157
158         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
159
160         return outvelocity;
161 }
162
163 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
164 {
165         if(proj.owner == world)
166                 error("Unowned missile");
167
168         dir = dir + upDir * (pUpSpeed / pSpeed);
169         dir.z += pZSpeed / pSpeed;
170         pSpeed *= vlen(dir);
171         dir = normalize(dir);
172
173         #if 0
174         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
175         {
176                 mspercallsum = mspercallcount = 0;
177                 mspercallsstyle = autocvar_g_projectiles_spread_style;
178         }
179         mspercallsum -= gettime(GETTIME_HIRES);
180         #endif
181
182         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
183
184         #if 0
185         mspercallsum += gettime(GETTIME_HIRES);
186         mspercallcount += 1;
187         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
188         #endif
189
190         proj.velocity = W_CalculateProjectileVelocity(proj.owner.velocity, pSpeed * dir, forceAbsolute);
191 }
192
193
194 // ====================
195 //  Ballistics Tracing
196 // ====================
197
198 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
199 {SELFPARAM();
200         vector hitloc, force, endpoint, dir;
201         entity ent, endent;
202         float endq3surfaceflags;
203         float totaldmg;
204         entity o;
205
206         float length;
207         vector beampos;
208         string snd;
209         entity pseudoprojectile;
210         float f, ffs;
211
212         pseudoprojectile = world;
213
214         dir = normalize(end - start);
215         length = vlen(end - start);
216         force = dir * bforce;
217
218         // go a little bit into the wall because we need to hit this wall later
219         end = end + dir;
220
221         totaldmg = 0;
222
223         // trace multiple times until we hit a wall, each obstacle will be made
224         // non-solid so we can hit the next, while doing this we spawn effects and
225         // note down which entities were hit so we can damage them later
226         o = self;
227         while (1)
228         {
229                 if(self.antilag_debug)
230                         WarpZone_traceline_antilag (self, start, end, false, o, self.antilag_debug);
231                 else
232                         WarpZone_traceline_antilag (self, start, end, false, o, ANTILAG_LATENCY(self));
233                 if(o && WarpZone_trace_firstzone)
234                 {
235                         o = world;
236                         continue;
237                 }
238
239                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
240                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, self);
241
242                 // if it is world we can't hurt it so stop now
243                 if (trace_ent == world || trace_fraction == 1)
244                         break;
245
246                 // make the entity non-solid so we can hit the next one
247                 trace_ent.railgunhit = true;
248                 trace_ent.railgunhitloc = end;
249                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
250                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
251                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
252
253                 // stop if this is a wall
254                 if (trace_ent.solid == SOLID_BSP)
255                         break;
256
257                 // make the entity non-solid
258                 trace_ent.solid = SOLID_NOT;
259         }
260
261         endpoint = trace_endpos;
262         endent = trace_ent;
263         endq3surfaceflags = trace_dphitq3surfaceflags;
264
265         // find all the entities the railgun hit and restore their solid state
266         ent = findfloat(world, railgunhit, true);
267         while (ent)
268         {
269                 // restore their solid type
270                 ent.solid = ent.railgunhitsolidbackup;
271                 ent = findfloat(ent, railgunhit, true);
272         }
273
274         // spawn a temporary explosion entity for RadiusDamage calls
275         //explosion = spawn();
276
277         // Find all non-hit players the beam passed close by
278         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id)
279         {
280                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != self, LAMBDA(
281                         if(!it.railgunhit)
282                         if(!(IS_SPEC(it) && it.enemy == self))
283                         {
284                                 msg_entity = it;
285                                 // nearest point on the beam
286                                 beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
287
288                                 f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
289                                 if(f <= 0)
290                                         continue;
291
292                                 snd = SND(NEXWHOOSH_RANDOM());
293
294                                 if(!pseudoprojectile)
295                                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
296                                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, snd, VOL_BASE * f, ATTEN_NONE);
297                         }
298                 ));
299
300                 if(pseudoprojectile)
301                         remove(pseudoprojectile);
302         }
303
304         // find all the entities the railgun hit and hurt them
305         ent = findfloat(world, railgunhit, true);
306         while (ent)
307         {
308                 // get the details we need to call the damage function
309                 hitloc = ent.railgunhitloc;
310
311                 f = ExponentialFalloff(mindist, maxdist, halflifedist, ent.railgundistance);
312                 ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, ent.railgundistance);
313
314                 if(accuracy_isgooddamage(self, ent))
315                         totaldmg += bdamage * f;
316
317                 // apply the damage
318                 if (ent.takedamage)
319                         Damage (ent, self, self, bdamage * f, deathtype, hitloc, ent.railgunforce * ffs);
320
321                 // create a small explosion to throw gibs around (if applicable)
322                 //setorigin (explosion, hitloc);
323                 //RadiusDamage (explosion, self, 10, 0, 50, world, world, 300, deathtype);
324
325                 ent.railgunhitloc = '0 0 0';
326                 ent.railgunhitsolidbackup = SOLID_NOT;
327                 ent.railgunhit = false;
328                 ent.railgundistance = 0;
329
330                 // advance to the next entity
331                 ent = findfloat(ent, railgunhit, true);
332         }
333
334         // calculate hits and fired shots for hitscan
335         accuracy_add(self, PS(self).m_weapon.m_id, 0, min(bdamage, totaldmg));
336
337         trace_endpos = endpoint;
338         trace_ent = endent;
339         trace_dphitq3surfaceflags = endq3surfaceflags;
340 }
341
342 void fireBullet_trace_callback(vector start, vector hit, vector end)
343 {
344         if(vlen(hit - start) > 16)
345                 trailparticles(world, fireBullet_trace_callback_eff, start, hit);
346         WarpZone_trace_forent = world;
347         fireBullet_last_hit = world;
348 }
349
350 void fireBullet(vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, int tracereffects)
351 {SELFPARAM();
352         vector  end;
353
354         dir = normalize(dir + randomvec() * spread);
355         end = start + dir * MAX_SHOT_DISTANCE;
356
357         fireBullet_last_hit = world;
358         float solid_penetration_left = 1;
359         float total_damage = 0;
360
361         if(tracereffects & EF_RED)
362                 fireBullet_trace_callback_eff = EFFECT_RIFLE;
363         else if(tracereffects & EF_BLUE)
364                 fireBullet_trace_callback_eff = EFFECT_RIFLE_WEAK;
365         else
366                 fireBullet_trace_callback_eff = EFFECT_BULLET;
367
368         float lag = ANTILAG_LATENCY(self);
369         if(lag < 0.001)
370                 lag = 0;
371         if (!IS_REAL_CLIENT(self))
372                 lag = 0;
373         if(autocvar_g_antilag == 0 || self.cvar_cl_noantilag)
374                 lag = 0; // only do hitscan, but no antilag
375         if(lag)
376         {
377                 FOREACH_CLIENT(IS_PLAYER(it) && it != self, LAMBDA(antilag_takeback(it, time - lag)));
378                 FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
379                         if(it != self)
380                                 antilag_takeback(it, time - lag);
381                 ));
382         }
383
384         WarpZone_trace_forent = self;
385
386         for (;;)
387         {
388                 // TODO also show effect while tracing
389                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, world, fireBullet_trace_callback);
390                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
391                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
392                 start = trace_endpos;
393                 entity hit = trace_ent;
394
395                 // When hitting sky, stop.
396                 if (pointcontents(start) == CONTENT_SKY)
397                         break;
398
399                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
400                         break;
401
402                 // if we hit "weapclip", bail out
403                 //
404                 // rationale of this check:
405                 //
406                 // any shader that is solid, nodraw AND trans is meant to clip weapon
407                 // shots and players, but has no other effect!
408                 //
409                 // if it is not trans, it is caulk and should not have this side effect
410                 //
411                 // matching shaders:
412                 //   common/weapclip (intended)
413                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
414                 float is_weapclip = 0;
415                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
416                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
417                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
418                         is_weapclip = 1;
419
420                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
421                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, self);
422
423                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
424                 {
425                         fireBullet_last_hit = hit;
426                         yoda = 0;
427                         MUTATOR_CALLHOOK(FireBullet_Hit, self, hit, start, end, damage);
428                         damage = frag_damage;
429                         float g = accuracy_isgooddamage(self, hit);
430                         Damage(hit, self, self, damage * solid_penetration_left, dtype, start, force * dir * solid_penetration_left);
431                         // calculate hits for ballistic weapons
432                         if(g)
433                         {
434                                 // do not exceed 100%
435                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
436                                 total_damage += damage * solid_penetration_left;
437                                 accuracy_add(self, PS(self).m_weapon.m_id, 0, added_damage);
438                         }
439                 }
440
441                 if (is_weapclip)
442                         break;
443
444                 // go through solid!
445                 // outside the world? forget it
446                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
447                         break;
448
449                 float maxdist;
450                 if(max_solid_penetration < 0)
451                         break;
452                 else if(hit.ballistics_density < -1)
453                         break; // -2: no solid penetration, ever
454                 else if(hit.ballistics_density < 0)
455                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
456                 else if(hit.ballistics_density == 0)
457                         maxdist = max_solid_penetration * solid_penetration_left;
458                 else
459                         maxdist = max_solid_penetration * solid_penetration_left * hit.ballistics_density;
460
461                 if(maxdist <= autocvar_g_ballistics_mindistance)
462                         break;
463
464                 // move the entity along its velocity until it's out of solid, then let it resume
465                 // The previously hit entity is ignored here!
466                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
467                 if(trace_fraction == 1) // 1: we never got out of solid
468                         break;
469
470                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
471                 solid_penetration_left *= (dist_taken / maxdist);
472
473                 // Only show effect when going through a player (invisible otherwise)
474                 if (hit && (hit.solid != SOLID_BSP))
475                         if(vlen(trace_endpos - start) > 4)
476                                 trailparticles(self, fireBullet_trace_callback_eff, start, trace_endpos);
477
478                 start = trace_endpos;
479
480                 if(hit.solid == SOLID_BSP)
481                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, self);
482         }
483
484         if(lag)
485         {
486                 FOREACH_CLIENT(IS_PLAYER(it) && it != self, LAMBDA(antilag_restore(it)));
487                 FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
488                         if(it != self)
489                                 antilag_restore(it);
490                 ));
491         }
492 }