qcsrc/server/weapons/tracing.qc

   1 // this function calculates w_shotorg and w_shotdir based on the weapon model
   2 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
   3 // make sure you call makevectors first (FIXME?)
   4 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
   5 {
   6         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
   7         float oldsolid;
   8         vector vecs, dv;
   9         oldsolid = ent.dphitcontentsmask;
  10         if(ent.weapon == WEP_RIFLE)
  11                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  12         else
  13                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  14         if(antilag)
  15                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  16                 // passing world, because we do NOT want it to touch dphitcontentsmask
  17         else
  18                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  19         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  20
  21         vector vf, vr, vu;
  22         vf = v_forward;
  23         vr = v_right;
  24         vu = v_up;
  25         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  26         v_forward = vf;
  27         v_right = vr;
  28         v_up = vu;
  29
  30         // un-adjust trueaim if shotend is too close
  31         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
  32                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  33
  34         // track max damage
  35         if(accuracy_canbegooddamage(ent))
  36                 accuracy_add(ent, ent.weapon, maxdamage, 0);
  37
  38         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
  39
  40         if(ent.weaponentity.movedir_x > 0)
  41                 vecs = ent.weaponentity.movedir;
  42         else
  43                 vecs = '0 0 0';
  44
  45         dv = v_right * -vecs_y + v_up * vecs_z;
  46         w_shotorg = ent.origin + ent.view_ofs + dv;
  47
  48         // now move the shotorg forward as much as requested if possible
  49         if(antilag)
  50         {
  51                 if(ent.antilag_debug)
  52                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
  53                 else
  54                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  55         }
  56         else
  57                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
  58         w_shotorg = trace_endpos - v_forward * nudge;
  59         // calculate the shotdir from the chosen shotorg
  60         w_shotdir = normalize(w_shotend - w_shotorg);
  61
  62         //vector prevdir = w_shotdir;
  63         //vector prevorg = w_shotorg;
  64         //vector prevend = w_shotend;
  65
  66         if (antilag)
  67         if (!ent.cvar_cl_noantilag)
  68         {
  69                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  70                 {
  71                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  72                         if (!trace_ent.takedamage)
  73                         {
  74                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  75                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
  76                                 {
  77                                         entity e;
  78                                         e = trace_ent;
  79                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
  80                                         if(trace_ent == e)
  81                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
  82                                 }
  83                         }
  84                 }
  85                 else if(autocvar_g_antilag == 3) // client side hitscan
  86                 {
  87                         // this part MUST use prydon cursor
  88                         if (ent.cursor_trace_ent)                 // client was aiming at someone
  89                         if (ent.cursor_trace_ent != ent)         // just to make sure
  90                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
  91                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
  92                         {
  93                                 // verify that the shot would miss without antilag
  94                                 // (avoids an issue where guns would always shoot at their origin)
  95                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  96                                 if (!trace_ent.takedamage)
  97                                 {
  98                                         // verify that the shot would hit if altered
  99                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 100                                         if (trace_ent == ent.cursor_trace_ent)
 101                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 102                                         else
 103                                                 print("antilag fail\n");
 104                                 }
 105                         }
 106                 }
 107         }
 108
 109         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 110
 111         if (!autocvar_g_norecoil)
 112                 ent.punchangle_x = recoil * -1;
 113
 114         if (snd != "")
 115         {
 116                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 117                 W_PlayStrengthSound(ent);
 118         }
 119
 120         // nudge w_shotend so a trace to w_shotend hits
 121         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 122         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 123         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 124         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 125 }
 126
 127 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
 128 {
 129         vector mdirection;
 130         float mspeed;
 131         vector outvelocity;
 132
 133         mvelocity = mvelocity * g_weaponspeedfactor;
 134
 135         mdirection = normalize(mvelocity);
 136         mspeed = vlen(mvelocity);
 137
 138         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 139
 140         return outvelocity;
 141 }
 142
 143 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 144 {
 145         if(proj.owner == world)
 146                 error("Unowned missile");
 147
 148         dir = dir + upDir * (pUpSpeed / pSpeed);
 149         dir_z += pZSpeed / pSpeed;
 150         pSpeed *= vlen(dir);
 151         dir = normalize(dir);
 152
 153         #if 0
 154         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 155         {
 156                 mspercallsum = mspercallcount = 0;
 157                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 158         }
 159         mspercallsum -= gettime(GETTIME_HIRES);
 160         #endif
 161
 162         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 163
 164         #if 0
 165         mspercallsum += gettime(GETTIME_HIRES);
 166         mspercallcount += 1;
 167         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
 168         #endif
 169
 170         proj.velocity = W_CalculateProjectileVelocity(proj.owner.velocity, pSpeed * dir, forceAbsolute);
 171 }
 172
 173
 174 // ====================
 175 //  Ballistics Tracing
 176 // ====================
 177
 178 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, float deathtype)
 179 {
 180         vector hitloc, force, endpoint, dir;
 181         entity ent, endent;
 182         float endq3surfaceflags;
 183         float totaldmg;
 184         entity o;
 185
 186         float length;
 187         vector beampos;
 188         string snd;
 189         entity pseudoprojectile;
 190         float f, ffs;
 191
 192         pseudoprojectile = world;
 193
 194         dir = normalize(end - start);
 195         length = vlen(end - start);
 196         force = dir * bforce;
 197
 198         // go a little bit into the wall because we need to hit this wall later
 199         end = end + dir;
 200
 201         totaldmg = 0;
 202
 203         // trace multiple times until we hit a wall, each obstacle will be made
 204         // non-solid so we can hit the next, while doing this we spawn effects and
 205         // note down which entities were hit so we can damage them later
 206         o = self;
 207         while (1)
 208         {
 209                 if(self.antilag_debug)
 210                         WarpZone_traceline_antilag (self, start, end, FALSE, o, self.antilag_debug);
 211                 else
 212                         WarpZone_traceline_antilag (self, start, end, FALSE, o, ANTILAG_LATENCY(self));
 213                 if(o && WarpZone_trace_firstzone)
 214                 {
 215                         o = world;
 216                         continue;
 217                 }
 218
 219                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 220                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, self);
 221
 222                 // if it is world we can't hurt it so stop now
 223                 if (trace_ent == world || trace_fraction == 1)
 224                         break;
 225
 226                 // make the entity non-solid so we can hit the next one
 227                 trace_ent.railgunhit = TRUE;
 228                 trace_ent.railgunhitloc = end;
 229                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 230                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 231                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 232
 233                 // stop if this is a wall
 234                 if (trace_ent.solid == SOLID_BSP)
 235                         break;
 236
 237                 // make the entity non-solid
 238                 trace_ent.solid = SOLID_NOT;
 239         }
 240
 241         endpoint = trace_endpos;
 242         endent = trace_ent;
 243         endq3surfaceflags = trace_dphitq3surfaceflags;
 244
 245         // find all the entities the railgun hit and restore their solid state
 246         ent = findfloat(world, railgunhit, TRUE);
 247         while (ent)
 248         {
 249                 // restore their solid type
 250                 ent.solid = ent.railgunhitsolidbackup;
 251                 ent = findfloat(ent, railgunhit, TRUE);
 252         }
 253
 254         // spawn a temporary explosion entity for RadiusDamage calls
 255         //explosion = spawn();
 256
 257         // Find all non-hit players the beam passed close by
 258         if(deathtype == WEP_VAPORIZER || deathtype == WEP_VORTEX)
 259         {
 260                 FOR_EACH_REALCLIENT(msg_entity)
 261                 if(msg_entity != self)
 262                 if(!msg_entity.railgunhit)
 263                 if(!(IS_SPEC(msg_entity) && msg_entity.enemy == self)) // we use realclient, so spectators can hear the whoosh too
 264                 {
 265                         // nearest point on the beam
 266                         beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 267
 268                         f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 269                         if(f <= 0)
 270                                 continue;
 271
 272                         snd = strcat("weapons/nexwhoosh", ftos(floor(random() * 3) + 1), ".wav");
 273
 274                         if(!pseudoprojectile)
 275                                 pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 276                         soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, snd, VOL_BASE * f, ATTEN_NONE);
 277                 }
 278
 279                 if(pseudoprojectile)
 280                         remove(pseudoprojectile);
 281         }
 282
 283         // find all the entities the railgun hit and hurt them
 284         ent = findfloat(world, railgunhit, TRUE);
 285         while (ent)
 286         {
 287                 // get the details we need to call the damage function
 288                 hitloc = ent.railgunhitloc;
 289
 290                 f = ExponentialFalloff(mindist, maxdist, halflifedist, ent.railgundistance);
 291                 ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, ent.railgundistance);
 292
 293                 if(accuracy_isgooddamage(self, ent))
 294                         totaldmg += bdamage * f;
 295
 296                 // apply the damage
 297                 if (ent.takedamage)
 298                         Damage (ent, self, self, bdamage * f, deathtype, hitloc, ent.railgunforce * ffs);
 299
 300                 // create a small explosion to throw gibs around (if applicable)
 301                 //setorigin (explosion, hitloc);
 302                 //RadiusDamage (explosion, self, 10, 0, 50, world, world, 300, deathtype);
 303
 304                 ent.railgunhitloc = '0 0 0';
 305                 ent.railgunhitsolidbackup = SOLID_NOT;
 306                 ent.railgunhit = FALSE;
 307                 ent.railgundistance = 0;
 308
 309                 // advance to the next entity
 310                 ent = findfloat(ent, railgunhit, TRUE);
 311         }
 312
 313         // calculate hits and fired shots for hitscan
 314         accuracy_add(self, self.weapon, 0, min(bdamage, totaldmg));
 315
 316         trace_endpos = endpoint;
 317         trace_ent = endent;
 318         trace_dphitq3surfaceflags = endq3surfaceflags;
 319 }
 320
 321 void fireBullet_trace_callback(vector start, vector hit, vector end)
 322 {
 323         if(vlen(hit - start) > 16)
 324                 trailparticles(world, fireBullet_trace_callback_eff, start, hit);
 325         WarpZone_trace_forent = world;
 326         fireBullet_last_hit = world;
 327 }
 328
 329 void fireBullet(vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, float tracereffects)
 330 {
 331         vector  end;
 332
 333         dir = normalize(dir + randomvec() * spread);
 334         end = start + dir * MAX_SHOT_DISTANCE;
 335
 336         entity pl;
 337         fireBullet_last_hit = world;
 338         float solid_penetration_left = 1;
 339         float total_damage = 0;
 340
 341         if(tracereffects & EF_RED)
 342                 fireBullet_trace_callback_eff = particleeffectnum("tr_rifle");
 343         else if(tracereffects & EF_BLUE)
 344                 fireBullet_trace_callback_eff = particleeffectnum("tr_rifle_weak");
 345         else
 346                 fireBullet_trace_callback_eff = particleeffectnum("tr_bullet");
 347
 348         float lag = ANTILAG_LATENCY(self);
 349         if(lag < 0.001)
 350                 lag = 0;
 351         if (!IS_REAL_CLIENT(self))
 352                 lag = 0;
 353         if(autocvar_g_antilag == 0 || self.cvar_cl_noantilag)
 354                 lag = 0; // only do hitscan, but no antilag
 355         if(lag)
 356         {
 357                 FOR_EACH_PLAYER(pl)
 358                         if(pl != self)
 359                                 antilag_takeback(pl, time - lag);
 360                 FOR_EACH_MONSTER(pl)
 361                         antilag_takeback(pl, time - lag);
 362         }
 363
 364         WarpZone_trace_forent = self;
 365
 366         for (;;)
 367         {
 368                 // TODO also show effect while tracing
 369                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, FALSE, WarpZone_trace_forent, world, fireBullet_trace_callback);
 370                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 371                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 372                 start = trace_endpos;
 373                 entity hit = trace_ent;
 374
 375                 // When hitting sky, stop.
 376                 if (pointcontents(start) == CONTENT_SKY)
 377                         break;
 378
 379                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 380                         break;
 381
 382                 // if we hit "weapclip", bail out
 383                 //
 384                 // rationale of this check:
 385                 //
 386                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 387                 // shots and players, but has no other effect!
 388                 //
 389                 // if it is not trans, it is caulk and should not have this side effect
 390                 //
 391                 // matching shaders:
 392                 //   common/weapclip (intended)
 393                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 394                 float is_weapclip = 0;
 395                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 396                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 397                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 398                         is_weapclip = 1;
 399
 400                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 401                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, self);
 402
 403                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 404                 {
 405                         fireBullet_last_hit = hit;
 406                         yoda = 0;
 407                         float g = accuracy_isgooddamage(self, hit);
 408                         Damage(hit, self, self, damage * solid_penetration_left, dtype, start, force * dir * solid_penetration_left);
 409                         // calculate hits for ballistic weapons
 410                         if(g)
 411                         {
 412                                 // do not exceed 100%
 413                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 414                                 total_damage += damage * solid_penetration_left;
 415                                 accuracy_add(self, self.weapon, 0, added_damage);
 416                         }
 417                 }
 418
 419                 if (is_weapclip)
 420                         break;
 421
 422                 // go through solid!
 423                 // outside the world? forget it
 424                 if(start_x > world.maxs_x || start_y > world.maxs_y || start_z > world.maxs_z || start_x < world.mins_x || start_y < world.mins_y || start_z < world.mins_z)
 425                         break;
 426
 427                 float maxdist;
 428                 if(max_solid_penetration < 0)
 429                         break;
 430                 else if(hit.ballistics_density < -1)
 431                         break; // -2: no solid penetration, ever
 432                 else if(hit.ballistics_density < 0)
 433                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 434                 else if(hit.ballistics_density == 0)
 435                         maxdist = max_solid_penetration * solid_penetration_left;
 436                 else
 437                         maxdist = max_solid_penetration * solid_penetration_left * hit.ballistics_density;
 438
 439                 if(maxdist <= autocvar_g_ballistics_mindistance)
 440                         break;
 441
 442                 // move the entity along its velocity until it's out of solid, then let it resume
 443                 // The previously hit entity is ignored here!
 444                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, TRUE, hit);
 445                 if(trace_fraction == 1) // 1: we never got out of solid
 446                         break;
 447
 448                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 449                 solid_penetration_left *= (dist_taken / maxdist);
 450
 451                 // Only show effect when going through a player (invisible otherwise)
 452                 if (hit && (hit.solid != SOLID_BSP))
 453                         if(vlen(trace_endpos - start) > 4)
 454                                 trailparticles(self, fireBullet_trace_callback_eff, start, trace_endpos);
 455
 456                 start = trace_endpos;
 457
 458                 if(hit.solid == SOLID_BSP)
 459                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, self);
 460         }
 461
 462         if(lag)
 463         {
 464                 FOR_EACH_PLAYER(pl)
 465                         if(pl != self)
 466                                 antilag_restore(pl);
 467                 FOR_EACH_MONSTER(pl)
 468                         antilag_restore(pl);
 469         }
 470 }