qcsrc/server/weapons/tracing.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../../dpdefs/progsdefs.qh"
   5     #include "../../dpdefs/dpextensions.qh"
   6     #include "../../warpzonelib/common.qh"
   7     #include "../../common/constants.qh"
   8     #include "../../common/util.qh"
   9     #include "../../common/weapons/weapons.qh"
  10     #include "tracing.qh"
  11     #include "../autocvars.qh"
  12     #include "../defs.qh"
  13     #include "../antilag.qh"
  14 #endif
  15
  16 // this function calculates w_shotorg and w_shotdir based on the weapon model
  17 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  18 // make sure you call makevectors first (FIXME?)
  19 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
  20 {
  21         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  22         float oldsolid;
  23         vector vecs, dv;
  24         oldsolid = ent.dphitcontentsmask;
  25         if(ent.weapon == WEP_RIFLE)
  26                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  27         else
  28                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  29         if(antilag)
  30                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  31                 // passing world, because we do NOT want it to touch dphitcontentsmask
  32         else
  33                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  34         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  35
  36         vector vf, vr, vu;
  37         vf = v_forward;
  38         vr = v_right;
  39         vu = v_up;
  40         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  41         v_forward = vf;
  42         v_right = vr;
  43         v_up = vu;
  44
  45         // un-adjust trueaim if shotend is too close
  46         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
  47                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  48
  49         // track max damage
  50         if(accuracy_canbegooddamage(ent))
  51                 accuracy_add(ent, ent.weapon, maxdamage, 0);
  52
  53         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
  54
  55         if(ent.weaponentity.movedir.x > 0)
  56                 vecs = ent.weaponentity.movedir;
  57         else
  58                 vecs = '0 0 0';
  59
  60         dv = v_right * -vecs.y + v_up * vecs.z;
  61         w_shotorg = ent.origin + ent.view_ofs + dv;
  62
  63         // now move the shotorg forward as much as requested if possible
  64         if(antilag)
  65         {
  66                 if(ent.antilag_debug)
  67                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
  68                 else
  69                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  70         }
  71         else
  72                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent);
  73         w_shotorg = trace_endpos - v_forward * nudge;
  74         // calculate the shotdir from the chosen shotorg
  75         w_shotdir = normalize(w_shotend - w_shotorg);
  76
  77         //vector prevdir = w_shotdir;
  78         //vector prevorg = w_shotorg;
  79         //vector prevend = w_shotend;
  80
  81         if (antilag)
  82         if (!ent.cvar_cl_noantilag)
  83         {
  84                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  85                 {
  86                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  87                         if (!trace_ent.takedamage)
  88                         {
  89                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  90                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
  91                                 {
  92                                         entity e;
  93                                         e = trace_ent;
  94                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
  95                                         if(trace_ent == e)
  96                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
  97                                 }
  98                         }
  99                 }
 100                 else if(autocvar_g_antilag == 3) // client side hitscan
 101                 {
 102                         // this part MUST use prydon cursor
 103                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 104                         if (ent.cursor_trace_ent != ent)         // just to make sure
 105                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 106                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
 107                         {
 108                                 // verify that the shot would miss without antilag
 109                                 // (avoids an issue where guns would always shoot at their origin)
 110                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 111                                 if (!trace_ent.takedamage)
 112                                 {
 113                                         // verify that the shot would hit if altered
 114                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 115                                         if (trace_ent == ent.cursor_trace_ent)
 116                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 117                                         else
 118                                                 print("antilag fail\n");
 119                                 }
 120                         }
 121                 }
 122         }
 123
 124         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 125
 126         if (!autocvar_g_norecoil)
 127                 ent.punchangle_x = recoil * -1;
 128
 129         if (snd != "")
 130         {
 131                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 132                 W_PlayStrengthSound(ent);
 133         }
 134
 135         // nudge w_shotend so a trace to w_shotend hits
 136         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 137         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 138         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 139         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 140 }
 141
 142 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
 143 {
 144         vector mdirection;
 145         float mspeed;
 146         vector outvelocity;
 147
 148         mvelocity = mvelocity * g_weaponspeedfactor;
 149
 150         mdirection = normalize(mvelocity);
 151         mspeed = vlen(mvelocity);
 152
 153         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 154
 155         return outvelocity;
 156 }
 157
 158 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 159 {
 160         if(proj.owner == world)
 161                 error("Unowned missile");
 162
 163         dir = dir + upDir * (pUpSpeed / pSpeed);
 164         dir.z += pZSpeed / pSpeed;
 165         pSpeed *= vlen(dir);
 166         dir = normalize(dir);
 167
 168         #if 0
 169         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 170         {
 171                 mspercallsum = mspercallcount = 0;
 172                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 173         }
 174         mspercallsum -= gettime(GETTIME_HIRES);
 175         #endif
 176
 177         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 178
 179         #if 0
 180         mspercallsum += gettime(GETTIME_HIRES);
 181         mspercallcount += 1;
 182         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
 183         #endif
 184
 185         proj.velocity = W_CalculateProjectileVelocity(proj.owner.velocity, pSpeed * dir, forceAbsolute);
 186 }
 187
 188
 189 // ====================
 190 //  Ballistics Tracing
 191 // ====================
 192
 193 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, float deathtype)
 194 {
 195         vector hitloc, force, endpoint, dir;
 196         entity ent, endent;
 197         float endq3surfaceflags;
 198         float totaldmg;
 199         entity o;
 200
 201         float length;
 202         vector beampos;
 203         string snd;
 204         entity pseudoprojectile;
 205         float f, ffs;
 206
 207         pseudoprojectile = world;
 208
 209         dir = normalize(end - start);
 210         length = vlen(end - start);
 211         force = dir * bforce;
 212
 213         // go a little bit into the wall because we need to hit this wall later
 214         end = end + dir;
 215
 216         totaldmg = 0;
 217
 218         // trace multiple times until we hit a wall, each obstacle will be made
 219         // non-solid so we can hit the next, while doing this we spawn effects and
 220         // note down which entities were hit so we can damage them later
 221         o = self;
 222         while (1)
 223         {
 224                 if(self.antilag_debug)
 225                         WarpZone_traceline_antilag (self, start, end, false, o, self.antilag_debug);
 226                 else
 227                         WarpZone_traceline_antilag (self, start, end, false, o, ANTILAG_LATENCY(self));
 228                 if(o && WarpZone_trace_firstzone)
 229                 {
 230                         o = world;
 231                         continue;
 232                 }
 233
 234                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 235                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, self);
 236
 237                 // if it is world we can't hurt it so stop now
 238                 if (trace_ent == world || trace_fraction == 1)
 239                         break;
 240
 241                 // make the entity non-solid so we can hit the next one
 242                 trace_ent.railgunhit = true;
 243                 trace_ent.railgunhitloc = end;
 244                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 245                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 246                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 247
 248                 // stop if this is a wall
 249                 if (trace_ent.solid == SOLID_BSP)
 250                         break;
 251
 252                 // make the entity non-solid
 253                 trace_ent.solid = SOLID_NOT;
 254         }
 255
 256         endpoint = trace_endpos;
 257         endent = trace_ent;
 258         endq3surfaceflags = trace_dphitq3surfaceflags;
 259
 260         // find all the entities the railgun hit and restore their solid state
 261         ent = findfloat(world, railgunhit, true);
 262         while (ent)
 263         {
 264                 // restore their solid type
 265                 ent.solid = ent.railgunhitsolidbackup;
 266                 ent = findfloat(ent, railgunhit, true);
 267         }
 268
 269         // spawn a temporary explosion entity for RadiusDamage calls
 270         //explosion = spawn();
 271
 272         // Find all non-hit players the beam passed close by
 273         if(deathtype == WEP_VAPORIZER || deathtype == WEP_VORTEX)
 274         {
 275                 FOR_EACH_REALCLIENT(msg_entity)
 276                 if(msg_entity != self)
 277                 if(!msg_entity.railgunhit)
 278                 if(!(IS_SPEC(msg_entity) && msg_entity.enemy == self)) // we use realclient, so spectators can hear the whoosh too
 279                 {
 280                         // nearest point on the beam
 281                         beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 282
 283                         f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 284                         if(f <= 0)
 285                                 continue;
 286
 287                         snd = strcat("weapons/nexwhoosh", ftos(floor(random() * 3) + 1), ".wav");
 288
 289                         if(!pseudoprojectile)
 290                                 pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 291                         soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, snd, VOL_BASE * f, ATTEN_NONE);
 292                 }
 293
 294                 if(pseudoprojectile)
 295                         remove(pseudoprojectile);
 296         }
 297
 298         // find all the entities the railgun hit and hurt them
 299         ent = findfloat(world, railgunhit, true);
 300         while (ent)
 301         {
 302                 // get the details we need to call the damage function
 303                 hitloc = ent.railgunhitloc;
 304
 305                 f = ExponentialFalloff(mindist, maxdist, halflifedist, ent.railgundistance);
 306                 ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, ent.railgundistance);
 307
 308                 if(accuracy_isgooddamage(self, ent))
 309                         totaldmg += bdamage * f;
 310
 311                 // apply the damage
 312                 if (ent.takedamage)
 313                         Damage (ent, self, self, bdamage * f, deathtype, hitloc, ent.railgunforce * ffs);
 314
 315                 // create a small explosion to throw gibs around (if applicable)
 316                 //setorigin (explosion, hitloc);
 317                 //RadiusDamage (explosion, self, 10, 0, 50, world, world, 300, deathtype);
 318
 319                 ent.railgunhitloc = '0 0 0';
 320                 ent.railgunhitsolidbackup = SOLID_NOT;
 321                 ent.railgunhit = false;
 322                 ent.railgundistance = 0;
 323
 324                 // advance to the next entity
 325                 ent = findfloat(ent, railgunhit, true);
 326         }
 327
 328         // calculate hits and fired shots for hitscan
 329         accuracy_add(self, self.weapon, 0, min(bdamage, totaldmg));
 330
 331         trace_endpos = endpoint;
 332         trace_ent = endent;
 333         trace_dphitq3surfaceflags = endq3surfaceflags;
 334 }
 335
 336 void fireBullet_trace_callback(vector start, vector hit, vector end)
 337 {
 338         if(vlen(hit - start) > 16)
 339                 trailparticles(world, fireBullet_trace_callback_eff, start, hit);
 340         WarpZone_trace_forent = world;
 341         fireBullet_last_hit = world;
 342 }
 343
 344 void fireBullet(vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, int tracereffects)
 345 {
 346         vector  end;
 347
 348         dir = normalize(dir + randomvec() * spread);
 349         end = start + dir * MAX_SHOT_DISTANCE;
 350
 351         entity pl;
 352         fireBullet_last_hit = world;
 353         float solid_penetration_left = 1;
 354         float total_damage = 0;
 355
 356         if(tracereffects & EF_RED)
 357                 fireBullet_trace_callback_eff = particleeffectnum("tr_rifle");
 358         else if(tracereffects & EF_BLUE)
 359                 fireBullet_trace_callback_eff = particleeffectnum("tr_rifle_weak");
 360         else
 361                 fireBullet_trace_callback_eff = particleeffectnum("tr_bullet");
 362
 363         float lag = ANTILAG_LATENCY(self);
 364         if(lag < 0.001)
 365                 lag = 0;
 366         if (!IS_REAL_CLIENT(self))
 367                 lag = 0;
 368         if(autocvar_g_antilag == 0 || self.cvar_cl_noantilag)
 369                 lag = 0; // only do hitscan, but no antilag
 370         if(lag)
 371         {
 372                 FOR_EACH_PLAYER(pl)
 373                         if(pl != self)
 374                                 antilag_takeback(pl, time - lag);
 375                 FOR_EACH_MONSTER(pl)
 376                         antilag_takeback(pl, time - lag);
 377         }
 378
 379         WarpZone_trace_forent = self;
 380
 381         for (;;)
 382         {
 383                 // TODO also show effect while tracing
 384                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, world, fireBullet_trace_callback);
 385                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 386                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 387                 start = trace_endpos;
 388                 entity hit = trace_ent;
 389
 390                 // When hitting sky, stop.
 391                 if (pointcontents(start) == CONTENT_SKY)
 392                         break;
 393
 394                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 395                         break;
 396
 397                 // if we hit "weapclip", bail out
 398                 //
 399                 // rationale of this check:
 400                 //
 401                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 402                 // shots and players, but has no other effect!
 403                 //
 404                 // if it is not trans, it is caulk and should not have this side effect
 405                 //
 406                 // matching shaders:
 407                 //   common/weapclip (intended)
 408                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 409                 float is_weapclip = 0;
 410                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 411                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 412                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 413                         is_weapclip = 1;
 414
 415                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 416                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, self);
 417
 418                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 419                 {
 420                         fireBullet_last_hit = hit;
 421                         yoda = 0;
 422                         float g = accuracy_isgooddamage(self, hit);
 423                         Damage(hit, self, self, damage * solid_penetration_left, dtype, start, force * dir * solid_penetration_left);
 424                         // calculate hits for ballistic weapons
 425                         if(g)
 426                         {
 427                                 // do not exceed 100%
 428                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 429                                 total_damage += damage * solid_penetration_left;
 430                                 accuracy_add(self, self.weapon, 0, added_damage);
 431                         }
 432                 }
 433
 434                 if (is_weapclip)
 435                         break;
 436
 437                 // go through solid!
 438                 // outside the world? forget it
 439                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 440                         break;
 441
 442                 float maxdist;
 443                 if(max_solid_penetration < 0)
 444                         break;
 445                 else if(hit.ballistics_density < -1)
 446                         break; // -2: no solid penetration, ever
 447                 else if(hit.ballistics_density < 0)
 448                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 449                 else if(hit.ballistics_density == 0)
 450                         maxdist = max_solid_penetration * solid_penetration_left;
 451                 else
 452                         maxdist = max_solid_penetration * solid_penetration_left * hit.ballistics_density;
 453
 454                 if(maxdist <= autocvar_g_ballistics_mindistance)
 455                         break;
 456
 457                 // move the entity along its velocity until it's out of solid, then let it resume
 458                 // The previously hit entity is ignored here!
 459                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 460                 if(trace_fraction == 1) // 1: we never got out of solid
 461                         break;
 462
 463                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 464                 solid_penetration_left *= (dist_taken / maxdist);
 465
 466                 // Only show effect when going through a player (invisible otherwise)
 467                 if (hit && (hit.solid != SOLID_BSP))
 468                         if(vlen(trace_endpos - start) > 4)
 469                                 trailparticles(self, fireBullet_trace_callback_eff, start, trace_endpos);
 470
 471                 start = trace_endpos;
 472
 473                 if(hit.solid == SOLID_BSP)
 474                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, self);
 475         }
 476
 477         if(lag)
 478         {
 479                 FOR_EACH_PLAYER(pl)
 480                         if(pl != self)
 481                                 antilag_restore(pl);
 482                 FOR_EACH_MONSTER(pl)
 483                         antilag_restore(pl);
 484         }
 485 }