qcsrc/server/weapons/tracing.qc

   1 #include "tracing.qh"
   2
   3 #include <common/effects/all.qh>
   4
   5 #include "accuracy.qh"
   6 #include "common.qh"
   7 #include "hitplot.qh"
   8 #include "weaponsystem.qh"
   9
  10 #include "../g_damage.qh"
  11 #include "../g_subs.qh"
  12 #include "../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/util.qh>
  17
  18 #include <common/weapons/_all.qh>
  19 #include <common/state.qh>
  20
  21 #include <lib/warpzone/common.qh>
  22
  23 // this function calculates w_shotorg and w_shotdir based on the weapon model
  24 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  25 // make sure you call makevectors first (FIXME?)
  26 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, .entity weaponentity, vector s_forward, vector mi, vector ma, float antilag, float recoil, Sound snd, float chan, float maxdamage, float range)
  27 {
  28         TC(Sound, snd);
  29         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  30         float oldsolid = ent.dphitcontentsmask;
  31         if(!IS_CLIENT(ent))
  32                 antilag = false; // no antilag for non-clients!
  33         if (IS_PLAYER(ent) && (ent.(weaponentity).m_weapon.spawnflags & WEP_FLAG_PENETRATEWALLS))
  34                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  35         else
  36                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  37         if(antilag)
  38                 WarpZone_traceline_antilag(NULL, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  39                 // passing NULL, because we do NOT want it to touch dphitcontentsmask
  40         else
  41                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  42         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  43
  44         vector vf, vr, vu;
  45         vf = v_forward;
  46         vr = v_right;
  47         vu = v_up;
  48         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  49         v_forward = vf;
  50         v_right = vr;
  51         v_up = vu;
  52
  53         // un-adjust trueaim if shotend is too close
  54         if(vdist(w_shotend - (ent.origin + ent.view_ofs), <, autocvar_g_trueaim_minrange))
  55                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  56
  57         // track max damage
  58         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
  59                 accuracy_add(ent, ent.(weaponentity).m_weapon.m_id, maxdamage, 0);
  60
  61         if(IS_PLAYER(ent))
  62                 W_HitPlotAnalysis(ent, weaponentity, v_forward, v_right, v_up);
  63
  64         vector md = ent.(weaponentity).movedir;
  65         vector vecs = ((md.x > 0) ? md : '0 0 0');
  66
  67         vector dv = v_right * -vecs.y + v_up * vecs.z;
  68         w_shotorg = ent.origin + ent.view_ofs + dv;
  69
  70         // now move the shotorg forward as much as requested if possible
  71         if(antilag)
  72         {
  73                 if(CS(ent).antilag_debug)
  74                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, CS(ent).antilag_debug);
  75                 else
  76                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  77         }
  78         else
  79                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent);
  80         w_shotorg = trace_endpos - v_forward * nudge;
  81         // calculate the shotdir from the chosen shotorg
  82         w_shotdir = normalize(w_shotend - w_shotorg);
  83
  84         //vector prevdir = w_shotdir;
  85         //vector prevorg = w_shotorg;
  86         //vector prevend = w_shotend;
  87
  88         if (antilag)
  89         if (!CS(ent).cvar_cl_noantilag)
  90         {
  91                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  92                 {
  93                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  94                         if (!trace_ent.takedamage)
  95                         {
  96                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  97                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
  98                                 {
  99                                         entity e;
 100                                         e = trace_ent;
 101                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 102                                         if(trace_ent == e)
 103                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 104                                 }
 105                         }
 106                 }
 107                 else if(autocvar_g_antilag == 3) // client side hitscan
 108                 {
 109                         // this part MUST use prydon cursor
 110                         if (CS(ent).cursor_trace_ent)                 // client was aiming at someone
 111                         if (CS(ent).cursor_trace_ent != ent)         // just to make sure
 112                         if (CS(ent).cursor_trace_ent.takedamage)      // and that person is killable
 113                         if (IS_PLAYER(CS(ent).cursor_trace_ent)) // and actually a player
 114                         {
 115                                 // verify that the shot would miss without antilag
 116                                 // (avoids an issue where guns would always shoot at their origin)
 117                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 118                                 if (!trace_ent.takedamage)
 119                                 {
 120                                         // verify that the shot would hit if altered
 121                                         traceline(w_shotorg, CS(ent).cursor_trace_ent.origin, MOVE_NORMAL, ent);
 122                                         if (trace_ent == CS(ent).cursor_trace_ent)
 123                                                 w_shotdir = normalize(CS(ent).cursor_trace_ent.origin - w_shotorg);
 124                                         else
 125                                                 LOG_INFO("antilag fail");
 126                                 }
 127                         }
 128                 }
 129         }
 130
 131         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 132
 133         if (!autocvar_g_norecoil)
 134                 ent.punchangle_x = recoil * -1;
 135
 136         if (snd != SND_Null) {
 137                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 138                 W_PlayStrengthSound(ent);
 139         }
 140
 141         // nudge w_shotend so a trace to w_shotend hits
 142         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 143         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 144         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 145         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 146 }
 147
 148 vector W_CalculateProjectileVelocity(entity actor, vector pvelocity, vector mvelocity, float forceAbsolute)
 149 {
 150         vector mdirection;
 151         float mspeed;
 152         vector outvelocity;
 153
 154         mvelocity = mvelocity * W_WeaponSpeedFactor(actor);
 155
 156         mdirection = normalize(mvelocity);
 157         mspeed = vlen(mvelocity);
 158
 159         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 160
 161         return outvelocity;
 162 }
 163
 164 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 165 {
 166         if(proj.owner == NULL)
 167                 error("Unowned missile");
 168
 169         dir = dir + upDir * (pUpSpeed / pSpeed);
 170         dir.z += pZSpeed / pSpeed;
 171         pSpeed *= vlen(dir);
 172         dir = normalize(dir);
 173
 174         #if 0
 175         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 176         {
 177                 mspercallsum = mspercallcount = 0;
 178                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 179         }
 180         mspercallsum -= gettime(GETTIME_HIRES);
 181         #endif
 182
 183         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 184
 185         #if 0
 186         mspercallsum += gettime(GETTIME_HIRES);
 187         mspercallcount += 1;
 188         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec");
 189         #endif
 190
 191         proj.velocity = W_CalculateProjectileVelocity(proj.owner, proj.owner.velocity, pSpeed * dir, forceAbsolute);
 192 }
 193
 194
 195 // ====================
 196 //  Ballistics Tracing
 197 // ====================
 198
 199 void FireRailgunBullet (entity this, .entity weaponentity, vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
 200 {
 201         entity pseudoprojectile = NULL;
 202
 203         vector dir = normalize(end - start);
 204         float length = vlen(end - start);
 205         vector force = dir * bforce;
 206
 207         // go a little bit into the wall because we need to hit this wall later
 208         end = end + dir;
 209
 210         float totaldmg = 0;
 211
 212         // trace multiple times until we hit a wall, each obstacle will be made
 213         // non-solid so we can hit the next, while doing this we spawn effects and
 214         // note down which entities were hit so we can damage them later
 215         entity o = this;
 216         while (1)
 217         {
 218                 if(CS(this).antilag_debug)
 219                         WarpZone_traceline_antilag (this, start, end, false, o, CS(this).antilag_debug);
 220                 else
 221                         WarpZone_traceline_antilag (this, start, end, false, o, ANTILAG_LATENCY(this));
 222                 if(o && WarpZone_trace_firstzone)
 223                 {
 224                         o = NULL;
 225                         continue;
 226                 }
 227
 228                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 229                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, this);
 230
 231                 // if it is NULL we can't hurt it so stop now
 232                 if (trace_ent == NULL || trace_fraction == 1)
 233                         break;
 234
 235                 // make the entity non-solid so we can hit the next one
 236                 IL_PUSH(g_railgunhit, trace_ent);
 237                 trace_ent.railgunhit = true;
 238                 trace_ent.railgunhitloc = end;
 239                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 240                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 241                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 242
 243                 // stop if this is a wall
 244                 if (trace_ent.solid == SOLID_BSP)
 245                         break;
 246
 247                 // make the entity non-solid
 248                 trace_ent.solid = SOLID_NOT;
 249         }
 250
 251         vector endpoint = trace_endpos;
 252         entity endent = trace_ent;
 253         float endq3surfaceflags = trace_dphitq3surfaceflags;
 254
 255         // find all the entities the railgun hit and restore their solid state
 256         IL_EACH(g_railgunhit, it.railgunhit,
 257         {
 258                 it.solid = it.railgunhitsolidbackup;
 259         });
 260
 261         // spawn a temporary explosion entity for RadiusDamage calls
 262         //explosion = spawn();
 263
 264         // Find all non-hit players the beam passed close by
 265         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id)
 266         {
 267                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != this, {
 268                         if(!it.railgunhit)
 269                         if(!(IS_SPEC(it) && it.enemy == this))
 270                         {
 271                                 msg_entity = it;
 272                                 // nearest point on the beam
 273                                 vector beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 274
 275                                 float f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 276                                 if(f <= 0)
 277                                         continue;
 278
 279                                 if(!pseudoprojectile)
 280                                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 281                                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, SND(NEXWHOOSH_RANDOM()), VOL_BASE * f, ATTEN_NONE);
 282                         }
 283                 });
 284
 285                 if(pseudoprojectile)
 286                         delete(pseudoprojectile);
 287         }
 288
 289         // find all the entities the railgun hit and hurt them
 290         IL_EACH(g_railgunhit, it.railgunhit,
 291         {
 292                 // removal from the list is handled below
 293
 294                 // get the details we need to call the damage function
 295                 vector hitloc = it.railgunhitloc;
 296
 297                 float foff = ExponentialFalloff(mindist, maxdist, halflifedist, it.railgundistance);
 298                 float ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, it.railgundistance);
 299
 300                 if(accuracy_isgooddamage(this, it))
 301                         totaldmg += bdamage * foff;
 302
 303                 // apply the damage
 304                 if (it.takedamage)
 305                         Damage (it, this, this, bdamage * foff, deathtype, hitloc, it.railgunforce * ffs);
 306
 307                 // create a small explosion to throw gibs around (if applicable)
 308                 //setorigin(explosion, hitloc);
 309                 //RadiusDamage (explosion, this, 10, 0, 50, NULL, NULL, 300, deathtype);
 310
 311                 it.railgunhitloc = '0 0 0';
 312                 it.railgunhitsolidbackup = SOLID_NOT;
 313                 it.railgunhit = false;
 314                 it.railgundistance = 0;
 315         });
 316
 317         IL_CLEAR(g_railgunhit);
 318
 319         // calculate hits and fired shots for hitscan
 320         accuracy_add(this, this.(weaponentity).m_weapon.m_id, 0, min(bdamage, totaldmg));
 321
 322         trace_endpos = endpoint;
 323         trace_ent = endent;
 324         trace_dphitq3surfaceflags = endq3surfaceflags;
 325 }
 326
 327 void fireBullet_trace_callback(vector start, vector hit, vector end)
 328 {
 329         if(vdist(hit - start, >, 16))
 330                 trailparticles(NULL, fireBullet_trace_callback_eff, start, hit);
 331         WarpZone_trace_forent = NULL;
 332         fireBullet_last_hit = NULL;
 333 }
 334
 335 void fireBullet(entity this, .entity weaponentity, vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, int tracereffects)
 336 {
 337         vector  end;
 338
 339         dir = normalize(dir + randomvec() * spread);
 340         end = start + dir * max_shot_distance;
 341
 342         fireBullet_last_hit = NULL;
 343         float solid_penetration_left = 1;
 344         float total_damage = 0;
 345
 346         if(tracereffects & EF_RED)
 347                 fireBullet_trace_callback_eff = EFFECT_RIFLE;
 348         else if(tracereffects & EF_BLUE)
 349                 fireBullet_trace_callback_eff = EFFECT_RIFLE_WEAK;
 350         else
 351                 fireBullet_trace_callback_eff = EFFECT_BULLET;
 352
 353         float lag = ((IS_REAL_CLIENT(this)) ? ANTILAG_LATENCY(this) : 0);
 354         if(lag < 0.001)
 355                 lag = 0;
 356         bool noantilag = ((IS_CLIENT(this)) ? CS(this).cvar_cl_noantilag : false);
 357         if(autocvar_g_antilag == 0 || noantilag)
 358                 lag = 0; // only do hitscan, but no antilag
 359         if(lag)
 360         {
 361                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, antilag_takeback(it, CS(it), time - lag));
 362                 IL_EACH(g_monsters, it != this,
 363                 {
 364                         antilag_takeback(it, it, time - lag);
 365                 });
 366         }
 367
 368         // change shooter to SOLID_BBOX so the shot can hit corpses
 369         int oldsolid = this.dphitcontentsmask;
 370         if(this)
 371                 this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 372
 373         WarpZone_trace_forent = this;
 374
 375         for (;;)
 376         {
 377                 // TODO also show effect while tracing
 378                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, NULL, fireBullet_trace_callback);
 379                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 380                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 381                 start = trace_endpos;
 382                 entity hit = trace_ent;
 383
 384                 // traced up to max_shot_distance and didn't hit anything at all
 385                 if (trace_fraction == 1.0)
 386                         break;
 387
 388                 // When hitting sky, stop.
 389                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
 390                         break;
 391
 392                 // can't use noimpact, as we need to pass through walls
 393                 //if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 394                         //break;
 395
 396                 // if we hit "weapclip", bail out
 397                 //
 398                 // rationale of this check:
 399                 //
 400                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 401                 // shots and players, but has no other effect!
 402                 //
 403                 // if it is not trans, it is caulk and should not have this side effect
 404                 //
 405                 // matching shaders:
 406                 //   common/weapclip (intended)
 407                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 408                 bool is_weapclip = false;
 409                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 410                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 411                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 412                         is_weapclip = true;
 413
 414                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 415                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, this);
 416
 417                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 418                 {
 419                         fireBullet_last_hit = hit;
 420                         yoda = 0;
 421                         MUTATOR_CALLHOOK(FireBullet_Hit, this, hit, start, end, damage, this.(weaponentity));
 422                         damage = M_ARGV(4, float);
 423                         float g = accuracy_isgooddamage(this, hit);
 424                         Damage(hit, this, this, damage * solid_penetration_left, dtype, start, force * dir * solid_penetration_left);
 425                         // calculate hits for ballistic weapons
 426                         if(g)
 427                         {
 428                                 // do not exceed 100%
 429                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 430                                 total_damage += damage * solid_penetration_left;
 431                                 accuracy_add(this, this.(weaponentity).m_weapon.m_id, 0, added_damage);
 432                         }
 433                 }
 434
 435                 if (is_weapclip && !autocvar_g_ballistics_penetrate_clips)
 436                         break;
 437
 438                 // go through solid!
 439                 // outside the world? forget it
 440                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 441                         break;
 442
 443                 float maxdist;
 444                 entity hitstore = IS_PLAYER(hit) ? PS(hit) : hit;
 445                 if(max_solid_penetration < 0)
 446                         break;
 447                 else if(hitstore.ballistics_density < -1)
 448                         break; // -2: no solid penetration, ever
 449                 else if(hitstore.ballistics_density < 0)
 450                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 451                 else if(hitstore.ballistics_density == 0)
 452                         maxdist = max_solid_penetration * solid_penetration_left;
 453                 else
 454                         maxdist = max_solid_penetration * solid_penetration_left * hitstore.ballistics_density;
 455
 456                 if(maxdist <= autocvar_g_ballistics_mindistance)
 457                         break;
 458
 459                 // move the entity along its velocity until it's out of solid, then let it resume
 460                 // The previously hit entity is ignored here!
 461                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 462                 if(trace_fraction == 1) // 1: we never got out of solid
 463                         break;
 464
 465                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 466                 // fraction_used_of_what_is_left = dist_taken / maxdist
 467                 // solid_penetration_left = solid_penetration_left - solid_penetration_left * fraction_used_of_what_is_left
 468                 solid_penetration_left *= 1 - dist_taken / maxdist;
 469                 solid_penetration_left = max(solid_penetration_left, 0);
 470
 471                 // Only show effect when going through a player (invisible otherwise)
 472                 if (hit && (hit.solid != SOLID_BSP))
 473                         if(vdist(trace_endpos - start, >, 4))
 474                                 trailparticles(this, fireBullet_trace_callback_eff, start, trace_endpos);
 475
 476                 start = trace_endpos;
 477
 478                 if(hit.solid == SOLID_BSP)
 479                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, this);
 480         }
 481
 482         if(lag)
 483         {
 484                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, antilag_restore(it, CS(it)));
 485                 IL_EACH(g_monsters, it != this,
 486                 {
 487                         antilag_restore(it, it);
 488                 });
 489         }
 490
 491         // restore shooter solid type
 492         if(this)
 493                 this.dphitcontentsmask = oldsolid;
 494 }