qcsrc/server/weapons/tracing.qc

   1 #include "tracing.qh"
   2
   3 #include "accuracy.qh"
   4 #include "common.qh"
   5 #include "hitplot.qh"
   6 #include "weaponsystem.qh"
   7
   8 #include "../g_damage.qh"
   9 #include "../g_subs.qh"
  10 #include "../antilag.qh"
  11
  12 #include <common/constants.qh>
  13 #include <common/util.qh>
  14
  15 #include <common/weapons/_all.qh>
  16 #include <common/state.qh>
  17
  18 #include <lib/warpzone/common.qh>
  19
  20 // this function calculates w_shotorg and w_shotdir based on the weapon model
  21 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  22 // make sure you call makevectors first (FIXME?)
  23 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, .entity weaponentity, vector s_forward, vector mi, vector ma, float antilag, float recoil, Sound snd, float chan, float maxdamage, float range)
  24 {
  25         TC(Sound, snd);
  26         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  27         float oldsolid;
  28         vector vecs, dv;
  29         oldsolid = ent.dphitcontentsmask;
  30         if (IS_PLAYER(ent) && PS(ent).m_weapon == WEP_RIFLE)
  31                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  32         else
  33                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  34         if(antilag)
  35                 WarpZone_traceline_antilag(NULL, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  36                 // passing NULL, because we do NOT want it to touch dphitcontentsmask
  37         else
  38                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  39         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  40
  41         vector vf, vr, vu;
  42         vf = v_forward;
  43         vr = v_right;
  44         vu = v_up;
  45         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  46         v_forward = vf;
  47         v_right = vr;
  48         v_up = vu;
  49
  50         // un-adjust trueaim if shotend is too close
  51         if(vdist(w_shotend - (ent.origin + ent.view_ofs), <, autocvar_g_trueaim_minrange))
  52                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  53
  54         // track max damage
  55         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
  56                 accuracy_add(ent, PS(ent).m_weapon.m_id, maxdamage, 0);
  57
  58         if(IS_PLAYER(ent))
  59                 W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
  60
  61         vector md = ent.(weaponentity).movedir;
  62         if(md.x > 0)
  63                 vecs = md;
  64         else
  65                 vecs = '0 0 0';
  66
  67         dv = v_right * -vecs.y + v_up * vecs.z;
  68         w_shotorg = ent.origin + ent.view_ofs + dv;
  69
  70         // now move the shotorg forward as much as requested if possible
  71         if(antilag)
  72         {
  73                 if(CS(ent).antilag_debug)
  74                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, CS(ent).antilag_debug);
  75                 else
  76                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  77         }
  78         else
  79                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent);
  80         w_shotorg = trace_endpos - v_forward * nudge;
  81         // calculate the shotdir from the chosen shotorg
  82         w_shotdir = normalize(w_shotend - w_shotorg);
  83
  84         //vector prevdir = w_shotdir;
  85         //vector prevorg = w_shotorg;
  86         //vector prevend = w_shotend;
  87
  88         if (antilag)
  89         if (!ent.cvar_cl_noantilag)
  90         {
  91                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  92                 {
  93                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  94                         if (!trace_ent.takedamage)
  95                         {
  96                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  97                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
  98                                 {
  99                                         entity e;
 100                                         e = trace_ent;
 101                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 102                                         if(trace_ent == e)
 103                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 104                                 }
 105                         }
 106                 }
 107                 else if(autocvar_g_antilag == 3) // client side hitscan
 108                 {
 109                         // this part MUST use prydon cursor
 110                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 111                         if (ent.cursor_trace_ent != ent)         // just to make sure
 112                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 113                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
 114                         {
 115                                 // verify that the shot would miss without antilag
 116                                 // (avoids an issue where guns would always shoot at their origin)
 117                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 118                                 if (!trace_ent.takedamage)
 119                                 {
 120                                         // verify that the shot would hit if altered
 121                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 122                                         if (trace_ent == ent.cursor_trace_ent)
 123                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 124                                         else
 125                                                 LOG_INFO("antilag fail\n");
 126                                 }
 127                         }
 128                 }
 129         }
 130
 131         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 132
 133         if (!autocvar_g_norecoil)
 134                 ent.punchangle_x = recoil * -1;
 135
 136         if (snd != SND_Null) {
 137                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 138                 W_PlayStrengthSound(ent);
 139         }
 140
 141         // nudge w_shotend so a trace to w_shotend hits
 142         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 143         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 144         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 145         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 146 }
 147
 148 vector W_CalculateProjectileVelocity(entity actor, vector pvelocity, vector mvelocity, float forceAbsolute)
 149 {
 150         vector mdirection;
 151         float mspeed;
 152         vector outvelocity;
 153
 154         mvelocity = mvelocity * W_WeaponSpeedFactor(actor);
 155
 156         mdirection = normalize(mvelocity);
 157         mspeed = vlen(mvelocity);
 158
 159         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 160
 161         return outvelocity;
 162 }
 163
 164 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 165 {
 166         if(proj.owner == NULL)
 167                 error("Unowned missile");
 168
 169         dir = dir + upDir * (pUpSpeed / pSpeed);
 170         dir.z += pZSpeed / pSpeed;
 171         pSpeed *= vlen(dir);
 172         dir = normalize(dir);
 173
 174         #if 0
 175         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 176         {
 177                 mspercallsum = mspercallcount = 0;
 178                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 179         }
 180         mspercallsum -= gettime(GETTIME_HIRES);
 181         #endif
 182
 183         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 184
 185         #if 0
 186         mspercallsum += gettime(GETTIME_HIRES);
 187         mspercallcount += 1;
 188         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
 189         #endif
 190
 191         proj.velocity = W_CalculateProjectileVelocity(proj.owner, proj.owner.velocity, pSpeed * dir, forceAbsolute);
 192 }
 193
 194
 195 // ====================
 196 //  Ballistics Tracing
 197 // ====================
 198
 199 void FireRailgunBullet (entity this, vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
 200 {
 201         vector hitloc, force, endpoint, dir;
 202         entity ent, endent;
 203         float endq3surfaceflags;
 204         float totaldmg;
 205         entity o;
 206
 207         float length;
 208         vector beampos;
 209         string snd;
 210         entity pseudoprojectile;
 211         float f, ffs;
 212
 213         pseudoprojectile = NULL;
 214
 215         dir = normalize(end - start);
 216         length = vlen(end - start);
 217         force = dir * bforce;
 218
 219         // go a little bit into the wall because we need to hit this wall later
 220         end = end + dir;
 221
 222         totaldmg = 0;
 223
 224         // trace multiple times until we hit a wall, each obstacle will be made
 225         // non-solid so we can hit the next, while doing this we spawn effects and
 226         // note down which entities were hit so we can damage them later
 227         o = this;
 228         while (1)
 229         {
 230                 if(CS(this).antilag_debug)
 231                         WarpZone_traceline_antilag (this, start, end, false, o, CS(this).antilag_debug);
 232                 else
 233                         WarpZone_traceline_antilag (this, start, end, false, o, ANTILAG_LATENCY(this));
 234                 if(o && WarpZone_trace_firstzone)
 235                 {
 236                         o = NULL;
 237                         continue;
 238                 }
 239
 240                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 241                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, this);
 242
 243                 // if it is NULL we can't hurt it so stop now
 244                 if (trace_ent == NULL || trace_fraction == 1)
 245                         break;
 246
 247                 // make the entity non-solid so we can hit the next one
 248                 trace_ent.railgunhit = true;
 249                 trace_ent.railgunhitloc = end;
 250                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 251                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 252                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 253
 254                 // stop if this is a wall
 255                 if (trace_ent.solid == SOLID_BSP)
 256                         break;
 257
 258                 // make the entity non-solid
 259                 trace_ent.solid = SOLID_NOT;
 260         }
 261
 262         endpoint = trace_endpos;
 263         endent = trace_ent;
 264         endq3surfaceflags = trace_dphitq3surfaceflags;
 265
 266         // find all the entities the railgun hit and restore their solid state
 267         ent = findfloat(NULL, railgunhit, true);
 268         while (ent)
 269         {
 270                 // restore their solid type
 271                 ent.solid = ent.railgunhitsolidbackup;
 272                 ent = findfloat(ent, railgunhit, true);
 273         }
 274
 275         // spawn a temporary explosion entity for RadiusDamage calls
 276         //explosion = spawn();
 277
 278         // Find all non-hit players the beam passed close by
 279         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id)
 280         {
 281                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != this, LAMBDA(
 282                         if(!it.railgunhit)
 283                         if(!(IS_SPEC(it) && it.enemy == this))
 284                         {
 285                                 msg_entity = it;
 286                                 // nearest point on the beam
 287                                 beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 288
 289                                 f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 290                                 if(f <= 0)
 291                                         continue;
 292
 293                                 snd = SND(NEXWHOOSH_RANDOM());
 294
 295                                 if(!pseudoprojectile)
 296                                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 297                                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, snd, VOL_BASE * f, ATTEN_NONE);
 298                         }
 299                 ));
 300
 301                 if(pseudoprojectile)
 302                         delete(pseudoprojectile);
 303         }
 304
 305         // find all the entities the railgun hit and hurt them
 306         ent = findfloat(NULL, railgunhit, true);
 307         while (ent)
 308         {
 309                 // get the details we need to call the damage function
 310                 hitloc = ent.railgunhitloc;
 311
 312                 f = ExponentialFalloff(mindist, maxdist, halflifedist, ent.railgundistance);
 313                 ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, ent.railgundistance);
 314
 315                 if(accuracy_isgooddamage(this, ent))
 316                         totaldmg += bdamage * f;
 317
 318                 // apply the damage
 319                 if (ent.takedamage)
 320                         Damage (ent, this, this, bdamage * f, deathtype, hitloc, ent.railgunforce * ffs);
 321
 322                 // create a small explosion to throw gibs around (if applicable)
 323                 //setorigin(explosion, hitloc);
 324                 //RadiusDamage (explosion, this, 10, 0, 50, NULL, NULL, 300, deathtype);
 325
 326                 ent.railgunhitloc = '0 0 0';
 327                 ent.railgunhitsolidbackup = SOLID_NOT;
 328                 ent.railgunhit = false;
 329                 ent.railgundistance = 0;
 330
 331                 // advance to the next entity
 332                 ent = findfloat(ent, railgunhit, true);
 333         }
 334
 335         // calculate hits and fired shots for hitscan
 336         accuracy_add(this, PS(this).m_weapon.m_id, 0, min(bdamage, totaldmg));
 337
 338         trace_endpos = endpoint;
 339         trace_ent = endent;
 340         trace_dphitq3surfaceflags = endq3surfaceflags;
 341 }
 342
 343 void fireBullet_trace_callback(vector start, vector hit, vector end)
 344 {
 345         if(vdist(hit - start, >, 16))
 346                 trailparticles(NULL, fireBullet_trace_callback_eff, start, hit);
 347         WarpZone_trace_forent = NULL;
 348         fireBullet_last_hit = NULL;
 349 }
 350
 351 void fireBullet(entity this, vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, int tracereffects)
 352 {
 353         vector  end;
 354
 355         dir = normalize(dir + randomvec() * spread);
 356         end = start + dir * MAX_SHOT_DISTANCE;
 357
 358         fireBullet_last_hit = NULL;
 359         float solid_penetration_left = 1;
 360         float total_damage = 0;
 361
 362         if(tracereffects & EF_RED)
 363                 fireBullet_trace_callback_eff = EFFECT_RIFLE;
 364         else if(tracereffects & EF_BLUE)
 365                 fireBullet_trace_callback_eff = EFFECT_RIFLE_WEAK;
 366         else
 367                 fireBullet_trace_callback_eff = EFFECT_BULLET;
 368
 369         float lag = ANTILAG_LATENCY(this);
 370         if(lag < 0.001)
 371                 lag = 0;
 372         if (!IS_REAL_CLIENT(this))
 373                 lag = 0;
 374         if(autocvar_g_antilag == 0 || this.cvar_cl_noantilag)
 375                 lag = 0; // only do hitscan, but no antilag
 376         if(lag)
 377         {
 378                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, antilag_takeback(it, CS(it), time - lag));
 379                 IL_EACH(g_monsters, it != this,
 380                 {
 381                         antilag_takeback(it, it, time - lag);
 382                 });
 383         }
 384
 385         // change shooter to SOLID_BBOX so the shot can hit corpses
 386         int oldsolid = this.dphitcontentsmask;
 387         if(this)
 388                 this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 389
 390         WarpZone_trace_forent = this;
 391
 392         for (;;)
 393         {
 394                 // TODO also show effect while tracing
 395                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, NULL, fireBullet_trace_callback);
 396                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 397                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 398                 start = trace_endpos;
 399                 entity hit = trace_ent;
 400
 401                 // When hitting sky, stop.
 402                 if (pointcontents(start) == CONTENT_SKY)
 403                         break;
 404
 405                 // can't use noimpact, as we need to pass through walls
 406                 //if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 407                         //break;
 408
 409                 // if we hit "weapclip", bail out
 410                 //
 411                 // rationale of this check:
 412                 //
 413                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 414                 // shots and players, but has no other effect!
 415                 //
 416                 // if it is not trans, it is caulk and should not have this side effect
 417                 //
 418                 // matching shaders:
 419                 //   common/weapclip (intended)
 420                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 421                 bool is_weapclip = false;
 422                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 423                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 424                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 425                         is_weapclip = true;
 426
 427                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 428                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, this);
 429
 430                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 431                 {
 432                         fireBullet_last_hit = hit;
 433                         yoda = 0;
 434                         MUTATOR_CALLHOOK(FireBullet_Hit, this, hit, start, end, damage);
 435                         damage = M_ARGV(4, float);
 436                         float g = accuracy_isgooddamage(this, hit);
 437                         Damage(hit, this, this, damage * solid_penetration_left, dtype, start, force * dir * solid_penetration_left);
 438                         // calculate hits for ballistic weapons
 439                         if(g)
 440                         {
 441                                 // do not exceed 100%
 442                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 443                                 total_damage += damage * solid_penetration_left;
 444                                 accuracy_add(this, PS(this).m_weapon.m_id, 0, added_damage);
 445                         }
 446                 }
 447
 448                 if (is_weapclip && !autocvar_g_ballistics_penetrate_clips)
 449                         break;
 450
 451                 // go through solid!
 452                 // outside the world? forget it
 453                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 454                         break;
 455
 456                 float maxdist;
 457                 if(max_solid_penetration < 0)
 458                         break;
 459                 else if(hit.ballistics_density < -1)
 460                         break; // -2: no solid penetration, ever
 461                 else if(hit.ballistics_density < 0)
 462                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 463                 else if(hit.ballistics_density == 0)
 464                         maxdist = max_solid_penetration * solid_penetration_left;
 465                 else
 466                         maxdist = max_solid_penetration * solid_penetration_left * hit.ballistics_density;
 467
 468                 if(maxdist <= autocvar_g_ballistics_mindistance)
 469                         break;
 470
 471                 // move the entity along its velocity until it's out of solid, then let it resume
 472                 // The previously hit entity is ignored here!
 473                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 474                 if(trace_fraction == 1) // 1: we never got out of solid
 475                         break;
 476
 477                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 478                 // fraction_used_of_what_is_left = dist_taken / maxdist
 479                 // solid_penetration_left = solid_penetration_left - solid_penetration_left * fraction_used_of_what_is_left
 480                 solid_penetration_left *= 1 - dist_taken / maxdist;
 481                 solid_penetration_left = max(solid_penetration_left, 0);
 482
 483                 // Only show effect when going through a player (invisible otherwise)
 484                 if (hit && (hit.solid != SOLID_BSP))
 485                         if(vdist(trace_endpos - start, >, 4))
 486                                 trailparticles(this, fireBullet_trace_callback_eff, start, trace_endpos);
 487
 488                 start = trace_endpos;
 489
 490                 if(hit.solid == SOLID_BSP)
 491                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, this);
 492         }
 493
 494         if(lag)
 495         {
 496                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, antilag_restore(it, CS(it)));
 497                 IL_EACH(g_monsters, it != this,
 498                 {
 499                         antilag_restore(it, it);
 500                 });
 501         }
 502
 503         // restore shooter solid type
 504         if(this)
 505                 this.dphitcontentsmask = oldsolid;
 506 }