qcsrc/server/weapons/tracing.qc

   1 #include "tracing.qh"
   2
   3 #include "accuracy.qh"
   4 #include "common.qh"
   5 #include "hitplot.qh"
   6 #include "weaponsystem.qh"
   7
   8 #include "../g_damage.qh"
   9 #include "../g_subs.qh"
  10 #include "../antilag.qh"
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/util.qh>
  15
  16 #include <common/weapons/_all.qh>
  17 #include <common/state.qh>
  18
  19 #include <lib/warpzone/common.qh>
  20
  21 // this function calculates w_shotorg and w_shotdir based on the weapon model
  22 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  23 // make sure you call makevectors first (FIXME?)
  24 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, .entity weaponentity, vector s_forward, vector mi, vector ma, float antilag, float recoil, Sound snd, float chan, float maxdamage, float range)
  25 {
  26         TC(Sound, snd);
  27         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  28         float oldsolid = ent.dphitcontentsmask;
  29         if(!IS_CLIENT(ent))
  30                 antilag = false; // no antilag for non-clients!
  31         if (IS_PLAYER(ent) && ent.(weaponentity).m_weapon == WEP_RIFLE)
  32                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  33         else
  34                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  35         if(antilag)
  36                 WarpZone_traceline_antilag(NULL, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  37                 // passing NULL, because we do NOT want it to touch dphitcontentsmask
  38         else
  39                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  40         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  41
  42         vector vf, vr, vu;
  43         vf = v_forward;
  44         vr = v_right;
  45         vu = v_up;
  46         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  47         v_forward = vf;
  48         v_right = vr;
  49         v_up = vu;
  50
  51         // un-adjust trueaim if shotend is too close
  52         if(vdist(w_shotend - (ent.origin + ent.view_ofs), <, autocvar_g_trueaim_minrange))
  53                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  54
  55         // track max damage
  56         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
  57                 accuracy_add(ent, ent.(weaponentity).m_weapon.m_id, maxdamage, 0);
  58
  59         if(IS_PLAYER(ent))
  60                 W_HitPlotAnalysis(ent, weaponentity, v_forward, v_right, v_up);
  61
  62         vector md = ent.(weaponentity).movedir;
  63         vector vecs = ((md.x > 0) ? md : '0 0 0');
  64
  65         vector dv = v_right * -vecs.y + v_up * vecs.z;
  66         w_shotorg = ent.origin + ent.view_ofs + dv;
  67
  68         // now move the shotorg forward as much as requested if possible
  69         if(antilag)
  70         {
  71                 if(CS(ent).antilag_debug)
  72                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, CS(ent).antilag_debug);
  73                 else
  74                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  75         }
  76         else
  77                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent);
  78         w_shotorg = trace_endpos - v_forward * nudge;
  79         // calculate the shotdir from the chosen shotorg
  80         w_shotdir = normalize(w_shotend - w_shotorg);
  81
  82         //vector prevdir = w_shotdir;
  83         //vector prevorg = w_shotorg;
  84         //vector prevend = w_shotend;
  85
  86         if (antilag)
  87         if (!ent.cvar_cl_noantilag)
  88         {
  89                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  90                 {
  91                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  92                         if (!trace_ent.takedamage)
  93                         {
  94                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  95                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
  96                                 {
  97                                         entity e;
  98                                         e = trace_ent;
  99                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 100                                         if(trace_ent == e)
 101                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 102                                 }
 103                         }
 104                 }
 105                 else if(autocvar_g_antilag == 3) // client side hitscan
 106                 {
 107                         // this part MUST use prydon cursor
 108                         if (CS(ent).cursor_trace_ent)                 // client was aiming at someone
 109                         if (CS(ent).cursor_trace_ent != ent)         // just to make sure
 110                         if (CS(ent).cursor_trace_ent.takedamage)      // and that person is killable
 111                         if (IS_PLAYER(CS(ent).cursor_trace_ent)) // and actually a player
 112                         {
 113                                 // verify that the shot would miss without antilag
 114                                 // (avoids an issue where guns would always shoot at their origin)
 115                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 116                                 if (!trace_ent.takedamage)
 117                                 {
 118                                         // verify that the shot would hit if altered
 119                                         traceline(w_shotorg, CS(ent).cursor_trace_ent.origin, MOVE_NORMAL, ent);
 120                                         if (trace_ent == CS(ent).cursor_trace_ent)
 121                                                 w_shotdir = normalize(CS(ent).cursor_trace_ent.origin - w_shotorg);
 122                                         else
 123                                                 LOG_INFO("antilag fail\n");
 124                                 }
 125                         }
 126                 }
 127         }
 128
 129         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 130
 131         if (!autocvar_g_norecoil)
 132                 ent.punchangle_x = recoil * -1;
 133
 134         if (snd != SND_Null) {
 135                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 136                 W_PlayStrengthSound(ent);
 137         }
 138
 139         // nudge w_shotend so a trace to w_shotend hits
 140         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 141         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 142         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 143         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 144 }
 145
 146 vector W_CalculateProjectileVelocity(entity actor, vector pvelocity, vector mvelocity, float forceAbsolute)
 147 {
 148         vector mdirection;
 149         float mspeed;
 150         vector outvelocity;
 151
 152         mvelocity = mvelocity * W_WeaponSpeedFactor(actor);
 153
 154         mdirection = normalize(mvelocity);
 155         mspeed = vlen(mvelocity);
 156
 157         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 158
 159         return outvelocity;
 160 }
 161
 162 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 163 {
 164         if(proj.owner == NULL)
 165                 error("Unowned missile");
 166
 167         dir = dir + upDir * (pUpSpeed / pSpeed);
 168         dir.z += pZSpeed / pSpeed;
 169         pSpeed *= vlen(dir);
 170         dir = normalize(dir);
 171
 172         #if 0
 173         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 174         {
 175                 mspercallsum = mspercallcount = 0;
 176                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 177         }
 178         mspercallsum -= gettime(GETTIME_HIRES);
 179         #endif
 180
 181         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 182
 183         #if 0
 184         mspercallsum += gettime(GETTIME_HIRES);
 185         mspercallcount += 1;
 186         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
 187         #endif
 188
 189         proj.velocity = W_CalculateProjectileVelocity(proj.owner, proj.owner.velocity, pSpeed * dir, forceAbsolute);
 190 }
 191
 192
 193 // ====================
 194 //  Ballistics Tracing
 195 // ====================
 196
 197 void FireRailgunBullet (entity this, .entity weaponentity, vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
 198 {
 199         entity pseudoprojectile = NULL;
 200
 201         vector dir = normalize(end - start);
 202         float length = vlen(end - start);
 203         vector force = dir * bforce;
 204
 205         // go a little bit into the wall because we need to hit this wall later
 206         end = end + dir;
 207
 208         float totaldmg = 0;
 209
 210         // trace multiple times until we hit a wall, each obstacle will be made
 211         // non-solid so we can hit the next, while doing this we spawn effects and
 212         // note down which entities were hit so we can damage them later
 213         entity o = this;
 214         while (1)
 215         {
 216                 if(CS(this).antilag_debug)
 217                         WarpZone_traceline_antilag (this, start, end, false, o, CS(this).antilag_debug);
 218                 else
 219                         WarpZone_traceline_antilag (this, start, end, false, o, ANTILAG_LATENCY(this));
 220                 if(o && WarpZone_trace_firstzone)
 221                 {
 222                         o = NULL;
 223                         continue;
 224                 }
 225
 226                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 227                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, this);
 228
 229                 // if it is NULL we can't hurt it so stop now
 230                 if (trace_ent == NULL || trace_fraction == 1)
 231                         break;
 232
 233                 // make the entity non-solid so we can hit the next one
 234                 IL_PUSH(g_railgunhit, trace_ent);
 235                 trace_ent.railgunhit = true;
 236                 trace_ent.railgunhitloc = end;
 237                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 238                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 239                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 240
 241                 // stop if this is a wall
 242                 if (trace_ent.solid == SOLID_BSP)
 243                         break;
 244
 245                 // make the entity non-solid
 246                 trace_ent.solid = SOLID_NOT;
 247         }
 248
 249         vector endpoint = trace_endpos;
 250         entity endent = trace_ent;
 251         float endq3surfaceflags = trace_dphitq3surfaceflags;
 252
 253         // find all the entities the railgun hit and restore their solid state
 254         IL_EACH(g_railgunhit, it.railgunhit,
 255         {
 256                 it.solid = it.railgunhitsolidbackup;
 257         });
 258
 259         // spawn a temporary explosion entity for RadiusDamage calls
 260         //explosion = spawn();
 261
 262         // Find all non-hit players the beam passed close by
 263         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id)
 264         {
 265                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != this, LAMBDA(
 266                         if(!it.railgunhit)
 267                         if(!(IS_SPEC(it) && it.enemy == this))
 268                         {
 269                                 msg_entity = it;
 270                                 // nearest point on the beam
 271                                 vector beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 272
 273                                 float f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 274                                 if(f <= 0)
 275                                         continue;
 276
 277                                 if(!pseudoprojectile)
 278                                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 279                                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, SND(NEXWHOOSH_RANDOM()), VOL_BASE * f, ATTEN_NONE);
 280                         }
 281                 ));
 282
 283                 if(pseudoprojectile)
 284                         delete(pseudoprojectile);
 285         }
 286
 287         // find all the entities the railgun hit and hurt them
 288         IL_EACH(g_railgunhit, it.railgunhit,
 289         {
 290                 // removal from the list is handled below
 291
 292                 // get the details we need to call the damage function
 293                 vector hitloc = it.railgunhitloc;
 294
 295                 float foff = ExponentialFalloff(mindist, maxdist, halflifedist, it.railgundistance);
 296                 float ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, it.railgundistance);
 297
 298                 if(accuracy_isgooddamage(this, it))
 299                         totaldmg += bdamage * foff;
 300
 301                 // apply the damage
 302                 if (it.takedamage)
 303                         Damage (it, this, this, bdamage * foff, deathtype, hitloc, it.railgunforce * ffs);
 304
 305                 // create a small explosion to throw gibs around (if applicable)
 306                 //setorigin(explosion, hitloc);
 307                 //RadiusDamage (explosion, this, 10, 0, 50, NULL, NULL, 300, deathtype);
 308
 309                 it.railgunhitloc = '0 0 0';
 310                 it.railgunhitsolidbackup = SOLID_NOT;
 311                 it.railgunhit = false;
 312                 it.railgundistance = 0;
 313         });
 314
 315         IL_CLEAR(g_railgunhit);
 316
 317         // calculate hits and fired shots for hitscan
 318         accuracy_add(this, this.(weaponentity).m_weapon.m_id, 0, min(bdamage, totaldmg));
 319
 320         trace_endpos = endpoint;
 321         trace_ent = endent;
 322         trace_dphitq3surfaceflags = endq3surfaceflags;
 323 }
 324
 325 void fireBullet_trace_callback(vector start, vector hit, vector end)
 326 {
 327         if(vdist(hit - start, >, 16))
 328                 trailparticles(NULL, fireBullet_trace_callback_eff, start, hit);
 329         WarpZone_trace_forent = NULL;
 330         fireBullet_last_hit = NULL;
 331 }
 332
 333 void fireBullet(entity this, .entity weaponentity, vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, int tracereffects)
 334 {
 335         vector  end;
 336
 337         dir = normalize(dir + randomvec() * spread);
 338         end = start + dir * max_shot_distance;
 339
 340         fireBullet_last_hit = NULL;
 341         float solid_penetration_left = 1;
 342         float total_damage = 0;
 343
 344         if(tracereffects & EF_RED)
 345                 fireBullet_trace_callback_eff = EFFECT_RIFLE;
 346         else if(tracereffects & EF_BLUE)
 347                 fireBullet_trace_callback_eff = EFFECT_RIFLE_WEAK;
 348         else
 349                 fireBullet_trace_callback_eff = EFFECT_BULLET;
 350
 351         float lag = ((IS_REAL_CLIENT(this)) ? ANTILAG_LATENCY(this) : 0);
 352         if(lag < 0.001)
 353                 lag = 0;
 354         if(autocvar_g_antilag == 0 || this.cvar_cl_noantilag)
 355                 lag = 0; // only do hitscan, but no antilag
 356         if(lag)
 357         {
 358                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, antilag_takeback(it, CS(it), time - lag));
 359                 IL_EACH(g_monsters, it != this,
 360                 {
 361                         antilag_takeback(it, it, time - lag);
 362                 });
 363         }
 364
 365         // change shooter to SOLID_BBOX so the shot can hit corpses
 366         int oldsolid = this.dphitcontentsmask;
 367         if(this)
 368                 this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 369
 370         WarpZone_trace_forent = this;
 371
 372         for (;;)
 373         {
 374                 // TODO also show effect while tracing
 375                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, NULL, fireBullet_trace_callback);
 376                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 377                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 378                 start = trace_endpos;
 379                 entity hit = trace_ent;
 380
 381                 // traced up to max_shot_distance and didn't hit anything at all
 382                 if (trace_fraction == 1.0)
 383                         break;
 384
 385                 // When hitting sky, stop.
 386                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
 387                         break;
 388
 389                 // can't use noimpact, as we need to pass through walls
 390                 //if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 391                         //break;
 392
 393                 // if we hit "weapclip", bail out
 394                 //
 395                 // rationale of this check:
 396                 //
 397                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 398                 // shots and players, but has no other effect!
 399                 //
 400                 // if it is not trans, it is caulk and should not have this side effect
 401                 //
 402                 // matching shaders:
 403                 //   common/weapclip (intended)
 404                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 405                 bool is_weapclip = false;
 406                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 407                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 408                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 409                         is_weapclip = true;
 410
 411                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 412                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, this);
 413
 414                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 415                 {
 416                         fireBullet_last_hit = hit;
 417                         yoda = 0;
 418                         MUTATOR_CALLHOOK(FireBullet_Hit, this, hit, start, end, damage, this.(weaponentity));
 419                         damage = M_ARGV(4, float);
 420                         float g = accuracy_isgooddamage(this, hit);
 421                         Damage(hit, this, this, damage * solid_penetration_left, dtype, start, force * dir * solid_penetration_left);
 422                         // calculate hits for ballistic weapons
 423                         if(g)
 424                         {
 425                                 // do not exceed 100%
 426                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 427                                 total_damage += damage * solid_penetration_left;
 428                                 accuracy_add(this, this.(weaponentity).m_weapon.m_id, 0, added_damage);
 429                         }
 430                 }
 431
 432                 if (is_weapclip && !autocvar_g_ballistics_penetrate_clips)
 433                         break;
 434
 435                 // go through solid!
 436                 // outside the world? forget it
 437                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 438                         break;
 439
 440                 float maxdist;
 441                 entity hitstore = IS_PLAYER(hit) ? PS(hit) : hit;
 442                 if(max_solid_penetration < 0)
 443                         break;
 444                 else if(hitstore.ballistics_density < -1)
 445                         break; // -2: no solid penetration, ever
 446                 else if(hitstore.ballistics_density < 0)
 447                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 448                 else if(hitstore.ballistics_density == 0)
 449                         maxdist = max_solid_penetration * solid_penetration_left;
 450                 else
 451                         maxdist = max_solid_penetration * solid_penetration_left * hitstore.ballistics_density;
 452
 453                 if(maxdist <= autocvar_g_ballistics_mindistance)
 454                         break;
 455
 456                 // move the entity along its velocity until it's out of solid, then let it resume
 457                 // The previously hit entity is ignored here!
 458                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 459                 if(trace_fraction == 1) // 1: we never got out of solid
 460                         break;
 461
 462                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 463                 // fraction_used_of_what_is_left = dist_taken / maxdist
 464                 // solid_penetration_left = solid_penetration_left - solid_penetration_left * fraction_used_of_what_is_left
 465                 solid_penetration_left *= 1 - dist_taken / maxdist;
 466                 solid_penetration_left = max(solid_penetration_left, 0);
 467
 468                 // Only show effect when going through a player (invisible otherwise)
 469                 if (hit && (hit.solid != SOLID_BSP))
 470                         if(vdist(trace_endpos - start, >, 4))
 471                                 trailparticles(this, fireBullet_trace_callback_eff, start, trace_endpos);
 472
 473                 start = trace_endpos;
 474
 475                 if(hit.solid == SOLID_BSP)
 476                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, this);
 477         }
 478
 479         if(lag)
 480         {
 481                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, antilag_restore(it, CS(it)));
 482                 IL_EACH(g_monsters, it != this,
 483                 {
 484                         antilag_restore(it, it);
 485                 });
 486         }
 487
 488         // restore shooter solid type
 489         if(this)
 490                 this.dphitcontentsmask = oldsolid;
 491 }