qcsrc/server/weapons/tracing.qc

   1 #include "tracing.qh"
   2
   3 #include <common/effects/all.qh>
   4
   5 #include "accuracy.qh"
   6 #include "common.qh"
   7 #include "hitplot.qh"
   8 #include "weaponsystem.qh"
   9
  10 #include "../g_damage.qh"
  11 #include "../g_subs.qh"
  12 #include "../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/util.qh>
  17
  18 #include <common/weapons/_all.qh>
  19 #include <common/wepent.qh>
  20 #include <common/state.qh>
  21
  22 #include <lib/warpzone/common.qh>
  23
  24 // this function calculates w_shotorg and w_shotdir based on the weapon model
  25 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  26 // make sure you call makevectors first (FIXME?)
  27 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, .entity weaponentity, vector s_forward, vector mi, vector ma, float antilag, float recoil, Sound snd, float chan, float maxdamage, float range, int deathtype)
  28 {
  29         TC(Sound, snd);
  30         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  31         float oldsolid = ent.dphitcontentsmask;
  32         Weapon wep = DEATH_WEAPONOF(deathtype);
  33         if(!IS_CLIENT(ent))
  34                 antilag = false; // no antilag for non-clients!
  35         if (IS_PLAYER(ent) && (wep.spawnflags & WEP_FLAG_PENETRATEWALLS))
  36                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  37         else
  38                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  39         if(antilag)
  40                 WarpZone_traceline_antilag(NULL, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  41                 // passing NULL, because we do NOT want it to touch dphitcontentsmask
  42         else
  43                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  44         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  45
  46         vector vf, vr, vu;
  47         vf = v_forward;
  48         vr = v_right;
  49         vu = v_up;
  50         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  51         v_forward = vf;
  52         v_right = vr;
  53         v_up = vu;
  54
  55         // un-adjust trueaim if shotend is too close
  56         if(vdist(w_shotend - (ent.origin + ent.view_ofs), <, autocvar_g_trueaim_minrange))
  57                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  58
  59         // track max damage
  60         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
  61                 accuracy_add(ent, wep.m_id, maxdamage, 0);
  62
  63         if(IS_PLAYER(ent))
  64                 W_HitPlotAnalysis(ent, wep, v_forward, v_right, v_up);
  65
  66         vector md = ent.(weaponentity).movedir;
  67         vector vecs = ((md.x > 0) ? md : '0 0 0');
  68
  69         vector dv = v_right * -vecs.y + v_up * vecs.z;
  70         w_shotorg = ent.origin + ent.view_ofs + dv;
  71
  72         // now move the shotorg forward as much as requested if possible
  73         if(antilag)
  74         {
  75                 if(CS(ent).antilag_debug)
  76                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, CS(ent).antilag_debug);
  77                 else
  78                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  79         }
  80         else
  81                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent);
  82         w_shotorg = trace_endpos - v_forward * nudge;
  83         // calculate the shotdir from the chosen shotorg
  84         w_shotdir = normalize(w_shotend - w_shotorg);
  85
  86         //vector prevdir = w_shotdir;
  87         //vector prevorg = w_shotorg;
  88         //vector prevend = w_shotend;
  89
  90         if (antilag)
  91         if (!CS(ent).cvar_cl_noantilag)
  92         {
  93                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  94                 {
  95                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  96                         if (!trace_ent.takedamage)
  97                         {
  98                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  99                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
 100                                 {
 101                                         entity e;
 102                                         e = trace_ent;
 103                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 104                                         if(trace_ent == e)
 105                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 106                                 }
 107                         }
 108                 }
 109                 else if(autocvar_g_antilag == 3) // client side hitscan
 110                 {
 111                         // this part MUST use prydon cursor
 112                         if (CS(ent).cursor_trace_ent)                 // client was aiming at someone
 113                         if (CS(ent).cursor_trace_ent != ent)         // just to make sure
 114                         if (CS(ent).cursor_trace_ent.takedamage)      // and that person is killable
 115                         if (IS_PLAYER(CS(ent).cursor_trace_ent)) // and actually a player
 116                         {
 117                                 // verify that the shot would miss without antilag
 118                                 // (avoids an issue where guns would always shoot at their origin)
 119                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 120                                 if (!trace_ent.takedamage)
 121                                 {
 122                                         // verify that the shot would hit if altered
 123                                         traceline(w_shotorg, CS(ent).cursor_trace_ent.origin, MOVE_NORMAL, ent);
 124                                         if (trace_ent == CS(ent).cursor_trace_ent)
 125                                                 w_shotdir = normalize(CS(ent).cursor_trace_ent.origin - w_shotorg);
 126                                         else
 127                                                 LOG_INFO("antilag fail");
 128                                 }
 129                         }
 130                 }
 131         }
 132
 133         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 134
 135         if (!autocvar_g_norecoil)
 136                 ent.punchangle_x = recoil * -1;
 137
 138         if (snd != SND_Null) {
 139                 sound (ent, chan, snd, (W_DualWielding(ent) ? VOL_BASE * 0.7 : VOL_BASE), ATTN_NORM);
 140                 W_PlayStrengthSound(ent);
 141         }
 142
 143         // nudge w_shotend so a trace to w_shotend hits
 144         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 145         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 146         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 147         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 148 }
 149
 150 vector W_CalculateProjectileVelocity(entity actor, vector pvelocity, vector mvelocity, float forceAbsolute)
 151 {
 152         vector mdirection;
 153         float mspeed;
 154         vector outvelocity;
 155
 156         mvelocity = mvelocity * W_WeaponSpeedFactor(actor);
 157
 158         mdirection = normalize(mvelocity);
 159         mspeed = vlen(mvelocity);
 160
 161         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 162
 163         return outvelocity;
 164 }
 165
 166 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 167 {
 168         if(proj.owner == NULL)
 169                 error("Unowned missile");
 170
 171         dir = dir + upDir * (pUpSpeed / pSpeed);
 172         dir.z += pZSpeed / pSpeed;
 173         pSpeed *= vlen(dir);
 174         dir = normalize(dir);
 175
 176         #if 0
 177         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 178         {
 179                 mspercallsum = mspercallcount = 0;
 180                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 181         }
 182         mspercallsum -= gettime(GETTIME_HIRES);
 183         #endif
 184
 185         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 186
 187         #if 0
 188         mspercallsum += gettime(GETTIME_HIRES);
 189         mspercallcount += 1;
 190         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec");
 191         #endif
 192
 193         proj.velocity = W_CalculateProjectileVelocity(proj.owner, proj.owner.velocity, pSpeed * dir, forceAbsolute);
 194 }
 195
 196
 197 // ====================
 198 //  Ballistics Tracing
 199 // ====================
 200
 201 void FireRailgunBullet (entity this, .entity weaponentity, vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
 202 {
 203         entity pseudoprojectile = NULL;
 204
 205         vector dir = normalize(end - start);
 206         float length = vlen(end - start);
 207         vector force = dir * bforce;
 208
 209         // go a little bit into the wall because we need to hit this wall later
 210         end = end + dir;
 211
 212         float totaldmg = 0;
 213
 214         // trace multiple times until we hit a wall, each obstacle will be made
 215         // non-solid so we can hit the next, while doing this we spawn effects and
 216         // note down which entities were hit so we can damage them later
 217         entity o = this;
 218         while (1)
 219         {
 220                 if(CS(this).antilag_debug)
 221                         WarpZone_traceline_antilag (this, start, end, false, o, CS(this).antilag_debug);
 222                 else
 223                         WarpZone_traceline_antilag (this, start, end, false, o, ANTILAG_LATENCY(this));
 224                 if(o && WarpZone_trace_firstzone)
 225                 {
 226                         o = NULL;
 227                         continue;
 228                 }
 229
 230                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 231                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, this);
 232
 233                 // if it is NULL we can't hurt it so stop now
 234                 if (trace_ent == NULL || trace_fraction == 1)
 235                         break;
 236
 237                 // make the entity non-solid so we can hit the next one
 238                 IL_PUSH(g_railgunhit, trace_ent);
 239                 trace_ent.railgunhit = true;
 240                 trace_ent.railgunhitloc = end;
 241                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 242                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 243                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 244
 245                 // stop if this is a wall
 246                 if (trace_ent.solid == SOLID_BSP)
 247                         break;
 248
 249                 // make the entity non-solid
 250                 trace_ent.solid = SOLID_NOT;
 251         }
 252
 253         vector endpoint = trace_endpos;
 254         entity endent = trace_ent;
 255         float endq3surfaceflags = trace_dphitq3surfaceflags;
 256
 257         // find all the entities the railgun hit and restore their solid state
 258         IL_EACH(g_railgunhit, it.railgunhit,
 259         {
 260                 it.solid = it.railgunhitsolidbackup;
 261         });
 262
 263         // spawn a temporary explosion entity for RadiusDamage calls
 264         //explosion = spawn();
 265
 266         // Find all non-hit players the beam passed close by
 267         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id)
 268         {
 269                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != this, {
 270                         if(!it.railgunhit)
 271                         if(!(IS_SPEC(it) && it.enemy == this))
 272                         {
 273                                 msg_entity = it;
 274                                 // nearest point on the beam
 275                                 vector beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 276
 277                                 float f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 278                                 if(f <= 0)
 279                                         continue;
 280
 281                                 if(!pseudoprojectile)
 282                                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 283                                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, SND(NEXWHOOSH_RANDOM()), VOL_BASE * f, ATTEN_NONE);
 284                         }
 285                 });
 286
 287                 if(pseudoprojectile)
 288                         delete(pseudoprojectile);
 289         }
 290
 291         // find all the entities the railgun hit and hurt them
 292         IL_EACH(g_railgunhit, it.railgunhit,
 293         {
 294                 // removal from the list is handled below
 295
 296                 // get the details we need to call the damage function
 297                 vector hitloc = it.railgunhitloc;
 298
 299                 float foff = ExponentialFalloff(mindist, maxdist, halflifedist, it.railgundistance);
 300                 float ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, it.railgundistance);
 301
 302                 if(accuracy_isgooddamage(this, it))
 303                         totaldmg += bdamage * foff;
 304
 305                 // apply the damage
 306                 if (it.takedamage)
 307                         Damage (it, this, this, bdamage * foff, deathtype, weaponentity, hitloc, it.railgunforce * ffs);
 308
 309                 // create a small explosion to throw gibs around (if applicable)
 310                 //setorigin(explosion, hitloc);
 311                 //RadiusDamage (explosion, this, 10, 0, 50, NULL, NULL, 300, deathtype);
 312
 313                 it.railgunhitloc = '0 0 0';
 314                 it.railgunhitsolidbackup = SOLID_NOT;
 315                 it.railgunhit = false;
 316                 it.railgundistance = 0;
 317         });
 318
 319         IL_CLEAR(g_railgunhit);
 320
 321         // calculate hits and fired shots for hitscan
 322         accuracy_add(this, this.(weaponentity).m_weapon.m_id, 0, min(bdamage, totaldmg));
 323
 324         trace_endpos = endpoint;
 325         trace_ent = endent;
 326         trace_dphitq3surfaceflags = endq3surfaceflags;
 327 }
 328
 329 void fireBullet_trace_callback(vector start, vector hit, vector end)
 330 {
 331         if(vdist(hit - start, >, 16))
 332                 trailparticles(NULL, fireBullet_trace_callback_eff, start, hit);
 333         WarpZone_trace_forent = NULL;
 334         fireBullet_last_hit = NULL;
 335 }
 336
 337 void fireBullet(entity this, .entity weaponentity, vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, int tracereffects)
 338 {
 339         vector  end;
 340
 341         dir = normalize(dir + randomvec() * spread);
 342         end = start + dir * max_shot_distance;
 343
 344         fireBullet_last_hit = NULL;
 345         float solid_penetration_left = 1;
 346         float total_damage = 0;
 347
 348         if(tracereffects & EF_RED)
 349                 fireBullet_trace_callback_eff = EFFECT_RIFLE;
 350         else if(tracereffects & EF_BLUE)
 351                 fireBullet_trace_callback_eff = EFFECT_RIFLE_WEAK;
 352         else
 353                 fireBullet_trace_callback_eff = EFFECT_BULLET;
 354
 355         float lag = ((IS_REAL_CLIENT(this)) ? ANTILAG_LATENCY(this) : 0);
 356         if(lag < 0.001)
 357                 lag = 0;
 358         bool noantilag = ((IS_CLIENT(this)) ? CS(this).cvar_cl_noantilag : false);
 359         if(autocvar_g_antilag == 0 || noantilag)
 360                 lag = 0; // only do hitscan, but no antilag
 361         if(lag)
 362                 antilag_takeback_all(this, lag);
 363
 364         // change shooter to SOLID_BBOX so the shot can hit corpses
 365         int oldsolid = this.dphitcontentsmask;
 366         if(this)
 367                 this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 368
 369         WarpZone_trace_forent = this;
 370
 371         for (;;)
 372         {
 373                 // TODO also show effect while tracing
 374                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, NULL, fireBullet_trace_callback);
 375                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 376                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 377                 start = trace_endpos;
 378                 entity hit = trace_ent;
 379
 380                 // traced up to max_shot_distance and didn't hit anything at all
 381                 if (trace_fraction == 1.0)
 382                         break;
 383
 384                 // When hitting sky, stop.
 385                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
 386                         break;
 387
 388                 // can't use noimpact, as we need to pass through walls
 389                 //if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 390                         //break;
 391
 392                 // if we hit "weapclip", bail out
 393                 //
 394                 // rationale of this check:
 395                 //
 396                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 397                 // shots and players, but has no other effect!
 398                 //
 399                 // if it is not trans, it is caulk and should not have this side effect
 400                 //
 401                 // matching shaders:
 402                 //   common/weapclip (intended)
 403                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 404                 bool is_weapclip = false;
 405                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 406                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 407                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 408                         is_weapclip = true;
 409
 410                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 411                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, this);
 412
 413                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 414                 {
 415                         fireBullet_last_hit = hit;
 416                         yoda = 0;
 417                         MUTATOR_CALLHOOK(FireBullet_Hit, this, hit, start, end, damage, this.(weaponentity));
 418                         damage = M_ARGV(4, float);
 419                         bool gooddamage = accuracy_isgooddamage(this, hit);
 420                         Damage(hit, this, this, damage * solid_penetration_left, dtype, weaponentity, start, force * dir * solid_penetration_left);
 421                         // calculate hits for ballistic weapons
 422                         if(gooddamage)
 423                         {
 424                                 // do not exceed 100%
 425                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 426                                 total_damage += damage * solid_penetration_left;
 427                                 accuracy_add(this, this.(weaponentity).m_weapon.m_id, 0, added_damage);
 428                         }
 429                 }
 430
 431                 if (is_weapclip && !autocvar_g_ballistics_penetrate_clips)
 432                         break;
 433
 434                 // go through solid!
 435                 // outside the world? forget it
 436                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 437                         break;
 438
 439                 float maxdist;
 440                 entity hitstore = IS_PLAYER(hit) ? PS(hit) : hit;
 441                 if(max_solid_penetration < 0)
 442                         break;
 443                 else if(hitstore.ballistics_density < -1)
 444                         break; // -2: no solid penetration, ever
 445                 else if(hitstore.ballistics_density < 0)
 446                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 447                 else if(hitstore.ballistics_density == 0)
 448                         maxdist = max_solid_penetration * solid_penetration_left;
 449                 else
 450                         maxdist = max_solid_penetration * solid_penetration_left * hitstore.ballistics_density;
 451
 452                 if(maxdist <= autocvar_g_ballistics_mindistance)
 453                         break;
 454
 455                 // move the entity along its velocity until it's out of solid, then let it resume
 456                 // The previously hit entity is ignored here!
 457                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 458                 if(trace_fraction == 1) // 1: we never got out of solid
 459                         break;
 460
 461                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 462                 // fraction_used_of_what_is_left = dist_taken / maxdist
 463                 // solid_penetration_left = solid_penetration_left - solid_penetration_left * fraction_used_of_what_is_left
 464                 solid_penetration_left *= 1 - dist_taken / maxdist;
 465                 solid_penetration_left = max(solid_penetration_left, 0);
 466
 467                 // Only show effect when going through a player (invisible otherwise)
 468                 if (hit && (hit.solid != SOLID_BSP))
 469                         if(vdist(trace_endpos - start, >, 4))
 470                                 trailparticles(this, fireBullet_trace_callback_eff, start, trace_endpos);
 471
 472                 start = trace_endpos;
 473
 474                 if(hit.solid == SOLID_BSP)
 475                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, this);
 476         }
 477
 478         if(lag)
 479                 antilag_restore_all(this);
 480
 481         // restore shooter solid type
 482         if(this)
 483                 this.dphitcontentsmask = oldsolid;
 484 }