qcsrc/server/weapons/tracing.qc

   1 // this function calculates w_shotorg and w_shotdir based on the weapon model
   2 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
   3 // make sure you call makevectors first (FIXME?)
   4 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
   5 {
   6         float nudge = 1; // added to traceline target and subtracted from result
   7         float oldsolid;
   8         vector vecs, dv;
   9         oldsolid = ent.dphitcontentsmask;
  10         if(ent.weapon == WEP_RIFLE)
  11                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  12         else
  13                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  14         if(antilag)
  15                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  16                 // passing world, because we do NOT want it to touch dphitcontentsmask
  17         else
  18                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  19         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  20
  21         vector vf, vr, vu;
  22         vf = v_forward;
  23         vr = v_right;
  24         vu = v_up;
  25         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  26         v_forward = vf;
  27         v_right = vr;
  28         v_up = vu;
  29
  30         // un-adjust trueaim if shotend is too close
  31         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
  32                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  33
  34         // track max damage
  35         if(accuracy_canbegooddamage(ent))
  36                 accuracy_add(ent, ent.weapon, maxdamage, 0);
  37
  38         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
  39
  40         if(ent.weaponentity.movedir_x > 0)
  41                 vecs = ent.weaponentity.movedir;
  42         else
  43                 vecs = '0 0 0';
  44
  45         dv = v_right * -vecs_y + v_up * vecs_z;
  46         w_shotorg = ent.origin + ent.view_ofs + dv;
  47
  48         // now move the shotorg forward as much as requested if possible
  49         if(antilag)
  50         {
  51                 if(ent.antilag_debug)
  52                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
  53                 else
  54                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  55         }
  56         else
  57                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
  58         w_shotorg = trace_endpos - v_forward * nudge;
  59         // calculate the shotdir from the chosen shotorg
  60         w_shotdir = normalize(w_shotend - w_shotorg);
  61
  62         if (antilag)
  63         if (!ent.cvar_cl_noantilag)
  64         {
  65                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  66                 {
  67                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  68                         if (!trace_ent.takedamage)
  69                         {
  70                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  71                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
  72                                 {
  73                                         entity e;
  74                                         e = trace_ent;
  75                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
  76                                         if(trace_ent == e)
  77                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
  78                                 }
  79                         }
  80                 }
  81                 else if(autocvar_g_antilag == 3) // client side hitscan
  82                 {
  83                         // this part MUST use prydon cursor
  84                         if (ent.cursor_trace_ent)                 // client was aiming at someone
  85                         if (ent.cursor_trace_ent != ent)         // just to make sure
  86                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
  87                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
  88                         {
  89                                 // verify that the shot would miss without antilag
  90                                 // (avoids an issue where guns would always shoot at their origin)
  91                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  92                                 if (!trace_ent.takedamage)
  93                                 {
  94                                         // verify that the shot would hit if altered
  95                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
  96                                         if (trace_ent == ent.cursor_trace_ent)
  97                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
  98                                         else
  99                                                 print("antilag fail\n");
 100                                 }
 101                         }
 102                 }
 103         }
 104
 105         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 106
 107         if (!autocvar_g_norecoil)
 108                 ent.punchangle_x = recoil * -1;
 109
 110         if (snd != "")
 111         {
 112                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 113                 W_PlayStrengthSound(ent);
 114         }
 115
 116         // nudge w_shotend so a trace to w_shotend hits
 117         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 118 }
 119
 120 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
 121 {
 122         vector mdirection;
 123         float mspeed;
 124         vector outvelocity;
 125
 126         mvelocity = mvelocity * g_weaponspeedfactor;
 127
 128         mdirection = normalize(mvelocity);
 129         mspeed = vlen(mvelocity);
 130
 131         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 132
 133         return outvelocity;
 134 }
 135
 136 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 137 {
 138         if(proj.owner == world)
 139                 error("Unowned missile");
 140
 141         dir = dir + upDir * (pUpSpeed / pSpeed);
 142         dir_z += pZSpeed / pSpeed;
 143         pSpeed *= vlen(dir);
 144         dir = normalize(dir);
 145
 146         #if 0
 147         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 148         {
 149                 mspercallsum = mspercallcount = 0;
 150                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 151         }
 152         mspercallsum -= gettime(GETTIME_HIRES);
 153         #endif
 154
 155         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 156
 157         #if 0
 158         mspercallsum += gettime(GETTIME_HIRES);
 159         mspercallcount += 1;
 160         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
 161         #endif
 162
 163         proj.velocity = W_CalculateProjectileVelocity(proj.owner.velocity, pSpeed * dir, forceAbsolute);
 164 }
 165
 166
 167 // ====================
 168 //  Ballistics Tracing
 169 // ====================
 170
 171 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, float deathtype)
 172 {
 173         vector hitloc, force, endpoint, dir;
 174         entity ent, endent;
 175         float endq3surfaceflags;
 176         float totaldmg;
 177         entity o;
 178
 179         float length;
 180         vector beampos;
 181         string snd;
 182         entity pseudoprojectile;
 183         float f, ffs;
 184
 185         pseudoprojectile = world;
 186
 187         dir = normalize(end - start);
 188         length = vlen(end - start);
 189         force = dir * bforce;
 190
 191         // go a little bit into the wall because we need to hit this wall later
 192         end = end + dir;
 193
 194         totaldmg = 0;
 195
 196         // trace multiple times until we hit a wall, each obstacle will be made
 197         // non-solid so we can hit the next, while doing this we spawn effects and
 198         // note down which entities were hit so we can damage them later
 199         o = self;
 200         while (1)
 201         {
 202                 if(self.antilag_debug)
 203                         WarpZone_traceline_antilag (self, start, end, FALSE, o, self.antilag_debug);
 204                 else
 205                         WarpZone_traceline_antilag (self, start, end, FALSE, o, ANTILAG_LATENCY(self));
 206                 if(o && WarpZone_trace_firstzone)
 207                 {
 208                         o = world;
 209                         continue;
 210                 }
 211
 212                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 213                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, self);
 214
 215                 // if it is world we can't hurt it so stop now
 216                 if (trace_ent == world || trace_fraction == 1)
 217                         break;
 218
 219                 // make the entity non-solid so we can hit the next one
 220                 trace_ent.railgunhit = TRUE;
 221                 trace_ent.railgunhitloc = end;
 222                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 223                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 224                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 225
 226                 // stop if this is a wall
 227                 if (trace_ent.solid == SOLID_BSP)
 228                         break;
 229
 230                 // make the entity non-solid
 231                 trace_ent.solid = SOLID_NOT;
 232         }
 233
 234         endpoint = trace_endpos;
 235         endent = trace_ent;
 236         endq3surfaceflags = trace_dphitq3surfaceflags;
 237
 238         // find all the entities the railgun hit and restore their solid state
 239         ent = findfloat(world, railgunhit, TRUE);
 240         while (ent)
 241         {
 242                 // restore their solid type
 243                 ent.solid = ent.railgunhitsolidbackup;
 244                 ent = findfloat(ent, railgunhit, TRUE);
 245         }
 246
 247         // spawn a temporary explosion entity for RadiusDamage calls
 248         //explosion = spawn();
 249
 250         // Find all non-hit players the beam passed close by
 251         if(deathtype == WEP_VAPORIZER || deathtype == WEP_VORTEX)
 252         {
 253                 FOR_EACH_REALCLIENT(msg_entity)
 254                 if(msg_entity != self)
 255                 if(!msg_entity.railgunhit)
 256                 if(!(IS_SPEC(msg_entity) && msg_entity.enemy == self)) // we use realclient, so spectators can hear the whoosh too
 257                 {
 258                         // nearest point on the beam
 259                         beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 260
 261                         f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 262                         if(f <= 0)
 263                                 continue;
 264
 265                         snd = strcat("weapons/nexwhoosh", ftos(floor(random() * 3) + 1), ".wav");
 266
 267                         if(!pseudoprojectile)
 268                                 pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 269                         soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, snd, VOL_BASE * f, ATTEN_NONE);
 270                 }
 271
 272                 if(pseudoprojectile)
 273                         remove(pseudoprojectile);
 274         }
 275
 276         // find all the entities the railgun hit and hurt them
 277         ent = findfloat(world, railgunhit, TRUE);
 278         while (ent)
 279         {
 280                 // get the details we need to call the damage function
 281                 hitloc = ent.railgunhitloc;
 282
 283                 f = ExponentialFalloff(mindist, maxdist, halflifedist, ent.railgundistance);
 284                 ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, ent.railgundistance);
 285
 286                 if(accuracy_isgooddamage(self.realowner, ent))
 287                         totaldmg += bdamage * f;
 288
 289                 // apply the damage
 290                 if (ent.takedamage)
 291                         Damage (ent, self, self, bdamage * f, deathtype, hitloc, ent.railgunforce * ffs);
 292
 293                 // create a small explosion to throw gibs around (if applicable)
 294                 //setorigin (explosion, hitloc);
 295                 //RadiusDamage (explosion, self, 10, 0, 50, world, world, 300, deathtype);
 296
 297                 ent.railgunhitloc = '0 0 0';
 298                 ent.railgunhitsolidbackup = SOLID_NOT;
 299                 ent.railgunhit = FALSE;
 300                 ent.railgundistance = 0;
 301
 302                 // advance to the next entity
 303                 ent = findfloat(ent, railgunhit, TRUE);
 304         }
 305
 306         // calculate hits and fired shots for hitscan
 307         accuracy_add(self, self.weapon, 0, min(bdamage, totaldmg));
 308
 309         trace_endpos = endpoint;
 310         trace_ent = endent;
 311         trace_dphitq3surfaceflags = endq3surfaceflags;
 312 }
 313
 314 void fireBullet_trace_callback(vector start, vector hit, vector end)
 315 {
 316         if(vlen(hit - start) > 16)
 317                 trailparticles(world, fireBullet_trace_callback_eff, start, hit);
 318         WarpZone_trace_forent = world;
 319         fireBullet_last_hit = world;
 320 }
 321
 322 void fireBullet(vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, float tracereffects)
 323 {
 324         vector  end;
 325
 326         dir = normalize(dir + randomvec() * spread);
 327         end = start + dir * MAX_SHOT_DISTANCE;
 328
 329         entity pl;
 330         fireBullet_last_hit = world;
 331         float solid_penetration_left = 1;
 332         float total_damage = 0;
 333
 334         if(tracereffects & EF_RED)
 335                 fireBullet_trace_callback_eff = particleeffectnum("tr_rifle");
 336         else if(tracereffects & EF_BLUE)
 337                 fireBullet_trace_callback_eff = particleeffectnum("tr_rifle_weak");
 338         else
 339                 fireBullet_trace_callback_eff = particleeffectnum("tr_bullet");
 340
 341         float lag = ANTILAG_LATENCY(self);
 342         if(lag < 0.001)
 343                 lag = 0;
 344         if (!IS_REAL_CLIENT(self))
 345                 lag = 0;
 346         if(autocvar_g_antilag == 0 || self.cvar_cl_noantilag)
 347                 lag = 0; // only do hitscan, but no antilag
 348         if(lag)
 349                 FOR_EACH_PLAYER(pl)
 350                         if(pl != self)
 351                                 antilag_takeback(pl, time - lag);
 352
 353         WarpZone_trace_forent = self;
 354
 355         for (;;)
 356         {
 357                 // TODO also show effect while tracing
 358                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, FALSE, WarpZone_trace_forent, world, fireBullet_trace_callback);
 359                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 360                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 361                 start = trace_endpos;
 362                 entity hit = trace_ent;
 363
 364                 // When hitting sky, stop.
 365                 if (pointcontents(start) == CONTENT_SKY)
 366                         break;
 367
 368                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 369                         break;
 370
 371                 // if we hit "weapclip", bail out
 372                 //
 373                 // rationale of this check:
 374                 //
 375                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 376                 // shots and players, but has no other effect!
 377                 //
 378                 // if it is not trans, it is caulk and should not have this side effect
 379                 //
 380                 // matching shaders:
 381                 //   common/weapclip (intended)
 382                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 383                 float is_weapclip = 0;
 384                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 385                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 386                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 387                         is_weapclip = 1;
 388
 389                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 390                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, self);
 391
 392                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 393                 {
 394                         fireBullet_last_hit = hit;
 395                         yoda = 0;
 396                         float g = accuracy_isgooddamage(self, hit);
 397                         Damage(hit, self, self, damage * solid_penetration_left, dtype, start, force * dir * solid_penetration_left);
 398                         // calculate hits for ballistic weapons
 399                         if(g)
 400                         {
 401                                 // do not exceed 100%
 402                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 403                                 total_damage += damage * solid_penetration_left;
 404                                 accuracy_add(self, self.weapon, 0, added_damage);
 405                         }
 406                 }
 407
 408                 if (is_weapclip)
 409                         break;
 410
 411                 // go through solid!
 412                 // outside the world? forget it
 413                 if(start_x > world.maxs_x || start_y > world.maxs_y || start_z > world.maxs_z || start_x < world.mins_x || start_y < world.mins_y || start_z < world.mins_z)
 414                         break;
 415
 416                 float maxdist;
 417                 if(max_solid_penetration < 0)
 418                         break;
 419                 else if(hit.ballistics_density < -1)
 420                         break; // -2: no solid penetration, ever
 421                 else if(hit.ballistics_density < 0)
 422                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 423                 else if(hit.ballistics_density == 0)
 424                         maxdist = max_solid_penetration * solid_penetration_left;
 425                 else
 426                         maxdist = max_solid_penetration * solid_penetration_left * hit.ballistics_density;
 427
 428                 if(maxdist <= autocvar_g_ballistics_mindistance)
 429                         break;
 430
 431                 // move the entity along its velocity until it's out of solid, then let it resume
 432                 // The previously hit entity is ignored here!
 433                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, TRUE, hit);
 434                 if(trace_fraction == 1) // 1: we never got out of solid
 435                         break;
 436
 437                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 438                 solid_penetration_left *= (dist_taken / maxdist);
 439
 440                 // Only show effect when going through a player (invisible otherwise)
 441                 if (hit && (hit.solid != SOLID_BSP))
 442                         if(vlen(trace_endpos - start) > 4)
 443                                 trailparticles(self, fireBullet_trace_callback_eff, start, trace_endpos);
 444
 445                 start = trace_endpos;
 446
 447                 if(hit.solid == SOLID_BSP)
 448                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, self);
 449         }
 450
 451         if(lag)
 452                 FOR_EACH_PLAYER(pl)
 453                         if(pl != self)
 454                                 antilag_restore(pl);
 455 }