qcsrc/server/weapons/weaponstats.qc

   1 #include "weaponstats.qh"
   2
   3 #include <common/weapons/_all.qh>
   4 #include <common/stats.qh>
   5 #include <server/miscfunctions.qh>
   6 #include "../g_world.qh"
   7
   8 #include <common/weapons/_all.qh>
   9
  10 void WeaponStats_Init()
  11 {
  12         weaponstats_buffer = ((autocvar_sv_weaponstats_file != "") ? buf_create() : -1);
  13 }
  14
  15 void WeaponStats_ready(entity fh, entity pass, float status)
  16 {
  17         float i, j, n, ibot, jbot, idx;
  18         vector v;
  19         string prefix, s;
  20         switch(status)
  21         {
  22                 case URL_READY_CANWRITE:
  23                         // we can write
  24                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  25                         url_fputs(fh, "#begin statsfile\n");
  26                         url_fputs(fh, strcat("#date ", strftime(true, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  27 #ifdef WATERMARK
  28                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  29 #endif
  30                         url_fputs(fh, strcat("#config ", ftos(crc16(false, cvar_purechanges)), "\n"));
  31                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  32                         n = tokenizebyseparator(cvar_purechanges, "\n");
  33                         for(i = 0; i < n; ++i)
  34                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  35                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  36                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  37                                 {
  38                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  39                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  40                                         if(v != '0 0 0')
  41                                         {
  42                                                 //vector is: kills hits damage
  43                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  44                                                 url_fputs(fh, sprintf("%d %d %g\n", v.x, v.y, v.z));
  45                                         }
  46                                 }
  47                         url_fputs(fh, "#end\n\n");
  48                         url_fclose(fh);
  49                         break;
  50                 case URL_READY_CANREAD:
  51                         // url_fclose is processing, we got a response for writing the data
  52                         // this must come from HTTP
  53                         LOG_INFO("Got response from weapon stats server:");
  54                         while((s = url_fgets(fh)))
  55                                 LOG_INFO("  ", s);
  56                         LOG_INFO("End of response.");
  57                         url_fclose(fh);
  58                         break;
  59                 case URL_READY_CLOSED:
  60                         // url_fclose has finished
  61                         LOG_INFO("Weapon stats written");
  62                         buf_del(weaponstats_buffer);
  63                         weaponstats_buffer = -1;
  64                         break;
  65                 case URL_READY_ERROR:
  66                 default:
  67                         LOG_INFO("Weapon stats writing failed: ", ftos(status));
  68                         buf_del(weaponstats_buffer);
  69                         weaponstats_buffer = -1;
  70                         break;
  71         }
  72 }
  73
  74 void WeaponStats_Shutdown()
  75 {
  76         if(weaponstats_buffer < 0)
  77                 return;
  78         if(autocvar_sv_weaponstats_file != "")
  79         {
  80                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, NULL);
  81         }
  82         else
  83         {
  84                 buf_del(weaponstats_buffer);
  85                 weaponstats_buffer = -1;
  86         }
  87 }
  88
  89 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  90 {
  91         float idx;
  92         if(weaponstats_buffer < 0)
  93                 return;
  94         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  95                 return;
  96         if(awep > WEP_LAST || vwep > WEP_LAST)
  97                 return;
  98         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  99         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 100 }
 101
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108
 109 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 110 {
 111         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 112 }