qcsrc/server/weapons/weaponstats.qc

   1 #include "weaponstats.qh"
   2 #include "../_all.qh"
   3
   4 #include "../g_world.qh"
   5
   6 #include "../../common/weapons/all.qh"
   7
   8 void WeaponStats_Init()
   9 {
  10         weaponstats_buffer = ((autocvar_sv_weaponstats_file != "") ? buf_create() : -1);
  11 }
  12
  13 void WeaponStats_ready(entity fh, entity pass, float status)
  14 {
  15         float i, j, n, ibot, jbot, idx;
  16         vector v;
  17         string prefix, s;
  18         switch(status)
  19         {
  20                 case URL_READY_CANWRITE:
  21                         // we can write
  22                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  23                         url_fputs(fh, "#begin statsfile\n");
  24                         url_fputs(fh, strcat("#date ", strftime(true, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  25 #ifdef WATERMARK
  26                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  27 #endif
  28                         url_fputs(fh, strcat("#config ", ftos(crc16(false, cvar_purechanges)), "\n"));
  29                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  30                         n = tokenizebyseparator(cvar_purechanges, "\n");
  31                         for(i = 0; i < n; ++i)
  32                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  33                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  34                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  35                                 {
  36                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  37                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  38                                         if(v != '0 0 0')
  39                                         {
  40                                                 //vector is: kills hits damage
  41                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  42                                                 url_fputs(fh, sprintf("%d %d %g\n", v.x, v.y, v.z));
  43                                         }
  44                                 }
  45                         url_fputs(fh, "#end\n\n");
  46                         url_fclose(fh);
  47                         break;
  48                 case URL_READY_CANREAD:
  49                         // url_fclose is processing, we got a response for writing the data
  50                         // this must come from HTTP
  51                         LOG_INFO("Got response from weapon stats server:\n");
  52                         while((s = url_fgets(fh)))
  53                                 LOG_INFO("  ", s, "\n");
  54                         LOG_INFO("End of response.\n");
  55                         url_fclose(fh);
  56                         break;
  57                 case URL_READY_CLOSED:
  58                         // url_fclose has finished
  59                         LOG_INFO("Weapon stats written\n");
  60                         buf_del(weaponstats_buffer);
  61                         weaponstats_buffer = -1;
  62                         break;
  63                 case URL_READY_ERROR:
  64                 default:
  65                         LOG_INFO("Weapon stats writing failed: ", ftos(status), "\n");
  66                         buf_del(weaponstats_buffer);
  67                         weaponstats_buffer = -1;
  68                         break;
  69         }
  70 }
  71
  72 void WeaponStats_Shutdown()
  73 {
  74         if(weaponstats_buffer < 0)
  75                 return;
  76         if(autocvar_sv_weaponstats_file != "")
  77         {
  78                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  79         }
  80         else
  81         {
  82                 buf_del(weaponstats_buffer);
  83                 weaponstats_buffer = -1;
  84         }
  85 }
  86
  87 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  88 {
  89         float idx;
  90         if(weaponstats_buffer < 0)
  91                 return;
  92         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  93                 return;
  94         if(awep > WEP_LAST || vwep > WEP_LAST)
  95                 return;
  96         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  97         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  98 }
  99
 100 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 101 {
 102         if(damage < 0)
 103                 error("negative damage?");
 104         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 105 }
 106
 107 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 108 {
 109         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 110 }