qcsrc/server/weapons/weaponstats.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../../dpdefs/progsdefs.qh"
   5         #include "../../dpdefs/dpextensions.qh"
   6         #include "../../common/urllib.qh"
   7         #include "../../common/weapons/weapons.qh"
   8         #include "weaponstats.qh"
   9         #include "../autocvars.qh"
  10         #include "../defs.qh"
  11 #endif
  12
  13 void WeaponStats_Init()
  14 {
  15         weaponstats_buffer = ((autocvar_sv_weaponstats_file != "") ? buf_create() : -1);
  16 }
  17
  18 void WeaponStats_ready(entity fh, entity pass, float status)
  19 {
  20         float i, j, n, ibot, jbot, idx;
  21         vector v;
  22         string prefix, s;
  23         switch(status)
  24         {
  25                 case URL_READY_CANWRITE:
  26                         // we can write
  27                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  28                         url_fputs(fh, "#begin statsfile\n");
  29                         url_fputs(fh, strcat("#date ", strftime(true, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  30 #ifdef WATERMARK
  31                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  32 #endif
  33                         url_fputs(fh, strcat("#config ", ftos(crc16(false, cvar_purechanges)), "\n"));
  34                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  35                         n = tokenizebyseparator(cvar_purechanges, "\n");
  36                         for(i = 0; i < n; ++i)
  37                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  38                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  39                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  40                                 {
  41                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  42                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  43                                         if(v != '0 0 0')
  44                                         {
  45                                                 //vector is: kills hits damage
  46                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  47                                                 url_fputs(fh, sprintf("%d %d %g\n", v.x, v.y, v.z));
  48                                         }
  49                                 }
  50                         url_fputs(fh, "#end\n\n");
  51                         url_fclose(fh);
  52                         break;
  53                 case URL_READY_CANREAD:
  54                         // url_fclose is processing, we got a response for writing the data
  55                         // this must come from HTTP
  56                         print("Got response from weapon stats server:\n");
  57                         while((s = url_fgets(fh)))
  58                                 print("  ", s, "\n");
  59                         print("End of response.\n");
  60                         url_fclose(fh);
  61                         break;
  62                 case URL_READY_CLOSED:
  63                         // url_fclose has finished
  64                         print("Weapon stats written\n");
  65                         buf_del(weaponstats_buffer);
  66                         weaponstats_buffer = -1;
  67                         break;
  68                 case URL_READY_ERROR:
  69                 default:
  70                         print("Weapon stats writing failed: ", ftos(status), "\n");
  71                         buf_del(weaponstats_buffer);
  72                         weaponstats_buffer = -1;
  73                         break;
  74         }
  75 }
  76
  77 void WeaponStats_Shutdown()
  78 {
  79         if(weaponstats_buffer < 0)
  80                 return;
  81         if(autocvar_sv_weaponstats_file != "")
  82         {
  83                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  84         }
  85         else
  86         {
  87                 buf_del(weaponstats_buffer);
  88                 weaponstats_buffer = -1;
  89         }
  90 }
  91
  92 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  93 {
  94         float idx;
  95         if(weaponstats_buffer < 0)
  96                 return;
  97         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  98                 return;
  99         if(awep > WEP_LAST || vwep > WEP_LAST)
 100                 return;
 101         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 102         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 103 }
 104
 105 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 106 {
 107         if(damage < 0)
 108                 error("negative damage?");
 109         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 110 }
 111
 112 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 113 {
 114         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 115 }