Update weapon skin with CSQC
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / weapons / weaponsystem.qc
1 #include "weaponsystem.qh"
2
3 #include "selection.qh"
4
5 #include "../command/common.qh"
6 #include <server/mutators/_mod.qh>
7 #include "../round_handler.qh"
8 #include <server/cheats.qh>
9 #include <server/resources.qh>
10 #include <common/t_items.qh>
11 #include <common/animdecide.qh>
12 #include <common/constants.qh>
13 #include <common/net_linked.qh>
14 #include <common/monsters/_mod.qh>
15 #include <common/notifications/all.qh>
16 #include <common/util.qh>
17 #include <common/weapons/_all.qh>
18 #include <common/state.qh>
19 #include <lib/csqcmodel/sv_model.qh>
20 #include <common/wepent.qh>
21
22 .int state;
23
24 .float weapon_frametime;
25
26 float W_WeaponRateFactor(entity this)
27 {
28         float t = 1;
29         if(g_weaponratefactor > 0)
30                 t = 1.0 / g_weaponratefactor;
31
32         MUTATOR_CALLHOOK(WeaponRateFactor, t, this);
33         t = M_ARGV(0, float);
34
35         return t;
36 }
37
38 float W_WeaponSpeedFactor(entity this)
39 {
40         float t = 1.0 * g_weaponspeedfactor;
41
42         MUTATOR_CALLHOOK(WeaponSpeedFactor, t, this);
43         t = M_ARGV(0, float);
44
45         return t;
46 }
47
48
49 bool CL_Weaponentity_CustomizeEntityForClient(entity this, entity client)
50 {
51         this.viewmodelforclient = this.owner;
52         if (IS_SPEC(client) && client.enemy == this.owner) this.viewmodelforclient = client;
53         return false;
54 }
55
56 vector CL_Weapon_GetShotOrg(int wpn)
57 {
58         entity wi = Weapons_from(wpn);
59         entity e = spawn();
60         CL_WeaponEntity_SetModel(e, wi.mdl, false);
61         vector ret = e.movedir;
62         CL_WeaponEntity_SetModel(e, "", false);
63         delete(e);
64         return ret;
65 }
66
67 .float m_alpha;
68 .string w_weaponname;
69 .int w_dmg;
70 .int w_deadflag;
71
72 void CL_Weaponentity_Think(entity this)
73 {
74         this.nextthink = time;
75         if (game_stopped) this.frame = this.anim_idle.x;
76         .entity weaponentity = this.weaponentity_fld;
77         if (this.owner.(weaponentity) != this)
78         {
79                 // owner has new gun; remove old one
80                 if (this.weaponchild) delete(this.weaponchild);
81                 if (this.hook) delete(this.hook);
82                 delete(this);
83                 return;
84         }
85         if (IS_DEAD(this.owner))
86         {
87                 // owner died; disappear
88                 this.model = "";
89                 if (this.weaponchild) this.weaponchild.model = "";
90                 return;
91         }
92         if (this.w_weaponname != this.weaponname
93             || this.w_dmg != this.modelindex
94             || this.w_deadflag != this.deadflag)
95         {
96                 // owner changed weapons; update appearance
97                 this.w_weaponname = this.weaponname;
98                 this.w_dmg = this.modelindex;
99                 this.w_deadflag = this.deadflag;
100
101                 CL_WeaponEntity_SetModel(this, this.weaponname, true);
102         }
103
104         this.alpha = -1;  // TODO: don't render this entity at all
105
106         if (this.owner.alpha == default_player_alpha) this.m_alpha = default_weapon_alpha;
107         else if (this.owner.alpha != 0) this.m_alpha = this.owner.alpha;
108         else this.m_alpha  = 1;
109
110         if (this.weaponchild)
111         {
112                 this.weaponchild.alpha = this.alpha;
113                 this.weaponchild.effects = this.effects;
114         }
115 }
116
117 void CL_ExteriorWeaponentity_Think(entity this)
118 {
119         this.nextthink = time;
120         .entity weaponentity = this.weaponentity_fld;
121         entity w_ent = this.owner.(weaponentity);
122         if (this.owner.exteriorweaponentity != this)
123         {
124                 delete(this);
125                 return;
126         }
127         if (IS_DEAD(this.owner))
128         {
129                 this.model = "";
130                 return;
131         }
132         if (this.weaponname != w_ent.weaponname || this.dmg != w_ent.modelindex
133             || this.deadflag != w_ent.deadflag)
134         {
135                 this.weaponname = w_ent.weaponname;
136                 this.dmg = w_ent.modelindex;
137                 this.deadflag = w_ent.deadflag;
138                 if (w_ent.weaponname != "")
139                 {
140                         _setmodel(this, W_Model(strcat("v_", w_ent.weaponname, ".md3")));
141                         setsize(this, '0 0 0', '0 0 0');
142                 }
143                 else this.model = "";
144
145                 int tag_found;
146                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
147                 {
148                         this.tag_index = tag_found;
149                         this.tag_entity = this.owner;
150                 }
151                 else
152                 {
153                         setattachment(this, this.owner, "bip01 r hand");
154                 }
155         }
156         this.effects = this.owner.effects;
157         this.effects |= EF_LOWPRECISION;
158         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
159         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
160         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
161         else this.alpha = 1;
162
163     Weapon wep = this.owner.(weaponentity).m_weapon;
164         if (wep) this.glowmod = weaponentity_glowmod(wep, this.owner, this.owner.clientcolors, this.owner.(weaponentity));
165         this.colormap = this.owner.colormap;
166         this.skin = w_ent.skin;
167
168         CSQCMODEL_AUTOUPDATE(this);
169 }
170
171 // spawning weaponentity for client
172 void CL_SpawnWeaponentity(entity actor, .entity weaponentity)
173 {
174         entity view = actor.(weaponentity) = new(weaponentity);
175         view.solid = SOLID_NOT;
176         view.owner = actor;
177         setmodel(view, MDL_Null);  // precision set when changed
178         setorigin(view, '0 0 0');
179         view.weaponentity_fld = weaponentity;
180         setthink(view, CL_Weaponentity_Think);
181         view.nextthink = time;
182         view.viewmodelforclient = actor;
183         view.draggable = drag_undraggable;
184         setcefc(view, CL_Weaponentity_CustomizeEntityForClient);
185
186         wepent_link(view);
187
188         if (weaponentity == weaponentities[0]) // only one exterior model, thank you very much
189         {
190                 entity exterior = actor.exteriorweaponentity = new(exteriorweaponentity);
191                 exterior.solid = SOLID_NOT;
192                 exterior.owner = actor;
193                 exterior.draggable = drag_undraggable;
194                 exterior.weaponentity_fld = weaponentity;
195                 setorigin(exterior, '0 0 0');
196                 setthink(exterior, CL_ExteriorWeaponentity_Think);
197                 exterior.nextthink = time;
198
199                 CSQCMODEL_AUTOINIT(exterior);
200         }
201 }
202
203 // Weapon subs
204 void w_clear(Weapon thiswep, entity actor, .entity weaponentity, int fire)
205 {
206         actor.(weaponentity).m_weapon = WEP_Null;
207         actor.(weaponentity).m_switchingweapon = WEP_Null;
208         entity this = actor.(weaponentity);
209         if (this)
210         {
211                 this.state = WS_CLEAR;
212                 this.effects = 0;
213         }
214 }
215
216 void w_ready(Weapon thiswep, entity actor, .entity weaponentity, int fire)
217 {
218         entity this = actor.(weaponentity);
219         if (this) this.state = WS_READY;
220         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
221 }
222
223 .float prevdryfire;
224 .float prevwarntime;
225 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary, .entity weaponentity)
226 {
227         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
228         bool ammo = false;
229         if (secondary) ammo = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
230         else ammo = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
231         if (ammo) return true;
232         // always keep the Mine Layer if we placed mines, so that we can detonate them
233         if (thiswep == WEP_MINE_LAYER)
234         {
235                 IL_EACH(g_mines, it.owner == actor && it.weaponentity_fld == weaponentity,
236                 {
237                         return false;
238                 });
239         }
240
241         if (thiswep == WEP_SHOTGUN)
242                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;           // no clicking, just allow
243
244         if (thiswep == actor.(weaponentity).m_switchweapon && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
245         {
246                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
247                 actor.prevdryfire = time;
248         }
249
250         // check if the other firing mode has enough ammo
251         bool ammo_other = false;
252         if (secondary) ammo_other = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
253         else ammo_other = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
254         if (ammo_other)
255         {
256                 if (time - actor.prevwarntime > 1)
257                 {
258                         Send_Notification(
259                                 NOTIF_ONE,
260                                 actor,
261                                 MSG_MULTI,
262                                 ITEM_WEAPON_PRIMORSEC,
263                                 thiswep.m_id,
264                                 secondary,
265                                 (1 - secondary)
266                                          );
267                 }
268                 actor.prevwarntime = time;
269         }
270         else  // this weapon is totally unable to fire, switch to another one
271         {
272                 W_SwitchToOtherWeapon(actor, weaponentity);
273         }
274
275         return false;
276 }
277
278 .float race_penalty;
279 bool weapon_prepareattack_check(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
280 {
281         if (actor.weaponentity == NULL) return true;
282         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary, weaponentity)) return false;
283
284         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
285         // if all players readied up and the countdown is running
286         if (time < game_starttime || time < actor.race_penalty) return false;
287
288         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
289                 return false;
290
291         // do not even think about shooting if switching
292         if (actor.(weaponentity).m_switchweapon != actor.(weaponentity).m_weapon) return false;
293
294         if (attacktime >= 0)
295         {
296                 // don't fire if previous attack is not finished
297                 if (ATTACK_FINISHED(actor, weaponentity) > time + actor.(weaponentity).weapon_frametime * 0.5) return false;
298                 entity this = actor.(weaponentity);
299                 // don't fire while changing weapon
300                 if (this.state != WS_READY) return false;
301         }
302         return true;
303 }
304
305 void weapon_prepareattack_do(entity actor, .entity weaponentity, bool secondary, float attacktime)
306 {
307         entity this = actor.(weaponentity);
308         if (this == NULL) return;
309         this.state = WS_INUSE;
310
311         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
312
313         // if the weapon hasn't been firing continuously, reset the timer
314         if (attacktime >= 0)
315         {
316                 if (ATTACK_FINISHED(actor, weaponentity) < time - this.weapon_frametime * 1.5)
317                 {
318                         ATTACK_FINISHED(actor, weaponentity) = time;
319                         // dprint("resetting attack finished to ", ftos(time), "\n");
320                 }
321                 float arate = W_WeaponRateFactor(actor);
322                 ATTACK_FINISHED(actor, weaponentity) = ATTACK_FINISHED(actor, weaponentity) + attacktime * arate;
323
324                 if(autocvar_g_weaponswitch_debug_alternate && W_DualWielding(actor))
325                 {
326                         int slot = weaponslot(weaponentity);
327                         for(int wepslot = 0; wepslot < MAX_WEAPONSLOTS; ++wepslot)
328                         {
329                                 if(slot == wepslot)
330                                         continue;
331                                 .entity wepent = weaponentities[wepslot];
332                                 if(actor.(wepent) && actor.(wepent).m_weapon != WEP_Null)
333                                 {
334                                         if(ATTACK_FINISHED(actor, wepent) > time + actor.(wepent).weapon_frametime * 0.5)
335                                                 continue; // still cooling down!
336                                         if (ATTACK_FINISHED(actor, wepent) < time - actor.(wepent).weapon_frametime * 1.5)
337                                                 ATTACK_FINISHED(actor, wepent) = time;
338                                         ATTACK_FINISHED(actor, wepent) = ATTACK_FINISHED(actor, wepent) + (attacktime * arate) / MAX_WEAPONSLOTS;
339                                 }
340                         }
341                 }
342         }
343         this.bulletcounter += 1;
344         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, weaponentity)), "\n");
345 }
346
347 bool weapon_prepareattack(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
348 {
349         if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
350         {
351                 weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
352                 return true;
353         }
354         return false;
355 }
356
357 /**
358  * @param t defer thinking until time + t
359  * @param func next think function
360  */
361 void weapon_thinkf(entity actor, .entity weaponentity, WFRAME fr, float t, void(Weapon thiswep, entity actor,
362         .entity weaponentity, int fire) func)
363 {
364         entity this = actor.(weaponentity);
365         if (this == NULL) return;
366         bool restartanim;
367         if (fr == WFRAME_DONTCHANGE)
368         {
369                 fr = this.wframe;
370                 restartanim = false;
371         }
372         else
373         {
374                 restartanim = fr != WFRAME_IDLE;
375         }
376
377         vector of = v_forward;
378         vector or = v_right;
379         vector ou = v_up;
380
381         vector a = '0 0 0';
382     this.wframe = fr;
383     if (fr == WFRAME_IDLE) a = this.anim_idle;
384     else if (fr == WFRAME_FIRE1) a = this.anim_fire1;
385     else if (fr == WFRAME_FIRE2) a = this.anim_fire2;
386     else  // if (fr == WFRAME_RELOAD)
387         a = this.anim_reload;
388     a.z *= g_weaponratefactor;
389
390         v_forward = of;
391         v_right = or;
392         v_up = ou;
393
394         if (this.weapon_think == w_ready && func != w_ready && this.state == WS_RAISE) backtrace(
395                         "Tried to override initial weapon think function - should this really happen?");
396
397         t *= W_WeaponRateFactor(actor);
398
399         // VorteX: haste can be added here
400         if (this.weapon_think == w_ready)
401         {
402                 this.weapon_nextthink = time;
403                 // dprint("started firing at ", ftos(time), "\n");
404         }
405         if (this.weapon_nextthink < time - this.weapon_frametime * 1.5
406             || this.weapon_nextthink > time + this.weapon_frametime * 1.5)
407         {
408                 this.weapon_nextthink = time;
409                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
410         }
411         this.weapon_nextthink += t;
412         this.weapon_think = func;
413         // dprint("next ", ftos(this.weapon_nextthink), "\n");
414
415         if (this)
416         {
417                 FOREACH_CLIENT(true, {
418                         if(it == actor || (IS_SPEC(it) && it.enemy == actor))
419                                 wframe_send(it, this, a, restartanim);
420                 });
421         }
422
423         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
424         {
425                 bool primary_melee = boolean(fr == WFRAME_FIRE1 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_PRI));
426                 bool secondary_melee = boolean(fr == WFRAME_FIRE2 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_SEC));
427                 int act = (primary_melee || secondary_melee)
428                         ? ANIMACTION_MELEE
429                         : ANIMACTION_SHOOT
430                         ;
431                 animdecide_setaction(actor, act, restartanim);
432         }
433         else if (actor.anim_upper_action == ANIMACTION_SHOOT || actor.anim_upper_action == ANIMACTION_MELEE)
434         {
435                 actor.anim_upper_action = 0;
436         }
437 }
438
439 bool weaponUseForbidden(entity player)
440 {
441         if (round_handler_IsActive() && !round_handler_IsRoundStarted()) return true;
442         if (MUTATOR_CALLHOOK(ForbidWeaponUse, player)) return true;
443         return false;
444 }
445
446 bool weaponLocked(entity player)
447 {
448         if (time < game_starttime && !sv_ready_restart_after_countdown) return true;
449         if (player.player_blocked) return true;
450         if (game_stopped) return true;
451         if (STAT(FROZEN, player)) return true;
452         if (MUTATOR_CALLHOOK(LockWeapon, player)) return true;
453         return false;
454 }
455
456 .bool hook_switchweapon;
457
458 void W_WeaponFrame(Player actor, .entity weaponentity)
459 {
460         TC(Player, actor);
461         TC(PlayerState, PS(actor));
462         entity this = actor.(weaponentity);
463         if (frametime) this.weapon_frametime = frametime;
464
465         if (!this || GetResource(actor, RES_HEALTH) < 1) return;  // Dead player can't use weapons and injure impulse commands
466
467         int button_atck = PHYS_INPUT_BUTTON_ATCK(actor);
468         int button_atck2 = PHYS_INPUT_BUTTON_ATCK2(actor);
469
470         if (weaponUseForbidden(actor))
471                 button_atck = button_atck2 = 0; // forbid primary and secondary fire, switching is allowed
472
473         if (weaponLocked(actor))
474         {
475                 if (this.state != WS_CLEAR)
476                 {
477                         Weapon wpn = this.m_weapon;
478                         w_ready(wpn, actor, weaponentity, button_atck | (button_atck2 << 1));
479                         return;
480                 }
481         }
482
483         if(autocvar_g_weaponswitch_debug == 2 && weaponslot(weaponentity) > 0)
484         {
485                 .entity wepe1 = weaponentities[0];
486                 entity wep1 = actor.(wepe1);
487                 this.m_switchweapon = wep1.m_switchweapon;
488                 entity store = IS_PLAYER(actor) ? PS(actor) : actor;
489                 if(!(this.m_switchweapon.spawnflags & WEP_FLAG_DUALWIELD) && !(store.dual_weapons & wep1.m_switchweapon.m_wepset))
490                 {
491                         this.m_weapon = WEP_Null;
492                         this.m_switchingweapon = WEP_Null;
493                         this.m_switchweapon = WEP_Null;
494                         this.state = WS_CLEAR;
495                         this.weaponname = "";
496                         return;
497                 }
498         }
499
500         if (this.m_switchweapon == WEP_Null)
501         {
502                 if (this.state != WS_CLEAR)
503                         w_ready(this.m_weapon, actor, weaponentity, button_atck | (button_atck2 << 1));
504                 this.m_weapon = WEP_Null;
505                 this.m_switchingweapon = WEP_Null;
506                 this.state = WS_CLEAR;
507                 this.weaponname = "";
508                 return;
509         }
510
511         makevectors(actor.v_angle);
512         vector fo = v_forward;  // save them in case the weapon think functions change it
513         vector ri = v_right;
514         vector up = v_up;
515
516         // Change weapon
517         if (this.m_weapon != this.m_switchweapon)
518         {
519                 switch (this.state)
520                 {
521                         default:
522                                 LOG_WARNF("unhandled weaponentity (%i) state for player (%i): %d", this, actor, this.state);
523                                 break;
524                         case WS_INUSE:
525                         case WS_RAISE:
526                                 break;
527                         case WS_CLEAR:
528                         {
529                                 // end switching!
530                                 Weapon newwep = this.m_switchweapon;
531                                 this.m_switchingweapon = newwep;
532
533                                 // the two weapon entities will notice this has changed and update their models
534                                 this.m_weapon = newwep;
535                                 this.weaponname = newwep.mdl;
536                                 this.bulletcounter = 0;
537                                 newwep.wr_setup(newwep, actor, weaponentity);
538                                 this.state = WS_RAISE;
539
540                                 // set our clip load to the load of the weapon we switched to, if it's reloadable
541                                 if ((newwep.spawnflags & WEP_FLAG_RELOADABLE) && newwep.reloading_ammo)  // prevent accessing undefined cvars
542                                 {
543                                         this.clip_load = this.(weapon_load[this.m_switchweapon.m_id]);
544                                         this.clip_size = newwep.reloading_ammo;
545                                 }
546                                 else
547                                 {
548                                         this.clip_load = this.clip_size = 0;
549                                 }
550
551                                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, newwep.switchdelay_raise, w_ready);
552                                 break;
553                         }
554                         case WS_DROP:
555                         {
556                                 // in dropping phase we can switch at any time
557                                 this.m_switchingweapon = this.m_switchweapon;
558                                 break;
559                         }
560                         case WS_READY:
561                         {
562                                 // start switching!
563                                 this.m_switchingweapon = this.m_switchweapon;
564                                 entity oldwep = this.m_weapon;
565
566                                 // set up weapon switch think in the future, and start drop anim
567                                 if (INDEPENDENT_ATTACK_FINISHED || ATTACK_FINISHED(actor, weaponentity) <= time + this.weapon_frametime * 0.5)
568                                 {
569                                         sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
570                                         this.state = WS_DROP;
571                                         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
572                                 }
573                                 break;
574                         }
575                 }
576         }
577
578         // LordHavoc: network timing test code
579         // if (actor.button0)
580         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, weaponentity)), " >= ", ftos(this.weapon_nextthink), "\n");
581
582         Weapon w = this.m_weapon;
583
584         // call the think code which may fire the weapon
585         // and do so multiple times to resolve framerate dependency issues if the
586         // server framerate is very low and the weapon fire rate very high
587         for (int c = 0; c < W_TICSPERFRAME; ++c)
588         {
589                 if (w != WEP_Null && !(STAT(WEAPONS, actor) & WepSet_FromWeapon(w)))
590                 {
591                         if (this.m_weapon == this.m_switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
592                         w = WEP_Null;
593                 }
594
595                 v_forward = fo;
596                 v_right = ri;
597                 v_up = up;
598
599                 bool block_weapon = false;
600                 {
601                         bool key_pressed = PHYS_INPUT_BUTTON_HOOK(actor) && !actor.vehicle;
602                         if (weaponUseForbidden(actor))
603                                 key_pressed = false;
604
605                         Weapon off = actor.offhand;
606                         if (off && (!(STAT(WEAPONS, actor) & WEPSET(HOOK)) || off != OFFHAND_HOOK))
607                         {
608                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
609                         }
610                         else
611                         {
612                                 if (key_pressed && this.m_switchweapon != WEP_HOOK && !actor.hook_switchweapon)
613                                         W_SwitchWeapon(actor, WEP_HOOK, weaponentity);
614                                 actor.hook_switchweapon = key_pressed;
615                                 Weapon h = WEP_HOOK;
616                                 block_weapon = (this.m_weapon == h && (button_atck || key_pressed));
617                                 h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
618                         }
619                 }
620
621                 v_forward = fo;
622                 v_right = ri;
623                 v_up = up;
624
625                 if (!block_weapon)
626                 {
627                         Weapon e = this.m_weapon;
628                         TC(Weapon, e);
629                         if (w != WEP_Null)
630                         {
631                                 e.wr_think(e, actor, weaponentity, button_atck | (button_atck2 << 1));
632                         }
633                         else if (e)
634                         {
635                                 e.wr_gonethink(e, actor, weaponentity);
636                         }
637                 }
638
639                 if (time + this.weapon_frametime * 0.5 >= this.weapon_nextthink)
640                 {
641                         if (this.weapon_think)
642                         {
643                                 v_forward = fo;
644                                 v_right = ri;
645                                 v_up = up;
646                                 Weapon wpn = this.m_weapon;
647                                 this.weapon_think(wpn, actor, weaponentity,
648                                         button_atck | (button_atck2 << 1));
649                         }
650                         else
651                         {
652                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
653                         }
654                 }
655         }
656 }
657
658 void W_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
659 {
660         flash.owner = actor;
661         flash.angles_z = random() * 360;
662
663         entity view = actor.(weaponentity);
664         entity exterior = actor.exteriorweaponentity;
665
666         if (gettagindex(view, "shot")) setattachment(flash, view, "shot");
667         else setattachment(flash, view, "tag_shot");
668         setorigin(flash, offset);
669
670         entity xflash = spawn();
671         copyentity(flash, xflash);
672
673         flash.viewmodelforclient = actor;
674
675         if (view.oldorigin.x > 0)
676         {
677                 setattachment(xflash, exterior, "");
678                 setorigin(xflash, view.oldorigin + offset);
679         }
680         else
681         {
682                 if (gettagindex(exterior, "shot")) setattachment(xflash, exterior, "shot");
683                 else setattachment(xflash, exterior, "tag_shot");
684                 setorigin(xflash, offset);
685         }
686 }
687
688 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use, .entity weaponentity)
689 {
690         if (MUTATOR_CALLHOOK(W_DecreaseAmmo, actor, actor.(weaponentity), ammo_use)) return;
691         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
692
693         ammo_use = M_ARGV(2, float);
694
695         entity w_ent = actor.(weaponentity);
696
697         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
698         if (wep.reloading_ammo)
699         {
700                 w_ent.clip_load -= ammo_use;
701                 w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
702         }
703         else if (wep.ammo_type != RES_NONE)
704         {
705                 float ammo = GetResource(actor, wep.ammo_type);
706                 if (ammo < ammo_use)
707                 {
708                         backtrace(sprintf(
709                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
710                                 "Please notify the developers immediately with a copy of this backtrace!\n",
711                                 ammo_use,
712                                 wep.netname,
713                                 GetAmmoPicture(wep.ammo_type),
714                                 actor.netname,
715                                 ammo
716                                              ));
717                 }
718                 SetResource(actor, wep.ammo_type, ammo - ammo_use);
719         }
720 }
721
722 // weapon reloading code
723
724 .float reload_ammo_amount, reload_ammo_min, reload_time;
725 .float reload_complain;
726 .string reload_sound;
727
728 void W_ReloadedAndReady(Weapon thiswep, entity actor, .entity weaponentity, int fire)
729 {
730         // finish the reloading process, and do the ammo transfer
731
732         entity w_ent = actor.(weaponentity);
733         Weapon wpn = w_ent.m_weapon;
734
735         w_ent.clip_load = w_ent.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
736
737         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
738         if (!w_ent.reload_ammo_min || (actor.items & IT_UNLIMITED_WEAPON_AMMO) || wpn.ammo_type == RES_NONE)
739         {
740                 w_ent.clip_load = w_ent.reload_ammo_amount;
741         }
742         else
743         {
744                 // make sure we don't add more ammo than we have
745                 float ammo = GetResource(actor, wpn.ammo_type);
746                 float load = min(w_ent.reload_ammo_amount - w_ent.clip_load, ammo);
747                 w_ent.clip_load += load;
748                 SetResource(actor, wpn.ammo_type, ammo - load);
749         }
750         w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
751
752         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
753         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
754         // so your weapon is disabled for a few seconds without reason
755
756         // ATTACK_FINISHED(actor, weaponentity) -= w_ent.reload_time - 1;
757
758         w_ready(wpn, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
759 }
760
761 void W_Reload(entity actor, .entity weaponentity, float sent_ammo_min, Sound sent_sound)
762 {
763         TC(Sound, sent_sound);
764         // set global values to work with
765         entity this = actor.(weaponentity);
766         Weapon e = this.m_weapon;
767
768         if (MUTATOR_CALLHOOK(W_Reload, actor)) return;
769
770         this.reload_ammo_min = sent_ammo_min;
771         this.reload_ammo_amount = e.reloading_ammo;
772         this.reload_time = e.reloading_time;
773         strcpy(actor.reload_sound, Sound_fixpath(sent_sound));
774
775         // don't reload weapons that don't have the RELOADABLE flag
776         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
777         {
778                 LOG_TRACE(
779                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
780                 return;
781         }
782
783         // return if reloading is disabled for this weapon
784         if (!this.reload_ammo_amount) return;
785
786         // our weapon is fully loaded, no need to reload
787         if (this.clip_load >= this.reload_ammo_amount) return;
788
789         // no ammo, so nothing to load
790         if (e.ammo_type != RES_NONE)
791         {
792                 if (!GetResource(actor, e.ammo_type) && this.reload_ammo_min)
793                 {
794                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
795                         {
796                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
797                                 {
798                                         play2(actor, SND(UNAVAILABLE));
799                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", this.m_weapon.m_name, "\n"));
800                                         actor.reload_complain = time + 1;
801                                 }
802                                 // switch away if the amount of ammo is not enough to keep using this weapon
803                                 if (!(e.wr_checkammo1(e, actor, weaponentity) + e.wr_checkammo2(e, actor, weaponentity)))
804                                 {
805                                         this.clip_load = -1;  // reload later
806                                         W_SwitchToOtherWeapon(actor, weaponentity);
807                                 }
808                                 return;
809                         }
810                 }
811         }
812
813         if (this)
814         {
815                 if (this.wframe == WFRAME_RELOAD) return;
816
817                 // allow switching away while reloading, but this will cause a new reload!
818                 this.state = WS_READY;
819         }
820
821         // now begin the reloading process
822
823         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
824
825         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
826         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
827         // so your weapon is disabled for a few seconds without reason
828
829         // ATTACK_FINISHED(actor, weaponentity) = max(time, ATTACK_FINISHED(actor, weaponentity)) + this.reload_time + 1;
830
831         weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, this.reload_time, W_ReloadedAndReady);
832
833         if (this.clip_load < 0) this.clip_load = 0;
834         this.old_clip_load = this.clip_load;
835         this.clip_load = this.(weapon_load[this.m_weapon.m_id]) = -1;
836 }
837
838 void W_DropEvent(.void(Weapon, entity actor, .entity) event, entity player, float weapon_type, entity weapon_item, .entity weaponentity)
839 {
840         Weapon w = Weapons_from(weapon_type);
841         weapon_dropevent_item = weapon_item;
842         w.event(w, player, weaponentity);
843 }