qcsrc/server/weapons/weaponsystem.qc

   1 #include "weaponsystem.qh"
   2
   3 #include "selection.qh"
   4
   5 #include "../command/common.qh"
   6 #include "../mutators/all.qh"
   7 #include "../round_handler.qh"
   8 #include "../t_items.qh"
   9 #include "../../common/animdecide.qh"
  10 #include "../../common/constants.qh"
  11 #include "../../common/monsters/all.qh"
  12 #include "../../common/notifications.qh"
  13 #include "../../common/util.qh"
  14 #include "../../common/weapons/all.qh"
  15 #include "../../lib/csqcmodel/sv_model.qh"
  16
  17 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
  18 {
  19         switch (algn)
  20         {
  21                 default: case 3: break; // right alignment
  22                 case 4: vecs.y = -vecs.y;
  23                         break;              // left
  24                 case 1: case 2: vecs.y = 0;
  25                         vecs.z -= 2;
  26                         break;              // center
  27         }
  28
  29         return vecs;
  30 }
  31
  32 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
  33 {
  34         string s;
  35
  36         if (visual)
  37         {
  38                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
  39         }
  40         else if (autocvar_g_shootfromeye)
  41         {
  42                 vecs.y = vecs.z = 0;
  43         }
  44         else if (autocvar_g_shootfromcenter)
  45         {
  46                 vecs.y = 0;
  47                 vecs.z -= 2;
  48         }
  49         else if ((s = autocvar_g_shootfromfixedorigin) != "")
  50         {
  51                 vector v = stov(s);
  52                 if (y_is_right) v.y = -v.y;
  53                 if (v.x != 0) vecs.x = v.x;
  54                 vecs.y = v.y;
  55                 vecs.z = v.z;
  56         }
  57         else  // just do the same as top
  58         {
  59                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
  60         }
  61
  62         return vecs;
  63 }
  64
  65 vector shotorg_adjust(vector vecs, bool y_is_right, bool visual, int algn)
  66 {
  67         return shotorg_adjust_values(vecs, y_is_right, visual, algn);
  68 }
  69
  70 .int state;
  71
  72 .float weapon_frametime;
  73
  74 float W_WeaponRateFactor()
  75 {
  76         float t = 1.0 / g_weaponratefactor;
  77
  78         MUTATOR_CALLHOOK(WeaponRateFactor, t);
  79         t = weapon_rate;
  80
  81         return t;
  82 }
  83
  84 float W_WeaponSpeedFactor()
  85 {
  86         float t = 1.0 * g_weaponspeedfactor;
  87
  88         MUTATOR_CALLHOOK(WeaponSpeedFactor, t);
  89         t = ret_float;
  90
  91         return t;
  92 }
  93
  94
  95 void weapon_thinkf(entity actor, .entity weaponentity, float fr, float t, void(Weapon thiswep, entity actor,
  96     .entity weaponentity, int fire) func);
  97
  98 bool CL_Weaponentity_CustomizeEntityForClient()
  99 {
 100         SELFPARAM();
 101         this.viewmodelforclient = this.owner;
 102         if (IS_SPEC(other) && other.enemy == this.owner) this.viewmodelforclient = other;
 103         return true;
 104 }
 105
 106 /*
 107  * supported formats:
 108  *
 109  * 1. simple animated model, muzzle flash handling on h_ model:
 110  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 111  *      tags:
 112  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 113  *        shell = casings ejection point (must be on the right hand side of the gun)
 114  *        weapon = attachment for v_tuba.md3
 115  *    v_tuba.md3 - first and third person model
 116  *    g_tuba.md3 - pickup model
 117  *
 118  * 2. simple animated model, muzzle flash handling on v_ model:
 119  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 120  *      tags:
 121  *        weapon = attachment for v_tuba.md3
 122  *    v_tuba.md3 - first and third person model
 123  *      tags:
 124  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 125  *        shell = casings ejection point (must be on the right hand side of the gun)
 126  *    g_tuba.md3 - pickup model
 127  *
 128  * 3. fully animated model, muzzle flash handling on h_ model:
 129  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 130  *      tags:
 131  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 132  *        shell = casings ejection point (must be on the right hand side of the gun)
 133  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 134  *    v_tuba.md3 - third person model
 135  *    g_tuba.md3 - pickup model
 136  *
 137  * 4. fully animated model, muzzle flash handling on v_ model:
 138  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 139  *      tags:
 140  *        shot = muzzle end (shot origin)
 141  *        shell = casings ejection point (must be on the right hand side of the gun)
 142  *    v_tuba.md3 - third person model
 143  *      tags:
 144  *        shot = muzzle end (for muzzle flashes)
 145  *    g_tuba.md3 - pickup model
 146  */
 147
 148 // writes:
 149 //   this.origin, this.angles
 150 //   this.weaponentity
 151 //   this.movedir, this.view_ofs
 152 //   attachment stuff
 153 //   anim stuff
 154 // to free:
 155 //   call again with ""
 156 //   remove the ent
 157 void CL_WeaponEntity_SetModel(entity this, .entity weaponentity, string name)
 158 {
 159         if (name != "")
 160         {
 161                 // if there is a child entity, hide it until we're sure we use it
 162                 if (this.(weaponentity)) this.(weaponentity).model = "";
 163                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 164                 int v_shot_idx = gettagindex(this, "shot");  // used later
 165                 if (!v_shot_idx) v_shot_idx = gettagindex(this, "tag_shot");
 166
 167                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 168                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 169                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 170                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 171                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 172                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 173
 174                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 175                 // if we don't, this is a "real" animated model
 176                 if (gettagindex(this, "weapon"))
 177                 {
 178                         if (!this.(weaponentity)) this.(weaponentity) = new(weaponentity);
 179                         _setmodel(this.(weaponentity), W_Model(strcat("v_", name, ".md3")));
 180                         setattachment(this.(weaponentity), this, "weapon");
 181                 }
 182                 else if (gettagindex(this, "tag_weapon"))
 183                 {
 184                         if (!this.(weaponentity)) this.(weaponentity) = new(weaponentity);
 185                         _setmodel(this.(weaponentity), W_Model(strcat("v_", name, ".md3")));
 186                         setattachment(this.(weaponentity), this, "tag_weapon");
 187                 }
 188                 else
 189                 {
 190                         if (this.(weaponentity)) remove(this.(weaponentity));
 191                         this.(weaponentity) = NULL;
 192                 }
 193
 194                 setorigin(this, '0 0 0');
 195                 this.angles = '0 0 0';
 196                 this.frame = 0;
 197                 this.viewmodelforclient = NULL;
 198
 199                 float idx;
 200
 201                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 202                 {
 203                         this.movedir = gettaginfo(this.(weaponentity), v_shot_idx);
 204                 }
 205                 else
 206                 {
 207                         idx = gettagindex(this, "shot");
 208                         if (!idx) idx = gettagindex(this, "tag_shot");
 209                         if (idx)
 210                         {
 211                                 this.movedir = gettaginfo(this, idx);
 212                         }
 213                         else
 214                         {
 215                                 LOG_INFO("WARNING: weapon model ", this.model,
 216                                         " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 217                                 this.movedir = '0 0 0';
 218                         }
 219                 }
 220
 221                 if (this.(weaponentity))  // v_ model attached to invisible h_ model
 222                 {
 223                         idx = gettagindex(this.(weaponentity), "shell");
 224                         if (!idx) idx = gettagindex(this.(weaponentity), "tag_shell");
 225                         if (idx) this.spawnorigin = gettaginfo(this.(weaponentity), idx);
 226                 }
 227                 else
 228                 {
 229                         idx = 0;
 230                 }
 231                 if (!idx)
 232                 {
 233                         idx = gettagindex(this, "shell");
 234                         if (!idx) idx = gettagindex(this, "tag_shell");
 235                         if (idx)
 236                         {
 237                                 this.spawnorigin = gettaginfo(this, idx);
 238                         }
 239                         else
 240                         {
 241                                 LOG_INFO("WARNING: weapon model ", this.model,
 242                                         " does not support the 'shell' tag, will display casings wrong\n");
 243                                 this.spawnorigin = this.movedir;
 244                         }
 245                 }
 246
 247                 if (v_shot_idx)
 248                 {
 249                         this.oldorigin = '0 0 0';  // use regular attachment
 250                 }
 251                 else
 252                 {
 253                         if (this.(weaponentity))
 254                         {
 255                                 idx = gettagindex(this, "weapon");
 256                                 if (!idx) idx = gettagindex(this, "tag_weapon");
 257                         }
 258                         else
 259                         {
 260                                 idx = gettagindex(this, "handle");
 261                                 if (!idx) idx = gettagindex(this, "tag_handle");
 262                         }
 263                         if (idx)
 264                         {
 265                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 266                         }
 267                         else
 268                         {
 269                                 LOG_INFO("WARNING: weapon model ", this.model,
 270                                         " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 271                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 272                         }
 273                 }
 274
 275                 this.viewmodelforclient = this.owner;
 276         }
 277         else
 278         {
 279                 this.model = "";
 280                 if (this.(weaponentity)) remove(this.(weaponentity));
 281                 this.(weaponentity) = NULL;
 282                 this.movedir = '0 0 0';
 283                 this.spawnorigin = '0 0 0';
 284                 this.oldorigin = '0 0 0';
 285                 this.anim_fire1  = '0 1 0.01';
 286                 this.anim_fire2  = '0 1 0.01';
 287                 this.anim_idle   = '0 1 0.01';
 288                 this.anim_reload = '0 1 0.01';
 289         }
 290
 291         this.view_ofs = '0 0 0';
 292
 293         if (this.movedir.x >= 0)
 294         {
 295                 vector v0 = this.movedir;
 296                 this.movedir = shotorg_adjust(v0, false, false, this.owner.cvar_cl_gunalign);
 297                 this.view_ofs = shotorg_adjust(v0, false, true, this.owner.cvar_cl_gunalign) - v0;
 298         }
 299         this.owner.stat_shotorg = compressShotOrigin(this.movedir);
 300         this.movedir = decompressShotOrigin(this.owner.stat_shotorg); // make them match perfectly
 301
 302         this.spawnorigin += this.view_ofs;                            // offset the casings origin by the same amount
 303
 304         // check if an instant weapon switch occurred
 305         setorigin(this, this.view_ofs);
 306         // reset animstate now
 307         this.wframe = WFRAME_IDLE;
 308         setanim(this, this.anim_idle, true, false, true);
 309 }
 310
 311 vector CL_Weapon_GetShotOrg(float wpn)
 312 {
 313         entity wi = Weapons_from(wpn);
 314         entity e = spawn();
 315         .entity weaponentity = weaponentities[0];
 316         CL_WeaponEntity_SetModel(e, weaponentity, wi.mdl);
 317         vector ret = e.movedir;
 318         CL_WeaponEntity_SetModel(e, weaponentity, "");
 319         remove(e);
 320         return ret;
 321 }
 322
 323 ..entity weaponentity_fld;
 324
 325 void CL_Weaponentity_Think()
 326 {
 327         SELFPARAM();
 328         this.nextthink = time;
 329         if (intermission_running) this.frame = this.anim_idle.x;
 330         .entity weaponentity = this.weaponentity_fld;
 331         if (this.owner.(weaponentity) != this)
 332         {
 333                 if (this.(weaponentity)) remove(this.(weaponentity));
 334                 remove(this);
 335                 return;
 336         }
 337         if (this.owner.deadflag != DEAD_NO)
 338         {
 339                 this.model = "";
 340                 if (this.(weaponentity)) this.(weaponentity).model = "";
 341                 return;
 342         }
 343         if (this.weaponname != this.owner.weaponname || this.dmg != this.owner.modelindex
 344             || this.deadflag != this.owner.deadflag)
 345         {
 346                 this.weaponname = this.owner.weaponname;
 347                 this.dmg = this.owner.modelindex;
 348                 this.deadflag = this.owner.deadflag;
 349
 350                 CL_WeaponEntity_SetModel(this, weaponentity, this.owner.weaponname);
 351         }
 352
 353         int tb = (this.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 354         this.effects = this.owner.effects & EFMASK_CHEAP;
 355         this.effects &= ~EF_LOWPRECISION;
 356         this.effects &= ~EF_FULLBRIGHT;  // can mask team color, so get rid of it
 357         this.effects &= ~EF_TELEPORT_BIT;
 358         this.effects &= ~EF_RESTARTANIM_BIT;
 359         this.effects |= tb;
 360         if (weaponentity != weaponentities[0]) this.effects |= EF_NODRAW;
 361
 362         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
 363         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
 364         else this.alpha = 1;
 365
 366         this.glowmod = this.owner.weaponentity_glowmod;
 367         this.colormap = this.owner.colormap;
 368         if (this.(weaponentity))
 369         {
 370                 this.(weaponentity).effects = this.effects;
 371                 this.(weaponentity).alpha = this.alpha;
 372                 this.(weaponentity).colormap = this.colormap;
 373                 this.(weaponentity).glowmod = this.glowmod;
 374         }
 375
 376         this.angles = '0 0 0';
 377
 378         float f = this.weapon_nextthink - time;
 379         if (this.state == WS_RAISE && !intermission_running)
 380         {
 381                 entity newwep = Weapons_from(this.owner.switchweapon);
 382                 f = f * g_weaponratefactor / max(f, newwep.switchdelay_raise);
 383                 this.angles_x = -90 * f * f;
 384         }
 385         else if (this.state == WS_DROP && !intermission_running)
 386         {
 387                 entity oldwep = Weapons_from(this.owner.weapon);
 388                 f = 1 - f * g_weaponratefactor / max(f, oldwep.switchdelay_drop);
 389                 this.angles_x = -90 * f * f;
 390         }
 391         else if (this.state == WS_CLEAR)
 392         {
 393                 f = 1;
 394                 this.angles_x = -90 * f * f;
 395         }
 396 }
 397
 398 void CL_ExteriorWeaponentity_Think()
 399 {
 400         SELFPARAM();
 401         this.nextthink = time;
 402         if (this.owner.exteriorweaponentity != this)
 403         {
 404                 remove(this);
 405                 return;
 406         }
 407         if (this.owner.deadflag != DEAD_NO)
 408         {
 409                 this.model = "";
 410                 return;
 411         }
 412         if (this.weaponname != this.owner.weaponname || this.dmg != this.owner.modelindex
 413             || this.deadflag != this.owner.deadflag)
 414         {
 415                 this.weaponname = this.owner.weaponname;
 416                 this.dmg = this.owner.modelindex;
 417                 this.deadflag = this.owner.deadflag;
 418                 if (this.owner.weaponname != "") _setmodel(this, W_Model(strcat("v_", this.owner.weaponname, ".md3")));
 419                 else this.model = "";
 420
 421                 int tag_found;
 422                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
 423                 {
 424                         this.tag_index = tag_found;
 425                         this.tag_entity = this.owner;
 426                 }
 427                 else
 428                 {
 429                         setattachment(this, this.owner, "bip01 r hand");
 430                 }
 431         }
 432         this.effects = this.owner.effects;
 433         this.effects |= EF_LOWPRECISION;
 434         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
 435         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
 436         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
 437         else this.alpha = 1;
 438
 439         this.glowmod = this.owner.weaponentity_glowmod;
 440         this.colormap = this.owner.colormap;
 441
 442         CSQCMODEL_AUTOUPDATE(this);
 443 }
 444
 445 // spawning weaponentity for client
 446 void CL_SpawnWeaponentity(entity e, .entity weaponentity)
 447 {
 448         entity view = e.(weaponentity) = new(weaponentity);
 449         make_pure(view);
 450         view.solid = SOLID_NOT;
 451         view.owner = e;
 452         setmodel(view, MDL_Null);  // precision set when changed
 453         setorigin(view, '0 0 0');
 454         view.angles = '0 0 0';
 455         view.viewmodelforclient = e;
 456         view.flags = 0;
 457         view.weaponentity_fld = weaponentity;
 458         view.think = CL_Weaponentity_Think;
 459         view.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 460         view.nextthink = time;
 461
 462         if (weaponentity == weaponentities[0])
 463         {
 464                 entity exterior = e.exteriorweaponentity = new(exteriorweaponentity);
 465                 make_pure(exterior);
 466                 exterior.solid = SOLID_NOT;
 467                 exterior.exteriorweaponentity = exterior;
 468                 exterior.owner = e;
 469                 setorigin(exterior, '0 0 0');
 470                 exterior.angles = '0 0 0';
 471                 exterior.think = CL_ExteriorWeaponentity_Think;
 472                 exterior.nextthink = time;
 473
 474                 CSQCMODEL_AUTOINIT(exterior);
 475         }
 476 }
 477
 478 // Weapon subs
 479 void w_clear(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 480 {
 481         if (actor.weapon != -1)
 482         {
 483                 actor.weapon = 0;
 484                 actor.switchingweapon = 0;
 485         }
 486         entity this = actor.(weaponentity);
 487         if (this)
 488         {
 489                 this.state = WS_CLEAR;
 490                 this.effects = 0;
 491         }
 492 }
 493
 494 void w_ready(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 495 {
 496         entity this = actor.(weaponentity);
 497         if (this) this.state = WS_READY;
 498         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
 499 }
 500
 501 .float prevdryfire;
 502 .float prevwarntime;
 503 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary)
 504 {
 505         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
 506         bool ammo = false;
 507         if (secondary) WITH(entity, self, actor, ammo = thiswep.wr_checkammo2(thiswep));
 508         else WITH(entity, self, actor, ammo = thiswep.wr_checkammo1(thiswep));
 509         if (ammo) return true;
 510         // always keep the Mine Layer if we placed mines, so that we can detonate them
 511         if (thiswep == WEP_MINE_LAYER)
 512                 for (entity mine; (mine = find(mine, classname, "mine")); )
 513                         if (mine.owner == actor) return false;
 514
 515         if (thiswep == WEP_SHOTGUN)
 516                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;             // no clicking, just allow
 517
 518         if (thiswep == Weapons_from(actor.switchweapon) && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 519         {
 520                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
 521                 actor.prevdryfire = time;
 522         }
 523
 524         // check if the other firing mode has enough ammo
 525         bool ammo_other = false;
 526         if (secondary) WITH(entity, self, actor, ammo_other = thiswep.wr_checkammo1(thiswep));
 527         else WITH(entity, self, actor, ammo_other = thiswep.wr_checkammo2(thiswep));
 528         if (ammo_other)
 529         {
 530                 if (time - actor.prevwarntime > 1)
 531                 {
 532                         Send_Notification(
 533                                 NOTIF_ONE,
 534                                 actor,
 535                                 MSG_MULTI,
 536                                 ITEM_WEAPON_PRIMORSEC,
 537                                 thiswep.m_id,
 538                                 secondary,
 539                                 (1 - secondary)
 540                                          );
 541                 }
 542                 actor.prevwarntime = time;
 543         }
 544         else  // this weapon is totally unable to fire, switch to another one
 545         {
 546                 W_SwitchToOtherWeapon(actor);
 547         }
 548
 549         return false;
 550 }
 551
 552 .float race_penalty;
 553 bool weapon_prepareattack_check(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 554 {
 555         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary)) return false;
 556
 557         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 558         // if all players readied up and the countdown is running
 559         if (time < game_starttime || time < actor.race_penalty) return false;
 560
 561         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
 562                 return false;
 563
 564         // do not even think about shooting if switching
 565         if (actor.switchweapon != actor.weapon) return false;
 566
 567         if (attacktime >= 0)
 568         {
 569                 int slot = weaponslot(weaponentity);
 570                 // don't fire if previous attack is not finished
 571                 if (ATTACK_FINISHED(actor, slot) > time + actor.weapon_frametime * 0.5) return false;
 572                 entity this = actor.(weaponentity);
 573                 // don't fire while changing weapon
 574                 if (this.state != WS_READY) return false;
 575         }
 576         return true;
 577 }
 578
 579 void weapon_prepareattack_do(entity actor, .entity weaponentity, bool secondary, float attacktime)
 580 {
 581         entity this = actor.(weaponentity);
 582         this.state = WS_INUSE;
 583
 584         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
 585
 586         // if the weapon hasn't been firing continuously, reset the timer
 587         if (attacktime >= 0)
 588         {
 589                 int slot = weaponslot(weaponentity);
 590                 if (ATTACK_FINISHED(actor, slot) < time - actor.weapon_frametime * 1.5)
 591                 {
 592                         ATTACK_FINISHED(actor, slot) = time;
 593                         // dprint("resetting attack finished to ", ftos(time), "\n");
 594                 }
 595                 ATTACK_FINISHED(actor, slot) = ATTACK_FINISHED(actor, slot) + attacktime * W_WeaponRateFactor();
 596         }
 597         actor.bulletcounter += 1;
 598         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, slot)), "\n");
 599 }
 600
 601 bool weapon_prepareattack(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 602 {
 603         if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
 604         {
 605                 weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
 606                 return true;
 607         }
 608         return false;
 609 }
 610
 611 void weapon_thinkf(entity actor, .entity weaponentity, float fr, float t, void(Weapon thiswep, entity actor,
 612         .entity weaponentity, int fire) func)
 613 {
 614         entity this = actor.(weaponentity);
 615         bool restartanim;
 616         if (fr == WFRAME_DONTCHANGE)
 617         {
 618                 fr = this.wframe;
 619                 restartanim = false;
 620         }
 621         else if (fr == WFRAME_IDLE)
 622         {
 623                 restartanim = false;
 624         }
 625         else
 626         {
 627                 restartanim = true;
 628         }
 629
 630         vector of = v_forward;
 631         vector or = v_right;
 632         vector ou = v_up;
 633
 634         if (this)
 635         {
 636                 this.wframe = fr;
 637                 vector a = '0 0 0';
 638                 if (fr == WFRAME_IDLE) a = this.anim_idle;
 639                 else if (fr == WFRAME_FIRE1) a = this.anim_fire1;
 640                 else if (fr == WFRAME_FIRE2) a = this.anim_fire2;
 641                 else  // if (fr == WFRAME_RELOAD)
 642                         a = this.anim_reload;
 643                 a.z *= g_weaponratefactor;
 644                 setanim(this, a, restartanim == false, restartanim, restartanim);
 645         }
 646
 647         v_forward = of;
 648         v_right = or;
 649         v_up = ou;
 650
 651         if (this.weapon_think == w_ready && func != w_ready && this.state == WS_RAISE) backtrace(
 652                         "Tried to override initial weapon think function - should this really happen?");
 653
 654         t *= W_WeaponRateFactor();
 655
 656         // VorteX: haste can be added here
 657         if (this.weapon_think == w_ready)
 658         {
 659                 this.weapon_nextthink = time;
 660                 // dprint("started firing at ", ftos(time), "\n");
 661         }
 662         if (this.weapon_nextthink < time - actor.weapon_frametime * 1.5
 663             || this.weapon_nextthink > time + actor.weapon_frametime * 1.5)
 664         {
 665                 this.weapon_nextthink = time;
 666                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
 667         }
 668         this.weapon_nextthink = this.weapon_nextthink + t;
 669         this.weapon_think = func;
 670         // dprint("next ", ftos(this.weapon_nextthink), "\n");
 671
 672         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 673         {
 674                 if ((actor.weapon == WEP_SHOCKWAVE.m_id || actor.weapon == WEP_SHOTGUN.m_id)
 675                     && fr == WFRAME_FIRE2) animdecide_setaction(actor, ANIMACTION_MELEE, restartanim);
 676                 else animdecide_setaction(actor, ANIMACTION_SHOOT, restartanim);
 677         }
 678         else
 679         {
 680                 if (actor.anim_upper_action == ANIMACTION_SHOOT
 681                     || actor.anim_upper_action == ANIMACTION_MELEE) actor.anim_upper_action = 0;
 682         }
 683 }
 684
 685 bool forbidWeaponUse(entity player)
 686 {
 687         if (time < game_starttime && !autocvar_sv_ready_restart_after_countdown) return true;
 688         if (round_handler_IsActive() && !round_handler_IsRoundStarted()) return true;
 689         if (player.player_blocked) return true;
 690         if (player.frozen) return true;
 691         if (player.weapon_blocked) return true;
 692         return false;
 693 }
 694
 695 .bool hook_switchweapon;
 696
 697 void W_WeaponFrame(entity actor)
 698 {
 699         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 700         entity this = actor.(weaponentity);
 701         if (frametime) actor.weapon_frametime = frametime;
 702
 703         if (!this || actor.health < 1) return; // Dead player can't use weapons and injure impulse commands
 704
 705
 706         if (forbidWeaponUse(actor))
 707         {
 708                 if (actor.(weaponentity).state != WS_CLEAR)
 709                 {
 710                         Weapon wpn = Weapons_from(actor.weapon);
 711                         w_ready(wpn, actor, weaponentity, (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
 712                         return;
 713                 }
 714         }
 715
 716         if (actor.switchweapon == 0)
 717         {
 718                 actor.weapon = 0;
 719                 actor.switchingweapon = 0;
 720                 this.state = WS_CLEAR;
 721                 actor.weaponname = "";
 722                 // actor.items &= ~IT_AMMO;
 723                 return;
 724         }
 725
 726         makevectors(actor.v_angle);
 727         vector fo = v_forward;  // save them in case the weapon think functions change it
 728         vector ri = v_right;
 729         vector up = v_up;
 730
 731         // Change weapon
 732         if (actor.weapon != actor.switchweapon)
 733         {
 734                 switch (this.state)
 735                 {
 736                         default:
 737                                 LOG_WARNINGF("unhandled weaponentity (%i) state for player (%i): %d\n", this, actor, this.state);
 738                                 break;
 739                         case WS_INUSE:
 740                         case WS_RAISE:
 741                                 break;
 742                         case WS_CLEAR:
 743                         {
 744                                 // end switching!
 745                                 actor.switchingweapon = actor.switchweapon;
 746                                 entity newwep = Weapons_from(actor.switchweapon);
 747
 748                                 // the two weapon entities will notice this has changed and update their models
 749                                 actor.weapon = actor.switchweapon;
 750                                 actor.weaponname = newwep.mdl;
 751                                 actor.bulletcounter = 0;
 752                                 actor.ammo_field = newwep.ammo_field;
 753                                 newwep.wr_setup(newwep);
 754                                 this.state = WS_RAISE;
 755
 756                                 // set our clip load to the load of the weapon we switched to, if it's reloadable
 757                                 if ((newwep.spawnflags & WEP_FLAG_RELOADABLE) && newwep.reloading_ammo)  // prevent accessing undefined cvars
 758                                 {
 759                                         actor.clip_load = actor.(weapon_load[actor.switchweapon]);
 760                                         actor.clip_size = newwep.reloading_ammo;
 761                                 }
 762                                 else
 763                                 {
 764                                         actor.clip_load = actor.clip_size = 0;
 765                                 }
 766
 767                                 weapon_thinkf(actor, weaponentity, WFRAME_IDLE, newwep.switchdelay_raise, w_ready);
 768                                 break;
 769                         }
 770                         case WS_DROP:
 771                         {
 772                                 // in dropping phase we can switch at any time
 773                                 actor.switchingweapon = actor.switchweapon;
 774                                 break;
 775                         }
 776                         case WS_READY:
 777                         {
 778                                 // start switching!
 779                                 actor.switchingweapon = actor.switchweapon;
 780                                 entity oldwep = Weapons_from(actor.weapon);
 781
 782                                 // set up weapon switch think in the future, and start drop anim
 783                                 if (
 784 #if INDEPENDENT_ATTACK_FINISHED
 785                                             true
 786 #else
 787                                             ATTACK_FINISHED(actor, slot) <= time + actor.weapon_frametime * 0.5
 788 #endif
 789                                    )
 790                                 {
 791                                         sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
 792                                         this.state = WS_DROP;
 793                                         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
 794                                 }
 795                                 break;
 796                         }
 797                 }
 798         }
 799
 800         // LordHavoc: network timing test code
 801         // if (actor.button0)
 802         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, slot)), " >= ", ftos(this.weapon_nextthink), "\n");
 803
 804         int w = actor.weapon;
 805
 806         // call the think code which may fire the weapon
 807         // and do so multiple times to resolve framerate dependency issues if the
 808         // server framerate is very low and the weapon fire rate very high
 809         for (int c = 0; c < W_TICSPERFRAME; ++c)
 810         {
 811                 if (w && !(actor.weapons & WepSet_FromWeapon(w)))
 812                 {
 813                         if (actor.weapon == actor.switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
 814                         w = 0;
 815                 }
 816
 817                 v_forward = fo;
 818                 v_right = ri;
 819                 v_up = up;
 820
 821                 bool block_weapon = false;
 822                 {
 823                         bool key_pressed = actor.BUTTON_HOOK && !actor.vehicle;
 824                         Weapon off = actor.offhand;
 825                         if (off && !(actor.weapons & WEPSET(HOOK)))
 826                         {
 827                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
 828                         }
 829                         else
 830                         {
 831                                 if (key_pressed && actor.switchweapon != WEP_HOOK.m_id && !actor.hook_switchweapon) W_SwitchWeapon(
 832                                                 WEP_HOOK.m_id);
 833                                 actor.hook_switchweapon = key_pressed;
 834                                 Weapon h = WEP_HOOK;
 835                                 block_weapon = (actor.weapon == h.m_id && (actor.BUTTON_ATCK || key_pressed));
 836                                 h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
 837                         }
 838                 }
 839
 840                 v_forward = fo;
 841                 v_right = ri;
 842                 v_up = up;
 843
 844                 if (!block_weapon)
 845                 {
 846                         if (w)
 847                         {
 848                                 Weapon e = Weapons_from(actor.weapon);
 849                                 e.wr_think(e, actor, weaponentity, (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
 850                         }
 851                         else
 852                         {
 853                                 Weapon w = Weapons_from(actor.weapon);
 854                                 w.wr_gonethink(w);
 855                         }
 856                 }
 857
 858                 if (time + actor.weapon_frametime * 0.5 >= this.weapon_nextthink)
 859                 {
 860                         if (this.weapon_think)
 861                         {
 862                                 v_forward = fo;
 863                                 v_right = ri;
 864                                 v_up = up;
 865                                 Weapon wpn = Weapons_from(actor.weapon);
 866                                 this.weapon_think(wpn, actor, weaponentity,
 867                                         (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
 868                         }
 869                         else
 870                         {
 871                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
 872                         }
 873                 }
 874         }
 875 }
 876
 877 void W_AttachToShotorg(entity actor, entity flash, vector offset)
 878 {
 879         .entity weaponentity = weaponentities[0];
 880         flash.owner = actor;
 881         flash.angles_z = random() * 360;
 882
 883         entity this = actor.(weaponentity);
 884         if (gettagindex(this, "shot")) setattachment(flash, this, "shot");
 885         else setattachment(flash, this, "tag_shot");
 886         setorigin(flash, offset);
 887
 888         entity xflash = spawn();
 889         copyentity(flash, xflash);
 890
 891         flash.viewmodelforclient = actor;
 892
 893         if (this.oldorigin.x > 0)
 894         {
 895                 setattachment(xflash, actor.exteriorweaponentity, "");
 896                 setorigin(xflash, this.oldorigin + offset);
 897         }
 898         else
 899         {
 900                 if (gettagindex(actor.exteriorweaponentity, "shot")) setattachment(xflash, actor.exteriorweaponentity, "shot");
 901                 else setattachment(xflash, actor.exteriorweaponentity, "tag_shot");
 902                 setorigin(xflash, offset);
 903         }
 904 }
 905
 906 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use)
 907 {
 908         if (MUTATOR_CALLHOOK(W_DecreaseAmmo, actor)) return;
 909
 910         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
 911
 912         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 913         if (wep.reloading_ammo)
 914         {
 915                 actor.clip_load -= ammo_use;
 916                 actor.(weapon_load[actor.weapon]) = actor.clip_load;
 917         }
 918         else if (wep.ammo_field != ammo_none)
 919         {
 920                 actor.(wep.ammo_field) -= ammo_use;
 921                 if (actor.(wep.ammo_field) < 0)
 922                 {
 923                         backtrace(sprintf(
 924                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
 925                                 "Please notify Samual immediately with a copy of this backtrace!\n",
 926                                 ammo_use,
 927                                 wep.netname,
 928                                 GetAmmoPicture(wep.ammo_field),
 929                                 actor.netname,
 930                                 actor.(wep.ammo_field)
 931                                              ));
 932                 }
 933         }
 934 }
 935
 936 // weapon reloading code
 937
 938 .float reload_ammo_amount, reload_ammo_min, reload_time;
 939 .float reload_complain;
 940 .string reload_sound;
 941
 942 void W_ReloadedAndReady(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 943 {
 944         // finish the reloading process, and do the ammo transfer
 945
 946         actor.clip_load = actor.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
 947
 948         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
 949         if (!actor.reload_ammo_min || actor.items & IT_UNLIMITED_WEAPON_AMMO || actor.ammo_field == ammo_none)
 950         {
 951                 actor.clip_load = actor.reload_ammo_amount;
 952         }
 953         else
 954         {
 955                 // make sure we don't add more ammo than we have
 956                 float load = min(actor.reload_ammo_amount - actor.clip_load, actor.(actor.ammo_field));
 957                 actor.clip_load += load;
 958                 actor.(actor.ammo_field) -= load;
 959         }
 960         actor.(weapon_load[actor.weapon]) = actor.clip_load;
 961
 962         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 963         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 964         // so your weapon is disabled for a few seconds without reason
 965
 966         // ATTACK_FINISHED(actor, slot) -= actor.reload_time - 1;
 967
 968         Weapon wpn = Weapons_from(actor.weapon);
 969         w_ready(wpn, actor, weaponentity, (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
 970 }
 971
 972 void W_Reload(entity actor, float sent_ammo_min, string sent_sound)
 973 {
 974         .entity weaponentity = weaponentities[0];
 975         // set global values to work with
 976         entity e = Weapons_from(actor.weapon);
 977
 978         if (MUTATOR_CALLHOOK(W_Reload, actor)) return;
 979
 980         actor.reload_ammo_min = sent_ammo_min;
 981         actor.reload_ammo_amount = e.reloading_ammo;
 982         actor.reload_time = e.reloading_time;
 983         actor.reload_sound = sent_sound;
 984
 985         // don't reload weapons that don't have the RELOADABLE flag
 986         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
 987         {
 988                 LOG_TRACE(
 989                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
 990                 return;
 991         }
 992
 993         // return if reloading is disabled for this weapon
 994         if (!actor.reload_ammo_amount) return;
 995
 996         // our weapon is fully loaded, no need to reload
 997         if (actor.clip_load >= actor.reload_ammo_amount) return;
 998
 999         // no ammo, so nothing to load
1000         if (actor.ammo_field != ammo_none)
1001         {
1002                 if (!actor.(actor.ammo_field) && actor.reload_ammo_min)
1003                 {
1004                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
1005                         {
1006                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
1007                                 {
1008                                         play2(actor, SND(UNAVAILABLE));
1009                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", WEP_NAME(actor.weapon), "\n"));
1010                                         actor.reload_complain = time + 1;
1011                                 }
1012                                 // switch away if the amount of ammo is not enough to keep using this weapon
1013                                 Weapon w = Weapons_from(actor.weapon);
1014                                 if (!(w.wr_checkammo1(w) + w.wr_checkammo2(w)))
1015                                 {
1016                                         actor.clip_load = -1;  // reload later
1017                                         W_SwitchToOtherWeapon(actor);
1018                                 }
1019                                 return;
1020                         }
1021                 }
1022         }
1023
1024         entity this = actor.(weaponentity);
1025         if (this)
1026         {
1027                 if (this.wframe == WFRAME_RELOAD) return;
1028
1029                 // allow switching away while reloading, but this will cause a new reload!
1030                 this.state = WS_READY;
1031         }
1032
1033         // now begin the reloading process
1034
1035         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
1036
1037         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1038         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1039         // so your weapon is disabled for a few seconds without reason
1040
1041         // ATTACK_FINISHED(actor, slot) = max(time, ATTACK_FINISHED(actor, slot)) + actor.reload_time + 1;
1042
1043         weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, actor.reload_time, W_ReloadedAndReady);
1044
1045         if (actor.clip_load < 0) actor.clip_load = 0;
1046         actor.old_clip_load = actor.clip_load;
1047         actor.clip_load = actor.(weapon_load[actor.weapon]) = -1;
1048 }
1049
1050 void W_DropEvent(.void(Weapon) event, entity player, float weapon_type, entity weapon_item)
1051 {
1052         Weapon w = Weapons_from(weapon_type);
1053         weapon_dropevent_item = weapon_item;
1054         WITH(entity, self, player, w.event(w));
1055 }