qcsrc/server/weapons/weaponsystem.qc

   1 #include "weaponsystem.qh"
   2
   3 #include "selection.qh"
   4
   5 #include "../command/common.qh"
   6 #include <server/mutators/_mod.qh>
   7 #include "../round_handler.qh"
   8 #include <server/cheats.qh>
   9 #include <server/resources.qh>
  10 #include <common/t_items.qh>
  11 #include <common/animdecide.qh>
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/monsters/_mod.qh>
  15 #include <common/notifications/all.qh>
  16 #include <common/util.qh>
  17 #include <common/weapons/_all.qh>
  18 #include <common/state.qh>
  19 #include <lib/csqcmodel/sv_model.qh>
  20 #include <common/wepent.qh>
  21
  22 .int state;
  23
  24 .float weapon_frametime;
  25
  26 float W_WeaponRateFactor(entity this)
  27 {
  28         float t = 1;
  29         if(g_weaponratefactor > 0)
  30                 t = 1.0 / g_weaponratefactor;
  31
  32         MUTATOR_CALLHOOK(WeaponRateFactor, t, this);
  33         t = M_ARGV(0, float);
  34
  35         return t;
  36 }
  37
  38 float W_WeaponSpeedFactor(entity this)
  39 {
  40         float t = 1.0 * g_weaponspeedfactor;
  41
  42         MUTATOR_CALLHOOK(WeaponSpeedFactor, t, this);
  43         t = M_ARGV(0, float);
  44
  45         return t;
  46 }
  47
  48
  49 bool CL_Weaponentity_CustomizeEntityForClient(entity this, entity client)
  50 {
  51         this.viewmodelforclient = this.owner;
  52         if (IS_SPEC(client) && client.enemy == this.owner) this.viewmodelforclient = client;
  53         return true;
  54 }
  55
  56 vector CL_Weapon_GetShotOrg(int wpn)
  57 {
  58         entity wi = Weapons_from(wpn);
  59         entity e = spawn();
  60         CL_WeaponEntity_SetModel(e, wi.mdl, false);
  61         vector ret = e.movedir;
  62         CL_WeaponEntity_SetModel(e, "", false);
  63         delete(e);
  64         return ret;
  65 }
  66
  67 .float m_alpha;
  68 .string w_weaponname;
  69 .int w_dmg;
  70 .int w_deadflag;
  71
  72 void CL_Weaponentity_Think(entity this)
  73 {
  74         this.nextthink = time;
  75         if (game_stopped) this.frame = this.anim_idle.x;
  76         .entity weaponentity = this.weaponentity_fld;
  77         if (this.owner.(weaponentity) != this)
  78         {
  79                 // owner has new gun; remove old one
  80                 if (this.weaponchild) delete(this.weaponchild);
  81                 if (this.hook) delete(this.hook);
  82                 delete(this);
  83                 return;
  84         }
  85         if (IS_DEAD(this.owner))
  86         {
  87                 // owner died; disappear
  88                 this.model = "";
  89                 if (this.weaponchild) this.weaponchild.model = "";
  90                 return;
  91         }
  92         if (this.w_weaponname != this.weaponname
  93             || this.w_dmg != this.modelindex
  94             || this.w_deadflag != this.deadflag)
  95         {
  96                 // owner changed weapons; update appearance
  97                 this.w_weaponname = this.weaponname;
  98                 this.w_dmg = this.modelindex;
  99                 this.w_deadflag = this.deadflag;
 100
 101                 CL_WeaponEntity_SetModel(this, this.weaponname, true);
 102         }
 103
 104         this.alpha = -1;  // TODO: don't render this entity at all
 105
 106         if (this.owner.alpha == default_player_alpha) this.m_alpha = default_weapon_alpha;
 107         else if (this.owner.alpha != 0) this.m_alpha = this.owner.alpha;
 108         else this.m_alpha  = 1;
 109
 110         if (this.weaponchild)
 111         {
 112                 this.weaponchild.alpha = this.alpha;
 113                 this.weaponchild.effects = this.effects;
 114         }
 115 }
 116
 117 void CL_ExteriorWeaponentity_Think(entity this)
 118 {
 119         this.nextthink = time;
 120         .entity weaponentity = this.weaponentity_fld;
 121         entity w_ent = this.owner.(weaponentity);
 122         if (this.owner.exteriorweaponentity != this)
 123         {
 124                 delete(this);
 125                 return;
 126         }
 127         if (IS_DEAD(this.owner))
 128         {
 129                 this.model = "";
 130                 return;
 131         }
 132         if (this.weaponname != w_ent.weaponname || this.dmg != w_ent.modelindex
 133             || this.deadflag != w_ent.deadflag)
 134         {
 135                 this.weaponname = w_ent.weaponname;
 136                 this.dmg = w_ent.modelindex;
 137                 this.deadflag = w_ent.deadflag;
 138                 if (w_ent.weaponname != "")
 139                 {
 140                         _setmodel(this, W_Model(strcat("v_", w_ent.weaponname, ".md3")));
 141                         setsize(this, '0 0 0', '0 0 0');
 142                 }
 143                 else this.model = "";
 144
 145                 int tag_found;
 146                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
 147                 {
 148                         this.tag_index = tag_found;
 149                         this.tag_entity = this.owner;
 150                 }
 151                 else
 152                 {
 153                         setattachment(this, this.owner, "bip01 r hand");
 154                 }
 155         }
 156         this.effects = this.owner.effects;
 157         this.effects |= EF_LOWPRECISION;
 158         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
 159         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
 160         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
 161         else this.alpha = 1;
 162
 163     Weapon wep = this.owner.(weaponentity).m_weapon;
 164         if (wep) this.glowmod = weaponentity_glowmod(wep, this.owner, this.owner.clientcolors, this.owner.(weaponentity));
 165         this.colormap = this.owner.colormap;
 166
 167         CSQCMODEL_AUTOUPDATE(this);
 168 }
 169
 170 // spawning weaponentity for client
 171 void CL_SpawnWeaponentity(entity actor, .entity weaponentity)
 172 {
 173         entity view = actor.(weaponentity) = new(weaponentity);
 174         view.solid = SOLID_NOT;
 175         view.owner = actor;
 176         setmodel(view, MDL_Null);  // precision set when changed
 177         setorigin(view, '0 0 0');
 178         view.weaponentity_fld = weaponentity;
 179         setthink(view, CL_Weaponentity_Think);
 180         view.nextthink = time;
 181         view.viewmodelforclient = actor;
 182         view.draggable = drag_undraggable;
 183         setcefc(view, CL_Weaponentity_CustomizeEntityForClient);
 184
 185         wepent_link(view);
 186
 187         if (weaponentity == weaponentities[0]) // only one exterior model, thank you very much
 188         {
 189                 entity exterior = actor.exteriorweaponentity = new(exteriorweaponentity);
 190                 exterior.solid = SOLID_NOT;
 191                 exterior.owner = actor;
 192                 exterior.draggable = drag_undraggable;
 193                 exterior.weaponentity_fld = weaponentity;
 194                 setorigin(exterior, '0 0 0');
 195                 setthink(exterior, CL_ExteriorWeaponentity_Think);
 196                 exterior.nextthink = time;
 197
 198                 CSQCMODEL_AUTOINIT(exterior);
 199         }
 200 }
 201
 202 // Weapon subs
 203 void w_clear(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 204 {
 205         actor.(weaponentity).m_weapon = WEP_Null;
 206         actor.(weaponentity).m_switchingweapon = WEP_Null;
 207         entity this = actor.(weaponentity);
 208         if (this)
 209         {
 210                 this.state = WS_CLEAR;
 211                 this.effects = 0;
 212         }
 213 }
 214
 215 void w_ready(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 216 {
 217         entity this = actor.(weaponentity);
 218         if (this) this.state = WS_READY;
 219         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
 220 }
 221
 222 .float prevdryfire;
 223 .float prevwarntime;
 224 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary, .entity weaponentity)
 225 {
 226         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
 227         bool ammo = false;
 228         if (secondary) ammo = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
 229         else ammo = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
 230         if (ammo) return true;
 231         // always keep the Mine Layer if we placed mines, so that we can detonate them
 232         if (thiswep == WEP_MINE_LAYER)
 233         {
 234                 IL_EACH(g_mines, it.owner == actor && it.weaponentity_fld == weaponentity,
 235                 {
 236                         return false;
 237                 });
 238         }
 239
 240         if (thiswep == WEP_SHOTGUN)
 241                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;           // no clicking, just allow
 242
 243         if (thiswep == actor.(weaponentity).m_switchweapon && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 244         {
 245                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
 246                 actor.prevdryfire = time;
 247         }
 248
 249         // check if the other firing mode has enough ammo
 250         bool ammo_other = false;
 251         if (secondary) ammo_other = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
 252         else ammo_other = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
 253         if (ammo_other)
 254         {
 255                 if (time - actor.prevwarntime > 1)
 256                 {
 257                         Send_Notification(
 258                                 NOTIF_ONE,
 259                                 actor,
 260                                 MSG_MULTI,
 261                                 ITEM_WEAPON_PRIMORSEC,
 262                                 thiswep.m_id,
 263                                 secondary,
 264                                 (1 - secondary)
 265                                          );
 266                 }
 267                 actor.prevwarntime = time;
 268         }
 269         else  // this weapon is totally unable to fire, switch to another one
 270         {
 271                 W_SwitchToOtherWeapon(actor, weaponentity);
 272         }
 273
 274         return false;
 275 }
 276
 277 .float race_penalty;
 278 bool weapon_prepareattack_check(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 279 {
 280         if (actor.weaponentity == NULL) return true;
 281         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary, weaponentity)) return false;
 282
 283         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 284         // if all players readied up and the countdown is running
 285         if (time < game_starttime || time < actor.race_penalty) return false;
 286
 287         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
 288                 return false;
 289
 290         // do not even think about shooting if switching
 291         if (actor.(weaponentity).m_switchweapon != actor.(weaponentity).m_weapon) return false;
 292
 293         if (attacktime >= 0)
 294         {
 295                 int slot = weaponslot(weaponentity);
 296                 // don't fire if previous attack is not finished
 297                 if (ATTACK_FINISHED(actor, slot) > time + actor.(weaponentity).weapon_frametime * 0.5) return false;
 298                 entity this = actor.(weaponentity);
 299                 // don't fire while changing weapon
 300                 if (this.state != WS_READY) return false;
 301         }
 302         return true;
 303 }
 304
 305 void weapon_prepareattack_do(entity actor, .entity weaponentity, bool secondary, float attacktime)
 306 {
 307         entity this = actor.(weaponentity);
 308         if (this == NULL) return;
 309         this.state = WS_INUSE;
 310
 311         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
 312
 313         // if the weapon hasn't been firing continuously, reset the timer
 314         if (attacktime >= 0)
 315         {
 316                 int slot = weaponslot(weaponentity);
 317                 if (ATTACK_FINISHED(actor, slot) < time - this.weapon_frametime * 1.5)
 318                 {
 319                         ATTACK_FINISHED(actor, slot) = time;
 320                         // dprint("resetting attack finished to ", ftos(time), "\n");
 321                 }
 322                 float arate = W_WeaponRateFactor(actor);
 323                 ATTACK_FINISHED(actor, slot) = ATTACK_FINISHED(actor, slot) + attacktime * arate;
 324
 325                 if(autocvar_g_weaponswitch_debug_alternate && W_DualWielding(actor))
 326                 {
 327                         for(int wepslot = 0; wepslot < MAX_WEAPONSLOTS; ++wepslot)
 328                         {
 329                                 if(slot == wepslot)
 330                                         continue;
 331                                 .entity wepent = weaponentities[wepslot];
 332                                 if(actor.(wepent) && actor.(wepent).m_weapon != WEP_Null)
 333                                 {
 334                                         if(ATTACK_FINISHED(actor, wepslot) > time + actor.(wepent).weapon_frametime * 0.5)
 335                                                 continue; // still cooling down!
 336                                         if (ATTACK_FINISHED(actor, wepslot) < time - actor.(wepent).weapon_frametime * 1.5)
 337                                                 ATTACK_FINISHED(actor, wepslot) = time;
 338                                         ATTACK_FINISHED(actor, wepslot) = ATTACK_FINISHED(actor, wepslot) + (attacktime * arate) * 0.5;
 339                                 }
 340                         }
 341                 }
 342         }
 343         this.bulletcounter += 1;
 344         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, slot)), "\n");
 345 }
 346
 347 bool weapon_prepareattack(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 348 {
 349         if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
 350         {
 351                 weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
 352                 return true;
 353         }
 354         return false;
 355 }
 356
 357 /**
 358  * @param t defer thinking until time + t
 359  * @param func next think function
 360  */
 361 void weapon_thinkf(entity actor, .entity weaponentity, WFRAME fr, float t, void(Weapon thiswep, entity actor,
 362         .entity weaponentity, int fire) func)
 363 {
 364         entity this = actor.(weaponentity);
 365         if (this == NULL) return;
 366         bool restartanim;
 367         if (fr == WFRAME_DONTCHANGE)
 368         {
 369                 fr = this.wframe;
 370                 restartanim = false;
 371         }
 372         else
 373         {
 374                 restartanim = fr != WFRAME_IDLE;
 375         }
 376
 377         vector of = v_forward;
 378         vector or = v_right;
 379         vector ou = v_up;
 380
 381         vector a = '0 0 0';
 382     this.wframe = fr;
 383     if (fr == WFRAME_IDLE) a = this.anim_idle;
 384     else if (fr == WFRAME_FIRE1) a = this.anim_fire1;
 385     else if (fr == WFRAME_FIRE2) a = this.anim_fire2;
 386     else  // if (fr == WFRAME_RELOAD)
 387         a = this.anim_reload;
 388     a.z *= g_weaponratefactor;
 389
 390         v_forward = of;
 391         v_right = or;
 392         v_up = ou;
 393
 394         if (this.weapon_think == w_ready && func != w_ready && this.state == WS_RAISE) backtrace(
 395                         "Tried to override initial weapon think function - should this really happen?");
 396
 397         t *= W_WeaponRateFactor(actor);
 398
 399         // VorteX: haste can be added here
 400         if (this.weapon_think == w_ready)
 401         {
 402                 this.weapon_nextthink = time;
 403                 // dprint("started firing at ", ftos(time), "\n");
 404         }
 405         if (this.weapon_nextthink < time - this.weapon_frametime * 1.5
 406             || this.weapon_nextthink > time + this.weapon_frametime * 1.5)
 407         {
 408                 this.weapon_nextthink = time;
 409                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
 410         }
 411         this.weapon_nextthink += t;
 412         this.weapon_think = func;
 413         // dprint("next ", ftos(this.weapon_nextthink), "\n");
 414
 415         if (this)
 416         {
 417                 FOREACH_CLIENT(true, {
 418                         if(it == actor || (IS_SPEC(it) && it.enemy == actor))
 419                                 wframe_send(it, this, a, restartanim);
 420                 });
 421         }
 422
 423         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 424         {
 425                 bool primary_melee = boolean(fr == WFRAME_FIRE1 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_PRI));
 426                 bool secondary_melee = boolean(fr == WFRAME_FIRE2 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_SEC));
 427                 int act = (primary_melee || secondary_melee)
 428                         ? ANIMACTION_MELEE
 429                         : ANIMACTION_SHOOT
 430                         ;
 431                 animdecide_setaction(actor, act, restartanim);
 432         }
 433         else if (actor.anim_upper_action == ANIMACTION_SHOOT || actor.anim_upper_action == ANIMACTION_MELEE)
 434         {
 435                 actor.anim_upper_action = 0;
 436         }
 437 }
 438
 439 bool forbidWeaponUse(entity player)
 440 {
 441         if (time < game_starttime && !sv_ready_restart_after_countdown) return true;
 442         if (player.player_blocked) return true;
 443         if (game_stopped) return true;
 444         if (STAT(FROZEN, player)) return true;
 445         if (MUTATOR_CALLHOOK(ForbidWeaponUse, player)) return true;
 446         return false;
 447 }
 448
 449 .bool hook_switchweapon;
 450
 451 void W_WeaponFrame(Player actor, .entity weaponentity)
 452 {
 453         TC(Player, actor);
 454         TC(PlayerState, PS(actor));
 455         entity this = actor.(weaponentity);
 456         if (frametime) this.weapon_frametime = frametime;
 457
 458         if (!this || GetResourceAmount(actor, RESOURCE_HEALTH) < 1) return;  // Dead player can't use weapons and injure impulse commands
 459
 460         int button_atck = PHYS_INPUT_BUTTON_ATCK(actor);
 461         int button_atck2 = PHYS_INPUT_BUTTON_ATCK2(actor);
 462
 463         if (round_handler_IsActive() && !round_handler_IsRoundStarted())
 464                 button_atck = button_atck2 = 0; // forbid primary and secondary fire, switching is allowed
 465
 466         if (forbidWeaponUse(actor))
 467         {
 468                 if (this.state != WS_CLEAR)
 469                 {
 470                         Weapon wpn = this.m_weapon;
 471                         w_ready(wpn, actor, weaponentity, button_atck | (button_atck2 << 1));
 472                         return;
 473                 }
 474         }
 475
 476         if(autocvar_g_weaponswitch_debug == 2 && weaponslot(weaponentity) > 0)
 477         {
 478                 .entity wepe1 = weaponentities[0];
 479                 entity wep1 = actor.(wepe1);
 480                 this.m_switchweapon = wep1.m_switchweapon;
 481                 entity store = IS_PLAYER(actor) ? PS(actor) : actor;
 482                 if(!(this.m_switchweapon.spawnflags & WEP_FLAG_DUALWIELD) && !(store.dual_weapons & wep1.m_switchweapon.m_wepset))
 483                 {
 484                         this.m_weapon = WEP_Null;
 485                         this.m_switchingweapon = WEP_Null;
 486                         this.m_switchweapon = WEP_Null;
 487                         this.state = WS_CLEAR;
 488                         this.weaponname = "";
 489                         return;
 490                 }
 491         }
 492
 493         if (this.m_switchweapon == WEP_Null)
 494         {
 495                 if (this.state != WS_CLEAR)
 496                         w_ready(this.m_weapon, actor, weaponentity, button_atck | (button_atck2 << 1));
 497                 this.m_weapon = WEP_Null;
 498                 this.m_switchingweapon = WEP_Null;
 499                 this.state = WS_CLEAR;
 500                 this.weaponname = "";
 501                 return;
 502         }
 503
 504         makevectors(actor.v_angle);
 505         vector fo = v_forward;  // save them in case the weapon think functions change it
 506         vector ri = v_right;
 507         vector up = v_up;
 508
 509         // Change weapon
 510         if (this.m_weapon != this.m_switchweapon)
 511         {
 512                 switch (this.state)
 513                 {
 514                         default:
 515                                 LOG_WARNF("unhandled weaponentity (%i) state for player (%i): %d", this, actor, this.state);
 516                                 break;
 517                         case WS_INUSE:
 518                         case WS_RAISE:
 519                                 break;
 520                         case WS_CLEAR:
 521                         {
 522                                 // end switching!
 523                                 Weapon newwep = this.m_switchweapon;
 524                                 this.m_switchingweapon = newwep;
 525
 526                                 // the two weapon entities will notice this has changed and update their models
 527                                 this.m_weapon = newwep;
 528                                 this.weaponname = newwep.mdl;
 529                                 this.bulletcounter = 0;
 530                                 newwep.wr_setup(newwep, actor, weaponentity);
 531                                 this.state = WS_RAISE;
 532
 533                                 // set our clip load to the load of the weapon we switched to, if it's reloadable
 534                                 if ((newwep.spawnflags & WEP_FLAG_RELOADABLE) && newwep.reloading_ammo)  // prevent accessing undefined cvars
 535                                 {
 536                                         this.clip_load = this.(weapon_load[this.m_switchweapon.m_id]);
 537                                         this.clip_size = newwep.reloading_ammo;
 538                                 }
 539                                 else
 540                                 {
 541                                         this.clip_load = this.clip_size = 0;
 542                                 }
 543
 544                                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, newwep.switchdelay_raise, w_ready);
 545                                 break;
 546                         }
 547                         case WS_DROP:
 548                         {
 549                                 // in dropping phase we can switch at any time
 550                                 this.m_switchingweapon = this.m_switchweapon;
 551                                 break;
 552                         }
 553                         case WS_READY:
 554                         {
 555                                 // start switching!
 556                                 this.m_switchingweapon = this.m_switchweapon;
 557                                 entity oldwep = this.m_weapon;
 558
 559                                 // set up weapon switch think in the future, and start drop anim
 560                                 if (INDEPENDENT_ATTACK_FINISHED || ATTACK_FINISHED(actor, weaponslot(weaponentity)) <= time + this.weapon_frametime * 0.5)
 561                                 {
 562                                         sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
 563                                         this.state = WS_DROP;
 564                                         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
 565                                 }
 566                                 break;
 567                         }
 568                 }
 569         }
 570
 571         // LordHavoc: network timing test code
 572         // if (actor.button0)
 573         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, slot)), " >= ", ftos(this.weapon_nextthink), "\n");
 574
 575         Weapon w = this.m_weapon;
 576
 577         // call the think code which may fire the weapon
 578         // and do so multiple times to resolve framerate dependency issues if the
 579         // server framerate is very low and the weapon fire rate very high
 580         for (int c = 0; c < W_TICSPERFRAME; ++c)
 581         {
 582                 if (w != WEP_Null && !(STAT(WEAPONS, actor) & WepSet_FromWeapon(w)))
 583                 {
 584                         if (this.m_weapon == this.m_switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 585                         w = WEP_Null;
 586                 }
 587
 588                 v_forward = fo;
 589                 v_right = ri;
 590                 v_up = up;
 591
 592                 bool block_weapon = false;
 593                 {
 594                         bool key_pressed = PHYS_INPUT_BUTTON_HOOK(actor) && !actor.vehicle;
 595                         if (round_handler_IsActive() && !round_handler_IsRoundStarted())
 596                                 key_pressed = false;
 597
 598                         Weapon off = actor.offhand;
 599                         if (off && (!(STAT(WEAPONS, actor) & WEPSET(HOOK)) || off != OFFHAND_HOOK))
 600                         {
 601                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
 602                         }
 603                         else
 604                         {
 605                                 if (key_pressed && this.m_switchweapon != WEP_HOOK && !actor.hook_switchweapon)
 606                                         W_SwitchWeapon(actor, WEP_HOOK, weaponentity);
 607                                 actor.hook_switchweapon = key_pressed;
 608                                 Weapon h = WEP_HOOK;
 609                                 block_weapon = (this.m_weapon == h && (button_atck || key_pressed));
 610                                 h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
 611                         }
 612                 }
 613
 614                 v_forward = fo;
 615                 v_right = ri;
 616                 v_up = up;
 617
 618                 if (!block_weapon)
 619                 {
 620                         Weapon e = this.m_weapon;
 621                         TC(Weapon, e);
 622                         if (w != WEP_Null)
 623                         {
 624                                 e.wr_think(e, actor, weaponentity, button_atck | (button_atck2 << 1));
 625                         }
 626                         else if (e)
 627                         {
 628                                 e.wr_gonethink(e, actor, weaponentity);
 629                         }
 630                 }
 631
 632                 if (time + this.weapon_frametime * 0.5 >= this.weapon_nextthink)
 633                 {
 634                         if (this.weapon_think)
 635                         {
 636                                 v_forward = fo;
 637                                 v_right = ri;
 638                                 v_up = up;
 639                                 Weapon wpn = this.m_weapon;
 640                                 this.weapon_think(wpn, actor, weaponentity,
 641                                         button_atck | (button_atck2 << 1));
 642                         }
 643                         else
 644                         {
 645                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
 646                         }
 647                 }
 648         }
 649 }
 650
 651 void W_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 652 {
 653         flash.owner = actor;
 654         flash.angles_z = random() * 360;
 655
 656         entity view = actor.(weaponentity);
 657         entity exterior = actor.exteriorweaponentity;
 658
 659         if (gettagindex(view, "shot")) setattachment(flash, view, "shot");
 660         else setattachment(flash, view, "tag_shot");
 661         setorigin(flash, offset);
 662
 663         entity xflash = spawn();
 664         copyentity(flash, xflash);
 665
 666         flash.viewmodelforclient = actor;
 667
 668         if (view.oldorigin.x > 0)
 669         {
 670                 setattachment(xflash, exterior, "");
 671                 setorigin(xflash, view.oldorigin + offset);
 672         }
 673         else
 674         {
 675                 if (gettagindex(exterior, "shot")) setattachment(xflash, exterior, "shot");
 676                 else setattachment(xflash, exterior, "tag_shot");
 677                 setorigin(xflash, offset);
 678         }
 679 }
 680
 681 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use, .entity weaponentity)
 682 {
 683         if (MUTATOR_CALLHOOK(W_DecreaseAmmo, actor, actor.(weaponentity), ammo_use)) return;
 684         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
 685
 686         ammo_use = M_ARGV(2, float);
 687
 688         entity w_ent = actor.(weaponentity);
 689
 690         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 691         if (wep.reloading_ammo)
 692         {
 693                 w_ent.clip_load -= ammo_use;
 694                 w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
 695         }
 696         else if (wep.ammo_type != RESOURCE_NONE)
 697         {
 698                 float ammo = GetResourceAmount(actor, wep.ammo_type);
 699                 if (ammo < ammo_use)
 700                 {
 701                         backtrace(sprintf(
 702                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
 703                                 "Please notify the developers immediately with a copy of this backtrace!\n",
 704                                 ammo_use,
 705                                 wep.netname,
 706                                 GetAmmoPicture(wep.ammo_type),
 707                                 actor.netname,
 708                                 ammo
 709                                              ));
 710                 }
 711                 SetResourceAmount(actor, wep.ammo_type, ammo - ammo_use);
 712         }
 713 }
 714
 715 // weapon reloading code
 716
 717 .float reload_ammo_amount, reload_ammo_min, reload_time;
 718 .float reload_complain;
 719 .string reload_sound;
 720
 721 void W_ReloadedAndReady(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 722 {
 723         // finish the reloading process, and do the ammo transfer
 724
 725         entity w_ent = actor.(weaponentity);
 726         Weapon wpn = w_ent.m_weapon;
 727
 728         w_ent.clip_load = w_ent.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
 729
 730         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
 731         if (!w_ent.reload_ammo_min || (actor.items & IT_UNLIMITED_WEAPON_AMMO) || wpn.ammo_type == RESOURCE_NONE)
 732         {
 733                 w_ent.clip_load = w_ent.reload_ammo_amount;
 734         }
 735         else
 736         {
 737                 // make sure we don't add more ammo than we have
 738                 float ammo = GetResourceAmount(actor, wpn.ammo_type);
 739                 float load = min(w_ent.reload_ammo_amount - w_ent.clip_load, ammo);
 740                 w_ent.clip_load += load;
 741                 SetResourceAmount(actor, wpn.ammo_type, ammo - load);
 742         }
 743         w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
 744
 745         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 746         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 747         // so your weapon is disabled for a few seconds without reason
 748
 749         // ATTACK_FINISHED(actor, slot) -= w_ent.reload_time - 1;
 750
 751         w_ready(wpn, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 752 }
 753
 754 void W_Reload(entity actor, .entity weaponentity, float sent_ammo_min, Sound sent_sound)
 755 {
 756         TC(Sound, sent_sound);
 757         // set global values to work with
 758         entity this = actor.(weaponentity);
 759         Weapon e = this.m_weapon;
 760
 761         if (MUTATOR_CALLHOOK(W_Reload, actor)) return;
 762
 763         this.reload_ammo_min = sent_ammo_min;
 764         this.reload_ammo_amount = e.reloading_ammo;
 765         this.reload_time = e.reloading_time;
 766         strcpy(actor.reload_sound, Sound_fixpath(sent_sound));
 767
 768         // don't reload weapons that don't have the RELOADABLE flag
 769         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
 770         {
 771                 LOG_TRACE(
 772                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
 773                 return;
 774         }
 775
 776         // return if reloading is disabled for this weapon
 777         if (!this.reload_ammo_amount) return;
 778
 779         // our weapon is fully loaded, no need to reload
 780         if (this.clip_load >= this.reload_ammo_amount) return;
 781
 782         // no ammo, so nothing to load
 783         if (e.ammo_type != RESOURCE_NONE)
 784         {
 785                 if (!GetResourceAmount(actor, e.ammo_type) && this.reload_ammo_min)
 786                 {
 787                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 788                         {
 789                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
 790                                 {
 791                                         play2(actor, SND(UNAVAILABLE));
 792                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", this.m_weapon.m_name, "\n"));
 793                                         actor.reload_complain = time + 1;
 794                                 }
 795                                 // switch away if the amount of ammo is not enough to keep using this weapon
 796                                 if (!(e.wr_checkammo1(e, actor, weaponentity) + e.wr_checkammo2(e, actor, weaponentity)))
 797                                 {
 798                                         this.clip_load = -1;  // reload later
 799                                         W_SwitchToOtherWeapon(actor, weaponentity);
 800                                 }
 801                                 return;
 802                         }
 803                 }
 804         }
 805
 806         if (this)
 807         {
 808                 if (this.wframe == WFRAME_RELOAD) return;
 809
 810                 // allow switching away while reloading, but this will cause a new reload!
 811                 this.state = WS_READY;
 812         }
 813
 814         // now begin the reloading process
 815
 816         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
 817
 818         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 819         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 820         // so your weapon is disabled for a few seconds without reason
 821
 822         // ATTACK_FINISHED(actor, slot) = max(time, ATTACK_FINISHED(actor, slot)) + this.reload_time + 1;
 823
 824         weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, this.reload_time, W_ReloadedAndReady);
 825
 826         if (this.clip_load < 0) this.clip_load = 0;
 827         this.old_clip_load = this.clip_load;
 828         this.clip_load = this.(weapon_load[this.m_weapon.m_id]) = -1;
 829 }
 830
 831 void W_DropEvent(.void(Weapon, entity actor, .entity) event, entity player, float weapon_type, entity weapon_item, .entity weaponentity)
 832 {
 833         Weapon w = Weapons_from(weapon_type);
 834         weapon_dropevent_item = weapon_item;
 835         w.event(w, player, weaponentity);
 836 }