Merge branch 'master' into martin-t/globals
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / weapons / weaponsystem.qc
1 #include "weaponsystem.qh"
2
3 #include "selection.qh"
4
5 #include "../command/common.qh"
6 #include <server/mutators/_mod.qh>
7 #include "../round_handler.qh"
8 #include <server/cheats.qh>
9 #include <server/resources.qh>
10 #include <common/t_items.qh>
11 #include <common/animdecide.qh>
12 #include <common/constants.qh>
13 #include <common/net_linked.qh>
14 #include <common/monsters/_mod.qh>
15 #include <common/notifications/all.qh>
16 #include <common/util.qh>
17 #include <common/weapons/_all.qh>
18 #include <common/state.qh>
19 #include <lib/csqcmodel/sv_model.qh>
20 #include <common/wepent.qh>
21
22 .int state;
23
24 .float weapon_frametime;
25
26 float W_WeaponRateFactor(entity this)
27 {
28         float t = 1;
29         if(g_weaponratefactor > 0)
30                 t = 1.0 / g_weaponratefactor;
31
32         MUTATOR_CALLHOOK(WeaponRateFactor, t, this);
33         t = M_ARGV(0, float);
34
35         return t;
36 }
37
38 float W_WeaponSpeedFactor(entity this)
39 {
40         float t = 1.0 * g_weaponspeedfactor;
41
42         MUTATOR_CALLHOOK(WeaponSpeedFactor, t, this);
43         t = M_ARGV(0, float);
44
45         return t;
46 }
47
48
49 bool CL_Weaponentity_CustomizeEntityForClient(entity this, entity client)
50 {
51         this.viewmodelforclient = this.owner;
52         if (IS_SPEC(client) && client.enemy == this.owner) this.viewmodelforclient = client;
53         return false;
54 }
55
56 vector CL_Weapon_GetShotOrg(int wpn)
57 {
58         entity wi = Weapons_from(wpn);
59         entity e = spawn();
60         CL_WeaponEntity_SetModel(e, wi.mdl, false);
61         vector ret = e.movedir;
62         CL_WeaponEntity_SetModel(e, "", false);
63         delete(e);
64         return ret;
65 }
66
67 .float m_alpha;
68 .string w_weaponname;
69 .int w_dmg;
70 .int w_deadflag;
71
72 void CL_Weaponentity_Think(entity this)
73 {
74         this.nextthink = time;
75         if (game_stopped) this.frame = this.anim_idle.x;
76         .entity weaponentity = this.weaponentity_fld;
77         if (this.owner.(weaponentity) != this)
78         {
79                 // owner has new gun; remove old one
80                 if (this.weaponchild) delete(this.weaponchild);
81                 if (this.hook) delete(this.hook);
82                 delete(this);
83                 return;
84         }
85         if (IS_DEAD(this.owner))
86         {
87                 // owner died; disappear
88                 this.model = "";
89                 if (this.weaponchild) this.weaponchild.model = "";
90                 return;
91         }
92         if (this.w_weaponname != this.weaponname
93             || this.w_dmg != this.modelindex
94             || this.w_deadflag != this.deadflag)
95         {
96                 // owner changed weapons; update appearance
97                 this.w_weaponname = this.weaponname;
98                 this.w_dmg = this.modelindex;
99                 this.w_deadflag = this.deadflag;
100
101                 CL_WeaponEntity_SetModel(this, this.weaponname, true);
102         }
103
104         this.alpha = -1;  // TODO: don't render this entity at all
105
106         if (this.owner.alpha == default_player_alpha) this.m_alpha = default_weapon_alpha;
107         else if (this.owner.alpha != 0) this.m_alpha = this.owner.alpha;
108         else this.m_alpha  = 1;
109
110         if (this.weaponchild)
111         {
112                 this.weaponchild.alpha = this.alpha;
113                 this.weaponchild.effects = this.effects;
114         }
115 }
116
117 void CL_ExteriorWeaponentity_Think(entity this)
118 {
119         this.nextthink = time;
120         .entity weaponentity = this.weaponentity_fld;
121         entity w_ent = this.owner.(weaponentity);
122         if (this.owner.exteriorweaponentity != this)
123         {
124                 delete(this);
125                 return;
126         }
127         if (IS_DEAD(this.owner))
128         {
129                 this.model = "";
130                 return;
131         }
132         if (this.weaponname != w_ent.weaponname || this.dmg != w_ent.modelindex
133             || this.deadflag != w_ent.deadflag)
134         {
135                 this.weaponname = w_ent.weaponname;
136                 this.dmg = w_ent.modelindex;
137                 this.deadflag = w_ent.deadflag;
138                 if (w_ent.weaponname != "")
139                 {
140                         _setmodel(this, W_Model(strcat("v_", w_ent.weaponname, ".md3")));
141                         setsize(this, '0 0 0', '0 0 0');
142                 }
143                 else this.model = "";
144
145                 int tag_found;
146                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
147                 {
148                         this.tag_index = tag_found;
149                         this.tag_entity = this.owner;
150                 }
151                 else
152                 {
153                         setattachment(this, this.owner, "bip01 r hand");
154                 }
155         }
156         this.effects = this.owner.effects;
157         this.effects |= EF_LOWPRECISION;
158         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
159         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
160         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
161         else this.alpha = 1;
162
163     Weapon wep = this.owner.(weaponentity).m_weapon;
164         if (wep) this.glowmod = weaponentity_glowmod(wep, this.owner, this.owner.clientcolors, this.owner.(weaponentity));
165         this.colormap = this.owner.colormap;
166
167         CSQCMODEL_AUTOUPDATE(this);
168 }
169
170 // spawning weaponentity for client
171 void CL_SpawnWeaponentity(entity actor, .entity weaponentity)
172 {
173         entity view = actor.(weaponentity) = new(weaponentity);
174         view.solid = SOLID_NOT;
175         view.owner = actor;
176         setmodel(view, MDL_Null);  // precision set when changed
177         setorigin(view, '0 0 0');
178         view.weaponentity_fld = weaponentity;
179         setthink(view, CL_Weaponentity_Think);
180         view.nextthink = time;
181         view.viewmodelforclient = actor;
182         view.draggable = drag_undraggable;
183         setcefc(view, CL_Weaponentity_CustomizeEntityForClient);
184
185         wepent_link(view);
186
187         if (weaponentity == weaponentities[0]) // only one exterior model, thank you very much
188         {
189                 entity exterior = actor.exteriorweaponentity = new(exteriorweaponentity);
190                 exterior.solid = SOLID_NOT;
191                 exterior.owner = actor;
192                 exterior.draggable = drag_undraggable;
193                 exterior.weaponentity_fld = weaponentity;
194                 setorigin(exterior, '0 0 0');
195                 setthink(exterior, CL_ExteriorWeaponentity_Think);
196                 exterior.nextthink = time;
197
198                 CSQCMODEL_AUTOINIT(exterior);
199         }
200 }
201
202 // Weapon subs
203 void w_clear(Weapon thiswep, entity actor, .entity weaponentity, int fire)
204 {
205         actor.(weaponentity).m_weapon = WEP_Null;
206         actor.(weaponentity).m_switchingweapon = WEP_Null;
207         entity this = actor.(weaponentity);
208         if (this)
209         {
210                 this.state = WS_CLEAR;
211                 this.effects = 0;
212         }
213 }
214
215 void w_ready(Weapon thiswep, entity actor, .entity weaponentity, int fire)
216 {
217         entity this = actor.(weaponentity);
218         if (this) this.state = WS_READY;
219         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
220 }
221
222 .float prevdryfire;
223 .float prevwarntime;
224 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary, .entity weaponentity)
225 {
226         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
227         bool ammo = false;
228         if (secondary) ammo = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
229         else ammo = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
230         if (ammo) return true;
231         // always keep the Mine Layer if we placed mines, so that we can detonate them
232         if (thiswep == WEP_MINE_LAYER)
233         {
234                 IL_EACH(g_mines, it.owner == actor && it.weaponentity_fld == weaponentity,
235                 {
236                         return false;
237                 });
238         }
239
240         if (thiswep == WEP_SHOTGUN)
241                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;           // no clicking, just allow
242
243         if (thiswep == actor.(weaponentity).m_switchweapon && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
244         {
245                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
246                 actor.prevdryfire = time;
247         }
248
249         // check if the other firing mode has enough ammo
250         bool ammo_other = false;
251         if (secondary) ammo_other = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
252         else ammo_other = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
253         if (ammo_other)
254         {
255                 if (time - actor.prevwarntime > 1)
256                 {
257                         Send_Notification(
258                                 NOTIF_ONE,
259                                 actor,
260                                 MSG_MULTI,
261                                 ITEM_WEAPON_PRIMORSEC,
262                                 thiswep.m_id,
263                                 secondary,
264                                 (1 - secondary)
265                                          );
266                 }
267                 actor.prevwarntime = time;
268         }
269         else  // this weapon is totally unable to fire, switch to another one
270         {
271                 W_SwitchToOtherWeapon(actor, weaponentity);
272         }
273
274         return false;
275 }
276
277 .float race_penalty;
278 bool weapon_prepareattack_check(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
279 {
280         if (actor.weaponentity == NULL) return true;
281         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary, weaponentity)) return false;
282
283         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
284         // if all players readied up and the countdown is running
285         if (time < game_starttime || time < actor.race_penalty) return false;
286
287         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
288                 return false;
289
290         // do not even think about shooting if switching
291         if (actor.(weaponentity).m_switchweapon != actor.(weaponentity).m_weapon) return false;
292
293         if (attacktime >= 0)
294         {
295                 // don't fire if previous attack is not finished
296                 if (ATTACK_FINISHED(actor, weaponentity) > time + actor.(weaponentity).weapon_frametime * 0.5) return false;
297                 entity this = actor.(weaponentity);
298                 // don't fire while changing weapon
299                 if (this.state != WS_READY) return false;
300         }
301         return true;
302 }
303
304 void weapon_prepareattack_do(entity actor, .entity weaponentity, bool secondary, float attacktime)
305 {
306         entity this = actor.(weaponentity);
307         if (this == NULL) return;
308         this.state = WS_INUSE;
309
310         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
311
312         // if the weapon hasn't been firing continuously, reset the timer
313         if (attacktime >= 0)
314         {
315                 if (ATTACK_FINISHED(actor, weaponentity) < time - this.weapon_frametime * 1.5)
316                 {
317                         ATTACK_FINISHED(actor, weaponentity) = time;
318                         // dprint("resetting attack finished to ", ftos(time), "\n");
319                 }
320                 float arate = W_WeaponRateFactor(actor);
321                 ATTACK_FINISHED(actor, weaponentity) = ATTACK_FINISHED(actor, weaponentity) + attacktime * arate;
322
323                 if(autocvar_g_weaponswitch_debug_alternate && W_DualWielding(actor))
324                 {
325                         int slot = weaponslot(weaponentity);
326                         for(int wepslot = 0; wepslot < MAX_WEAPONSLOTS; ++wepslot)
327                         {
328                                 if(slot == wepslot)
329                                         continue;
330                                 .entity wepent = weaponentities[wepslot];
331                                 if(actor.(wepent) && actor.(wepent).m_weapon != WEP_Null)
332                                 {
333                                         if(ATTACK_FINISHED(actor, wepent) > time + actor.(wepent).weapon_frametime * 0.5)
334                                                 continue; // still cooling down!
335                                         if (ATTACK_FINISHED(actor, wepent) < time - actor.(wepent).weapon_frametime * 1.5)
336                                                 ATTACK_FINISHED(actor, wepent) = time;
337                                         ATTACK_FINISHED(actor, wepent) = ATTACK_FINISHED(actor, wepent) + (attacktime * arate) / MAX_WEAPONSLOTS;
338                                 }
339                         }
340                 }
341         }
342         this.bulletcounter += 1;
343         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, weaponentity)), "\n");
344 }
345
346 bool weapon_prepareattack(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
347 {
348         if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
349         {
350                 weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
351                 return true;
352         }
353         return false;
354 }
355
356 /**
357  * @param t defer thinking until time + t
358  * @param func next think function
359  */
360 void weapon_thinkf(entity actor, .entity weaponentity, WFRAME fr, float t, void(Weapon thiswep, entity actor,
361         .entity weaponentity, int fire) func)
362 {
363         entity this = actor.(weaponentity);
364         if (this == NULL) return;
365         bool restartanim;
366         if (fr == WFRAME_DONTCHANGE)
367         {
368                 fr = this.wframe;
369                 restartanim = false;
370         }
371         else
372         {
373                 restartanim = fr != WFRAME_IDLE;
374         }
375
376         vector a = '0 0 0';
377     this.wframe = fr;
378     if (fr == WFRAME_IDLE) a = this.anim_idle;
379     else if (fr == WFRAME_FIRE1) a = this.anim_fire1;
380     else if (fr == WFRAME_FIRE2) a = this.anim_fire2;
381     else  // if (fr == WFRAME_RELOAD)
382         a = this.anim_reload;
383     a.z *= g_weaponratefactor;
384
385         if (this.weapon_think == w_ready && func != w_ready && this.state == WS_RAISE) backtrace(
386                         "Tried to override initial weapon think function - should this really happen?");
387
388         t *= W_WeaponRateFactor(actor);
389
390         // VorteX: haste can be added here
391         if (this.weapon_think == w_ready)
392         {
393                 this.weapon_nextthink = time;
394                 // dprint("started firing at ", ftos(time), "\n");
395         }
396         if (this.weapon_nextthink < time - this.weapon_frametime * 1.5
397             || this.weapon_nextthink > time + this.weapon_frametime * 1.5)
398         {
399                 this.weapon_nextthink = time;
400                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
401         }
402         this.weapon_nextthink += t;
403         this.weapon_think = func;
404         // dprint("next ", ftos(this.weapon_nextthink), "\n");
405
406         if (this)
407         {
408                 FOREACH_CLIENT(true, {
409                         if(it == actor || (IS_SPEC(it) && it.enemy == actor))
410                                 wframe_send(it, this, a, restartanim);
411                 });
412         }
413
414         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
415         {
416                 bool primary_melee = boolean(fr == WFRAME_FIRE1 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_PRI));
417                 bool secondary_melee = boolean(fr == WFRAME_FIRE2 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_SEC));
418                 int act = (primary_melee || secondary_melee)
419                         ? ANIMACTION_MELEE
420                         : ANIMACTION_SHOOT
421                         ;
422                 animdecide_setaction(actor, act, restartanim);
423         }
424         else if (actor.anim_upper_action == ANIMACTION_SHOOT || actor.anim_upper_action == ANIMACTION_MELEE)
425         {
426                 actor.anim_upper_action = 0;
427         }
428 }
429
430 bool weaponUseForbidden(entity player)
431 {
432         if (round_handler_IsActive() && !round_handler_IsRoundStarted()) return true;
433         if (MUTATOR_CALLHOOK(ForbidWeaponUse, player)) return true;
434         return false;
435 }
436
437 bool weaponLocked(entity player)
438 {
439         if (time < game_starttime && !sv_ready_restart_after_countdown) return true;
440         if (player.player_blocked) return true;
441         if (game_stopped) return true;
442         if (STAT(FROZEN, player)) return true;
443         if (MUTATOR_CALLHOOK(LockWeapon, player)) return true;
444         return false;
445 }
446
447 .bool hook_switchweapon;
448
449 void W_WeaponFrame(Player actor, .entity weaponentity)
450 {
451         TC(Player, actor);
452         TC(PlayerState, PS(actor));
453         entity this = actor.(weaponentity);
454         if (frametime) this.weapon_frametime = frametime;
455
456         if (!this || GetResource(actor, RES_HEALTH) < 1) return;  // Dead player can't use weapons and injure impulse commands
457
458         int button_atck = PHYS_INPUT_BUTTON_ATCK(actor);
459         int button_atck2 = PHYS_INPUT_BUTTON_ATCK2(actor);
460
461         if (weaponUseForbidden(actor))
462                 button_atck = button_atck2 = 0; // forbid primary and secondary fire, switching is allowed
463
464         if (weaponLocked(actor))
465         {
466                 if (this.state != WS_CLEAR)
467                 {
468                         Weapon wpn = this.m_weapon;
469                         w_ready(wpn, actor, weaponentity, button_atck | (button_atck2 << 1));
470                         return;
471                 }
472         }
473
474         if(autocvar_g_weaponswitch_debug == 2 && weaponslot(weaponentity) > 0)
475         {
476                 .entity wepe1 = weaponentities[0];
477                 entity wep1 = actor.(wepe1);
478                 this.m_switchweapon = wep1.m_switchweapon;
479                 entity store = IS_PLAYER(actor) ? PS(actor) : actor;
480                 if(!(this.m_switchweapon.spawnflags & WEP_FLAG_DUALWIELD) && !(store.dual_weapons & wep1.m_switchweapon.m_wepset))
481                 {
482                         this.m_weapon = WEP_Null;
483                         this.m_switchingweapon = WEP_Null;
484                         this.m_switchweapon = WEP_Null;
485                         this.state = WS_CLEAR;
486                         this.weaponname = "";
487                         return;
488                 }
489         }
490
491         if (this.m_switchweapon == WEP_Null)
492         {
493                 if (this.state != WS_CLEAR)
494                         w_ready(this.m_weapon, actor, weaponentity, button_atck | (button_atck2 << 1));
495                 this.m_weapon = WEP_Null;
496                 this.m_switchingweapon = WEP_Null;
497                 this.state = WS_CLEAR;
498                 this.weaponname = "";
499                 return;
500         }
501
502         MAKE_VECTORS_NEW(actor.v_angle, fo, ri, up);
503
504         // Change weapon
505         if (this.m_weapon != this.m_switchweapon)
506         {
507                 switch (this.state)
508                 {
509                         default:
510                                 LOG_WARNF("unhandled weaponentity (%i) state for player (%i): %d", this, actor, this.state);
511                                 break;
512                         case WS_INUSE:
513                         case WS_RAISE:
514                                 break;
515                         case WS_CLEAR:
516                         {
517                                 // end switching!
518                                 Weapon newwep = this.m_switchweapon;
519                                 this.m_switchingweapon = newwep;
520
521                                 // the two weapon entities will notice this has changed and update their models
522                                 this.m_weapon = newwep;
523                                 this.weaponname = newwep.mdl;
524                                 this.bulletcounter = 0;
525                                 newwep.wr_setup(newwep, actor, weaponentity);
526                                 this.state = WS_RAISE;
527
528                                 // set our clip load to the load of the weapon we switched to, if it's reloadable
529                                 if ((newwep.spawnflags & WEP_FLAG_RELOADABLE) && newwep.reloading_ammo)  // prevent accessing undefined cvars
530                                 {
531                                         this.clip_load = this.(weapon_load[this.m_switchweapon.m_id]);
532                                         this.clip_size = newwep.reloading_ammo;
533                                 }
534                                 else
535                                 {
536                                         this.clip_load = this.clip_size = 0;
537                                 }
538
539                                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, newwep.switchdelay_raise, w_ready);
540                                 break;
541                         }
542                         case WS_DROP:
543                         {
544                                 // in dropping phase we can switch at any time
545                                 this.m_switchingweapon = this.m_switchweapon;
546                                 break;
547                         }
548                         case WS_READY:
549                         {
550                                 // start switching!
551                                 this.m_switchingweapon = this.m_switchweapon;
552                                 entity oldwep = this.m_weapon;
553
554                                 // set up weapon switch think in the future, and start drop anim
555                                 if (INDEPENDENT_ATTACK_FINISHED || ATTACK_FINISHED(actor, weaponentity) <= time + this.weapon_frametime * 0.5)
556                                 {
557                                         sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
558                                         this.state = WS_DROP;
559                                         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
560                                 }
561                                 break;
562                         }
563                 }
564         }
565
566         // LordHavoc: network timing test code
567         // if (actor.button0)
568         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, weaponentity)), " >= ", ftos(this.weapon_nextthink), "\n");
569
570         Weapon w = this.m_weapon;
571
572         // call the think code which may fire the weapon
573         // and do so multiple times to resolve framerate dependency issues if the
574         // server framerate is very low and the weapon fire rate very high
575         for (int c = 0; c < W_TICSPERFRAME; ++c)
576         {
577                 if (w != WEP_Null && !(STAT(WEAPONS, actor) & WepSet_FromWeapon(w)))
578                 {
579                         if (this.m_weapon == this.m_switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
580                         w = WEP_Null;
581                 }
582
583                 v_forward = fo;
584                 v_right = ri;
585                 v_up = up;
586
587                 bool block_weapon = false;
588                 {
589                         bool key_pressed = PHYS_INPUT_BUTTON_HOOK(actor) && !actor.vehicle;
590                         if (weaponUseForbidden(actor))
591                                 key_pressed = false;
592
593                         Weapon off = actor.offhand;
594                         if (off && (!(STAT(WEAPONS, actor) & WEPSET(HOOK)) || off != OFFHAND_HOOK))
595                         {
596                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
597                         }
598                         else
599                         {
600                                 if (key_pressed && this.m_switchweapon != WEP_HOOK && !actor.hook_switchweapon)
601                                         W_SwitchWeapon(actor, WEP_HOOK, weaponentity);
602                                 actor.hook_switchweapon = key_pressed;
603                                 Weapon h = WEP_HOOK;
604                                 block_weapon = (this.m_weapon == h && (button_atck || key_pressed));
605                                 h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
606                         }
607                 }
608
609                 v_forward = fo;
610                 v_right = ri;
611                 v_up = up;
612
613                 if (!block_weapon)
614                 {
615                         Weapon e = this.m_weapon;
616                         TC(Weapon, e);
617                         if (w != WEP_Null)
618                         {
619                                 e.wr_think(e, actor, weaponentity, button_atck | (button_atck2 << 1));
620                         }
621                         else if (e)
622                         {
623                                 e.wr_gonethink(e, actor, weaponentity);
624                         }
625                 }
626
627                 if (time + this.weapon_frametime * 0.5 >= this.weapon_nextthink)
628                 {
629                         if (this.weapon_think)
630                         {
631                                 v_forward = fo;
632                                 v_right = ri;
633                                 v_up = up;
634                                 Weapon wpn = this.m_weapon;
635                                 this.weapon_think(wpn, actor, weaponentity,
636                                         button_atck | (button_atck2 << 1));
637                         }
638                         else
639                         {
640                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
641                         }
642                 }
643         }
644 }
645
646 void W_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
647 {
648         flash.owner = actor;
649         flash.angles_z = random() * 360;
650
651         entity view = actor.(weaponentity);
652         entity exterior = actor.exteriorweaponentity;
653
654         if (gettagindex(view, "shot")) setattachment(flash, view, "shot");
655         else setattachment(flash, view, "tag_shot");
656         setorigin(flash, offset);
657
658         entity xflash = spawn();
659         copyentity(flash, xflash);
660
661         flash.viewmodelforclient = actor;
662
663         if (view.oldorigin.x > 0)
664         {
665                 setattachment(xflash, exterior, "");
666                 setorigin(xflash, view.oldorigin + offset);
667         }
668         else
669         {
670                 if (gettagindex(exterior, "shot")) setattachment(xflash, exterior, "shot");
671                 else setattachment(xflash, exterior, "tag_shot");
672                 setorigin(xflash, offset);
673         }
674 }
675
676 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use, .entity weaponentity)
677 {
678         if (MUTATOR_CALLHOOK(W_DecreaseAmmo, actor, actor.(weaponentity), ammo_use)) return;
679         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
680
681         ammo_use = M_ARGV(2, float);
682
683         entity w_ent = actor.(weaponentity);
684
685         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
686         if (wep.reloading_ammo)
687         {
688                 w_ent.clip_load -= ammo_use;
689                 w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
690         }
691         else if (wep.ammo_type != RES_NONE)
692         {
693                 float ammo = GetResource(actor, wep.ammo_type);
694                 if (ammo < ammo_use)
695                 {
696                         backtrace(sprintf(
697                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
698                                 "Please notify the developers immediately with a copy of this backtrace!\n",
699                                 ammo_use,
700                                 wep.netname,
701                                 GetAmmoPicture(wep.ammo_type),
702                                 actor.netname,
703                                 ammo
704                                              ));
705                 }
706                 SetResource(actor, wep.ammo_type, ammo - ammo_use);
707         }
708 }
709
710 // weapon reloading code
711
712 .float reload_ammo_amount, reload_ammo_min, reload_time;
713 .float reload_complain;
714 .string reload_sound;
715
716 void W_ReloadedAndReady(Weapon thiswep, entity actor, .entity weaponentity, int fire)
717 {
718         // finish the reloading process, and do the ammo transfer
719
720         entity w_ent = actor.(weaponentity);
721         Weapon wpn = w_ent.m_weapon;
722
723         w_ent.clip_load = w_ent.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
724
725         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
726         if (!w_ent.reload_ammo_min || (actor.items & IT_UNLIMITED_WEAPON_AMMO) || wpn.ammo_type == RES_NONE)
727         {
728                 w_ent.clip_load = w_ent.reload_ammo_amount;
729         }
730         else
731         {
732                 // make sure we don't add more ammo than we have
733                 float ammo = GetResource(actor, wpn.ammo_type);
734                 float load = min(w_ent.reload_ammo_amount - w_ent.clip_load, ammo);
735                 w_ent.clip_load += load;
736                 SetResource(actor, wpn.ammo_type, ammo - load);
737         }
738         w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
739
740         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
741         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
742         // so your weapon is disabled for a few seconds without reason
743
744         // ATTACK_FINISHED(actor, weaponentity) -= w_ent.reload_time - 1;
745
746         w_ready(wpn, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
747 }
748
749 void W_Reload(entity actor, .entity weaponentity, float sent_ammo_min, Sound sent_sound)
750 {
751         TC(Sound, sent_sound);
752         // set global values to work with
753         entity this = actor.(weaponentity);
754         Weapon e = this.m_weapon;
755
756         if (MUTATOR_CALLHOOK(W_Reload, actor)) return;
757
758         this.reload_ammo_min = sent_ammo_min;
759         this.reload_ammo_amount = e.reloading_ammo;
760         this.reload_time = e.reloading_time;
761         strcpy(actor.reload_sound, Sound_fixpath(sent_sound));
762
763         // don't reload weapons that don't have the RELOADABLE flag
764         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
765         {
766                 LOG_TRACE(
767                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
768                 return;
769         }
770
771         // return if reloading is disabled for this weapon
772         if (!this.reload_ammo_amount) return;
773
774         // our weapon is fully loaded, no need to reload
775         if (this.clip_load >= this.reload_ammo_amount) return;
776
777         // no ammo, so nothing to load
778         if (e.ammo_type != RES_NONE)
779         {
780                 if (!GetResource(actor, e.ammo_type) && this.reload_ammo_min)
781                 {
782                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
783                         {
784                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
785                                 {
786                                         play2(actor, SND(UNAVAILABLE));
787                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", this.m_weapon.m_name, "\n"));
788                                         actor.reload_complain = time + 1;
789                                 }
790                                 // switch away if the amount of ammo is not enough to keep using this weapon
791                                 if (!(e.wr_checkammo1(e, actor, weaponentity) + e.wr_checkammo2(e, actor, weaponentity)))
792                                 {
793                                         this.clip_load = -1;  // reload later
794                                         W_SwitchToOtherWeapon(actor, weaponentity);
795                                 }
796                                 return;
797                         }
798                 }
799         }
800
801         if (this)
802         {
803                 if (this.wframe == WFRAME_RELOAD) return;
804
805                 // allow switching away while reloading, but this will cause a new reload!
806                 this.state = WS_READY;
807         }
808
809         // now begin the reloading process
810
811         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
812
813         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
814         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
815         // so your weapon is disabled for a few seconds without reason
816
817         // ATTACK_FINISHED(actor, weaponentity) = max(time, ATTACK_FINISHED(actor, weaponentity)) + this.reload_time + 1;
818
819         weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, this.reload_time, W_ReloadedAndReady);
820
821         if (this.clip_load < 0) this.clip_load = 0;
822         this.old_clip_load = this.clip_load;
823         this.clip_load = this.(weapon_load[this.m_weapon.m_id]) = -1;
824 }
825
826 void W_DropEvent(.void(Weapon, entity actor, .entity) event, entity player, float weapon_type, entity weapon_item, .entity weaponentity)
827 {
828         Weapon w = Weapons_from(weapon_type);
829         weapon_dropevent_item = weapon_item;
830         w.event(w, player, weaponentity);
831 }