a6961aec87196383bb63f383e850fc873c7f92fb
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / weapons / weaponsystem.qc
1 #include "weaponsystem.qh"
2 #include "../_all.qh"
3
4 #include "selection.qh"
5
6 #include "../command/common.qh"
7 #include "../mutators/mutators_include.qh"
8 #include "../round_handler.qh"
9 #include "../t_items.qh"
10 #include "../../common/animdecide.qh"
11 #include "../../common/constants.qh"
12 #include "../../common/monsters/all.qh"
13 #include "../../common/notifications.qh"
14 #include "../../common/util.qh"
15 #include "../../common/weapons/all.qh"
16 #include "../../csqcmodellib/sv_model.qh"
17
18 /*
19 ===========================================================================
20
21   CLIENT WEAPONSYSTEM CODE
22   Bring back W_Weaponframe
23
24 ===========================================================================
25 */
26
27 .float weapon_frametime;
28
29 float W_WeaponRateFactor()
30 {
31         float t = 1.0 / g_weaponratefactor;
32
33         MUTATOR_CALLHOOK(WeaponRateFactor, t);
34         t = weapon_rate;
35
36         return t;
37 }
38
39 float W_WeaponSpeedFactor()
40 {
41         float t = 1.0 * g_weaponspeedfactor;
42
43         MUTATOR_CALLHOOK(WeaponSpeedFactor, t);
44         t = ret_float;
45
46         return t;
47 }
48
49
50 void weapon_thinkf(float fr, float t, void(Weapon thiswep, bool fire1, bool fire2) func);
51
52 float CL_Weaponentity_CustomizeEntityForClient()
53 {SELFPARAM();
54         self.viewmodelforclient = self.owner;
55         if(IS_SPEC(other))
56                 if(other.enemy == self.owner)
57                         self.viewmodelforclient = other;
58         return true;
59 }
60
61 /*
62  * supported formats:
63  *
64  * 1. simple animated model, muzzle flash handling on h_ model:
65  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
66  *      tags:
67  *        shot = muzzle end (shot origin, also used for muzzle flashes)
68  *        shell = casings ejection point (must be on the right hand side of the gun)
69  *        weapon = attachment for v_tuba.md3
70  *    v_tuba.md3 - first and third person model
71  *    g_tuba.md3 - pickup model
72  *
73  * 2. simple animated model, muzzle flash handling on v_ model:
74  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
75  *      tags:
76  *        weapon = attachment for v_tuba.md3
77  *    v_tuba.md3 - first and third person model
78  *      tags:
79  *        shot = muzzle end (shot origin, also used for muzzle flashes)
80  *        shell = casings ejection point (must be on the right hand side of the gun)
81  *    g_tuba.md3 - pickup model
82  *
83  * 3. fully animated model, muzzle flash handling on h_ model:
84  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
85  *      tags:
86  *        shot = muzzle end (shot origin, also used for muzzle flashes)
87  *        shell = casings ejection point (must be on the right hand side of the gun)
88  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
89  *    v_tuba.md3 - third person model
90  *    g_tuba.md3 - pickup model
91  *
92  * 4. fully animated model, muzzle flash handling on v_ model:
93  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
94  *      tags:
95  *        shot = muzzle end (shot origin)
96  *        shell = casings ejection point (must be on the right hand side of the gun)
97  *    v_tuba.md3 - third person model
98  *      tags:
99  *        shot = muzzle end (for muzzle flashes)
100  *    g_tuba.md3 - pickup model
101  */
102
103 // writes:
104 //   self.origin, self.angles
105 //   self.weaponentity
106 //   self.movedir, self.view_ofs
107 //   attachment stuff
108 //   anim stuff
109 // to free:
110 //   call again with ""
111 //   remove the ent
112 void CL_WeaponEntity_SetModel(string name)
113 {SELFPARAM();
114         float v_shot_idx;
115         if (name != "")
116         {
117                 // if there is a child entity, hide it until we're sure we use it
118                 if (self.weaponentity)
119                         self.weaponentity.model = "";
120                 _setmodel(self, W_Model(strcat("v_", name, ".md3")));
121                 v_shot_idx = gettagindex(self, "shot"); // used later
122                 if(!v_shot_idx)
123                         v_shot_idx = gettagindex(self, "tag_shot");
124
125                 _setmodel(self, W_Model(strcat("h_", name, ".iqm")));
126                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
127                 self.anim_fire1  = animfixfps(self, '0 1 0.01', '0 0 0');
128                 self.anim_fire2  = animfixfps(self, '1 1 0.01', '0 0 0');
129                 self.anim_idle   = animfixfps(self, '2 1 0.01', '0 0 0');
130                 self.anim_reload = animfixfps(self, '3 1 0.01', '0 0 0');
131
132                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
133                 // if we don't, this is a "real" animated model
134                 if(gettagindex(self, "weapon"))
135                 {
136                         if (!self.weaponentity)
137                                 self.weaponentity = spawn();
138                         _setmodel(self.weaponentity, W_Model(strcat("v_", name, ".md3")));
139                         setattachment(self.weaponentity, self, "weapon");
140                 }
141                 else if(gettagindex(self, "tag_weapon"))
142                 {
143                         if (!self.weaponentity)
144                                 self.weaponentity = spawn();
145                         _setmodel(self.weaponentity, W_Model(strcat("v_", name, ".md3")));
146                         setattachment(self.weaponentity, self, "tag_weapon");
147                 }
148                 else
149                 {
150                         if(self.weaponentity)
151                                 remove(self.weaponentity);
152                         self.weaponentity = world;
153                 }
154
155                 setorigin(self,'0 0 0');
156                 self.angles = '0 0 0';
157                 self.frame = 0;
158                 self.viewmodelforclient = world;
159
160                 float idx;
161
162                 if(v_shot_idx) // v_ model attached to invisible h_ model
163                 {
164                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
165                 }
166                 else
167                 {
168                         idx = gettagindex(self, "shot");
169                         if(!idx)
170                                 idx = gettagindex(self, "tag_shot");
171                         if(idx)
172                                 self.movedir = gettaginfo(self, idx);
173                         else
174                         {
175                                 LOG_INFO("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
176                                 self.movedir = '0 0 0';
177                         }
178                 }
179
180                 if(self.weaponentity) // v_ model attached to invisible h_ model
181                 {
182                         idx = gettagindex(self.weaponentity, "shell");
183                         if(!idx)
184                                 idx = gettagindex(self.weaponentity, "tag_shell");
185                         if(idx)
186                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
187                 }
188                 else
189                         idx = 0;
190                 if(!idx)
191                 {
192                         idx = gettagindex(self, "shell");
193                         if(!idx)
194                                 idx = gettagindex(self, "tag_shell");
195                         if(idx)
196                                 self.spawnorigin = gettaginfo(self, idx);
197                         else
198                         {
199                                 LOG_INFO("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
200                                 self.spawnorigin = self.movedir;
201                         }
202                 }
203
204                 if(v_shot_idx)
205                 {
206                         self.oldorigin = '0 0 0'; // use regular attachment
207                 }
208                 else
209                 {
210                         if(self.weaponentity)
211                         {
212                                 idx = gettagindex(self, "weapon");
213                                 if(!idx)
214                                         idx = gettagindex(self, "tag_weapon");
215                         }
216                         else
217                         {
218                                 idx = gettagindex(self, "handle");
219                                 if(!idx)
220                                         idx = gettagindex(self, "tag_handle");
221                         }
222                         if(idx)
223                         {
224                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
225                         }
226                         else
227                         {
228                                 LOG_INFO("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
229                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
230                         }
231                 }
232
233                 self.viewmodelforclient = self.owner;
234         }
235         else
236         {
237                 self.model = "";
238                 if(self.weaponentity)
239                         remove(self.weaponentity);
240                 self.weaponentity = world;
241                 self.movedir = '0 0 0';
242                 self.spawnorigin = '0 0 0';
243                 self.oldorigin = '0 0 0';
244                 self.anim_fire1  = '0 1 0.01';
245                 self.anim_fire2  = '0 1 0.01';
246                 self.anim_idle   = '0 1 0.01';
247                 self.anim_reload = '0 1 0.01';
248         }
249
250         self.view_ofs = '0 0 0';
251
252         if(self.movedir.x >= 0)
253         {
254                 vector v0;
255                 v0 = self.movedir;
256                 self.movedir = shotorg_adjust(v0, false, false);
257                 self.view_ofs = shotorg_adjust(v0, false, true) - v0;
258         }
259         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
260         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
261
262         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
263
264         // check if an instant weapon switch occurred
265         setorigin(self, self.view_ofs);
266         // reset animstate now
267         self.wframe = WFRAME_IDLE;
268         setanim(self, self.anim_idle, true, false, true);
269 }
270
271 vector CL_Weapon_GetShotOrg(float wpn)
272 {SELFPARAM();
273         entity wi = get_weaponinfo(wpn);
274         setself(spawn());
275         CL_WeaponEntity_SetModel(wi.mdl);
276         vector ret = self.movedir;
277         CL_WeaponEntity_SetModel("");
278         remove(self);
279         setself(this);
280         return ret;
281 }
282
283 void CL_Weaponentity_Think()
284 {SELFPARAM();
285         int tb;
286         self.nextthink = time;
287         if (intermission_running)
288                 self.frame = self.anim_idle.x;
289         if (self.owner.weaponentity != self)
290         {
291                 if (self.weaponentity)
292                         remove(self.weaponentity);
293                 remove(self);
294                 return;
295         }
296         if (self.owner.deadflag != DEAD_NO)
297         {
298                 self.model = "";
299                 if (self.weaponentity)
300                         self.weaponentity.model = "";
301                 return;
302         }
303         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
304         {
305                 self.weaponname = self.owner.weaponname;
306                 self.dmg = self.owner.modelindex;
307                 self.deadflag = self.owner.deadflag;
308
309                 CL_WeaponEntity_SetModel(self.owner.weaponname);
310         }
311
312         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
313         self.effects = self.owner.effects & EFMASK_CHEAP;
314         self.effects &= ~EF_LOWPRECISION;
315         self.effects &= ~EF_FULLBRIGHT; // can mask team color, so get rid of it
316         self.effects &= ~EF_TELEPORT_BIT;
317         self.effects &= ~EF_RESTARTANIM_BIT;
318         self.effects |= tb;
319
320         if(self.owner.alpha == default_player_alpha)
321                 self.alpha = default_weapon_alpha;
322         else if(self.owner.alpha != 0)
323                 self.alpha = self.owner.alpha;
324         else
325                 self.alpha = 1;
326
327         self.glowmod = self.owner.weaponentity_glowmod;
328         self.colormap = self.owner.colormap;
329         if (self.weaponentity)
330         {
331                 self.weaponentity.effects = self.effects;
332                 self.weaponentity.alpha = self.alpha;
333                 self.weaponentity.colormap = self.colormap;
334                 self.weaponentity.glowmod = self.glowmod;
335         }
336
337         self.angles = '0 0 0';
338
339         float f = (self.owner.weapon_nextthink - time);
340         if (self.state == WS_RAISE && !intermission_running)
341         {
342                 entity newwep = get_weaponinfo(self.owner.switchweapon);
343                 f = f * g_weaponratefactor / max(f, newwep.switchdelay_raise);
344                 self.angles_x = -90 * f * f;
345         }
346         else if (self.state == WS_DROP && !intermission_running)
347         {
348                 entity oldwep = get_weaponinfo(self.owner.weapon);
349                 f = 1 - f * g_weaponratefactor / max(f, oldwep.switchdelay_drop);
350                 self.angles_x = -90 * f * f;
351         }
352         else if (self.state == WS_CLEAR)
353         {
354                 f = 1;
355                 self.angles_x = -90 * f * f;
356         }
357 }
358
359 void CL_ExteriorWeaponentity_Think()
360 {SELFPARAM();
361         float tag_found;
362         self.nextthink = time;
363         if (self.owner.exteriorweaponentity != self)
364         {
365                 remove(self);
366                 return;
367         }
368         if (self.owner.deadflag != DEAD_NO)
369         {
370                 self.model = "";
371                 return;
372         }
373         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
374         {
375                 self.weaponname = self.owner.weaponname;
376                 self.dmg = self.owner.modelindex;
377                 self.deadflag = self.owner.deadflag;
378                 if (self.owner.weaponname != "")
379                         _setmodel(self, W_Model(strcat("v_", self.owner.weaponname, ".md3")));
380                 else
381                         self.model = "";
382
383                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
384                 {
385                         self.tag_index = tag_found;
386                         self.tag_entity = self.owner;
387                 }
388                 else
389                         setattachment(self, self.owner, "bip01 r hand");
390         }
391         self.effects = self.owner.effects;
392         self.effects |= EF_LOWPRECISION;
393         self.effects = self.effects & EFMASK_CHEAP; // eat performance
394         if(self.owner.alpha == default_player_alpha)
395                 self.alpha = default_weapon_alpha;
396         else if(self.owner.alpha != 0)
397                 self.alpha = self.owner.alpha;
398         else
399                 self.alpha = 1;
400
401         self.glowmod = self.owner.weaponentity_glowmod;
402         self.colormap = self.owner.colormap;
403
404         CSQCMODEL_AUTOUPDATE(self);
405 }
406
407 // spawning weaponentity for client
408 void CL_SpawnWeaponentity(entity e)
409 {
410         entity view = e.weaponentity = spawn();
411         view.classname = "weaponentity";
412         view.solid = SOLID_NOT;
413         view.owner = e;
414         setmodel(view, MDL_Null); // precision set when changed
415         setorigin(view, '0 0 0');
416         view.angles = '0 0 0';
417         view.viewmodelforclient = e;
418         view.flags = 0;
419         view.think = CL_Weaponentity_Think;
420         view.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
421         view.nextthink = time;
422
423         entity exterior = e.exteriorweaponentity = spawn();
424         exterior.classname = "exteriorweaponentity";
425         exterior.solid = SOLID_NOT;
426         exterior.exteriorweaponentity = exterior;
427         exterior.owner = e;
428         setorigin(exterior, '0 0 0');
429         exterior.angles = '0 0 0';
430         exterior.think = CL_ExteriorWeaponentity_Think;
431         exterior.nextthink = time;
432
433         CSQCMODEL_AUTOINIT(exterior);
434 }
435
436 // Weapon subs
437 void w_clear(Weapon thiswep, bool fire1, bool fire2)
438 {SELFPARAM();
439         if (self.weapon != -1)
440         {
441                 self.weapon = 0;
442                 self.switchingweapon = 0;
443         }
444         if (self.weaponentity)
445         {
446                 self.weaponentity.state = WS_CLEAR;
447                 self.weaponentity.effects = 0;
448         }
449 }
450
451 void w_ready(Weapon thiswep, bool fire1, bool fire2)
452 {SELFPARAM();
453         if (self.weaponentity)
454                 self.weaponentity.state = WS_READY;
455         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
456 }
457
458 .float prevdryfire;
459 .float prevwarntime;
460 float weapon_prepareattack_checkammo(float secondary)
461 {SELFPARAM();
462         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
463         if (!_WEP_ACTION(self.weapon, WR_CHECKAMMO1 + secondary))
464         {
465                 // always keep the Mine Layer if we placed mines, so that we can detonate them
466                 entity mine;
467                 if(self.weapon == WEP_MINE_LAYER.m_id)
468                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
469                         return false;
470
471                 if(self.weapon == WEP_SHOTGUN.m_id)
472                 if(!secondary && WEP_CVAR(shotgun, secondary) == 1)
473                         return false; // no clicking, just allow
474
475                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
476                 {
477                         sound (self, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
478                         self.prevdryfire = time;
479                 }
480
481                 if(_WEP_ACTION(self.weapon, WR_CHECKAMMO2 - secondary)) // check if the other firing mode has enough ammo
482                 {
483                         if(time - self.prevwarntime > 1)
484                         {
485                                 Send_Notification(
486                                         NOTIF_ONE,
487                                         self,
488                                         MSG_MULTI,
489                                         ITEM_WEAPON_PRIMORSEC,
490                                         self.weapon,
491                                         secondary,
492                                         (1 - secondary)
493                                 );
494                         }
495                         self.prevwarntime = time;
496                 }
497                 else // this weapon is totally unable to fire, switch to another one
498                 {
499                         W_SwitchToOtherWeapon(self);
500                 }
501
502                 return false;
503         }
504         return true;
505 }
506 .float race_penalty;
507 float weapon_prepareattack_check(float secondary, float attacktime)
508 {SELFPARAM();
509         if(!weapon_prepareattack_checkammo(secondary))
510                 return false;
511
512         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
513         //if all players readied up and the countdown is running
514         if(time < game_starttime || time < self.race_penalty) {
515                 return false;
516         }
517
518         if (timeout_status == TIMEOUT_ACTIVE) //don't allow the player to shoot while game is paused
519                 return false;
520
521         // do not even think about shooting if switching
522         if(self.switchweapon != self.weapon)
523                 return false;
524
525         if(attacktime >= 0)
526         {
527                 // don't fire if previous attack is not finished
528                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
529                         return false;
530                 // don't fire while changing weapon
531                 if (self.weaponentity.state != WS_READY)
532                         return false;
533         }
534
535         return true;
536 }
537 float weapon_prepareattack_do(float secondary, float attacktime)
538 {SELFPARAM();
539         self.weaponentity.state = WS_INUSE;
540
541         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
542
543         // if the weapon hasn't been firing continuously, reset the timer
544         if(attacktime >= 0)
545         {
546                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
547                 {
548                         ATTACK_FINISHED(self) = time;
549                         //dprint("resetting attack finished to ", ftos(time), "\n");
550                 }
551                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
552         }
553         self.bulletcounter += 1;
554         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
555         return true;
556 }
557 float weapon_prepareattack(float secondary, float attacktime)
558 {
559         if(weapon_prepareattack_check(secondary, attacktime))
560         {
561                 weapon_prepareattack_do(secondary, attacktime);
562                 return true;
563         }
564         else
565                 return false;
566 }
567
568 void weapon_thinkf(float fr, float t, void(Weapon thiswep, bool fire1, bool fire2) func)
569 {SELFPARAM();
570         vector a;
571         vector of, or, ou;
572         float restartanim;
573
574         if(fr == WFRAME_DONTCHANGE)
575         {
576                 fr = self.weaponentity.wframe;
577                 restartanim = false;
578         }
579         else if (fr == WFRAME_IDLE)
580                 restartanim = false;
581         else
582                 restartanim = true;
583
584         of = v_forward;
585         or = v_right;
586         ou = v_up;
587
588         if (self.weaponentity)
589         {
590                 self.weaponentity.wframe = fr;
591                 a = '0 0 0';
592                 if (fr == WFRAME_IDLE)
593                         a = self.weaponentity.anim_idle;
594                 else if (fr == WFRAME_FIRE1)
595                         a = self.weaponentity.anim_fire1;
596                 else if (fr == WFRAME_FIRE2)
597                         a = self.weaponentity.anim_fire2;
598                 else // if (fr == WFRAME_RELOAD)
599                         a = self.weaponentity.anim_reload;
600                 a.z *= g_weaponratefactor;
601                 setanim(self.weaponentity, a, restartanim == false, restartanim, restartanim);
602         }
603
604         v_forward = of;
605         v_right = or;
606         v_up = ou;
607
608         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
609         {
610                 backtrace("Tried to override initial weapon think function - should this really happen?");
611         }
612
613         t *= W_WeaponRateFactor();
614
615         // VorteX: haste can be added here
616         if (self.weapon_think == w_ready)
617         {
618                 self.weapon_nextthink = time;
619                 //dprint("started firing at ", ftos(time), "\n");
620         }
621         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
622         {
623                 self.weapon_nextthink = time;
624                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
625         }
626         self.weapon_nextthink = self.weapon_nextthink + t;
627         self.weapon_think = func;
628         //dprint("next ", ftos(self.weapon_nextthink), "\n");
629
630         if((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
631         {
632                 if((self.weapon == WEP_SHOCKWAVE.m_id || self.weapon == WEP_SHOTGUN.m_id) && fr == WFRAME_FIRE2)
633                         animdecide_setaction(self, ANIMACTION_MELEE, restartanim);
634                 else
635                         animdecide_setaction(self, ANIMACTION_SHOOT, restartanim);
636         }
637         else
638         {
639                 if(self.anim_upper_action == ANIMACTION_SHOOT || self.anim_upper_action == ANIMACTION_MELEE)
640                         self.anim_upper_action = 0;
641         }
642 }
643
644 float forbidWeaponUse(entity player)
645 {
646         if(time < game_starttime && !autocvar_sv_ready_restart_after_countdown)
647                 return 1;
648         if(round_handler_IsActive() && !round_handler_IsRoundStarted())
649                 return 1;
650         if(player.player_blocked)
651                 return 1;
652         if(player.frozen)
653                 return 1;
654         if(player.weapon_blocked)
655                 return 1;
656         return 0;
657 }
658
659 void W_WeaponFrame()
660 {SELFPARAM();
661         vector fo, ri, up;
662
663         if (frametime)
664                 self.weapon_frametime = frametime;
665
666         if (!self.weaponentity || self.health < 1)
667                 return; // Dead player can't use weapons and injure impulse commands
668
669         if(forbidWeaponUse(self))
670         if(self.weaponentity.state != WS_CLEAR)
671         {
672                 Weapon wpn = get_weaponinfo(self.weapon);
673                 w_ready(wpn, self.BUTTON_ATCK, self.BUTTON_ATCK2);
674                 return;
675         }
676
677         if(!self.switchweapon)
678         {
679                 self.weapon = 0;
680                 self.switchingweapon = 0;
681                 self.weaponentity.state = WS_CLEAR;
682                 self.weaponname = "";
683                 //self.items &= ~IT_AMMO;
684                 return;
685         }
686
687         makevectors(self.v_angle);
688         fo = v_forward; // save them in case the weapon think functions change it
689         ri = v_right;
690         up = v_up;
691
692         // Change weapon
693         if (self.weapon != self.switchweapon)
694         {
695                 if (self.weaponentity.state == WS_CLEAR)
696                 {
697                         // end switching!
698                         self.switchingweapon = self.switchweapon;
699                         entity newwep = get_weaponinfo(self.switchweapon);
700
701                         // the two weapon entities will notice this has changed and update their models
702                         self.weapon = self.switchweapon;
703                         self.weaponname = newwep.mdl;
704                         self.bulletcounter = 0;
705                         self.ammo_field = newwep.ammo_field;
706                         _WEP_ACTION(self.switchweapon, WR_SETUP);
707                         self.weaponentity.state = WS_RAISE;
708
709                         // set our clip load to the load of the weapon we switched to, if it's reloadable
710                         if(newwep.spawnflags & WEP_FLAG_RELOADABLE && newwep.reloading_ammo) // prevent accessing undefined cvars
711                         {
712                                 self.clip_load = self.(weapon_load[self.switchweapon]);
713                                 self.clip_size = newwep.reloading_ammo;
714                         }
715                         else
716                                 self.clip_load = self.clip_size = 0;
717
718                         weapon_thinkf(WFRAME_IDLE, newwep.switchdelay_raise, w_ready);
719                 }
720                 else if (self.weaponentity.state == WS_DROP)
721                 {
722                         // in dropping phase we can switch at any time
723                         self.switchingweapon = self.switchweapon;
724                 }
725                 else if (self.weaponentity.state == WS_READY)
726                 {
727                         // start switching!
728                         self.switchingweapon = self.switchweapon;
729                         entity oldwep = get_weaponinfo(self.weapon);
730
731                         // set up weapon switch think in the future, and start drop anim
732                         #ifndef INDEPENDENT_ATTACK_FINISHED
733                         if(ATTACK_FINISHED(self) <= time + self.weapon_frametime * 0.5)
734                         {
735                         #endif
736                                 sound(self, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
737                                 self.weaponentity.state = WS_DROP;
738                                 weapon_thinkf(WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
739                         #ifndef INDEPENDENT_ATTACK_FINISHED
740                         }
741                         #endif
742                 }
743         }
744
745         // LordHavoc: network timing test code
746         //if (self.button0)
747         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(self)), " >= ", ftos(self.weapon_nextthink), "\n");
748
749         float w;
750         w = self.weapon;
751
752         // call the think code which may fire the weapon
753         // and do so multiple times to resolve framerate dependency issues if the
754         // server framerate is very low and the weapon fire rate very high
755         float c;
756         c = 0;
757         while (c < W_TICSPERFRAME)
758         {
759                 c = c + 1;
760                 if(w && !(self.weapons & WepSet_FromWeapon(w)))
761                 {
762                         if(self.weapon == self.switchweapon)
763                                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
764                         w = 0;
765                 }
766
767                 v_forward = fo;
768                 v_right = ri;
769                 v_up = up;
770
771                 {
772                         bool key_pressed = self.BUTTON_HOOK;
773                 Weapon wpn = self.offhand;
774                 if (wpn.offhand_think) wpn.offhand_think(wpn, self, key_pressed);
775         }
776
777                 if (w) {
778                         entity e = get_weaponinfo(self.weapon);
779                         if (e.wr_think) e.wr_think(e, self.BUTTON_ATCK, self.BUTTON_ATCK2);
780                 } else {
781                         _WEP_ACTION(self.weapon, WR_GONETHINK);
782                 }
783
784                 if (time + self.weapon_frametime * 0.5 >= self.weapon_nextthink)
785                 {
786                         if(self.weapon_think)
787                         {
788                                 v_forward = fo;
789                                 v_right = ri;
790                                 v_up = up;
791                                 Weapon wpn = get_weaponinfo(self.weapon);
792                                 self.weapon_think(wpn, self.BUTTON_ATCK, self.BUTTON_ATCK2);
793                         }
794                         else
795                                 bprint("\{1}^1ERROR: undefined weapon think function for ", self.netname, "\n");
796                 }
797         }
798 }
799
800 void W_AttachToShotorg(entity flash, vector offset)
801 {SELFPARAM();
802         entity xflash;
803         flash.owner = self;
804         flash.angles_z = random() * 360;
805
806         if(gettagindex(self.weaponentity, "shot"))
807                 setattachment(flash, self.weaponentity, "shot");
808         else
809                 setattachment(flash, self.weaponentity, "tag_shot");
810         setorigin(flash, offset);
811
812         xflash = spawn();
813         copyentity(flash, xflash);
814
815         flash.viewmodelforclient = self;
816
817         if(self.weaponentity.oldorigin.x > 0)
818         {
819                 setattachment(xflash, self.exteriorweaponentity, "");
820                 setorigin(xflash, self.weaponentity.oldorigin + offset);
821         }
822         else
823         {
824                 if(gettagindex(self.exteriorweaponentity, "shot"))
825                         setattachment(xflash, self.exteriorweaponentity, "shot");
826                 else
827                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
828                 setorigin(xflash, offset);
829         }
830 }
831
832 void W_DecreaseAmmo(Weapon wep, float ammo_use)
833 {SELFPARAM();
834
835         if(cvar("g_overkill"))
836         if(self.ok_use_ammocharge)
837         {
838                 ok_DecreaseCharge(self, self.weapon);
839                 return; // TODO
840         }
841
842         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo)
843                 return;
844
845         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
846         if(wep.reloading_ammo)
847         {
848                 self.clip_load -= ammo_use;
849                 self.(weapon_load[self.weapon]) = self.clip_load;
850         }
851         else if(wep.ammo_field != ammo_none)
852         {
853                 self.(wep.ammo_field) -= ammo_use;
854                 if(self.(wep.ammo_field) < 0)
855                 {
856                         backtrace(sprintf(
857                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
858                                 "Please notify Samual immediately with a copy of this backtrace!\n",
859                                 ammo_use,
860                                 wep.netname,
861                                 GetAmmoPicture(wep.ammo_field),
862                                 self.netname,
863                                 self.(wep.ammo_field)
864                         ));
865                 }
866         }
867 }
868
869 // weapon reloading code
870
871 .float reload_ammo_amount, reload_ammo_min, reload_time;
872 .float reload_complain;
873 .string reload_sound;
874
875 void W_ReloadedAndReady(Weapon thiswep, bool fire1, bool fire2)
876 {SELFPARAM();
877         // finish the reloading process, and do the ammo transfer
878
879         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
880
881         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
882         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO || self.ammo_field == ammo_none)
883                 self.clip_load = self.reload_ammo_amount;
884         else
885         {
886                 // make sure we don't add more ammo than we have
887                 float load = min(self.reload_ammo_amount - self.clip_load, self.(self.ammo_field));
888         self.clip_load += load;
889         self.(self.ammo_field) -= load;
890         }
891         self.(weapon_load[self.weapon]) = self.clip_load;
892
893         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
894         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
895         // so your weapon is disabled for a few seconds without reason
896
897         //ATTACK_FINISHED(self) -= self.reload_time - 1;
898
899         Weapon wpn = get_weaponinfo(self.weapon);
900         w_ready(wpn, self.BUTTON_ATCK, self.BUTTON_ATCK2);
901 }
902
903 void W_Reload(float sent_ammo_min, string sent_sound)
904 {SELFPARAM();
905         // set global values to work with
906         entity e;
907         e = get_weaponinfo(self.weapon);
908
909         if(cvar("g_overkill"))
910         if(self.ok_use_ammocharge)
911                 return; // TODO
912
913         self.reload_ammo_min = sent_ammo_min;
914         self.reload_ammo_amount = e.reloading_ammo;
915         self.reload_time = e.reloading_time;
916         self.reload_sound = sent_sound;
917
918         // don't reload weapons that don't have the RELOADABLE flag
919         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
920         {
921                 LOG_TRACE("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
922                 return;
923         }
924
925         // return if reloading is disabled for this weapon
926         if(!self.reload_ammo_amount)
927                 return;
928
929         // our weapon is fully loaded, no need to reload
930         if (self.clip_load >= self.reload_ammo_amount)
931                 return;
932
933         // no ammo, so nothing to load
934         if(self.ammo_field != ammo_none)
935         if(!self.(self.ammo_field) && self.reload_ammo_min)
936         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
937         {
938                 if(IS_REAL_CLIENT(self) && self.reload_complain < time)
939                 {
940                         play2(self, SND(UNAVAILABLE));
941                         sprint(self, strcat("You don't have enough ammo to reload the ^2", WEP_NAME(self.weapon), "\n"));
942                         self.reload_complain = time + 1;
943                 }
944                 // switch away if the amount of ammo is not enough to keep using this weapon
945                 if (!(_WEP_ACTION(self.weapon, WR_CHECKAMMO1) + _WEP_ACTION(self.weapon, WR_CHECKAMMO2)))
946                 {
947                         self.clip_load = -1; // reload later
948                         W_SwitchToOtherWeapon(self);
949                 }
950                 return;
951         }
952
953         if (self.weaponentity)
954         {
955                 if (self.weaponentity.wframe == WFRAME_RELOAD)
956                         return;
957
958                 // allow switching away while reloading, but this will cause a new reload!
959                 self.weaponentity.state = WS_READY;
960         }
961
962         // now begin the reloading process
963
964         _sound(self, CH_WEAPON_SINGLE, self.reload_sound, VOL_BASE, ATTEN_NORM);
965
966         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
967         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
968         // so your weapon is disabled for a few seconds without reason
969
970         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
971
972         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
973
974         if(self.clip_load < 0)
975                 self.clip_load = 0;
976         self.old_clip_load = self.clip_load;
977         self.clip_load = self.(weapon_load[self.weapon]) = -1;
978 }
979
980 void W_DropEvent(float event, entity player, float weapon_type, entity weapon_item)
981 {SELFPARAM();
982         setself(player);
983         weapon_dropevent_item = weapon_item;
984         _WEP_ACTION(weapon_type, event);
985         setself(this);
986 }