qcsrc/server/weapons/weaponsystem.qc

   1 #include "weaponsystem.qh"
   2
   3 #include "selection.qh"
   4
   5 #include "../command/common.qh"
   6 #include "../mutators/_mod.qh"
   7 #include "../round_handler.qh"
   8 #include "../resources.qh"
   9 #include <common/t_items.qh>
  10 #include <common/animdecide.qh>
  11 #include <common/constants.qh>
  12 #include <common/net_linked.qh>
  13 #include <common/monsters/_mod.qh>
  14 #include <common/notifications/all.qh>
  15 #include <common/util.qh>
  16 #include <common/weapons/_all.qh>
  17 #include <common/state.qh>
  18 #include <lib/csqcmodel/sv_model.qh>
  19 #include <common/wepent.qh>
  20
  21 .int state;
  22
  23 .float weapon_frametime;
  24
  25 float W_WeaponRateFactor(entity this)
  26 {
  27         float t = 1;
  28         if(g_weaponratefactor > 0)
  29                 t = 1.0 / g_weaponratefactor;
  30
  31         MUTATOR_CALLHOOK(WeaponRateFactor, t, this);
  32         t = M_ARGV(0, float);
  33
  34         return t;
  35 }
  36
  37 float W_WeaponSpeedFactor(entity this)
  38 {
  39         float t = 1.0 * g_weaponspeedfactor;
  40
  41         MUTATOR_CALLHOOK(WeaponSpeedFactor, t, this);
  42         t = M_ARGV(0, float);
  43
  44         return t;
  45 }
  46
  47
  48 bool CL_Weaponentity_CustomizeEntityForClient(entity this, entity client)
  49 {
  50         this.viewmodelforclient = this.owner;
  51         if (IS_SPEC(client) && client.enemy == this.owner) this.viewmodelforclient = client;
  52         return true;
  53 }
  54
  55 vector CL_Weapon_GetShotOrg(int wpn)
  56 {
  57         entity wi = Weapons_from(wpn);
  58         entity e = spawn();
  59         CL_WeaponEntity_SetModel(e, wi.mdl, false);
  60         vector ret = e.movedir;
  61         CL_WeaponEntity_SetModel(e, "", false);
  62         delete(e);
  63         return ret;
  64 }
  65
  66 .float m_alpha;
  67 .string w_weaponname;
  68 .int w_dmg;
  69 .int w_deadflag;
  70
  71 void CL_Weaponentity_Think(entity this)
  72 {
  73         this.nextthink = time;
  74         if (game_stopped) this.frame = this.anim_idle.x;
  75         .entity weaponentity = this.weaponentity_fld;
  76         if (this.owner.(weaponentity) != this)
  77         {
  78                 // owner has new gun; remove old one
  79                 if (this.weaponchild) delete(this.weaponchild);
  80                 if (this.hook) delete(this.hook);
  81                 delete(this);
  82                 return;
  83         }
  84         if (IS_DEAD(this.owner))
  85         {
  86                 // owner died; disappear
  87                 this.model = "";
  88                 if (this.weaponchild) this.weaponchild.model = "";
  89                 return;
  90         }
  91         if (this.w_weaponname != this.weaponname
  92             || this.w_dmg != this.modelindex
  93             || this.w_deadflag != this.deadflag)
  94         {
  95                 // owner changed weapons; update appearance
  96                 this.w_weaponname = this.weaponname;
  97                 this.w_dmg = this.modelindex;
  98                 this.w_deadflag = this.deadflag;
  99
 100                 CL_WeaponEntity_SetModel(this, this.weaponname, true);
 101         }
 102
 103         this.alpha = -1;  // TODO: don't render this entity at all
 104
 105         if (this.owner.alpha == default_player_alpha) this.m_alpha = default_weapon_alpha;
 106         else if (this.owner.alpha != 0) this.m_alpha = this.owner.alpha;
 107         else this.m_alpha  = 1;
 108
 109         if (this.weaponchild)
 110         {
 111                 this.weaponchild.alpha = this.alpha;
 112                 this.weaponchild.effects = this.effects;
 113         }
 114 }
 115
 116 void CL_ExteriorWeaponentity_Think(entity this)
 117 {
 118         this.nextthink = time;
 119         .entity weaponentity = this.weaponentity_fld;
 120         entity w_ent = this.owner.(weaponentity);
 121         if (this.owner.exteriorweaponentity != this)
 122         {
 123                 delete(this);
 124                 return;
 125         }
 126         if (IS_DEAD(this.owner))
 127         {
 128                 this.model = "";
 129                 return;
 130         }
 131         if (this.weaponname != w_ent.weaponname || this.dmg != w_ent.modelindex
 132             || this.deadflag != w_ent.deadflag)
 133         {
 134                 this.weaponname = w_ent.weaponname;
 135                 this.dmg = w_ent.modelindex;
 136                 this.deadflag = w_ent.deadflag;
 137                 if (w_ent.weaponname != "")
 138                 {
 139                         _setmodel(this, W_Model(strcat("v_", w_ent.weaponname, ".md3")));
 140                         setsize(this, '0 0 0', '0 0 0');
 141                 }
 142                 else this.model = "";
 143
 144                 int tag_found;
 145                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
 146                 {
 147                         this.tag_index = tag_found;
 148                         this.tag_entity = this.owner;
 149                 }
 150                 else
 151                 {
 152                         setattachment(this, this.owner, "bip01 r hand");
 153                 }
 154         }
 155         this.effects = this.owner.effects;
 156         this.effects |= EF_LOWPRECISION;
 157         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
 158         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
 159         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
 160         else this.alpha = 1;
 161
 162     Weapon wep = this.owner.(weaponentity).m_weapon;
 163         if (wep) this.glowmod = weaponentity_glowmod(wep, this.owner, this.owner.clientcolors, this.owner.(weaponentity));
 164         this.colormap = this.owner.colormap;
 165
 166         CSQCMODEL_AUTOUPDATE(this);
 167 }
 168
 169 // spawning weaponentity for client
 170 void CL_SpawnWeaponentity(entity actor, .entity weaponentity)
 171 {
 172         entity view = actor.(weaponentity) = new(weaponentity);
 173         view.solid = SOLID_NOT;
 174         view.owner = actor;
 175         setmodel(view, MDL_Null);  // precision set when changed
 176         setorigin(view, '0 0 0');
 177         view.weaponentity_fld = weaponentity;
 178         setthink(view, CL_Weaponentity_Think);
 179         view.nextthink = time;
 180         view.viewmodelforclient = actor;
 181         setcefc(view, CL_Weaponentity_CustomizeEntityForClient);
 182
 183         wepent_link(view);
 184
 185         if (weaponentity == weaponentities[0]) // only one exterior model, thank you very much
 186         {
 187                 entity exterior = actor.exteriorweaponentity = new(exteriorweaponentity);
 188                 exterior.solid = SOLID_NOT;
 189                 exterior.owner = actor;
 190                 exterior.weaponentity_fld = weaponentity;
 191                 setorigin(exterior, '0 0 0');
 192                 setthink(exterior, CL_ExteriorWeaponentity_Think);
 193                 exterior.nextthink = time;
 194
 195                 CSQCMODEL_AUTOINIT(exterior);
 196         }
 197 }
 198
 199 // Weapon subs
 200 void w_clear(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 201 {
 202         actor.(weaponentity).m_weapon = WEP_Null;
 203         actor.(weaponentity).m_switchingweapon = WEP_Null;
 204         entity this = actor.(weaponentity);
 205         if (this)
 206         {
 207                 this.state = WS_CLEAR;
 208                 this.effects = 0;
 209         }
 210 }
 211
 212 void w_ready(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 213 {
 214         entity this = actor.(weaponentity);
 215         if (this) this.state = WS_READY;
 216         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
 217 }
 218
 219 .float prevdryfire;
 220 .float prevwarntime;
 221 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary, .entity weaponentity)
 222 {
 223         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
 224         bool ammo = false;
 225         if (secondary) ammo = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
 226         else ammo = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
 227         if (ammo) return true;
 228         // always keep the Mine Layer if we placed mines, so that we can detonate them
 229         if (thiswep == WEP_MINE_LAYER)
 230         {
 231                 IL_EACH(g_mines, it.owner == actor && it.weaponentity_fld == weaponentity,
 232                 {
 233                         return false;
 234                 });
 235         }
 236
 237         if (thiswep == WEP_SHOTGUN)
 238                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;           // no clicking, just allow
 239
 240         if (thiswep == actor.(weaponentity).m_switchweapon && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 241         {
 242                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
 243                 actor.prevdryfire = time;
 244         }
 245
 246         // check if the other firing mode has enough ammo
 247         bool ammo_other = false;
 248         if (secondary) ammo_other = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
 249         else ammo_other = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
 250         if (ammo_other)
 251         {
 252                 if (time - actor.prevwarntime > 1)
 253                 {
 254                         Send_Notification(
 255                                 NOTIF_ONE,
 256                                 actor,
 257                                 MSG_MULTI,
 258                                 ITEM_WEAPON_PRIMORSEC,
 259                                 thiswep.m_id,
 260                                 secondary,
 261                                 (1 - secondary)
 262                                          );
 263                 }
 264                 actor.prevwarntime = time;
 265         }
 266         else  // this weapon is totally unable to fire, switch to another one
 267         {
 268                 W_SwitchToOtherWeapon(actor, weaponentity);
 269         }
 270
 271         return false;
 272 }
 273
 274 .float race_penalty;
 275 bool weapon_prepareattack_check(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 276 {
 277         if (actor.weaponentity == NULL) return true;
 278         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary, weaponentity)) return false;
 279
 280         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 281         // if all players readied up and the countdown is running
 282         if (time < game_starttime || time < actor.race_penalty) return false;
 283
 284         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
 285                 return false;
 286
 287         // do not even think about shooting if switching
 288         if (actor.(weaponentity).m_switchweapon != actor.(weaponentity).m_weapon) return false;
 289
 290         if (attacktime >= 0)
 291         {
 292                 int slot = weaponslot(weaponentity);
 293                 // don't fire if previous attack is not finished
 294                 if (ATTACK_FINISHED(actor, slot) > time + actor.(weaponentity).weapon_frametime * 0.5) return false;
 295                 entity this = actor.(weaponentity);
 296                 // don't fire while changing weapon
 297                 if (this.state != WS_READY) return false;
 298         }
 299         return true;
 300 }
 301
 302 void weapon_prepareattack_do(entity actor, .entity weaponentity, bool secondary, float attacktime)
 303 {
 304         entity this = actor.(weaponentity);
 305         if (this == NULL) return;
 306         this.state = WS_INUSE;
 307
 308         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
 309
 310         // if the weapon hasn't been firing continuously, reset the timer
 311         if (attacktime >= 0)
 312         {
 313                 int slot = weaponslot(weaponentity);
 314                 if (ATTACK_FINISHED(actor, slot) < time - this.weapon_frametime * 1.5)
 315                 {
 316                         ATTACK_FINISHED(actor, slot) = time;
 317                         // dprint("resetting attack finished to ", ftos(time), "\n");
 318                 }
 319                 ATTACK_FINISHED(actor, slot) = ATTACK_FINISHED(actor, slot) + attacktime * W_WeaponRateFactor(actor);
 320         }
 321         this.bulletcounter += 1;
 322         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, slot)), "\n");
 323 }
 324
 325 bool weapon_prepareattack(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 326 {
 327         if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
 328         {
 329                 weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
 330                 return true;
 331         }
 332         return false;
 333 }
 334
 335 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim);
 336
 337 /**
 338  * @param t defer thinking until time + t
 339  * @param func next think function
 340  */
 341 void weapon_thinkf(entity actor, .entity weaponentity, WFRAME fr, float t, void(Weapon thiswep, entity actor,
 342         .entity weaponentity, int fire) func)
 343 {
 344         entity this = actor.(weaponentity);
 345         if (this == NULL) return;
 346         bool restartanim;
 347         if (fr == WFRAME_DONTCHANGE)
 348         {
 349                 fr = this.wframe;
 350                 restartanim = false;
 351         }
 352         else
 353         {
 354                 restartanim = fr != WFRAME_IDLE;
 355         }
 356
 357         vector of = v_forward;
 358         vector or = v_right;
 359         vector ou = v_up;
 360
 361         vector a = '0 0 0';
 362     this.wframe = fr;
 363     if (fr == WFRAME_IDLE) a = this.anim_idle;
 364     else if (fr == WFRAME_FIRE1) a = this.anim_fire1;
 365     else if (fr == WFRAME_FIRE2) a = this.anim_fire2;
 366     else  // if (fr == WFRAME_RELOAD)
 367         a = this.anim_reload;
 368     a.z *= g_weaponratefactor;
 369
 370         v_forward = of;
 371         v_right = or;
 372         v_up = ou;
 373
 374         if (this.weapon_think == w_ready && func != w_ready && this.state == WS_RAISE) backtrace(
 375                         "Tried to override initial weapon think function - should this really happen?");
 376
 377         t *= W_WeaponRateFactor(actor);
 378
 379         // VorteX: haste can be added here
 380         if (this.weapon_think == w_ready)
 381         {
 382                 this.weapon_nextthink = time;
 383                 // dprint("started firing at ", ftos(time), "\n");
 384         }
 385         if (this.weapon_nextthink < time - this.weapon_frametime * 1.5
 386             || this.weapon_nextthink > time + this.weapon_frametime * 1.5)
 387         {
 388                 this.weapon_nextthink = time;
 389                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
 390         }
 391         this.weapon_nextthink += t;
 392         this.weapon_think = func;
 393         // dprint("next ", ftos(this.weapon_nextthink), "\n");
 394
 395         if (this)
 396         {
 397                 FOREACH_CLIENT(true, {
 398                         if(it == actor || (IS_SPEC(it) && it.enemy == actor))
 399                                 wframe_send(it, this, a, restartanim);
 400                 });
 401         }
 402
 403         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 404         {
 405                 bool primary_melee = boolean(fr == WFRAME_FIRE1 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_PRI));
 406                 bool secondary_melee = boolean(fr == WFRAME_FIRE2 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_SEC));
 407                 int act = (primary_melee || secondary_melee)
 408                         ? ANIMACTION_MELEE
 409                         : ANIMACTION_SHOOT
 410                         ;
 411                 animdecide_setaction(actor, act, restartanim);
 412         }
 413         else if (actor.anim_upper_action == ANIMACTION_SHOOT || actor.anim_upper_action == ANIMACTION_MELEE)
 414         {
 415                 actor.anim_upper_action = 0;
 416         }
 417 }
 418
 419 bool forbidWeaponUse(entity player)
 420 {
 421         if (time < game_starttime && !autocvar_sv_ready_restart_after_countdown) return true;
 422         if (player.player_blocked) return true;
 423         if (game_stopped) return true;
 424         if (STAT(FROZEN, player)) return true;
 425         if (MUTATOR_CALLHOOK(ForbidWeaponUse, player)) return true;
 426         return false;
 427 }
 428
 429 .bool hook_switchweapon;
 430
 431 void W_WeaponFrame(Player actor, .entity weaponentity)
 432 {
 433     TC(Player, actor);
 434     TC(PlayerState, PS(actor));
 435         entity this = actor.(weaponentity);
 436         if (frametime) this.weapon_frametime = frametime;
 437
 438         if (!this || actor.health < 1) return;  // Dead player can't use weapons and injure impulse commands
 439
 440         int button_atck = PHYS_INPUT_BUTTON_ATCK(actor);
 441         int button_atck2 = PHYS_INPUT_BUTTON_ATCK2(actor);
 442
 443         if (round_handler_IsActive() && !round_handler_IsRoundStarted())
 444                 button_atck = button_atck2 = 0; // forbid primary and secondary fire, switching is allowed
 445
 446         if (forbidWeaponUse(actor))
 447         {
 448                 if (this.state != WS_CLEAR)
 449                 {
 450                         Weapon wpn = this.m_weapon;
 451                         w_ready(wpn, actor, weaponentity, button_atck | (button_atck2 << 1));
 452                         return;
 453                 }
 454         }
 455
 456         if(autocvar_g_weaponswitch_debug == 2 && weaponslot(weaponentity) > 0)
 457         {
 458                 .entity wepe1 = weaponentities[0];
 459                 entity wep1 = actor.(wepe1);
 460                 this.m_switchweapon = wep1.m_switchweapon;
 461                 entity store = IS_PLAYER(actor) ? PS(actor) : actor;
 462                 if(!(this.m_switchweapon.spawnflags & WEP_FLAG_DUALWIELD) && !(store.dual_weapons & wep1.m_switchweapon.m_wepset))
 463                 {
 464                         this.m_weapon = WEP_Null;
 465                         this.m_switchingweapon = WEP_Null;
 466                         this.m_switchweapon = WEP_Null;
 467                         this.state = WS_CLEAR;
 468                         this.weaponname = "";
 469                         return;
 470                 }
 471         }
 472
 473         if (this.m_switchweapon == WEP_Null)
 474         {
 475                 this.m_weapon = WEP_Null;
 476                 this.m_switchingweapon = WEP_Null;
 477                 this.state = WS_CLEAR;
 478                 this.weaponname = "";
 479                 return;
 480         }
 481
 482         makevectors(actor.v_angle);
 483         vector fo = v_forward;  // save them in case the weapon think functions change it
 484         vector ri = v_right;
 485         vector up = v_up;
 486
 487         // Change weapon
 488         if (this.m_weapon != this.m_switchweapon)
 489         {
 490                 switch (this.state)
 491                 {
 492                         default:
 493                                 LOG_WARNF("unhandled weaponentity (%i) state for player (%i): %d", this, actor, this.state);
 494                                 break;
 495                         case WS_INUSE:
 496                         case WS_RAISE:
 497                                 break;
 498                         case WS_CLEAR:
 499                         {
 500                                 // end switching!
 501                                 Weapon newwep = this.m_switchweapon;
 502                                 this.m_switchingweapon = newwep;
 503
 504                                 // the two weapon entities will notice this has changed and update their models
 505                                 this.m_weapon = newwep;
 506                                 this.weaponname = newwep.mdl;
 507                                 this.bulletcounter = 0;
 508                                 newwep.wr_setup(newwep, actor, weaponentity);
 509                                 this.state = WS_RAISE;
 510
 511                                 // set our clip load to the load of the weapon we switched to, if it's reloadable
 512                                 if ((newwep.spawnflags & WEP_FLAG_RELOADABLE) && newwep.reloading_ammo)  // prevent accessing undefined cvars
 513                                 {
 514                                         this.clip_load = this.(weapon_load[this.m_switchweapon.m_id]);
 515                                         this.clip_size = newwep.reloading_ammo;
 516                                 }
 517                                 else
 518                                 {
 519                                         this.clip_load = this.clip_size = 0;
 520                                 }
 521
 522                                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, newwep.switchdelay_raise, w_ready);
 523                                 break;
 524                         }
 525                         case WS_DROP:
 526                         {
 527                                 // in dropping phase we can switch at any time
 528                                 this.m_switchingweapon = this.m_switchweapon;
 529                                 break;
 530                         }
 531                         case WS_READY:
 532                         {
 533                                 // start switching!
 534                                 this.m_switchingweapon = this.m_switchweapon;
 535                                 entity oldwep = this.m_weapon;
 536
 537                                 // set up weapon switch think in the future, and start drop anim
 538                                 if (INDEPENDENT_ATTACK_FINISHED || ATTACK_FINISHED(actor, weaponslot(weaponentity)) <= time + this.weapon_frametime * 0.5)
 539                                 {
 540                                         sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
 541                                         this.state = WS_DROP;
 542                                         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
 543                                 }
 544                                 break;
 545                         }
 546                 }
 547         }
 548
 549         // LordHavoc: network timing test code
 550         // if (actor.button0)
 551         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, slot)), " >= ", ftos(this.weapon_nextthink), "\n");
 552
 553         Weapon w = this.m_weapon;
 554
 555         // call the think code which may fire the weapon
 556         // and do so multiple times to resolve framerate dependency issues if the
 557         // server framerate is very low and the weapon fire rate very high
 558         for (int c = 0; c < W_TICSPERFRAME; ++c)
 559         {
 560                 if (w != WEP_Null && !(actor.weapons & WepSet_FromWeapon(w)))
 561                 {
 562                         if (this.m_weapon == this.m_switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 563                         w = WEP_Null;
 564                 }
 565
 566                 v_forward = fo;
 567                 v_right = ri;
 568                 v_up = up;
 569
 570                 bool block_weapon = false;
 571                 {
 572                         bool key_pressed = PHYS_INPUT_BUTTON_HOOK(actor) && !actor.vehicle;
 573                         if (round_handler_IsActive() && !round_handler_IsRoundStarted())
 574                                 key_pressed = false;
 575
 576                         Weapon off = actor.offhand;
 577                         if (off && !(actor.weapons & WEPSET(HOOK)))
 578                         {
 579                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
 580                         }
 581                         else
 582                         {
 583                                 if (key_pressed && this.m_switchweapon != WEP_HOOK && !actor.hook_switchweapon)
 584                                         W_SwitchWeapon(actor, WEP_HOOK, weaponentity);
 585                                 actor.hook_switchweapon = key_pressed;
 586                                 Weapon h = WEP_HOOK;
 587                                 block_weapon = (this.m_weapon == h && (button_atck || key_pressed));
 588                                 h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
 589                         }
 590                 }
 591
 592                 v_forward = fo;
 593                 v_right = ri;
 594                 v_up = up;
 595
 596                 if (!block_weapon)
 597                 {
 598             Weapon e = this.m_weapon;
 599             TC(Weapon, e);
 600                         if (w != WEP_Null)
 601                         {
 602                                 e.wr_think(e, actor, weaponentity, button_atck | (button_atck2 << 1));
 603                         }
 604                         else if (e)
 605                         {
 606                                 e.wr_gonethink(e, actor, weaponentity);
 607                         }
 608                 }
 609
 610                 if (time + this.weapon_frametime * 0.5 >= this.weapon_nextthink)
 611                 {
 612                         if (this.weapon_think)
 613                         {
 614                                 v_forward = fo;
 615                                 v_right = ri;
 616                                 v_up = up;
 617                                 Weapon wpn = this.m_weapon;
 618                                 this.weapon_think(wpn, actor, weaponentity,
 619                                         button_atck | (button_atck2 << 1));
 620                         }
 621                         else
 622                         {
 623                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
 624                         }
 625                 }
 626         }
 627 }
 628
 629 void W_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 630 {
 631         flash.owner = actor;
 632         flash.angles_z = random() * 360;
 633
 634         entity view = actor.(weaponentity);
 635         entity exterior = actor.exteriorweaponentity;
 636
 637         if (gettagindex(view, "shot")) setattachment(flash, view, "shot");
 638         else setattachment(flash, view, "tag_shot");
 639         setorigin(flash, offset);
 640
 641         entity xflash = spawn();
 642         copyentity(flash, xflash);
 643
 644         flash.viewmodelforclient = actor;
 645
 646         if (view.oldorigin.x > 0)
 647         {
 648                 setattachment(xflash, exterior, "");
 649                 setorigin(xflash, view.oldorigin + offset);
 650         }
 651         else
 652         {
 653                 if (gettagindex(exterior, "shot")) setattachment(xflash, exterior, "shot");
 654                 else setattachment(xflash, exterior, "tag_shot");
 655                 setorigin(xflash, offset);
 656         }
 657 }
 658
 659 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use, .entity weaponentity)
 660 {
 661         if (MUTATOR_CALLHOOK(W_DecreaseAmmo, actor, actor.(weaponentity))) return;
 662         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
 663
 664         entity w_ent = actor.(weaponentity);
 665
 666         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 667         if (wep.reloading_ammo)
 668         {
 669                 w_ent.clip_load -= ammo_use;
 670                 w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
 671         }
 672         else if (wep.ammo_type != RESOURCE_NONE)
 673         {
 674                 float ammo = GetResourceAmount(actor, wep.ammo_type);
 675                 if (ammo < ammo_use)
 676                 {
 677                         backtrace(sprintf(
 678                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
 679                                 "Please notify Samual immediately with a copy of this backtrace!\n",
 680                                 ammo_use,
 681                                 wep.netname,
 682                                 GetAmmoPicture(wep.ammo_type),
 683                                 actor.netname,
 684                                 ammo
 685                                              ));
 686                 }
 687                 SetResourceAmount(actor, wep.ammo_type, ammo - ammo_use);
 688         }
 689 }
 690
 691 // weapon reloading code
 692
 693 .float reload_ammo_amount, reload_ammo_min, reload_time;
 694 .float reload_complain;
 695 .string reload_sound;
 696
 697 void W_ReloadedAndReady(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 698 {
 699         // finish the reloading process, and do the ammo transfer
 700
 701         entity w_ent = actor.(weaponentity);
 702         Weapon wpn = w_ent.m_weapon;
 703
 704         w_ent.clip_load = w_ent.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
 705
 706         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
 707         if (!w_ent.reload_ammo_min || (actor.items & IT_UNLIMITED_WEAPON_AMMO) || wpn.ammo_type == RESOURCE_NONE)
 708         {
 709                 w_ent.clip_load = w_ent.reload_ammo_amount;
 710         }
 711         else
 712         {
 713                 // make sure we don't add more ammo than we have
 714                 float ammo = GetResourceAmount(actor, wpn.ammo_type);
 715                 float load = min(w_ent.reload_ammo_amount - w_ent.clip_load, ammo);
 716                 w_ent.clip_load += load;
 717                 SetResourceAmount(actor, wpn.ammo_type, ammo - load);
 718         }
 719         w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
 720
 721         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 722         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 723         // so your weapon is disabled for a few seconds without reason
 724
 725         // ATTACK_FINISHED(actor, slot) -= w_ent.reload_time - 1;
 726
 727         w_ready(wpn, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 728 }
 729
 730 void W_Reload(entity actor, .entity weaponentity, float sent_ammo_min, Sound sent_sound)
 731 {
 732     TC(Sound, sent_sound);
 733         // set global values to work with
 734         entity this = actor.(weaponentity);
 735         Weapon e = this.m_weapon;
 736
 737         if (MUTATOR_CALLHOOK(W_Reload, actor)) return;
 738
 739         this.reload_ammo_min = sent_ammo_min;
 740         this.reload_ammo_amount = e.reloading_ammo;
 741         this.reload_time = e.reloading_time;
 742         if (actor.reload_sound) strunzone(actor.reload_sound);
 743         actor.reload_sound = strzone(Sound_fixpath(sent_sound));
 744
 745         // don't reload weapons that don't have the RELOADABLE flag
 746         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
 747         {
 748                 LOG_TRACE(
 749                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
 750                 return;
 751         }
 752
 753         // return if reloading is disabled for this weapon
 754         if (!this.reload_ammo_amount) return;
 755
 756         // our weapon is fully loaded, no need to reload
 757         if (this.clip_load >= this.reload_ammo_amount) return;
 758
 759         // no ammo, so nothing to load
 760         if (e.ammo_type != RESOURCE_NONE)
 761         {
 762                 if (!GetResourceAmount(actor, e.ammo_type) && this.reload_ammo_min)
 763                 {
 764                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 765                         {
 766                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
 767                                 {
 768                                         play2(actor, SND(UNAVAILABLE));
 769                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", this.m_weapon.m_name, "\n"));
 770                                         actor.reload_complain = time + 1;
 771                                 }
 772                                 // switch away if the amount of ammo is not enough to keep using this weapon
 773                                 if (!(e.wr_checkammo1(e, actor, weaponentity) + e.wr_checkammo2(e, actor, weaponentity)))
 774                                 {
 775                                         this.clip_load = -1;  // reload later
 776                                         W_SwitchToOtherWeapon(actor, weaponentity);
 777                                 }
 778                                 return;
 779                         }
 780                 }
 781         }
 782
 783         if (this)
 784         {
 785                 if (this.wframe == WFRAME_RELOAD) return;
 786
 787                 // allow switching away while reloading, but this will cause a new reload!
 788                 this.state = WS_READY;
 789         }
 790
 791         // now begin the reloading process
 792
 793         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
 794
 795         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 796         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 797         // so your weapon is disabled for a few seconds without reason
 798
 799         // ATTACK_FINISHED(actor, slot) = max(time, ATTACK_FINISHED(actor, slot)) + this.reload_time + 1;
 800
 801         weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, this.reload_time, W_ReloadedAndReady);
 802
 803         if (this.clip_load < 0) this.clip_load = 0;
 804         this.old_clip_load = this.clip_load;
 805         this.clip_load = this.(weapon_load[this.m_weapon.m_id]) = -1;
 806 }
 807
 808 void W_DropEvent(.void(Weapon, entity actor, .entity) event, entity player, float weapon_type, entity weapon_item, .entity weaponentity)
 809 {
 810         Weapon w = Weapons_from(weapon_type);
 811         weapon_dropevent_item = weapon_item;
 812         w.event(w, player, weaponentity);
 813 }