warpzonelib: expose WarpZone_trace_firstzone
[xonotic/xonotic-data.pk3dir.git] / qcsrc / warpzonelib / common.qc
1 float trace_dphitcontents;
2 .float dphitcontentsmask;
3
4 void WarpZone_Accumulator_Clear(entity acc)
5 {
6         acc.warpzone_transform = '0 0 0';
7         acc.warpzone_shift = '0 0 0';
8 }
9 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
10 {
11         vector tr, st;
12         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
13         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
14         acc.warpzone_transform = tr;
15         acc.warpzone_shift = st;
16 }
17 void WarpZone_Accumulator_Add(entity acc, entity wz)
18 {
19         vector t, st;
20         t = AnglesTransform_Multiply(wz.warpzone_transform, acc.warpzone_transform);
21         st = AnglesTransform_Multiply_GetPostShift(wz.warpzone_transform, wz.warpzone_shift, acc.warpzone_transform, acc.warpzone_shift);
22         acc.warpzone_transform = t;
23         acc.warpzone_shift = st;
24 }
25
26 .vector(vector, vector) camera_transform;
27 var float autocvar_cl_warpzone_usetrace = 1;
28 vector WarpZone_camera_transform(vector org, vector ang)
29 {
30         vector vf, vr, vu;
31         if(self.warpzone_fadestart)
32                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
33                         return org;
34                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
35                         // unneeded on client, on server this helps a lot
36         vf = v_forward;
37         vr = v_right;
38         vu = v_up;
39         org = WarpZone_TransformOrigin(self, org);
40         vf = WarpZone_TransformVelocity(self, vf);
41         vr = WarpZone_TransformVelocity(self, vr);
42         vu = WarpZone_TransformVelocity(self, vu);
43         if(autocvar_cl_warpzone_usetrace)
44                 traceline(self.warpzone_targetorigin, org, MOVE_NOMONSTERS, world);
45         else
46                 trace_endpos = self.warpzone_targetorigin;
47         v_forward = vf;
48         v_right = vr;
49         v_up = vu;
50         return org;
51 }
52
53 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
54 {
55         e.warpzone_transform = AnglesTransform_Divide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
56         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
57         e.warpzone_origin = my_org;
58         e.warpzone_targetorigin = other_org;
59         e.warpzone_angles = my_ang;
60         e.warpzone_targetangles = other_ang;
61         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
62         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
63         e.camera_transform = WarpZone_camera_transform;
64 }
65
66 vector WarpZone_Camera_camera_transform(vector org, vector ang)
67 {
68         // a fixed camera view
69         if(self.warpzone_fadestart)
70                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
71                         return org;
72                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
73                         // unneeded on client, on server this helps a lot
74         trace_endpos = self.warpzone_origin;
75         makevectors(self.warpzone_angles);
76         return self.warpzone_origin;
77 }
78
79 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
80 {
81         e.warpzone_origin = my_org;
82         e.warpzone_angles = my_ang;
83         e.camera_transform = WarpZone_Camera_camera_transform;
84 }
85
86 .entity enemy;
87
88 vector WarpZoneLib_BoxTouchesBrush_mins;
89 vector WarpZoneLib_BoxTouchesBrush_maxs;
90 entity WarpZoneLib_BoxTouchesBrush_ent;
91 entity WarpZoneLib_BoxTouchesBrush_ignore;
92 float WarpZoneLib_BoxTouchesBrush_Recurse()
93 {
94         float s;
95         entity se;
96         float f;
97
98         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
99 #ifdef CSQC
100         if (trace_networkentity)
101         {
102                 dprint("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush\n");
103                 // we cannot continue, as a player blocks us...
104                 // so, abort
105                 return 0;
106         }
107 #endif
108         if not(trace_ent)
109                 return 0;
110         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
111                 return 1;
112
113         se = trace_ent;
114         s = se.solid;
115         se.solid = SOLID_NOT;
116         f = WarpZoneLib_BoxTouchesBrush_Recurse();
117         se.solid = s;
118
119         return f;
120 }
121
122 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
123 {
124     float f, s;
125
126     if(!e.modelindex || e.warpzone_isboxy)
127         return 1;
128
129     s = e.solid;
130     e.solid = SOLID_BSP;
131     WarpZoneLib_BoxTouchesBrush_mins = mi;
132     WarpZoneLib_BoxTouchesBrush_maxs = ma;
133     WarpZoneLib_BoxTouchesBrush_ent = e;
134     WarpZoneLib_BoxTouchesBrush_ignore = ig;
135     f = WarpZoneLib_BoxTouchesBrush_Recurse();
136     e.solid = s;
137
138     return f;
139 }
140
141 entity WarpZone_Find(vector mi, vector ma)
142 {
143         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
144         entity e;
145         if(!warpzone_warpzones_exist)
146                 return world;
147         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
148                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
149                         return e;
150         return world;
151 }
152
153 void WarpZone_MakeAllSolid()
154 {
155         entity e;
156         if(!warpzone_warpzones_exist)
157                 return;
158         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
159                 e.solid = SOLID_BSP;
160 }
161
162 void WarpZone_MakeAllOther()
163 {
164         entity e;
165         if(!warpzone_warpzones_exist)
166                 return;
167         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
168                 e.solid = SOLID_TRIGGER;
169 }
170
171 void WarpZone_Trace_InitTransform()
172 {
173         if(!WarpZone_trace_transform)
174         {
175                 WarpZone_trace_transform = spawn();
176                 WarpZone_trace_transform.classname = "warpzone_trace_transform";
177         }
178         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
179 }
180 void WarpZone_Trace_AddTransform(entity wz)
181 {
182         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
183 }
184
185 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
186 {
187         float nomonsters_adjusted;
188         float frac, sol, i;
189         float contentshack;
190         vector o0, e0;
191         entity wz;
192         vector vf, vr, vu;
193
194         WarpZone_trace_firstzone = world;
195         WarpZone_Trace_InitTransform();
196         if(!warpzone_warpzones_exist)
197         {
198                 if(nomonsters == MOVE_NOTHING)
199                 {
200                         trace_endpos = end;
201                         trace_fraction = 1;
202                         if(cb)
203                                 cb(org, trace_endpos, end);
204                         return;
205                 }
206                 else
207                 {
208                         tracebox(org, mi, ma, end, nomonsters, forent);
209                         if(cb)
210                                 cb(org, trace_endpos, end);
211                         return;
212                 }
213         }
214
215         vf = v_forward;
216         vr = v_right;
217         vu = v_up;
218         o0 = org;
219         e0 = end;
220
221         switch(nomonsters)
222         {
223                 case MOVE_WORLDONLY:
224                 case MOVE_NOTHING:
225                         nomonsters_adjusted = MOVE_NOMONSTERS;
226                         break;
227                 default:
228                         nomonsters_adjusted = nomonsters;
229                         break;
230         }
231         if((contentshack = (forent.dphitcontentsmask && !(forent.dphitcontentsmask & DPCONTENTS_SOLID))))
232                 forent.dphitcontentsmask |= DPCONTENTS_SOLID;
233
234         // if starting in warpzone, first transform
235         wz = WarpZone_Find(org + mi, org + ma);
236         if(wz)
237         {
238                 WarpZone_trace_firstzone = wz;
239                 if(zone && wz != zone)
240                 {
241                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
242                         sol = 1;
243                         trace_fraction = 0;
244                         trace_endpos = org;
245                         goto fail;
246                 }
247                 WarpZone_Trace_AddTransform(wz);
248                 org = WarpZone_TransformOrigin(wz, org);
249                 end = WarpZone_TransformOrigin(wz, end);
250         }
251         WarpZone_MakeAllSolid();
252         sol = -1;
253         frac = 0;
254         i = 16;
255         for(;;)
256         {
257                 if(--i < 1)
258                 {
259                         dprint("Too many warpzones in sequence, aborting trace.\n");
260                         trace_ent = world;
261                         break;
262                 }
263                 tracebox(org, mi, ma, end, nomonsters_adjusted, forent);
264                 if(cb)
265                         cb(org, trace_endpos, end);
266                 if(sol < 0)
267                         sol = trace_startsolid;
268
269                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
270                 if(trace_fraction >= 1)
271                         break;
272                 if(trace_ent.classname != "trigger_warpzone")
273                 {
274                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & forent.dphitcontentsmask) == DPCONTENTS_SOLID))
275                         {
276                                 // continue the trace, ignoring this hit (we only care for warpzones)
277                                 org = trace_endpos + normalize(end - org);
278                                 continue;
279                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
280                                 // otherwise, players could block entrances that way
281                         }
282                         break;
283                 }
284                 if(trace_ent == wz)
285                 {
286                         // FIXME can this check be removed? Do we really need it?
287                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
288                         trace_ent = world;
289                         break;
290                 }
291                 wz = trace_ent;
292                 WarpZone_trace_firstzone = wz;
293                 if(zone && wz != zone)
294                         break;
295                 WarpZone_Trace_AddTransform(wz);
296                 // we hit a warpzone... so, let's perform the trace after the warp again
297                 org = WarpZone_TransformOrigin(wz, trace_endpos);
298                 end = WarpZone_TransformOrigin(wz, end);
299         }
300         WarpZone_MakeAllOther();
301 :fail
302         if(contentshack)
303                 forent.dphitcontentsmask &~= DPCONTENTS_SOLID;
304         trace_startsolid = sol;
305         v_forward = vf;
306         v_right = vr;
307         v_up = vu;
308 }
309
310 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
311 {
312         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, world, WarpZone_trace_callback_t_null);
313 }
314
315 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
316 {
317         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
318 }
319
320 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
321 {
322         float g, dt, i;
323         vector vf, vr, vu, v0, o0;
324         entity wz;
325
326         o0 = e.origin;
327         v0 = e.velocity;
328
329         WarpZone_Trace_InitTransform();
330         WarpZone_trace_firstzone = world;
331         WarpZone_tracetoss_time = 0;
332         if(!warpzone_warpzones_exist)
333         {
334                 tracetoss(e, forent);
335                 if(cb)
336                         cb(e.origin, trace_endpos, trace_endpos);
337                 dt = vlen(e.origin - o0) / vlen(e.velocity);
338                 WarpZone_tracetoss_time += dt;
339                 e.velocity_z -= dt * g;
340                 WarpZone_tracetoss_velocity = e.velocity;
341                 e.velocity = v0;
342                 return;
343         }
344
345         vf = v_forward;
346         vr = v_right;
347         vu = v_up;
348
349         // if starting in warpzone, first transform
350         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
351         if(wz)
352         {
353                 WarpZone_trace_firstzone = wz;
354                 if(zone && wz != zone)
355                 {
356                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
357
358                         WarpZone_tracetoss_time = 0;
359                         trace_endpos = o0;
360                         goto fail;
361                 }
362                 WarpZone_Trace_AddTransform(wz);
363                 setorigin(e, WarpZone_TransformOrigin(wz, e.origin));
364                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
365         }
366         WarpZone_MakeAllSolid();
367         g = cvar("sv_gravity") * e.gravity;
368         i = 16;
369         for(;;)
370         {
371                 if(--i < 1)
372                 {
373                         dprint("Too many warpzones in sequence, aborting trace.\n");
374                         trace_ent = world;
375                         break;
376                 }
377                 tracetoss(e, forent);
378                 if(cb)
379                         cb(e.origin, trace_endpos, trace_endpos);
380                 e.origin = trace_endpos;
381                 dt = vlen(e.origin - o0) / vlen(e.velocity);
382                 WarpZone_tracetoss_time += dt;
383                 e.velocity_z -= dt * g;
384                 if(trace_fraction >= 1)
385                         break;
386                 if(trace_ent.classname != "trigger_warpzone")
387                         break;
388                 if(trace_ent == wz)
389                 {
390                         // FIXME can this check be removed? Do we really need it?
391                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
392                         trace_ent = world;
393                         break;
394                 }
395                 wz = trace_ent;
396                 WarpZone_trace_firstzone = wz;
397                 if(zone && wz != zone)
398                         break;
399                 WarpZone_Trace_AddTransform(wz);
400                 // we hit a warpzone... so, let's perform the trace after the warp again
401                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
402                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
403         }
404         WarpZone_MakeAllOther();
405 :fail
406         WarpZone_tracetoss_velocity = e.velocity;
407         v_forward = vf;
408         v_right = vr;
409         v_up = vu;
410         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
411         e.velocity = v0;
412         e.origin = o0;
413 }
414
415 void WarpZone_TraceToss(entity e, entity forent)
416 {
417         WarpZone_TraceToss_ThroughZone(e, forent, world, WarpZone_trace_callback_t_null);
418 }
419
420 entity WarpZone_TrailParticles_trace_callback_own;
421 float WarpZone_TrailParticles_trace_callback_eff;
422 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
423 {
424         trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
425 }
426
427 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
428 {
429         WarpZone_TrailParticles_trace_callback_own = own;
430         WarpZone_TrailParticles_trace_callback_eff = eff;
431         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_trace_callback);
432 }
433
434 #ifdef CSQC
435 float WarpZone_TrailParticles_trace_callback_f;
436 float WarpZone_TrailParticles_trace_callback_flags;
437 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
438 {
439         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
440 }
441
442 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, float boxflags)
443 {
444         WarpZone_TrailParticles_trace_callback_own = own;
445         WarpZone_TrailParticles_trace_callback_eff = eff;
446         WarpZone_TrailParticles_trace_callback_f = f;
447         WarpZone_TrailParticles_trace_callback_flags = boxflags;
448         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_WithMultiplier_trace_callback);
449 }
450 #endif
451
452 float WarpZone_PlaneDist(entity wz, vector v)
453 {
454         return (v - wz.warpzone_origin) * wz.warpzone_forward;
455 }
456
457 float WarpZone_TargetPlaneDist(entity wz, vector v)
458 {
459         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
460 }
461
462 vector WarpZone_TransformOrigin(entity wz, vector v)
463 {
464         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
465 }
466
467 vector WarpZone_TransformVelocity(entity wz, vector v)
468 {
469         return AnglesTransform_Apply(wz.warpzone_transform, v);
470 }
471
472 vector WarpZone_TransformAngles(entity wz, vector v)
473 {
474         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
475 }
476
477 vector WarpZone_TransformVAngles(entity wz, vector ang)
478 {
479 #ifdef KEEP_ROLL
480         float roll;
481         roll = ang_z;
482         ang_z = 0;
483 #endif
484
485         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
486
487 #ifdef KEEP_ROLL
488         ang = AnglesTransform_Normalize(ang, TRUE);
489         ang = AnglesTransform_CancelRoll(ang);
490         ang_z = roll;
491 #else
492         ang = AnglesTransform_Normalize(ang, FALSE);
493 #endif
494
495         return ang;
496 }
497
498 vector WarpZone_UnTransformOrigin(entity wz, vector v)
499 {
500         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
501 }
502
503 vector WarpZone_UnTransformVelocity(entity wz, vector v)
504 {
505         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
506 }
507
508 vector WarpZone_UnTransformAngles(entity wz, vector v)
509 {
510         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
511 }
512
513 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
514 {
515         float roll;
516
517         roll = ang_z;
518         ang_z = 0;
519
520         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
521         ang = AnglesTransform_Normalize(ang, TRUE);
522         ang = AnglesTransform_CancelRoll(ang);
523
524         ang_z = roll;
525         return ang;
526 }
527
528 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
529 {
530         vector nearest;
531         nearest_x = bound(mi_x, org_x, ma_x);
532         nearest_y = bound(mi_y, org_y, ma_y);
533         nearest_z = bound(mi_z, org_z, ma_z);
534         return nearest;
535 }
536
537 .float WarpZone_findradius_hit;
538 .entity WarpZone_findradius_next;
539 void WarpZone_FindRadius_Recurse(vector org, float rad,        vector org0,               vector transform, vector shift, float needlineofsight)
540 //                               blast origin of current search   original blast origin   how to untransform (victim to blast system)
541 {
542         vector org_new;
543         vector org0_new;
544         vector shift_new, transform_new;
545         vector p;
546         entity e, e0;
547         entity wz;
548         if(rad <= 0)
549                 return;
550         e0 = findradius(org, rad);
551         wz = world;
552
553         for(e = e0; e; e = e.chain)
554         {
555                 p = WarpZoneLib_NearestPointOnBox(e.origin + e.mins, e.origin + e.maxs, org0);
556                 if(needlineofsight)
557                 {
558                         traceline(org, p, MOVE_NOMONSTERS, e);
559                         if(trace_fraction < 1)
560                                 continue;
561                 }
562                 if(!e.WarpZone_findradius_hit || vlen(e.WarpZone_findradius_dist) > vlen(org0 - p))
563                 {
564                         e.WarpZone_findradius_nearest = p;
565                         e.WarpZone_findradius_dist = org0 - p;
566                         e.WarpZone_findradius_findorigin = org;
567                         e.WarpZone_findradius_findradius = rad;
568                         if(e.classname == "warpzone_refsys")
569                         {
570                                 // ignore, especially: do not overwrite the refsys parameters
571                         }
572                         else if(e.classname == "trigger_warpzone")
573                         {
574                                 e.WarpZone_findradius_next = wz;
575                                 wz = e;
576                                 e.WarpZone_findradius_hit = 1;
577                                 e.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
578                                 e.enemy.WarpZone_findradius_hit = 1;
579                         }
580                         else
581                         {
582                                 e.warpzone_transform = transform;
583                                 e.warpzone_shift = shift;
584                                 e.WarpZone_findradius_hit = 1;
585                         }
586                 }
587         }
588         for(e = wz; e; e = e.WarpZone_findradius_next)
589         {
590                 org0_new = WarpZone_TransformOrigin(e, org);
591                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
592                 org_new = trace_endpos;
593
594                 transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
595                 shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
596                 WarpZone_FindRadius_Recurse(
597                         org_new,
598                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
599                         org0_new,
600                         transform_new, shift_new,
601                         needlineofsight);
602                 e.WarpZone_findradius_hit = 0;
603                 e.enemy.WarpZone_findradius_hit = 0;
604         }
605 }
606 entity WarpZone_FindRadius(vector org, float rad, float needlineofsight)
607 {
608         entity e0, e;
609         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
610         e0 = findchainfloat(WarpZone_findradius_hit, 1);
611         for(e = e0; e; e = e.chain)
612                 e.WarpZone_findradius_hit = 0;
613         return e0;
614 }
615
616 .entity WarpZone_refsys;
617 void WarpZone_RefSys_GC()
618 {
619         // garbage collect unused reference systems
620         self.nextthink = time + 1;
621         if(self.owner.WarpZone_refsys != self)
622                 remove(self);
623 }
624 void WarpZone_RefSys_Add(entity me, entity wz)
625 {
626         if(me.WarpZone_refsys.owner != me)
627         {
628                 me.WarpZone_refsys = spawn();
629                 me.WarpZone_refsys.classname = "warpzone_refsys";
630                 me.WarpZone_refsys.owner = me;
631                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
632                 me.WarpZone_refsys.nextthink = time + 1;
633                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
634         }
635         if(wz)
636                 WarpZone_Accumulator_Add(me.WarpZone_refsys, wz);
637 }
638 .vector WarpZone_refsys_incremental_shift;
639 .vector WarpZone_refsys_incremental_transform;
640 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
641 {
642         vector t, s;
643         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
644         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
645                 return;
646         if(me.WarpZone_refsys.owner != me)
647         {
648                 me.WarpZone_refsys = spawn();
649                 me.WarpZone_refsys.classname = "warpzone_refsys";
650                 me.WarpZone_refsys.owner = me;
651                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
652                 me.WarpZone_refsys.nextthink = time + 1;
653                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
654         }
655         t = AnglesTransform_Invert(me.WarpZone_refsys_incremental_transform);
656         s = AnglesTransform_PrePostShift_GetPostShift(me.WarpZone_refsys_incremental_shift, t, '0 0 0');
657         WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
658         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref);
659         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
660         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
661 }
662 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
663 {
664         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
665         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
666 }
667 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
668 {
669         if(from.WarpZone_refsys)
670                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
671         if(to.WarpZone_refsys)
672                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
673         return org;
674 }
675 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
676 {
677         if(from.WarpZone_refsys)
678                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
679         if(to.WarpZone_refsys)
680                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
681         return vel;
682 }
683 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
684 {
685         if(from.WarpZone_refsys)
686                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
687         if(to.WarpZone_refsys)
688                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
689         return ang;
690 }
691 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
692 {
693         if(from.WarpZone_refsys)
694                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
695         if(to.WarpZone_refsys)
696                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
697         return ang;
698 }
699 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
700 {
701         entity e;
702         e = spawn();
703         if(me.WarpZone_refsys)
704         {
705                 e.WarpZone_refsys = spawn();
706                 e.WarpZone_refsys.classname = "warpzone_refsys";
707                 e.WarpZone_refsys.owner = e;
708                 e.WarpZone_refsys.think = WarpZone_RefSys_GC;
709                 e.WarpZone_refsys.nextthink = time + 1;
710                 e.WarpZone_refsys.warpzone_shift = me.WarpZone_refsys.warpzone_shift;
711                 e.WarpZone_refsys.warpzone_transform = me.WarpZone_refsys.warpzone_transform;
712         }
713         return e;
714 }