also expose the last zone
[xonotic/xonotic-data.pk3dir.git] / qcsrc / warpzonelib / common.qc
1 float trace_dphitcontents;
2 .float dphitcontentsmask;
3
4 void WarpZone_Accumulator_Clear(entity acc)
5 {
6         acc.warpzone_transform = '0 0 0';
7         acc.warpzone_shift = '0 0 0';
8 }
9 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
10 {
11         vector tr, st;
12         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
13         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
14         acc.warpzone_transform = tr;
15         acc.warpzone_shift = st;
16 }
17 void WarpZone_Accumulator_Add(entity acc, entity wz)
18 {
19         vector t, st;
20         t = AnglesTransform_Multiply(wz.warpzone_transform, acc.warpzone_transform);
21         st = AnglesTransform_Multiply_GetPostShift(wz.warpzone_transform, wz.warpzone_shift, acc.warpzone_transform, acc.warpzone_shift);
22         acc.warpzone_transform = t;
23         acc.warpzone_shift = st;
24 }
25
26 .vector(vector, vector) camera_transform;
27 var float autocvar_cl_warpzone_usetrace = 1;
28 vector WarpZone_camera_transform(vector org, vector ang)
29 {
30         vector vf, vr, vu;
31         if(self.warpzone_fadestart)
32                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
33                         return org;
34                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
35                         // unneeded on client, on server this helps a lot
36         vf = v_forward;
37         vr = v_right;
38         vu = v_up;
39         org = WarpZone_TransformOrigin(self, org);
40         vf = WarpZone_TransformVelocity(self, vf);
41         vr = WarpZone_TransformVelocity(self, vr);
42         vu = WarpZone_TransformVelocity(self, vu);
43         if(autocvar_cl_warpzone_usetrace)
44                 traceline(self.warpzone_targetorigin, org, MOVE_NOMONSTERS, world);
45         else
46                 trace_endpos = self.warpzone_targetorigin;
47         v_forward = vf;
48         v_right = vr;
49         v_up = vu;
50         return org;
51 }
52
53 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
54 {
55         e.warpzone_transform = AnglesTransform_Divide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
56         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
57         e.warpzone_origin = my_org;
58         e.warpzone_targetorigin = other_org;
59         e.warpzone_angles = my_ang;
60         e.warpzone_targetangles = other_ang;
61         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
62         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
63         e.camera_transform = WarpZone_camera_transform;
64 }
65
66 vector WarpZone_Camera_camera_transform(vector org, vector ang)
67 {
68         // a fixed camera view
69         if(self.warpzone_fadestart)
70                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
71                         return org;
72                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
73                         // unneeded on client, on server this helps a lot
74         trace_endpos = self.warpzone_origin;
75         makevectors(self.warpzone_angles);
76         return self.warpzone_origin;
77 }
78
79 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
80 {
81         e.warpzone_origin = my_org;
82         e.warpzone_angles = my_ang;
83         e.camera_transform = WarpZone_Camera_camera_transform;
84 }
85
86 .entity enemy;
87
88 vector WarpZoneLib_BoxTouchesBrush_mins;
89 vector WarpZoneLib_BoxTouchesBrush_maxs;
90 entity WarpZoneLib_BoxTouchesBrush_ent;
91 entity WarpZoneLib_BoxTouchesBrush_ignore;
92 float WarpZoneLib_BoxTouchesBrush_Recurse()
93 {
94         float s;
95         entity se;
96         float f;
97
98         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
99 #ifdef CSQC
100         if (trace_networkentity)
101         {
102                 dprint("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush\n");
103                 // we cannot continue, as a player blocks us...
104                 // so, abort
105                 return 0;
106         }
107 #endif
108         if not(trace_ent)
109                 return 0;
110         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
111                 return 1;
112
113         se = trace_ent;
114         s = se.solid;
115         se.solid = SOLID_NOT;
116         f = WarpZoneLib_BoxTouchesBrush_Recurse();
117         se.solid = s;
118
119         return f;
120 }
121
122 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
123 {
124     float f, s;
125
126     if(!e.modelindex || e.warpzone_isboxy)
127         return 1;
128
129     s = e.solid;
130     e.solid = SOLID_BSP;
131     WarpZoneLib_BoxTouchesBrush_mins = mi;
132     WarpZoneLib_BoxTouchesBrush_maxs = ma;
133     WarpZoneLib_BoxTouchesBrush_ent = e;
134     WarpZoneLib_BoxTouchesBrush_ignore = ig;
135     f = WarpZoneLib_BoxTouchesBrush_Recurse();
136     e.solid = s;
137
138     return f;
139 }
140
141 entity WarpZone_Find(vector mi, vector ma)
142 {
143         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
144         entity e;
145         if(!warpzone_warpzones_exist)
146                 return world;
147         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
148                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
149                         return e;
150         return world;
151 }
152
153 void WarpZone_MakeAllSolid()
154 {
155         entity e;
156         if(!warpzone_warpzones_exist)
157                 return;
158         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
159                 e.solid = SOLID_BSP;
160 }
161
162 void WarpZone_MakeAllOther()
163 {
164         entity e;
165         if(!warpzone_warpzones_exist)
166                 return;
167         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
168                 e.solid = SOLID_TRIGGER;
169 }
170
171 void WarpZone_Trace_InitTransform()
172 {
173         if(!WarpZone_trace_transform)
174         {
175                 WarpZone_trace_transform = spawn();
176                 WarpZone_trace_transform.classname = "warpzone_trace_transform";
177         }
178         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
179 }
180 void WarpZone_Trace_AddTransform(entity wz)
181 {
182         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
183 }
184
185 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
186 {
187         float nomonsters_adjusted;
188         float frac, sol, i;
189         float contentshack;
190         vector o0, e0;
191         entity wz;
192         vector vf, vr, vu;
193
194         WarpZone_trace_firstzone = world;
195         WarpZone_trace_lastzone = world;
196         WarpZone_Trace_InitTransform();
197         if(!warpzone_warpzones_exist)
198         {
199                 if(nomonsters == MOVE_NOTHING)
200                 {
201                         trace_endpos = end;
202                         trace_fraction = 1;
203                         if(cb)
204                                 cb(org, trace_endpos, end);
205                         return;
206                 }
207                 else
208                 {
209                         tracebox(org, mi, ma, end, nomonsters, forent);
210                         if(cb)
211                                 cb(org, trace_endpos, end);
212                         return;
213                 }
214         }
215
216         vf = v_forward;
217         vr = v_right;
218         vu = v_up;
219         o0 = org;
220         e0 = end;
221
222         switch(nomonsters)
223         {
224                 case MOVE_WORLDONLY:
225                 case MOVE_NOTHING:
226                         nomonsters_adjusted = MOVE_NOMONSTERS;
227                         break;
228                 default:
229                         nomonsters_adjusted = nomonsters;
230                         break;
231         }
232         if((contentshack = (forent.dphitcontentsmask && !(forent.dphitcontentsmask & DPCONTENTS_SOLID))))
233                 forent.dphitcontentsmask |= DPCONTENTS_SOLID;
234
235         // if starting in warpzone, first transform
236         wz = WarpZone_Find(org + mi, org + ma);
237         if(wz)
238         {
239                 WarpZone_trace_firstzone = wz;
240                 WarpZone_trace_lastzone = wz;
241                 if(zone && wz != zone)
242                 {
243                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
244                         sol = 1;
245                         trace_fraction = 0;
246                         trace_endpos = org;
247                         goto fail;
248                 }
249                 WarpZone_Trace_AddTransform(wz);
250                 org = WarpZone_TransformOrigin(wz, org);
251                 end = WarpZone_TransformOrigin(wz, end);
252         }
253         WarpZone_MakeAllSolid();
254         sol = -1;
255         frac = 0;
256         i = 16;
257         for(;;)
258         {
259                 if(--i < 1)
260                 {
261                         dprint("Too many warpzones in sequence, aborting trace.\n");
262                         trace_ent = world;
263                         break;
264                 }
265                 tracebox(org, mi, ma, end, nomonsters_adjusted, forent);
266                 if(cb)
267                         cb(org, trace_endpos, end);
268                 if(sol < 0)
269                         sol = trace_startsolid;
270
271                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
272                 if(trace_fraction >= 1)
273                         break;
274                 if(trace_ent.classname != "trigger_warpzone")
275                 {
276                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & forent.dphitcontentsmask) == DPCONTENTS_SOLID))
277                         {
278                                 // continue the trace, ignoring this hit (we only care for warpzones)
279                                 org = trace_endpos + normalize(end - org);
280                                 continue;
281                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
282                                 // otherwise, players could block entrances that way
283                         }
284                         break;
285                 }
286                 if(trace_ent == wz)
287                 {
288                         // FIXME can this check be removed? Do we really need it?
289                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
290                         trace_ent = world;
291                         break;
292                 }
293                 wz = trace_ent;
294                 if(!WarpZone_trace_firstzone)
295                         WarpZone_trace_firstzone = wz;
296                 WarpZone_trace_lastzone = wz;
297                 if(zone && wz != zone)
298                         break;
299                 WarpZone_Trace_AddTransform(wz);
300                 // we hit a warpzone... so, let's perform the trace after the warp again
301                 org = WarpZone_TransformOrigin(wz, trace_endpos);
302                 end = WarpZone_TransformOrigin(wz, end);
303         }
304         WarpZone_MakeAllOther();
305 :fail
306         if(contentshack)
307                 forent.dphitcontentsmask &~= DPCONTENTS_SOLID;
308         trace_startsolid = sol;
309         v_forward = vf;
310         v_right = vr;
311         v_up = vu;
312 }
313
314 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
315 {
316         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, world, WarpZone_trace_callback_t_null);
317 }
318
319 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
320 {
321         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
322 }
323
324 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
325 {
326         float g, dt, i;
327         vector vf, vr, vu, v0, o0;
328         entity wz;
329
330         o0 = e.origin;
331         v0 = e.velocity;
332
333         WarpZone_trace_firstzone = world;
334         WarpZone_trace_lastzone = world;
335         WarpZone_Trace_InitTransform();
336         WarpZone_tracetoss_time = 0;
337         if(!warpzone_warpzones_exist)
338         {
339                 tracetoss(e, forent);
340                 if(cb)
341                         cb(e.origin, trace_endpos, trace_endpos);
342                 dt = vlen(e.origin - o0) / vlen(e.velocity);
343                 WarpZone_tracetoss_time += dt;
344                 e.velocity_z -= dt * g;
345                 WarpZone_tracetoss_velocity = e.velocity;
346                 e.velocity = v0;
347                 return;
348         }
349
350         vf = v_forward;
351         vr = v_right;
352         vu = v_up;
353
354         // if starting in warpzone, first transform
355         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
356         if(wz)
357         {
358                 WarpZone_trace_firstzone = wz;
359                 WarpZone_trace_lastzone = wz;
360                 if(zone && wz != zone)
361                 {
362                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
363
364                         WarpZone_tracetoss_time = 0;
365                         trace_endpos = o0;
366                         goto fail;
367                 }
368                 WarpZone_Trace_AddTransform(wz);
369                 setorigin(e, WarpZone_TransformOrigin(wz, e.origin));
370                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
371         }
372         WarpZone_MakeAllSolid();
373         g = cvar("sv_gravity") * e.gravity;
374         i = 16;
375         for(;;)
376         {
377                 if(--i < 1)
378                 {
379                         dprint("Too many warpzones in sequence, aborting trace.\n");
380                         trace_ent = world;
381                         break;
382                 }
383                 tracetoss(e, forent);
384                 if(cb)
385                         cb(e.origin, trace_endpos, trace_endpos);
386                 e.origin = trace_endpos;
387                 dt = vlen(e.origin - o0) / vlen(e.velocity);
388                 WarpZone_tracetoss_time += dt;
389                 e.velocity_z -= dt * g;
390                 if(trace_fraction >= 1)
391                         break;
392                 if(trace_ent.classname != "trigger_warpzone")
393                         break;
394                 if(trace_ent == wz)
395                 {
396                         // FIXME can this check be removed? Do we really need it?
397                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
398                         trace_ent = world;
399                         break;
400                 }
401                 wz = trace_ent;
402                 if(!WarpZone_trace_firstzone)
403                         WarpZone_trace_firstzone = wz;
404                 WarpZone_trace_lastzone = wz;
405                 if(zone && wz != zone)
406                         break;
407                 WarpZone_Trace_AddTransform(wz);
408                 // we hit a warpzone... so, let's perform the trace after the warp again
409                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
410                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
411         }
412         WarpZone_MakeAllOther();
413 :fail
414         WarpZone_tracetoss_velocity = e.velocity;
415         v_forward = vf;
416         v_right = vr;
417         v_up = vu;
418         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
419         e.velocity = v0;
420         e.origin = o0;
421 }
422
423 void WarpZone_TraceToss(entity e, entity forent)
424 {
425         WarpZone_TraceToss_ThroughZone(e, forent, world, WarpZone_trace_callback_t_null);
426 }
427
428 entity WarpZone_TrailParticles_trace_callback_own;
429 float WarpZone_TrailParticles_trace_callback_eff;
430 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
431 {
432         trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
433 }
434
435 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
436 {
437         WarpZone_TrailParticles_trace_callback_own = own;
438         WarpZone_TrailParticles_trace_callback_eff = eff;
439         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_trace_callback);
440 }
441
442 #ifdef CSQC
443 float WarpZone_TrailParticles_trace_callback_f;
444 float WarpZone_TrailParticles_trace_callback_flags;
445 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
446 {
447         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
448 }
449
450 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, float boxflags)
451 {
452         WarpZone_TrailParticles_trace_callback_own = own;
453         WarpZone_TrailParticles_trace_callback_eff = eff;
454         WarpZone_TrailParticles_trace_callback_f = f;
455         WarpZone_TrailParticles_trace_callback_flags = boxflags;
456         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_WithMultiplier_trace_callback);
457 }
458 #endif
459
460 float WarpZone_PlaneDist(entity wz, vector v)
461 {
462         return (v - wz.warpzone_origin) * wz.warpzone_forward;
463 }
464
465 float WarpZone_TargetPlaneDist(entity wz, vector v)
466 {
467         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
468 }
469
470 vector WarpZone_TransformOrigin(entity wz, vector v)
471 {
472         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
473 }
474
475 vector WarpZone_TransformVelocity(entity wz, vector v)
476 {
477         return AnglesTransform_Apply(wz.warpzone_transform, v);
478 }
479
480 vector WarpZone_TransformAngles(entity wz, vector v)
481 {
482         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
483 }
484
485 vector WarpZone_TransformVAngles(entity wz, vector ang)
486 {
487 #ifdef KEEP_ROLL
488         float roll;
489         roll = ang_z;
490         ang_z = 0;
491 #endif
492
493         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
494
495 #ifdef KEEP_ROLL
496         ang = AnglesTransform_Normalize(ang, TRUE);
497         ang = AnglesTransform_CancelRoll(ang);
498         ang_z = roll;
499 #else
500         ang = AnglesTransform_Normalize(ang, FALSE);
501 #endif
502
503         return ang;
504 }
505
506 vector WarpZone_UnTransformOrigin(entity wz, vector v)
507 {
508         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
509 }
510
511 vector WarpZone_UnTransformVelocity(entity wz, vector v)
512 {
513         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
514 }
515
516 vector WarpZone_UnTransformAngles(entity wz, vector v)
517 {
518         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
519 }
520
521 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
522 {
523         float roll;
524
525         roll = ang_z;
526         ang_z = 0;
527
528         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
529         ang = AnglesTransform_Normalize(ang, TRUE);
530         ang = AnglesTransform_CancelRoll(ang);
531
532         ang_z = roll;
533         return ang;
534 }
535
536 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
537 {
538         vector nearest;
539         nearest_x = bound(mi_x, org_x, ma_x);
540         nearest_y = bound(mi_y, org_y, ma_y);
541         nearest_z = bound(mi_z, org_z, ma_z);
542         return nearest;
543 }
544
545 .float WarpZone_findradius_hit;
546 .entity WarpZone_findradius_next;
547 void WarpZone_FindRadius_Recurse(vector org, float rad,        vector org0,               vector transform, vector shift, float needlineofsight)
548 //                               blast origin of current search   original blast origin   how to untransform (victim to blast system)
549 {
550         vector org_new;
551         vector org0_new;
552         vector shift_new, transform_new;
553         vector p;
554         entity e, e0;
555         entity wz;
556         if(rad <= 0)
557                 return;
558         e0 = findradius(org, rad);
559         wz = world;
560
561         for(e = e0; e; e = e.chain)
562         {
563                 p = WarpZoneLib_NearestPointOnBox(e.origin + e.mins, e.origin + e.maxs, org0);
564                 if(needlineofsight)
565                 {
566                         traceline(org, p, MOVE_NOMONSTERS, e);
567                         if(trace_fraction < 1)
568                                 continue;
569                 }
570                 if(!e.WarpZone_findradius_hit || vlen(e.WarpZone_findradius_dist) > vlen(org0 - p))
571                 {
572                         e.WarpZone_findradius_nearest = p;
573                         e.WarpZone_findradius_dist = org0 - p;
574                         e.WarpZone_findradius_findorigin = org;
575                         e.WarpZone_findradius_findradius = rad;
576                         if(e.classname == "warpzone_refsys")
577                         {
578                                 // ignore, especially: do not overwrite the refsys parameters
579                         }
580                         else if(e.classname == "trigger_warpzone")
581                         {
582                                 e.WarpZone_findradius_next = wz;
583                                 wz = e;
584                                 e.WarpZone_findradius_hit = 1;
585                                 e.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
586                                 e.enemy.WarpZone_findradius_hit = 1;
587                         }
588                         else
589                         {
590                                 e.warpzone_transform = transform;
591                                 e.warpzone_shift = shift;
592                                 e.WarpZone_findradius_hit = 1;
593                         }
594                 }
595         }
596         for(e = wz; e; e = e.WarpZone_findradius_next)
597         {
598                 org0_new = WarpZone_TransformOrigin(e, org);
599                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
600                 org_new = trace_endpos;
601
602                 transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
603                 shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
604                 WarpZone_FindRadius_Recurse(
605                         org_new,
606                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
607                         org0_new,
608                         transform_new, shift_new,
609                         needlineofsight);
610                 e.WarpZone_findradius_hit = 0;
611                 e.enemy.WarpZone_findradius_hit = 0;
612         }
613 }
614 entity WarpZone_FindRadius(vector org, float rad, float needlineofsight)
615 {
616         entity e0, e;
617         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
618         e0 = findchainfloat(WarpZone_findradius_hit, 1);
619         for(e = e0; e; e = e.chain)
620                 e.WarpZone_findradius_hit = 0;
621         return e0;
622 }
623
624 .entity WarpZone_refsys;
625 void WarpZone_RefSys_GC()
626 {
627         // garbage collect unused reference systems
628         self.nextthink = time + 1;
629         if(self.owner.WarpZone_refsys != self)
630                 remove(self);
631 }
632 void WarpZone_RefSys_Add(entity me, entity wz)
633 {
634         if(me.WarpZone_refsys.owner != me)
635         {
636                 me.WarpZone_refsys = spawn();
637                 me.WarpZone_refsys.classname = "warpzone_refsys";
638                 me.WarpZone_refsys.owner = me;
639                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
640                 me.WarpZone_refsys.nextthink = time + 1;
641                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
642         }
643         if(wz)
644                 WarpZone_Accumulator_Add(me.WarpZone_refsys, wz);
645 }
646 .vector WarpZone_refsys_incremental_shift;
647 .vector WarpZone_refsys_incremental_transform;
648 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
649 {
650         vector t, s;
651         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
652         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
653                 return;
654         if(me.WarpZone_refsys.owner != me)
655         {
656                 me.WarpZone_refsys = spawn();
657                 me.WarpZone_refsys.classname = "warpzone_refsys";
658                 me.WarpZone_refsys.owner = me;
659                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
660                 me.WarpZone_refsys.nextthink = time + 1;
661                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
662         }
663         t = AnglesTransform_Invert(me.WarpZone_refsys_incremental_transform);
664         s = AnglesTransform_PrePostShift_GetPostShift(me.WarpZone_refsys_incremental_shift, t, '0 0 0');
665         WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
666         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref);
667         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
668         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
669 }
670 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
671 {
672         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
673         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
674 }
675 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
676 {
677         if(from.WarpZone_refsys)
678                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
679         if(to.WarpZone_refsys)
680                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
681         return org;
682 }
683 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
684 {
685         if(from.WarpZone_refsys)
686                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
687         if(to.WarpZone_refsys)
688                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
689         return vel;
690 }
691 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
692 {
693         if(from.WarpZone_refsys)
694                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
695         if(to.WarpZone_refsys)
696                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
697         return ang;
698 }
699 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
700 {
701         if(from.WarpZone_refsys)
702                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
703         if(to.WarpZone_refsys)
704                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
705         return ang;
706 }
707 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
708 {
709         entity e;
710         e = spawn();
711         if(me.WarpZone_refsys)
712         {
713                 e.WarpZone_refsys = spawn();
714                 e.WarpZone_refsys.classname = "warpzone_refsys";
715                 e.WarpZone_refsys.owner = e;
716                 e.WarpZone_refsys.think = WarpZone_RefSys_GC;
717                 e.WarpZone_refsys.nextthink = time + 1;
718                 e.WarpZone_refsys.warpzone_shift = me.WarpZone_refsys.warpzone_shift;
719                 e.WarpZone_refsys.warpzone_transform = me.WarpZone_refsys.warpzone_transform;
720         }
721         return e;
722 }