c10658f0b3f5e66cfb866381d2a423dad318f6a1
[xonotic/xonotic-data.pk3dir.git] / qcsrc / warpzonelib / common.qc
1 #include "common.qh"
2
3 #if defined(CSQC)
4         #include "../dpdefs/csprogsdefs.qh"
5     #include "../server/t_items.qh"
6 #elif defined(MENUQC)
7 #elif defined(SVQC)
8     #include "../common/weapons/all.qh"
9     #include "../dpdefs/dpextensions.qh"
10         #include "../dpdefs/progsdefs.qh"
11 #endif
12
13 void WarpZone_Accumulator_Clear(entity acc)
14 {
15         acc.warpzone_transform = '0 0 0';
16         acc.warpzone_shift = '0 0 0';
17 }
18 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
19 {
20         vector tr, st;
21         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
22         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
23         acc.warpzone_transform = tr;
24         acc.warpzone_shift = st;
25 }
26 void WarpZone_Accumulator_Add(entity acc, entity wz)
27 {
28         WarpZone_Accumulator_AddTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
29 }
30 void WarpZone_Accumulator_AddInverseTransform(entity acc, vector t, vector s)
31 {
32         vector tt, ss;
33         tt = AnglesTransform_Invert(t);
34         ss = AnglesTransform_PrePostShift_GetPostShift(s, tt, '0 0 0');
35         WarpZone_Accumulator_AddTransform(acc, tt, ss);
36         // yes, this probably can be done simpler... but this way is "obvious" :)
37 }
38 void WarpZone_Accumulator_AddInverse(entity acc, entity wz)
39 {
40         WarpZone_Accumulator_AddInverseTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
41 }
42
43 .vector(vector, vector) camera_transform;
44 float autocvar_cl_warpzone_usetrace = 1;
45 vector WarpZone_camera_transform(vector org, vector ang)
46 {SELFPARAM();
47         vector vf, vr, vu;
48         if(self.warpzone_fadestart)
49                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
50                         return org;
51                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
52                         // unneeded on client, on server this helps a lot
53         vf = v_forward;
54         vr = v_right;
55         vu = v_up;
56         org = WarpZone_TransformOrigin(self, org);
57         vf = WarpZone_TransformVelocity(self, vf);
58         vr = WarpZone_TransformVelocity(self, vr);
59         vu = WarpZone_TransformVelocity(self, vu);
60         if(autocvar_cl_warpzone_usetrace)
61                 traceline(self.warpzone_targetorigin, org, MOVE_NOMONSTERS, world);
62         else
63                 trace_endpos = self.warpzone_targetorigin;
64         v_forward = vf;
65         v_right = vr;
66         v_up = vu;
67         return org;
68 }
69
70 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
71 {
72         e.warpzone_transform = AnglesTransform_RightDivide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
73         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
74         e.warpzone_origin = my_org;
75         e.warpzone_targetorigin = other_org;
76         e.warpzone_angles = my_ang;
77         e.warpzone_targetangles = other_ang;
78         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
79         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
80         e.camera_transform = WarpZone_camera_transform;
81 }
82
83 vector WarpZone_Camera_camera_transform(vector org, vector ang)
84 {SELFPARAM();
85         // a fixed camera view
86         if(self.warpzone_fadestart)
87                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
88                         return org;
89                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
90                         // unneeded on client, on server this helps a lot
91         trace_endpos = self.warpzone_origin;
92         makevectors(self.warpzone_angles);
93         return self.warpzone_origin;
94 }
95
96 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
97 {
98         e.warpzone_origin = my_org;
99         e.warpzone_angles = my_ang;
100         e.camera_transform = WarpZone_Camera_camera_transform;
101 }
102
103 .entity enemy;
104
105 vector WarpZoneLib_BoxTouchesBrush_mins;
106 vector WarpZoneLib_BoxTouchesBrush_maxs;
107 entity WarpZoneLib_BoxTouchesBrush_ent;
108 entity WarpZoneLib_BoxTouchesBrush_ignore;
109 float WarpZoneLib_BoxTouchesBrush_Recurse()
110 {
111         float s;
112         entity se;
113         float f;
114
115         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
116 #ifdef CSQC
117         if (trace_networkentity)
118         {
119                 LOG_TRACE("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush\n");
120                 // we cannot continue, as a player blocks us...
121                 // so, abort
122                 return 0;
123         }
124 #endif
125         if (!trace_ent)
126                 return 0;
127         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
128                 return 1;
129
130         se = trace_ent;
131         s = se.solid;
132         se.solid = SOLID_NOT;
133         f = WarpZoneLib_BoxTouchesBrush_Recurse();
134         se.solid = s;
135
136         return f;
137 }
138
139 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
140 {
141     float f, s;
142
143     if(!e.modelindex || e.warpzone_isboxy)
144         return 1;
145
146     s = e.solid;
147     e.solid = SOLID_BSP;
148     WarpZoneLib_BoxTouchesBrush_mins = mi;
149     WarpZoneLib_BoxTouchesBrush_maxs = ma;
150     WarpZoneLib_BoxTouchesBrush_ent = e;
151     WarpZoneLib_BoxTouchesBrush_ignore = ig;
152     f = WarpZoneLib_BoxTouchesBrush_Recurse();
153     e.solid = s;
154
155     return f;
156 }
157
158 entity WarpZone_Find(vector mi, vector ma)
159 {
160         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
161         entity e;
162         if(!warpzone_warpzones_exist)
163                 return world;
164         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
165                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
166                         return e;
167         return world;
168 }
169
170 void WarpZone_MakeAllSolid()
171 {
172         entity e;
173         if(!warpzone_warpzones_exist)
174                 return;
175         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
176                 e.solid = SOLID_BSP;
177 }
178
179 void WarpZone_MakeAllOther()
180 {
181         entity e;
182         if(!warpzone_warpzones_exist)
183                 return;
184         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
185                 e.solid = SOLID_TRIGGER;
186 }
187
188 void WarpZone_Trace_InitTransform()
189 {
190         if(!WarpZone_trace_transform)
191         {
192                 WarpZone_trace_transform = spawn();
193                 WarpZone_trace_transform.classname = "warpzone_trace_transform";
194         }
195         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
196 }
197 void WarpZone_Trace_AddTransform(entity wz)
198 {
199         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
200 }
201
202 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
203 {
204         float nomonsters_adjusted;
205         float frac, sol, i;
206         float contentshack;
207         vector o0, e0;
208         entity wz;
209         vector vf, vr, vu;
210
211         WarpZone_trace_forent = forent;
212         WarpZone_trace_firstzone = world;
213         WarpZone_trace_lastzone = world;
214         WarpZone_Trace_InitTransform();
215         if(!warpzone_warpzones_exist)
216         {
217                 if(nomonsters == MOVE_NOTHING)
218                 {
219                         trace_endpos = end;
220                         trace_fraction = 1;
221                         if(cb)
222                                 cb(org, trace_endpos, end);
223                         return;
224                 }
225                 else
226                 {
227                         tracebox(org, mi, ma, end, nomonsters, WarpZone_trace_forent);
228                         if(cb)
229                                 cb(org, trace_endpos, end);
230                         return;
231                 }
232         }
233
234         vf = v_forward;
235         vr = v_right;
236         vu = v_up;
237         o0 = org;
238         e0 = end;
239
240         switch(nomonsters)
241         {
242                 case MOVE_WORLDONLY:
243                 case MOVE_NOTHING:
244                         nomonsters_adjusted = MOVE_NOMONSTERS;
245                         break;
246                 default:
247                         nomonsters_adjusted = nomonsters;
248                         break;
249         }
250         if((contentshack = (WarpZone_trace_forent.dphitcontentsmask && !(WarpZone_trace_forent.dphitcontentsmask & DPCONTENTS_SOLID))))
251                 BITSET_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
252
253         // if starting in warpzone, first transform
254         wz = WarpZone_Find(org + mi, org + ma);
255         if(wz)
256         {
257                 WarpZone_trace_firstzone = wz;
258                 WarpZone_trace_lastzone = wz;
259                 if(zone && wz != zone)
260                 {
261                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
262                         sol = 1;
263                         trace_fraction = 0;
264                         trace_endpos = org;
265                         goto fail;
266                 }
267                 WarpZone_Trace_AddTransform(wz);
268                 org = WarpZone_TransformOrigin(wz, org);
269                 end = WarpZone_TransformOrigin(wz, end);
270         }
271         WarpZone_MakeAllSolid();
272         sol = -1;
273         frac = 0;
274         i = 16;
275         for (;;)
276         {
277                 if(--i < 1)
278                 {
279                         LOG_TRACE("Too many warpzones in sequence, aborting trace.\n");
280                         trace_ent = world;
281                         break;
282                 }
283                 tracebox(org, mi, ma, end, nomonsters_adjusted, WarpZone_trace_forent);
284                 if(cb)
285                         cb(org, trace_endpos, end);
286                 if(sol < 0)
287                         sol = trace_startsolid;
288
289                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
290                 if(trace_fraction >= 1)
291                         break;
292                 if(trace_ent.classname != "trigger_warpzone")
293                 {
294                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & WarpZone_trace_forent.dphitcontentsmask) == DPCONTENTS_SOLID))
295                         {
296                                 // continue the trace, ignoring this hit (we only care for warpzones)
297                                 org = trace_endpos + normalize(end - org);
298                                 continue;
299                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
300                                 // otherwise, players could block entrances that way
301                         }
302                         break;
303                 }
304                 if(trace_ent == wz)
305                 {
306                         // FIXME can this check be removed? Do we really need it?
307                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace\n");
308                         trace_ent = world;
309                         break;
310                 }
311                 wz = trace_ent;
312                 if(!WarpZone_trace_firstzone)
313                         WarpZone_trace_firstzone = wz;
314                 WarpZone_trace_lastzone = wz;
315                 if(zone && wz != zone)
316                         break;
317                 WarpZone_Trace_AddTransform(wz);
318                 // we hit a warpzone... so, let's perform the trace after the warp again
319                 org = WarpZone_TransformOrigin(wz, trace_endpos);
320                 end = WarpZone_TransformOrigin(wz, end);
321
322                 // we got warped, so let's step back a bit
323                 tracebox(org, mi, ma, org + normalize(org - end) * 32, nomonsters_adjusted, WarpZone_trace_forent);
324                 org = trace_endpos;
325         }
326         WarpZone_MakeAllOther();
327 :fail
328         if(contentshack)
329                 BITCLR_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
330         trace_startsolid = sol;
331         v_forward = vf;
332         v_right = vr;
333         v_up = vu;
334 }
335
336 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
337 {
338         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, world, WarpZone_trace_callback_t_null);
339 }
340
341 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
342 {
343         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
344 }
345
346 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
347 {
348         float g, dt, i;
349         vector vf, vr, vu, v0, o0;
350         entity wz;
351
352         o0 = e.origin;
353         v0 = e.velocity;
354         g = cvar("sv_gravity") * e.gravity;
355
356         WarpZone_trace_forent = forent;
357         WarpZone_trace_firstzone = world;
358         WarpZone_trace_lastzone = world;
359         WarpZone_Trace_InitTransform();
360         WarpZone_tracetoss_time = 0;
361         if(!warpzone_warpzones_exist)
362         {
363                 tracetoss(e, WarpZone_trace_forent);
364                 if(cb)
365                         cb(e.origin, trace_endpos, trace_endpos);
366                 dt = vlen(e.origin - o0) / vlen(e.velocity);
367                 WarpZone_tracetoss_time += dt;
368                 e.velocity_z -= dt * g;
369                 WarpZone_tracetoss_velocity = e.velocity;
370                 e.velocity = v0;
371                 return;
372         }
373
374         vf = v_forward;
375         vr = v_right;
376         vu = v_up;
377
378         // if starting in warpzone, first transform
379         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
380         if(wz)
381         {
382                 WarpZone_trace_firstzone = wz;
383                 WarpZone_trace_lastzone = wz;
384                 if(zone && wz != zone)
385                 {
386                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
387
388                         WarpZone_tracetoss_time = 0;
389                         trace_endpos = o0;
390                         goto fail;
391                 }
392                 WarpZone_Trace_AddTransform(wz);
393                 setorigin(e, WarpZone_TransformOrigin(wz, e.origin));
394                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
395         }
396         WarpZone_MakeAllSolid();
397         i = 16;
398         for (;;)
399         {
400                 if(--i < 1)
401                 {
402                         LOG_TRACE("Too many warpzones in sequence, aborting trace.\n");
403                         trace_ent = world;
404                         break;
405                 }
406                 tracetoss(e, WarpZone_trace_forent);
407                 if(cb)
408                         cb(e.origin, trace_endpos, trace_endpos);
409                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
410                 WarpZone_tracetoss_time += dt;
411                 e.origin = trace_endpos;
412                 e.velocity_z -= dt * g;
413                 if(trace_fraction >= 1)
414                         break;
415                 if(trace_ent.classname != "trigger_warpzone")
416                         break;
417                 if(trace_ent == wz)
418                 {
419                         // FIXME can this check be removed? Do we really need it?
420                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace\n");
421                         trace_ent = world;
422                         break;
423                 }
424                 wz = trace_ent;
425                 if(!WarpZone_trace_firstzone)
426                         WarpZone_trace_firstzone = wz;
427                 WarpZone_trace_lastzone = wz;
428                 if(zone && wz != zone)
429                         break;
430                 WarpZone_Trace_AddTransform(wz);
431                 // we hit a warpzone... so, let's perform the trace after the warp again
432                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
433                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
434
435                 // we got warped, so let's step back a bit
436                 e.velocity = -e.velocity;
437                 tracetoss(e, WarpZone_trace_forent);
438                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
439                 WarpZone_tracetoss_time -= dt;
440                 e.origin = trace_endpos;
441                 e.velocity = -e.velocity;
442         }
443         WarpZone_MakeAllOther();
444 :fail
445         WarpZone_tracetoss_velocity = e.velocity;
446         v_forward = vf;
447         v_right = vr;
448         v_up = vu;
449         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
450         e.velocity = v0;
451         e.origin = o0;
452 }
453
454 void WarpZone_TraceToss(entity e, entity forent)
455 {
456         WarpZone_TraceToss_ThroughZone(e, forent, world, WarpZone_trace_callback_t_null);
457 }
458
459 entity WarpZone_TrailParticles_trace_callback_own;
460 float WarpZone_TrailParticles_trace_callback_eff;
461 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
462 {
463         trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
464 }
465
466 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
467 {
468         WarpZone_TrailParticles_trace_callback_own = own;
469         WarpZone_TrailParticles_trace_callback_eff = eff;
470         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_trace_callback);
471 }
472
473 #ifdef CSQC
474 float WarpZone_TrailParticles_trace_callback_f;
475 float WarpZone_TrailParticles_trace_callback_flags;
476 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
477 {
478         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
479 }
480
481 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, int boxflags)
482 {
483         WarpZone_TrailParticles_trace_callback_own = own;
484         WarpZone_TrailParticles_trace_callback_eff = eff;
485         WarpZone_TrailParticles_trace_callback_f = f;
486         WarpZone_TrailParticles_trace_callback_flags = boxflags | PARTICLES_DRAWASTRAIL;
487         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_WithMultiplier_trace_callback);
488 }
489 #endif
490
491 float WarpZone_PlaneDist(entity wz, vector v)
492 {
493         return (v - wz.warpzone_origin) * wz.warpzone_forward;
494 }
495
496 float WarpZone_TargetPlaneDist(entity wz, vector v)
497 {
498         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
499 }
500
501 vector WarpZone_TransformOrigin(entity wz, vector v)
502 {
503         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
504 }
505
506 vector WarpZone_TransformVelocity(entity wz, vector v)
507 {
508         return AnglesTransform_Apply(wz.warpzone_transform, v);
509 }
510
511 vector WarpZone_TransformAngles(entity wz, vector v)
512 {
513         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
514 }
515
516 vector WarpZone_TransformVAngles(entity wz, vector ang)
517 {
518 #ifdef KEEP_ROLL
519         float roll;
520         roll = ang.z;
521         ang.z = 0;
522 #endif
523
524         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
525
526 #ifdef KEEP_ROLL
527         ang = AnglesTransform_Normalize(ang, true);
528         ang = AnglesTransform_CancelRoll(ang);
529         ang.z = roll;
530 #else
531         ang = AnglesTransform_Normalize(ang, false);
532 #endif
533
534         return ang;
535 }
536
537 vector WarpZone_UnTransformOrigin(entity wz, vector v)
538 {
539         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
540 }
541
542 vector WarpZone_UnTransformVelocity(entity wz, vector v)
543 {
544         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
545 }
546
547 vector WarpZone_UnTransformAngles(entity wz, vector v)
548 {
549         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
550 }
551
552 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
553 {
554         float roll;
555
556         roll = ang.z;
557         ang.z = 0;
558
559         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
560         ang = AnglesTransform_Normalize(ang, true);
561         ang = AnglesTransform_CancelRoll(ang);
562
563         ang.z = roll;
564         return ang;
565 }
566
567 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
568 {
569         vector nearest;
570         nearest.x = bound(mi.x, org.x, ma.x);
571         nearest.y = bound(mi.y, org.y, ma.y);
572         nearest.z = bound(mi.z, org.z, ma.z);
573         return nearest;
574 }
575
576 bool WarpZoneLib_BadEntity(entity e)
577 {
578         string myclassname = e.classname;
579         if (e.instanceOfObject) return true;
580         switch(myclassname)
581         {
582                 case "deathtype":
583                 case "weaponentity":
584                 case "exteriorweaponentity":
585                 case "csqc_score_team":
586                 case "pingplreport":
587                 case "ent_client_scoreinfo":
588                 case "saved_cvar_value":
589                 case "accuracy":
590                 case "entcs_sender_v2":
591                 case "entcs_receiver_v2":
592                 case "clientinit":
593                 case "sprite_waypoint":
594                 case "waypoint":
595                 case "gibsplash":
596                 //case "net_linked": // actually some real entities are linked without classname, fail
597                 case "":
598                         return true;
599         }
600
601         if(startsWith(myclassname, "msg_"))
602                 return true;
603
604         if(startsWith(myclassname, "target_"))
605                 return true;
606
607         if(startsWith(myclassname, "info_"))
608                 return true;
609
610         return false;
611 }
612
613 .float WarpZone_findradius_hit;
614 .entity WarpZone_findradius_next;
615 void WarpZone_FindRadius_Recurse(vector org, float rad,        vector org0,               vector transform, vector shift, float needlineofsight)
616 //                               blast origin of current search   original blast origin   how to untransform (victim to blast system)
617 {
618         vector org_new;
619         vector org0_new;
620         vector shift_new, transform_new;
621         vector p;
622         entity e, e0;
623         entity wz;
624         if(rad <= 0)
625                 return;
626         e0 = findradius(org, rad);
627         wz = world;
628
629         for(e = e0; e; e = e.chain)
630         {
631                 if(WarpZoneLib_BadEntity(e))
632                         continue;
633                 p = WarpZoneLib_NearestPointOnBox(e.origin + e.mins, e.origin + e.maxs, org0);
634                 if(needlineofsight)
635                 {
636                         traceline(org, p, MOVE_NOMONSTERS, e);
637                         if(trace_fraction < 1)
638                                 continue;
639                 }
640                 if(!e.WarpZone_findradius_hit || vlen(e.WarpZone_findradius_dist) > vlen(org0 - p))
641                 {
642                         e.WarpZone_findradius_nearest = p;
643                         e.WarpZone_findradius_dist = org0 - p;
644                         e.WarpZone_findradius_findorigin = org;
645                         e.WarpZone_findradius_findradius = rad;
646                         if(e.classname == "warpzone_refsys")
647                         {
648                                 // ignore, especially: do not overwrite the refsys parameters
649                         }
650                         else if(e.classname == "trigger_warpzone")
651                         {
652                                 e.WarpZone_findradius_next = wz;
653                                 wz = e;
654                                 e.WarpZone_findradius_hit = 1;
655                                 e.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
656                                 e.enemy.WarpZone_findradius_hit = 1;
657                         }
658                         else
659                         {
660                                 e.warpzone_transform = transform;
661                                 e.warpzone_shift = shift;
662                                 e.WarpZone_findradius_hit = 1;
663                         }
664                 }
665         }
666         for(e = wz; e; e = e.WarpZone_findradius_next)
667         {
668                 if(WarpZoneLib_BadEntity(e))
669                         continue;
670
671                 org0_new = WarpZone_TransformOrigin(e, org);
672                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
673                 org_new = trace_endpos;
674
675                 transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
676                 shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
677                 WarpZone_FindRadius_Recurse(
678                         org_new,
679                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
680                         org0_new,
681                         transform_new, shift_new,
682                         needlineofsight);
683                 e.WarpZone_findradius_hit = 0;
684                 e.enemy.WarpZone_findradius_hit = 0;
685         }
686 }
687 entity WarpZone_FindRadius(vector org, float rad, float needlineofsight)
688 {
689         entity e0, e;
690         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
691         e0 = findchainfloat(WarpZone_findradius_hit, 1);
692         for(e = e0; e; e = e.chain)
693                 e.WarpZone_findradius_hit = 0;
694         return e0;
695 }
696
697 .entity WarpZone_refsys;
698 void WarpZone_RefSys_GC()
699 {SELFPARAM();
700         // garbage collect unused reference systems
701         self.nextthink = time + 1;
702         if(self.owner.WarpZone_refsys != self)
703                 remove(self);
704 }
705 void WarpZone_RefSys_CheckCreate(entity me)
706 {
707         if(me.WarpZone_refsys.owner != me)
708         {
709                 me.WarpZone_refsys = spawn();
710                 me.WarpZone_refsys.classname = "warpzone_refsys";
711                 me.WarpZone_refsys.owner = me;
712                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
713                 me.WarpZone_refsys.nextthink = time + 1;
714                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
715         }
716 }
717 void WarpZone_RefSys_Clear(entity me)
718 {
719         if(me.WarpZone_refsys)
720         {
721                 remove(me.WarpZone_refsys);
722                 me.WarpZone_refsys = world;
723         }
724 }
725 void WarpZone_RefSys_AddTransform(entity me, vector t, vector s)
726 {
727         if(t != '0 0 0' || s != '0 0 0')
728         {
729                 WarpZone_RefSys_CheckCreate(me);
730                 WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
731         }
732 }
733 void WarpZone_RefSys_Add(entity me, entity wz)
734 {
735         WarpZone_RefSys_AddTransform(me, wz.warpzone_transform, wz.warpzone_shift);
736 }
737 void WarpZone_RefSys_AddInverseTransform(entity me, vector t, vector s)
738 {
739         if(t != '0 0 0' || s != '0 0 0')
740         {
741                 WarpZone_RefSys_CheckCreate(me);
742                 WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, t, s);
743         }
744 }
745 void WarpZone_RefSys_AddInverse(entity me, entity wz)
746 {
747         WarpZone_RefSys_AddInverseTransform(me, wz.warpzone_transform, wz.warpzone_shift);
748 }
749 .vector WarpZone_refsys_incremental_shift;
750 .vector WarpZone_refsys_incremental_transform;
751 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
752 {
753         //vector t, s;
754         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
755         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
756                 return;
757         WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, me.WarpZone_refsys_incremental_transform, me.WarpZone_refsys_incremental_shift);
758         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref.WarpZone_refsys);
759         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
760         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
761 }
762 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
763 {
764         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
765         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
766 }
767 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
768 {
769         if(from.WarpZone_refsys)
770                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
771         if(to.WarpZone_refsys)
772                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
773         return org;
774 }
775 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
776 {
777         if(from.WarpZone_refsys)
778                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
779         if(to.WarpZone_refsys)
780                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
781         return vel;
782 }
783 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
784 {
785         if(from.WarpZone_refsys)
786                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
787         if(to.WarpZone_refsys)
788                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
789         return ang;
790 }
791 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
792 {
793         if(from.WarpZone_refsys)
794                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
795         if(to.WarpZone_refsys)
796                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
797         return ang;
798 }
799 void WarpZone_RefSys_Copy(entity me, entity from)
800 {
801         if(from.WarpZone_refsys)
802         {
803                 WarpZone_RefSys_CheckCreate(me);
804                 me.WarpZone_refsys.warpzone_shift = from.WarpZone_refsys.warpzone_shift;
805                 me.WarpZone_refsys.warpzone_transform = from.WarpZone_refsys.warpzone_transform;
806         }
807         else
808                 WarpZone_RefSys_Clear(me);
809 }
810 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
811 {
812         entity e;
813         e = spawn();
814         WarpZone_RefSys_Copy(e, me);
815         return e;
816 }
817
818 float WarpZoneLib_ExactTrigger_Touch()
819 {SELFPARAM();
820         return !WarpZoneLib_BoxTouchesBrush(other.absmin, other.absmax, self, other);
821 }
822
823
824 void WarpZoneLib_MoveOutOfSolid_Expand(entity e, vector by)
825 {
826         float eps = 0.0625;
827         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
828         if (trace_startsolid)
829                 return;
830         if (trace_fraction < 1)
831         {
832                 // hit something
833                 // adjust origin in the other direction...
834                 setorigin(e,e.origin - by * (1 - trace_fraction));
835         }
836 }
837
838 float WarpZoneLib_MoveOutOfSolid(entity e)
839 {
840         vector o, m0, m1;
841
842         o = e.origin;
843         traceline(o, o, MOVE_WORLDONLY, e);
844         if (trace_startsolid)
845                 return false;
846
847         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
848         if (!trace_startsolid)
849                 return true;
850
851         m0 = e.mins;
852         m1 = e.maxs;
853         e.mins = '0 0 0';
854         e.maxs = '0 0 0';
855         WarpZoneLib_MoveOutOfSolid_Expand(e, '1 0 0' * m0_x);
856         e.mins_x = m0_x;
857         WarpZoneLib_MoveOutOfSolid_Expand(e, '1 0 0' * m1_x);
858         e.maxs_x = m1_x;
859         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 1 0' * m0_y);
860         e.mins_y = m0_y;
861         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 1 0' * m1_y);
862         e.maxs_y = m1_y;
863         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 0 1' * m0_z);
864         e.mins_z = m0_z;
865         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 0 1' * m1_z);
866         e.maxs_z = m1_z;
867         setorigin(e, e.origin);
868
869         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
870         if (trace_startsolid)
871         {
872                 setorigin(e, o);
873                 return false;
874         }
875
876         return true;
877 }