e76bc0eb96761c5efa52f02a07400b51fa28cdaa
[xonotic/xonotic-data.pk3dir.git] / qcsrc / warpzonelib / common.qc
1 float trace_dphitcontents;
2 .float dphitcontentsmask;
3
4 void WarpZone_Accumulator_Clear(entity acc)
5 {
6         acc.warpzone_transform = '0 0 0';
7         acc.warpzone_shift = '0 0 0';
8 }
9 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
10 {
11         vector tr, st;
12         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
13         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
14         acc.warpzone_transform = tr;
15         acc.warpzone_shift = st;
16 }
17 void WarpZone_Accumulator_Add(entity acc, entity wz)
18 {
19         vector t, st;
20         t = AnglesTransform_Multiply(wz.warpzone_transform, acc.warpzone_transform);
21         st = AnglesTransform_Multiply_GetPostShift(wz.warpzone_transform, wz.warpzone_shift, acc.warpzone_transform, acc.warpzone_shift);
22         acc.warpzone_transform = t;
23         acc.warpzone_shift = st;
24 }
25
26 .vector(vector, vector) camera_transform;
27 var float autocvar_cl_warpzone_usetrace = 1;
28 vector WarpZone_camera_transform(vector org, vector ang)
29 {
30         vector vf, vr, vu;
31         if(self.warpzone_fadestart)
32                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
33                         return org;
34                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
35                         // unneeded on client, on server this helps a lot
36         vf = v_forward;
37         vr = v_right;
38         vu = v_up;
39         org = WarpZone_TransformOrigin(self, org);
40         vf = WarpZone_TransformVelocity(self, vf);
41         vr = WarpZone_TransformVelocity(self, vr);
42         vu = WarpZone_TransformVelocity(self, vu);
43         if(autocvar_cl_warpzone_usetrace)
44                 traceline(self.warpzone_targetorigin, org, MOVE_NOMONSTERS, world);
45         else
46                 trace_endpos = self.warpzone_targetorigin;
47         v_forward = vf;
48         v_right = vr;
49         v_up = vu;
50         return org;
51 }
52
53 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
54 {
55         e.warpzone_transform = AnglesTransform_Divide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
56         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
57         e.warpzone_origin = my_org;
58         e.warpzone_targetorigin = other_org;
59         e.warpzone_angles = my_ang;
60         e.warpzone_targetangles = other_ang;
61         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
62         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
63         e.camera_transform = WarpZone_camera_transform;
64 }
65
66 vector WarpZone_Camera_camera_transform(vector org, vector ang)
67 {
68         // a fixed camera view
69         if(self.warpzone_fadestart)
70                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
71                         return org;
72                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
73                         // unneeded on client, on server this helps a lot
74         trace_endpos = self.warpzone_origin;
75         makevectors(self.warpzone_angles);
76         return self.warpzone_origin;
77 }
78
79 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
80 {
81         e.warpzone_origin = my_org;
82         e.warpzone_angles = my_ang;
83         e.camera_transform = WarpZone_Camera_camera_transform;
84 }
85
86 .entity enemy;
87
88 vector WarpZoneLib_BoxTouchesBrush_mins;
89 vector WarpZoneLib_BoxTouchesBrush_maxs;
90 entity WarpZoneLib_BoxTouchesBrush_ent;
91 entity WarpZoneLib_BoxTouchesBrush_ignore;
92 float WarpZoneLib_BoxTouchesBrush_Recurse()
93 {
94         float s;
95         entity se;
96         float f;
97
98         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
99 #ifdef CSQC
100         if (trace_networkentity)
101         {
102                 dprint("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush\n");
103                 // we cannot continue, as a player blocks us...
104                 // so, abort
105                 return 0;
106         }
107 #endif
108         if not(trace_ent)
109                 return 0;
110         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
111                 return 1;
112
113         se = trace_ent;
114         s = se.solid;
115         se.solid = SOLID_NOT;
116         f = WarpZoneLib_BoxTouchesBrush_Recurse();
117         se.solid = s;
118
119         return f;
120 }
121
122 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
123 {
124     float f, s;
125
126     if(!e.modelindex || e.warpzone_isboxy)
127         return 1;
128
129     s = e.solid;
130     e.solid = SOLID_BSP;
131     WarpZoneLib_BoxTouchesBrush_mins = mi;
132     WarpZoneLib_BoxTouchesBrush_maxs = ma;
133     WarpZoneLib_BoxTouchesBrush_ent = e;
134     WarpZoneLib_BoxTouchesBrush_ignore = ig;
135     f = WarpZoneLib_BoxTouchesBrush_Recurse();
136     e.solid = s;
137
138     return f;
139 }
140
141 entity WarpZone_Find(vector mi, vector ma)
142 {
143         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
144         entity e;
145         if(!warpzone_warpzones_exist)
146                 return world;
147         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
148                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
149                         return e;
150         return world;
151 }
152
153 void WarpZone_MakeAllSolid()
154 {
155         entity e;
156         if(!warpzone_warpzones_exist)
157                 return;
158         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
159                 e.solid = SOLID_BSP;
160 }
161
162 void WarpZone_MakeAllOther()
163 {
164         entity e;
165         if(!warpzone_warpzones_exist)
166                 return;
167         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
168                 e.solid = SOLID_TRIGGER;
169 }
170
171 void WarpZone_Trace_InitTransform()
172 {
173         if(!WarpZone_trace_transform)
174         {
175                 WarpZone_trace_transform = spawn();
176                 WarpZone_trace_transform.classname = "warpzone_trace_transform";
177         }
178         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
179 }
180 void WarpZone_Trace_AddTransform(entity wz)
181 {
182         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
183 }
184
185 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
186 {
187         float nomonsters_adjusted;
188         float frac, sol, i;
189         float contentshack;
190         vector o0, e0;
191         entity wz;
192         vector vf, vr, vu;
193
194         WarpZone_Trace_InitTransform();
195         if(!warpzone_warpzones_exist)
196         {
197                 if(nomonsters == MOVE_NOTHING)
198                 {
199                         trace_endpos = end;
200                         trace_fraction = 1;
201                         if(cb)
202                                 cb(org, trace_endpos, end);
203                         return;
204                 }
205                 else
206                 {
207                         tracebox(org, mi, ma, end, nomonsters, forent);
208                         if(cb)
209                                 cb(org, trace_endpos, end);
210                         return;
211                 }
212         }
213
214         vf = v_forward;
215         vr = v_right;
216         vu = v_up;
217         o0 = org;
218         e0 = end;
219
220         switch(nomonsters)
221         {
222                 case MOVE_WORLDONLY:
223                 case MOVE_NOTHING:
224                         nomonsters_adjusted = MOVE_NOMONSTERS;
225                         break;
226                 default:
227                         nomonsters_adjusted = nomonsters;
228                         break;
229         }
230         if((contentshack = (forent.dphitcontentsmask && !(forent.dphitcontentsmask & DPCONTENTS_SOLID))))
231                 forent.dphitcontentsmask |= DPCONTENTS_SOLID;
232
233         // if starting in warpzone, first transform
234         wz = WarpZone_Find(org + mi, org + ma);
235         if(wz)
236         {
237                 if(zone && wz != zone)
238                 {
239                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
240                         sol = 1;
241                         trace_fraction = 0;
242                         trace_endpos = org;
243                         goto fail;
244                 }
245                 WarpZone_Trace_AddTransform(wz);
246                 org = WarpZone_TransformOrigin(wz, org);
247                 end = WarpZone_TransformOrigin(wz, end);
248         }
249         WarpZone_MakeAllSolid();
250         sol = -1;
251         frac = 0;
252         i = 16;
253         for(;;)
254         {
255                 if(--i < 1)
256                 {
257                         dprint("Too many warpzones in sequence, aborting trace.\n");
258                         trace_ent = world;
259                         break;
260                 }
261                 tracebox(org, mi, ma, end, nomonsters_adjusted, forent);
262                 if(cb)
263                         cb(org, trace_endpos, end);
264                 if(sol < 0)
265                         sol = trace_startsolid;
266
267                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
268                 if(trace_fraction >= 1)
269                         break;
270                 if(trace_ent.classname != "trigger_warpzone")
271                 {
272                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & forent.dphitcontentsmask) == DPCONTENTS_SOLID))
273                         {
274                                 // continue the trace, ignoring this hit (we only care for warpzones)
275                                 org = trace_endpos + normalize(end - org);
276                                 continue;
277                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
278                                 // otherwise, players could block entrances that way
279                         }
280                         break;
281                 }
282                 if(trace_ent == wz)
283                 {
284                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
285                         trace_ent = world;
286                         break;
287                 }
288                 wz = trace_ent;
289                 if(zone && wz != zone)
290                         break;
291                 WarpZone_Trace_AddTransform(wz);
292                 // we hit a warpzone... so, let's perform the trace after the warp again
293                 org = WarpZone_TransformOrigin(wz, trace_endpos);
294                 end = WarpZone_TransformOrigin(wz, end);
295         }
296         WarpZone_MakeAllOther();
297 :fail
298         if(contentshack)
299                 forent.dphitcontentsmask &~= DPCONTENTS_SOLID;
300         trace_startsolid = sol;
301         v_forward = vf;
302         v_right = vr;
303         v_up = vu;
304 }
305
306 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
307 {
308         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, world, WarpZone_trace_callback_t_null);
309 }
310
311 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
312 {
313         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
314 }
315
316 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
317 {
318         float g, dt, i;
319         vector vf, vr, vu, v0, o0;
320         entity wz;
321
322         o0 = e.origin;
323         v0 = e.velocity;
324
325         WarpZone_Trace_InitTransform();
326         WarpZone_tracetoss_time = 0;
327         if(!warpzone_warpzones_exist)
328         {
329                 tracetoss(e, forent);
330                 if(cb)
331                         cb(e.origin, trace_endpos, trace_endpos);
332                 dt = vlen(e.origin - o0) / vlen(e.velocity);
333                 WarpZone_tracetoss_time += dt;
334                 e.velocity_z -= dt * g;
335                 WarpZone_tracetoss_velocity = e.velocity;
336                 e.velocity = v0;
337                 return;
338         }
339
340         vf = v_forward;
341         vr = v_right;
342         vu = v_up;
343
344         // if starting in warpzone, first transform
345         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
346         if(wz)
347         {
348                 if(zone && wz != zone)
349                 {
350                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
351
352                         WarpZone_tracetoss_time = 0;
353                         trace_endpos = o0;
354                         goto fail;
355                 }
356                 WarpZone_Trace_AddTransform(wz);
357                 setorigin(e, WarpZone_TransformOrigin(wz, e.origin));
358                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
359         }
360         WarpZone_MakeAllSolid();
361         g = cvar("sv_gravity") * e.gravity;
362         i = 16;
363         for(;;)
364         {
365                 if(--i < 1)
366                 {
367                         dprint("Too many warpzones in sequence, aborting trace.\n");
368                         trace_ent = world;
369                         break;
370                 }
371                 tracetoss(e, forent);
372                 if(cb)
373                         cb(e.origin, trace_endpos, trace_endpos);
374                 e.origin = trace_endpos;
375                 dt = vlen(e.origin - o0) / vlen(e.velocity);
376                 WarpZone_tracetoss_time += dt;
377                 e.velocity_z -= dt * g;
378                 if(trace_fraction >= 1)
379                         break;
380                 if(trace_ent.classname != "trigger_warpzone")
381                         break;
382                 if(trace_ent == wz)
383                 {
384                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
385                         trace_ent = world;
386                         break;
387                 }
388                 wz = trace_ent;
389                 if(zone && wz != zone)
390                         break;
391                 WarpZone_Trace_AddTransform(wz);
392                 // we hit a warpzone... so, let's perform the trace after the warp again
393                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
394                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
395         }
396         WarpZone_MakeAllOther();
397 :fail
398         WarpZone_tracetoss_velocity = e.velocity;
399         v_forward = vf;
400         v_right = vr;
401         v_up = vu;
402         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
403         e.velocity = v0;
404         e.origin = o0;
405 }
406
407 void WarpZone_TraceToss(entity e, entity forent)
408 {
409         WarpZone_TraceToss_ThroughZone(e, forent, world, WarpZone_trace_callback_t_null);
410 }
411
412 entity WarpZone_TrailParticles_trace_callback_own;
413 float WarpZone_TrailParticles_trace_callback_eff;
414 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
415 {
416         trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
417 }
418
419 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
420 {
421         WarpZone_TrailParticles_trace_callback_own = own;
422         WarpZone_TrailParticles_trace_callback_eff = eff;
423         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_trace_callback);
424 }
425
426 #ifdef CSQC
427 float WarpZone_TrailParticles_trace_callback_f;
428 float WarpZone_TrailParticles_trace_callback_flags;
429 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
430 {
431         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
432 }
433
434 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, float boxflags)
435 {
436         WarpZone_TrailParticles_trace_callback_own = own;
437         WarpZone_TrailParticles_trace_callback_eff = eff;
438         WarpZone_TrailParticles_trace_callback_f = f;
439         WarpZone_TrailParticles_trace_callback_flags = boxflags;
440         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_WithMultiplier_trace_callback);
441 }
442 #endif
443
444 float WarpZone_PlaneDist(entity wz, vector v)
445 {
446         return (v - wz.warpzone_origin) * wz.warpzone_forward;
447 }
448
449 float WarpZone_TargetPlaneDist(entity wz, vector v)
450 {
451         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
452 }
453
454 vector WarpZone_TransformOrigin(entity wz, vector v)
455 {
456         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
457 }
458
459 vector WarpZone_TransformVelocity(entity wz, vector v)
460 {
461         return AnglesTransform_Apply(wz.warpzone_transform, v);
462 }
463
464 vector WarpZone_TransformAngles(entity wz, vector v)
465 {
466         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
467 }
468
469 vector WarpZone_TransformVAngles(entity wz, vector ang)
470 {
471 #ifdef KEEP_ROLL
472         float roll;
473         roll = ang_z;
474         ang_z = 0;
475 #endif
476
477         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
478
479 #ifdef KEEP_ROLL
480         ang = AnglesTransform_Normalize(ang, TRUE);
481         ang = AnglesTransform_CancelRoll(ang);
482         ang_z = roll;
483 #else
484         ang = AnglesTransform_Normalize(ang, FALSE);
485 #endif
486
487         return ang;
488 }
489
490 vector WarpZone_UnTransformOrigin(entity wz, vector v)
491 {
492         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
493 }
494
495 vector WarpZone_UnTransformVelocity(entity wz, vector v)
496 {
497         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
498 }
499
500 vector WarpZone_UnTransformAngles(entity wz, vector v)
501 {
502         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
503 }
504
505 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
506 {
507         float roll;
508
509         roll = ang_z;
510         ang_z = 0;
511
512         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
513         ang = AnglesTransform_Normalize(ang, TRUE);
514         ang = AnglesTransform_CancelRoll(ang);
515
516         ang_z = roll;
517         return ang;
518 }
519
520 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
521 {
522         vector nearest;
523         nearest_x = bound(mi_x, org_x, ma_x);
524         nearest_y = bound(mi_y, org_y, ma_y);
525         nearest_z = bound(mi_z, org_z, ma_z);
526         return nearest;
527 }
528
529 .float WarpZone_findradius_hit;
530 .entity WarpZone_findradius_next;
531 void WarpZone_FindRadius_Recurse(vector org, float rad,        vector org0,               vector transform, vector shift, float needlineofsight)
532 //                               blast origin of current search   original blast origin   how to untransform (victim to blast system)
533 {
534         vector org_new;
535         vector org0_new;
536         vector shift_new, transform_new;
537         vector p;
538         entity e, e0;
539         entity wz;
540         if(rad <= 0)
541                 return;
542         e0 = findradius(org, rad);
543         wz = world;
544
545         for(e = e0; e; e = e.chain)
546         {
547                 p = WarpZoneLib_NearestPointOnBox(e.origin + e.mins, e.origin + e.maxs, org0);
548                 if(needlineofsight)
549                 {
550                         traceline(org, p, MOVE_NOMONSTERS, e);
551                         if(trace_fraction < 1)
552                                 continue;
553                 }
554                 if(!e.WarpZone_findradius_hit || vlen(e.WarpZone_findradius_dist) > vlen(org0 - p))
555                 {
556                         e.WarpZone_findradius_nearest = p;
557                         e.WarpZone_findradius_dist = org0 - p;
558                         e.WarpZone_findradius_findorigin = org;
559                         e.WarpZone_findradius_findradius = rad;
560                         if(e.classname == "warpzone_refsys")
561                         {
562                                 // ignore, especially: do not overwrite the refsys parameters
563                         }
564                         else if(e.classname == "trigger_warpzone")
565                         {
566                                 e.WarpZone_findradius_next = wz;
567                                 wz = e;
568                                 e.WarpZone_findradius_hit = 1;
569                                 e.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
570                                 e.enemy.WarpZone_findradius_hit = 1;
571                         }
572                         else
573                         {
574                                 e.warpzone_transform = transform;
575                                 e.warpzone_shift = shift;
576                                 e.WarpZone_findradius_hit = 1;
577                         }
578                 }
579         }
580         for(e = wz; e; e = e.WarpZone_findradius_next)
581         {
582                 org0_new = WarpZone_TransformOrigin(e, org);
583                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
584                 org_new = trace_endpos;
585
586                 transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
587                 shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
588                 WarpZone_FindRadius_Recurse(
589                         org_new,
590                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
591                         org0_new,
592                         transform_new, shift_new,
593                         needlineofsight);
594                 e.WarpZone_findradius_hit = 0;
595                 e.enemy.WarpZone_findradius_hit = 0;
596         }
597 }
598 entity WarpZone_FindRadius(vector org, float rad, float needlineofsight)
599 {
600         entity e0, e;
601         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
602         e0 = findchainfloat(WarpZone_findradius_hit, 1);
603         for(e = e0; e; e = e.chain)
604                 e.WarpZone_findradius_hit = 0;
605         return e0;
606 }
607
608 .entity WarpZone_refsys;
609 void WarpZone_RefSys_GC()
610 {
611         // garbage collect unused reference systems
612         self.nextthink = time + 1;
613         if(self.owner.WarpZone_refsys != self)
614                 remove(self);
615 }
616 void WarpZone_RefSys_Add(entity me, entity wz)
617 {
618         if(me.WarpZone_refsys.owner != me)
619         {
620                 me.WarpZone_refsys = spawn();
621                 me.WarpZone_refsys.classname = "warpzone_refsys";
622                 me.WarpZone_refsys.owner = me;
623                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
624                 me.WarpZone_refsys.nextthink = time + 1;
625                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
626         }
627         if(wz)
628                 WarpZone_Accumulator_Add(me.WarpZone_refsys, wz);
629 }
630 .vector WarpZone_refsys_incremental_shift;
631 .vector WarpZone_refsys_incremental_transform;
632 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
633 {
634         vector t, s;
635         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
636         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
637                 return;
638         if(me.WarpZone_refsys.owner != me)
639         {
640                 me.WarpZone_refsys = spawn();
641                 me.WarpZone_refsys.classname = "warpzone_refsys";
642                 me.WarpZone_refsys.owner = me;
643                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
644                 me.WarpZone_refsys.nextthink = time + 1;
645                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
646         }
647         t = AnglesTransform_Invert(me.WarpZone_refsys_incremental_transform);
648         s = AnglesTransform_PrePostShift_GetPostShift(me.WarpZone_refsys_incremental_shift, t, '0 0 0');
649         WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
650         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref);
651         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
652         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
653 }
654 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
655 {
656         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
657         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
658 }
659 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
660 {
661         if(from.WarpZone_refsys)
662                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
663         if(to.WarpZone_refsys)
664                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
665         return org;
666 }
667 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
668 {
669         if(from.WarpZone_refsys)
670                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
671         if(to.WarpZone_refsys)
672                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
673         return vel;
674 }
675 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
676 {
677         if(from.WarpZone_refsys)
678                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
679         if(to.WarpZone_refsys)
680                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
681         return ang;
682 }
683 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
684 {
685         if(from.WarpZone_refsys)
686                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
687         if(to.WarpZone_refsys)
688                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
689         return ang;
690 }
691 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
692 {
693         entity e;
694         e = spawn();
695         if(me.WarpZone_refsys)
696         {
697                 e.WarpZone_refsys = spawn();
698                 e.WarpZone_refsys.classname = "warpzone_refsys";
699                 e.WarpZone_refsys.owner = e;
700                 e.WarpZone_refsys.think = WarpZone_RefSys_GC;
701                 e.WarpZone_refsys.nextthink = time + 1;
702                 e.WarpZone_refsys.warpzone_shift = me.WarpZone_refsys.warpzone_shift;
703                 e.WarpZone_refsys.warpzone_transform = me.WarpZone_refsys.warpzone_transform;
704         }
705         return e;
706 }