qcsrc/warpzonelib/common.qc

   1 float trace_dphitcontents;
   2 .float dphitcontents;
   3
   4 void WarpZone_Accumulator_Clear(entity acc)
   5 {
   6         acc.warpzone_transform = '0 0 0';
   7         acc.warpzone_shift = '0 0 0';
   8 }
   9 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  10 {
  11         vector tr, st;
  12         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  13         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  14         acc.warpzone_transform = tr;
  15         acc.warpzone_shift = st;
  16 }
  17 void WarpZone_Accumulator_Add(entity acc, entity wz)
  18 {
  19         vector t, st;
  20         t = AnglesTransform_Multiply(wz.warpzone_transform, acc.warpzone_transform);
  21         st = AnglesTransform_Multiply_GetPostShift(wz.warpzone_transform, wz.warpzone_shift, acc.warpzone_transform, acc.warpzone_shift);
  22         acc.warpzone_transform = t;
  23         acc.warpzone_shift = st;
  24 }
  25
  26 .vector(vector, vector) camera_transform;
  27 var float autocvar_cl_warpzone_usetrace = 1;
  28 vector WarpZone_camera_transform(vector org, vector ang)
  29 {
  30         vector vf, vr, vu;
  31         vf = v_forward;
  32         vr = v_right;
  33         vu = v_up;
  34         org = WarpZone_TransformOrigin(self, org);
  35         vf = WarpZone_TransformVelocity(self, vf);
  36         vr = WarpZone_TransformVelocity(self, vr);
  37         vu = WarpZone_TransformVelocity(self, vu);
  38         if(autocvar_cl_warpzone_usetrace)
  39                 traceline(self.warpzone_targetorigin, org, MOVE_NOMONSTERS, world);
  40         else
  41                 trace_endpos = self.warpzone_targetorigin;
  42         v_forward = vf;
  43         v_right = vr;
  44         v_up = vu;
  45         return org;
  46 }
  47
  48 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  49 {
  50         e.warpzone_transform = AnglesTransform_Divide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  51         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  52         e.warpzone_origin = my_org;
  53         e.warpzone_targetorigin = other_org;
  54         e.warpzone_angles = my_ang;
  55         e.warpzone_targetangles = other_ang;
  56         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
  57         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
  58         e.camera_transform = WarpZone_camera_transform;
  59 }
  60
  61 vector WarpZone_Camera_camera_transform(vector org, vector ang)
  62 {
  63         // a fixed camera view
  64         trace_endpos = self.warpzone_origin;
  65         makevectors(self.warpzone_angles);
  66         return self.warpzone_origin;
  67 }
  68
  69 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  70 {
  71         e.warpzone_origin = my_org;
  72         e.warpzone_angles = my_ang;
  73         e.camera_transform = WarpZone_Camera_camera_transform;
  74 }
  75
  76 .entity enemy;
  77
  78 vector WarpZoneLib_BoxTouchesBrush_mins;
  79 vector WarpZoneLib_BoxTouchesBrush_maxs;
  80 entity WarpZoneLib_BoxTouchesBrush_ent;
  81 entity WarpZoneLib_BoxTouchesBrush_ignore;
  82 float WarpZoneLib_BoxTouchesBrush_Recurse()
  83 {
  84         float s;
  85         entity se;
  86         float f;
  87
  88         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
  89 #ifdef CSQC
  90         if (trace_networkentity)
  91         {
  92                 dprint("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush\n");
  93                 // we cannot continue, as a player blocks us...
  94                 // so, abort
  95                 return 0;
  96         }
  97 #endif
  98         if not(trace_ent)
  99                 return 0;
 100         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
 101                 return 1;
 102
 103         se = trace_ent;
 104         s = se.solid;
 105         se.solid = SOLID_NOT;
 106         f = WarpZoneLib_BoxTouchesBrush_Recurse();
 107         se.solid = s;
 108
 109         return f;
 110 }
 111
 112 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 113 {
 114     float f, s;
 115
 116     if(!e.modelindex || e.warpzone_isboxy)
 117         return 1;
 118
 119     s = e.solid;
 120     e.solid = SOLID_BSP;
 121     WarpZoneLib_BoxTouchesBrush_mins = mi;
 122     WarpZoneLib_BoxTouchesBrush_maxs = ma;
 123     WarpZoneLib_BoxTouchesBrush_ent = e;
 124     WarpZoneLib_BoxTouchesBrush_ignore = ig;
 125     f = WarpZoneLib_BoxTouchesBrush_Recurse();
 126     e.solid = s;
 127
 128     return f;
 129 }
 130
 131 entity WarpZone_Find(vector mi, vector ma)
 132 {
 133         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 134         entity e;
 135         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 136                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
 137                         return e;
 138         return world;
 139 }
 140
 141 void WarpZone_MakeAllSolid()
 142 {
 143         entity e;
 144         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 145                 e.solid = SOLID_BSP;
 146 }
 147
 148 void WarpZone_MakeAllOther()
 149 {
 150         entity e;
 151         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 152                 e.solid = SOLID_TRIGGER;
 153 }
 154
 155 void WarpZone_Trace_InitTransform()
 156 {
 157         if(!WarpZone_trace_transform)
 158         {
 159                 WarpZone_trace_transform = spawn();
 160                 WarpZone_trace_transform.classname = "warpzone_trace_transform";
 161         }
 162         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 163 }
 164 void WarpZone_Trace_AddTransform(entity wz)
 165 {
 166         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 167 }
 168
 169 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 170 {
 171         float nomonsters_adjusted;
 172         float frac, sol, i;
 173         float contentshack;
 174         vector o0, e0;
 175         entity wz;
 176         vector vf, vr, vu;
 177
 178         WarpZone_Trace_InitTransform();
 179         if(!warpzone_warpzones_exist)
 180         {
 181                 if(nomonsters == MOVE_NOTHING)
 182                 {
 183                         trace_endpos = end;
 184                         trace_fraction = 1;
 185                         if(cb)
 186                                 cb(org, trace_endpos, end);
 187                         return;
 188                 }
 189                 else
 190                 {
 191                         tracebox(org, mi, ma, end, nomonsters, forent);
 192                         if(cb)
 193                                 cb(org, trace_endpos, end);
 194                         return;
 195                 }
 196         }
 197
 198         vf = v_forward;
 199         vr = v_right;
 200         vu = v_up;
 201         o0 = org;
 202         e0 = end;
 203
 204         switch(nomonsters)
 205         {
 206                 case MOVE_WORLDONLY:
 207                 case MOVE_NOTHING:
 208                         nomonsters_adjusted = MOVE_NOMONSTERS;
 209                         break;
 210                 default:
 211                         nomonsters_adjusted = nomonsters;
 212                         break;
 213         }
 214         if((contentshack = (forent.dphitcontentsmask && !(forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 215                 forent.dphitcontentsmask |= DPCONTENTS_SOLID;
 216
 217         // if starting in warpzone, first transform
 218         wz = WarpZone_Find(org + mi, org + ma);
 219         if(wz)
 220         {
 221                 if(zone && wz != zone)
 222                 {
 223                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 224                         sol = 1;
 225                         trace_fraction = 0;
 226                         trace_endpos = org;
 227                         goto fail;
 228                 }
 229                 WarpZone_Trace_AddTransform(wz);
 230                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 231                 end = WarpZone_TransformOrigin(wz, end);
 232         }
 233         WarpZone_MakeAllSolid();
 234         sol = -1;
 235         frac = 0;
 236         i = 16;
 237         for(;;)
 238         {
 239                 if(--i < 1)
 240                 {
 241                         dprint("Too many warpzones in sequence, aborting trace.\n");
 242                         trace_ent = world;
 243                         break;
 244                 }
 245                 tracebox(org, mi, ma, end, nomonsters_adjusted, forent);
 246                 if(cb)
 247                         cb(org, trace_endpos, end);
 248                 if(sol < 0)
 249                         sol = trace_startsolid;
 250
 251                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 252                 if(trace_fraction >= 1)
 253                         break;
 254                 if(trace_ent.classname != "trigger_warpzone")
 255                 {
 256                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 257                         {
 258                                 // continue the trace, ignoring this hit (we only care for warpzones)
 259                                 org = trace_endpos + normalize(end - org);
 260                                 continue;
 261                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 262                                 // otherwise, players could block entrances that way
 263                         }
 264                         break;
 265                 }
 266                 if(trace_ent == wz)
 267                 {
 268                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
 269                         trace_ent = world;
 270                         break;
 271                 }
 272                 wz = trace_ent;
 273                 if(zone && wz != zone)
 274                         break;
 275                 WarpZone_Trace_AddTransform(wz);
 276                 // we hit a warpzone... so, let's perform the trace after the warp again
 277                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 278                 end = WarpZone_TransformOrigin(wz, end);
 279         }
 280         WarpZone_MakeAllOther();
 281 :fail
 282         if(contentshack)
 283                 forent.dphitcontentsmask &~= DPCONTENTS_SOLID;
 284         trace_startsolid = sol;
 285         v_forward = vf;
 286         v_right = vr;
 287         v_up = vu;
 288 }
 289
 290 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 291 {
 292         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, world, WarpZone_trace_callback_t_null);
 293 }
 294
 295 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 296 {
 297         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 298 }
 299
 300 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 301 {
 302         float g, dt, i;
 303         vector vf, vr, vu, v0, o0;
 304         entity wz;
 305
 306         o0 = e.origin;
 307         v0 = e.velocity;
 308
 309         WarpZone_Trace_InitTransform();
 310         WarpZone_tracetoss_time = 0;
 311         if(!warpzone_warpzones_exist)
 312         {
 313                 tracetoss(e, forent);
 314                 if(cb)
 315                         cb(e.origin, trace_endpos, trace_endpos);
 316                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 317                 WarpZone_tracetoss_time += dt;
 318                 e.velocity_z -= dt * g;
 319                 WarpZone_tracetoss_velocity = e.velocity;
 320                 e.velocity = v0;
 321                 return;
 322         }
 323
 324         vf = v_forward;
 325         vr = v_right;
 326         vu = v_up;
 327
 328         // if starting in warpzone, first transform
 329         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 330         if(wz)
 331         {
 332                 if(zone && wz != zone)
 333                 {
 334                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 335
 336                         WarpZone_tracetoss_time = 0;
 337                         trace_endpos = o0;
 338                         goto fail;
 339                 }
 340                 WarpZone_Trace_AddTransform(wz);
 341                 setorigin(e, WarpZone_TransformOrigin(wz, e.origin));
 342                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 343         }
 344         WarpZone_MakeAllSolid();
 345         g = cvar("sv_gravity") * e.gravity;
 346         i = 16;
 347         for(;;)
 348         {
 349                 if(--i < 1)
 350                 {
 351                         dprint("Too many warpzones in sequence, aborting trace.\n");
 352                         trace_ent = world;
 353                         break;
 354                 }
 355                 tracetoss(e, forent);
 356                 if(cb)
 357                         cb(e.origin, trace_endpos, trace_endpos);
 358                 e.origin = trace_endpos;
 359                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 360                 WarpZone_tracetoss_time += dt;
 361                 e.velocity_z -= dt * g;
 362                 if(trace_fraction >= 1)
 363                         break;
 364                 if(trace_ent.classname != "trigger_warpzone")
 365                         break;
 366                 if(trace_ent == wz)
 367                 {
 368                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
 369                         trace_ent = world;
 370                         break;
 371                 }
 372                 wz = trace_ent;
 373                 if(zone && wz != zone)
 374                         break;
 375                 WarpZone_Trace_AddTransform(wz);
 376                 // we hit a warpzone... so, let's perform the trace after the warp again
 377                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 378                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 379         }
 380         WarpZone_MakeAllOther();
 381 :fail
 382         WarpZone_tracetoss_velocity = e.velocity;
 383         v_forward = vf;
 384         v_right = vr;
 385         v_up = vu;
 386         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 387         e.velocity = v0;
 388         e.origin = o0;
 389 }
 390
 391 void WarpZone_TraceToss(entity e, entity forent)
 392 {
 393         WarpZone_TraceToss_ThroughZone(e, forent, world, WarpZone_trace_callback_t_null);
 394 }
 395
 396 entity WarpZone_TrailParticles_trace_callback_own;
 397 float WarpZone_TrailParticles_trace_callback_eff;
 398 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 399 {
 400         trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 401 }
 402
 403 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 404 {
 405         WarpZone_TrailParticles_trace_callback_own = own;
 406         WarpZone_TrailParticles_trace_callback_eff = eff;
 407         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_trace_callback);
 408 }
 409
 410 float WarpZone_PlaneDist(entity wz, vector v)
 411 {
 412         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 413 }
 414
 415 float WarpZone_TargetPlaneDist(entity wz, vector v)
 416 {
 417         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 418 }
 419
 420 vector WarpZone_TransformOrigin(entity wz, vector v)
 421 {
 422         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 423 }
 424
 425 vector WarpZone_TransformVelocity(entity wz, vector v)
 426 {
 427         return AnglesTransform_Apply(wz.warpzone_transform, v);
 428 }
 429
 430 vector WarpZone_TransformAngles(entity wz, vector v)
 431 {
 432         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 433 }
 434
 435 vector WarpZone_TransformVAngles(entity wz, vector ang)
 436 {
 437 #ifdef KEEP_ROLL
 438         float roll;
 439         roll = ang_z;
 440         ang_z = 0;
 441 #endif
 442
 443         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 444
 445 #ifdef KEEP_ROLL
 446         ang = AnglesTransform_Normalize(ang, TRUE);
 447         ang = AnglesTransform_CancelRoll(ang);
 448         ang_z = roll;
 449 #else
 450         ang = AnglesTransform_Normalize(ang, FALSE);
 451 #endif
 452
 453         return ang;
 454 }
 455
 456 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 457 {
 458         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 459 }
 460
 461 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 462 {
 463         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 464 }
 465
 466 vector WarpZone_UnTransformAngles(entity wz, vector v)
 467 {
 468         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 469 }
 470
 471 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 472 {
 473         float roll;
 474
 475         roll = ang_z;
 476         ang_z = 0;
 477
 478         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 479         ang = AnglesTransform_Normalize(ang, TRUE);
 480         ang = AnglesTransform_CancelRoll(ang);
 481
 482         ang_z = roll;
 483         return ang;
 484 }
 485
 486 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 487 {
 488         vector nearest;
 489         nearest_x = bound(mi_x, org_x, ma_x);
 490         nearest_y = bound(mi_y, org_y, ma_y);
 491         nearest_z = bound(mi_z, org_z, ma_z);
 492         return nearest;
 493 }
 494
 495 .float WarpZone_findradius_hit;
 496 .entity WarpZone_findradius_next;
 497 void WarpZone_FindRadius_Recurse(vector org, float rad,        vector org0,               vector transform, vector shift, float needlineofsight)
 498 //                               blast origin of current search   original blast origin   how to untransform (victim to blast system)
 499 {
 500         vector org_new;
 501         vector org0_new;
 502         vector shift_new, transform_new;
 503         vector p;
 504         entity e, e0;
 505         entity wz;
 506         if(rad <= 0)
 507                 return;
 508         e0 = findradius(org, rad);
 509         wz = world;
 510
 511         for(e = e0; e; e = e.chain)
 512         {
 513                 p = WarpZoneLib_NearestPointOnBox(e.origin + e.mins, e.origin + e.maxs, org0);
 514                 if(needlineofsight)
 515                 {
 516                         traceline(org, p, MOVE_NOMONSTERS, e);
 517                         if(trace_fraction < 1)
 518                                 continue;
 519                 }
 520                 if(!e.WarpZone_findradius_hit || vlen(e.WarpZone_findradius_dist) > vlen(org0 - p))
 521                 {
 522                         e.WarpZone_findradius_nearest = p;
 523                         e.WarpZone_findradius_dist = org0 - p;
 524                         e.WarpZone_findradius_findorigin = org;
 525                         e.WarpZone_findradius_findradius = rad;
 526                         if(e.classname == "warpzone_refsys")
 527                         {
 528                                 // ignore, especially: do not overwrite the refsys parameters
 529                         }
 530                         else if(e.classname == "trigger_warpzone")
 531                         {
 532                                 e.WarpZone_findradius_next = wz;
 533                                 wz = e;
 534                                 e.WarpZone_findradius_hit = 1;
 535                                 e.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 536                                 e.enemy.WarpZone_findradius_hit = 1;
 537                         }
 538                         else
 539                         {
 540                                 e.warpzone_transform = transform;
 541                                 e.warpzone_shift = shift;
 542                                 e.WarpZone_findradius_hit = 1;
 543                         }
 544                 }
 545         }
 546         for(e = wz; e; e = e.WarpZone_findradius_next)
 547         {
 548                 org0_new = WarpZone_TransformOrigin(e, org);
 549                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 550                 org_new = trace_endpos;
 551
 552                 transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 553                 shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 554                 WarpZone_FindRadius_Recurse(
 555                         org_new,
 556                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 557                         org0_new,
 558                         transform_new, shift_new,
 559                         needlineofsight);
 560                 e.WarpZone_findradius_hit = 0;
 561                 e.enemy.WarpZone_findradius_hit = 0;
 562         }
 563 }
 564 entity WarpZone_FindRadius(vector org, float rad, float needlineofsight)
 565 {
 566         entity e0, e;
 567         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 568         e0 = findchainfloat(WarpZone_findradius_hit, 1);
 569         for(e = e0; e; e = e.chain)
 570                 e.WarpZone_findradius_hit = 0;
 571         return e0;
 572 }
 573
 574 .entity WarpZone_refsys;
 575 void WarpZone_RefSys_GC()
 576 {
 577         // garbage collect unused reference systems
 578         self.nextthink = time + 1;
 579         if(self.owner.WarpZone_refsys != self)
 580                 remove(self);
 581 }
 582 void WarpZone_RefSys_Add(entity me, entity wz)
 583 {
 584         if(me.WarpZone_refsys.owner != me)
 585         {
 586                 me.WarpZone_refsys = spawn();
 587                 me.WarpZone_refsys.classname = "warpzone_refsys";
 588                 me.WarpZone_refsys.owner = me;
 589                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
 590                 me.WarpZone_refsys.nextthink = time + 1;
 591                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 592         }
 593         if(wz)
 594                 WarpZone_Accumulator_Add(me.WarpZone_refsys, wz);
 595 }
 596 .vector WarpZone_refsys_incremental_shift;
 597 .vector WarpZone_refsys_incremental_transform;
 598 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 599 {
 600         vector t, s;
 601         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 602         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 603                 return;
 604         if(me.WarpZone_refsys.owner != me)
 605         {
 606                 me.WarpZone_refsys = spawn();
 607                 me.WarpZone_refsys.classname = "warpzone_refsys";
 608                 me.WarpZone_refsys.owner = me;
 609                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
 610                 me.WarpZone_refsys.nextthink = time + 1;
 611                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 612         }
 613         t = AnglesTransform_Invert(me.WarpZone_refsys_incremental_transform);
 614         s = AnglesTransform_PrePostShift_GetPostShift(me.WarpZone_refsys_incremental_shift, t, '0 0 0');
 615         WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 616         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref);
 617         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 618         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 619 }
 620 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 621 {
 622         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 623         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 624 }
 625 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 626 {
 627         if(from.WarpZone_refsys)
 628                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 629         if(to.WarpZone_refsys)
 630                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 631         return org;
 632 }
 633 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 634 {
 635         if(from.WarpZone_refsys)
 636                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 637         if(to.WarpZone_refsys)
 638                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 639         return vel;
 640 }
 641 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 642 {
 643         if(from.WarpZone_refsys)
 644                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 645         if(to.WarpZone_refsys)
 646                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 647         return ang;
 648 }
 649 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 650 {
 651         if(from.WarpZone_refsys)
 652                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 653         if(to.WarpZone_refsys)
 654                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 655         return ang;
 656 }
 657 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 658 {
 659         entity e;
 660         e = spawn();
 661         if(me.WarpZone_refsys)
 662         {
 663                 e.WarpZone_refsys = spawn();
 664                 e.WarpZone_refsys.classname = "warpzone_refsys";
 665                 e.WarpZone_refsys.owner = e;
 666                 e.WarpZone_refsys.think = WarpZone_RefSys_GC;
 667                 e.WarpZone_refsys.nextthink = time + 1;
 668                 e.WarpZone_refsys.warpzone_shift = me.WarpZone_refsys.warpzone_shift;
 669                 e.WarpZone_refsys.warpzone_transform = me.WarpZone_refsys.warpzone_transform;
 670         }
 671         return e;
 672 }