qcsrc/warpzonelib/common.qc

   1 float trace_dphitcontents;
   2 .float dphitcontentsmask;
   3
   4 void WarpZone_Accumulator_Clear(entity acc)
   5 {
   6         acc.warpzone_transform = '0 0 0';
   7         acc.warpzone_shift = '0 0 0';
   8 }
   9 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  10 {
  11         vector tr, st;
  12         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  13         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  14         acc.warpzone_transform = tr;
  15         acc.warpzone_shift = st;
  16 }
  17 void WarpZone_Accumulator_Add(entity acc, entity wz)
  18 {
  19         vector t, st;
  20         t = AnglesTransform_Multiply(wz.warpzone_transform, acc.warpzone_transform);
  21         st = AnglesTransform_Multiply_GetPostShift(wz.warpzone_transform, wz.warpzone_shift, acc.warpzone_transform, acc.warpzone_shift);
  22         acc.warpzone_transform = t;
  23         acc.warpzone_shift = st;
  24 }
  25
  26 .vector(vector, vector) camera_transform;
  27 var float autocvar_cl_warpzone_usetrace = 1;
  28 vector WarpZone_camera_transform(vector org, vector ang)
  29 {
  30         vector vf, vr, vu;
  31         if(self.warpzone_fadestart)
  32                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
  33                         return org;
  34                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  35                         // unneeded on client, on server this helps a lot
  36         vf = v_forward;
  37         vr = v_right;
  38         vu = v_up;
  39         org = WarpZone_TransformOrigin(self, org);
  40         vf = WarpZone_TransformVelocity(self, vf);
  41         vr = WarpZone_TransformVelocity(self, vr);
  42         vu = WarpZone_TransformVelocity(self, vu);
  43         if(autocvar_cl_warpzone_usetrace)
  44                 traceline(self.warpzone_targetorigin, org, MOVE_NOMONSTERS, world);
  45         else
  46                 trace_endpos = self.warpzone_targetorigin;
  47         v_forward = vf;
  48         v_right = vr;
  49         v_up = vu;
  50         return org;
  51 }
  52
  53 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  54 {
  55         e.warpzone_transform = AnglesTransform_RightDivide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  56         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  57         e.warpzone_origin = my_org;
  58         e.warpzone_targetorigin = other_org;
  59         e.warpzone_angles = my_ang;
  60         e.warpzone_targetangles = other_ang;
  61         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
  62         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
  63         e.camera_transform = WarpZone_camera_transform;
  64 }
  65
  66 vector WarpZone_Camera_camera_transform(vector org, vector ang)
  67 {
  68         // a fixed camera view
  69         if(self.warpzone_fadestart)
  70                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
  71                         return org;
  72                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  73                         // unneeded on client, on server this helps a lot
  74         trace_endpos = self.warpzone_origin;
  75         makevectors(self.warpzone_angles);
  76         return self.warpzone_origin;
  77 }
  78
  79 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  80 {
  81         e.warpzone_origin = my_org;
  82         e.warpzone_angles = my_ang;
  83         e.camera_transform = WarpZone_Camera_camera_transform;
  84 }
  85
  86 .entity enemy;
  87
  88 vector WarpZoneLib_BoxTouchesBrush_mins;
  89 vector WarpZoneLib_BoxTouchesBrush_maxs;
  90 entity WarpZoneLib_BoxTouchesBrush_ent;
  91 entity WarpZoneLib_BoxTouchesBrush_ignore;
  92 float WarpZoneLib_BoxTouchesBrush_Recurse()
  93 {
  94         float s;
  95         entity se;
  96         float f;
  97
  98         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
  99 #ifdef CSQC
 100         if (trace_networkentity)
 101         {
 102                 dprint("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush\n");
 103                 // we cannot continue, as a player blocks us...
 104                 // so, abort
 105                 return 0;
 106         }
 107 #endif
 108         if not(trace_ent)
 109                 return 0;
 110         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
 111                 return 1;
 112
 113         se = trace_ent;
 114         s = se.solid;
 115         se.solid = SOLID_NOT;
 116         f = WarpZoneLib_BoxTouchesBrush_Recurse();
 117         se.solid = s;
 118
 119         return f;
 120 }
 121
 122 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 123 {
 124     float f, s;
 125
 126     if(!e.modelindex || e.warpzone_isboxy)
 127         return 1;
 128
 129     s = e.solid;
 130     e.solid = SOLID_BSP;
 131     WarpZoneLib_BoxTouchesBrush_mins = mi;
 132     WarpZoneLib_BoxTouchesBrush_maxs = ma;
 133     WarpZoneLib_BoxTouchesBrush_ent = e;
 134     WarpZoneLib_BoxTouchesBrush_ignore = ig;
 135     f = WarpZoneLib_BoxTouchesBrush_Recurse();
 136     e.solid = s;
 137
 138     return f;
 139 }
 140
 141 entity WarpZone_Find(vector mi, vector ma)
 142 {
 143         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 144         entity e;
 145         if(!warpzone_warpzones_exist)
 146                 return world;
 147         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 148                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
 149                         return e;
 150         return world;
 151 }
 152
 153 void WarpZone_MakeAllSolid()
 154 {
 155         entity e;
 156         if(!warpzone_warpzones_exist)
 157                 return;
 158         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 159                 e.solid = SOLID_BSP;
 160 }
 161
 162 void WarpZone_MakeAllOther()
 163 {
 164         entity e;
 165         if(!warpzone_warpzones_exist)
 166                 return;
 167         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 168                 e.solid = SOLID_TRIGGER;
 169 }
 170
 171 void WarpZone_Trace_InitTransform()
 172 {
 173         if(!WarpZone_trace_transform)
 174         {
 175                 WarpZone_trace_transform = spawn();
 176                 WarpZone_trace_transform.classname = "warpzone_trace_transform";
 177         }
 178         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 179 }
 180 void WarpZone_Trace_AddTransform(entity wz)
 181 {
 182         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 183 }
 184
 185 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 186 {
 187         float nomonsters_adjusted;
 188         float frac, sol, i;
 189         float contentshack;
 190         vector o0, e0;
 191         entity wz;
 192         vector vf, vr, vu;
 193
 194         WarpZone_trace_forent = forent;
 195         WarpZone_trace_firstzone = world;
 196         WarpZone_trace_lastzone = world;
 197         WarpZone_Trace_InitTransform();
 198         if(!warpzone_warpzones_exist)
 199         {
 200                 if(nomonsters == MOVE_NOTHING)
 201                 {
 202                         trace_endpos = end;
 203                         trace_fraction = 1;
 204                         if(cb)
 205                                 cb(org, trace_endpos, end);
 206                         return;
 207                 }
 208                 else
 209                 {
 210                         tracebox(org, mi, ma, end, nomonsters, WarpZone_trace_forent);
 211                         if(cb)
 212                                 cb(org, trace_endpos, end);
 213                         return;
 214                 }
 215         }
 216
 217         vf = v_forward;
 218         vr = v_right;
 219         vu = v_up;
 220         o0 = org;
 221         e0 = end;
 222
 223         switch(nomonsters)
 224         {
 225                 case MOVE_WORLDONLY:
 226                 case MOVE_NOTHING:
 227                         nomonsters_adjusted = MOVE_NOMONSTERS;
 228                         break;
 229                 default:
 230                         nomonsters_adjusted = nomonsters;
 231                         break;
 232         }
 233         if((contentshack = (WarpZone_trace_forent.dphitcontentsmask && !(WarpZone_trace_forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 234                 BITSET_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 235
 236         // if starting in warpzone, first transform
 237         wz = WarpZone_Find(org + mi, org + ma);
 238         if(wz)
 239         {
 240                 WarpZone_trace_firstzone = wz;
 241                 WarpZone_trace_lastzone = wz;
 242                 if(zone && wz != zone)
 243                 {
 244                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 245                         sol = 1;
 246                         trace_fraction = 0;
 247                         trace_endpos = org;
 248                         goto fail;
 249                 }
 250                 WarpZone_Trace_AddTransform(wz);
 251                 org = WarpZone_TransformOrigin(wz, org);
 252                 end = WarpZone_TransformOrigin(wz, end);
 253         }
 254         WarpZone_MakeAllSolid();
 255         sol = -1;
 256         frac = 0;
 257         i = 16;
 258         for(;;)
 259         {
 260                 if(--i < 1)
 261                 {
 262                         dprint("Too many warpzones in sequence, aborting trace.\n");
 263                         trace_ent = world;
 264                         break;
 265                 }
 266                 tracebox(org, mi, ma, end, nomonsters_adjusted, WarpZone_trace_forent);
 267                 if(cb)
 268                         cb(org, trace_endpos, end);
 269                 if(sol < 0)
 270                         sol = trace_startsolid;
 271
 272                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 273                 if(trace_fraction >= 1)
 274                         break;
 275                 if(trace_ent.classname != "trigger_warpzone")
 276                 {
 277                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & WarpZone_trace_forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 278                         {
 279                                 // continue the trace, ignoring this hit (we only care for warpzones)
 280                                 org = trace_endpos + normalize(end - org);
 281                                 continue;
 282                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 283                                 // otherwise, players could block entrances that way
 284                         }
 285                         break;
 286                 }
 287                 if(trace_ent == wz)
 288                 {
 289                         // FIXME can this check be removed? Do we really need it?
 290                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
 291                         trace_ent = world;
 292                         break;
 293                 }
 294                 wz = trace_ent;
 295                 if(!WarpZone_trace_firstzone)
 296                         WarpZone_trace_firstzone = wz;
 297                 WarpZone_trace_lastzone = wz;
 298                 if(zone && wz != zone)
 299                         break;
 300                 WarpZone_Trace_AddTransform(wz);
 301                 // we hit a warpzone... so, let's perform the trace after the warp again
 302                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 303                 end = WarpZone_TransformOrigin(wz, end);
 304
 305                 // we got warped, so let's step back a bit
 306                 tracebox(org, mi, ma, org + normalize(org - end) * 32, nomonsters_adjusted, WarpZone_trace_forent);
 307                 org = trace_endpos;
 308         }
 309         WarpZone_MakeAllOther();
 310 :fail
 311         if(contentshack)
 312                 BITCLR_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 313         trace_startsolid = sol;
 314         v_forward = vf;
 315         v_right = vr;
 316         v_up = vu;
 317 }
 318
 319 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 320 {
 321         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, world, WarpZone_trace_callback_t_null);
 322 }
 323
 324 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 325 {
 326         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 327 }
 328
 329 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 330 {
 331         float g, dt, i;
 332         vector vf, vr, vu, v0, o0;
 333         entity wz;
 334
 335         o0 = e.origin;
 336         v0 = e.velocity;
 337         g = cvar("sv_gravity") * e.gravity;
 338
 339         WarpZone_trace_forent = forent;
 340         WarpZone_trace_firstzone = world;
 341         WarpZone_trace_lastzone = world;
 342         WarpZone_Trace_InitTransform();
 343         WarpZone_tracetoss_time = 0;
 344         if(!warpzone_warpzones_exist)
 345         {
 346                 tracetoss(e, WarpZone_trace_forent);
 347                 if(cb)
 348                         cb(e.origin, trace_endpos, trace_endpos);
 349                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 350                 WarpZone_tracetoss_time += dt;
 351                 e.velocity_z -= dt * g;
 352                 WarpZone_tracetoss_velocity = e.velocity;
 353                 e.velocity = v0;
 354                 return;
 355         }
 356
 357         vf = v_forward;
 358         vr = v_right;
 359         vu = v_up;
 360
 361         // if starting in warpzone, first transform
 362         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 363         if(wz)
 364         {
 365                 WarpZone_trace_firstzone = wz;
 366                 WarpZone_trace_lastzone = wz;
 367                 if(zone && wz != zone)
 368                 {
 369                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 370
 371                         WarpZone_tracetoss_time = 0;
 372                         trace_endpos = o0;
 373                         goto fail;
 374                 }
 375                 WarpZone_Trace_AddTransform(wz);
 376                 setorigin(e, WarpZone_TransformOrigin(wz, e.origin));
 377                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 378         }
 379         WarpZone_MakeAllSolid();
 380         i = 16;
 381         for(;;)
 382         {
 383                 if(--i < 1)
 384                 {
 385                         dprint("Too many warpzones in sequence, aborting trace.\n");
 386                         trace_ent = world;
 387                         break;
 388                 }
 389                 tracetoss(e, WarpZone_trace_forent);
 390                 if(cb)
 391                         cb(e.origin, trace_endpos, trace_endpos);
 392                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 393                 WarpZone_tracetoss_time += dt;
 394                 e.origin = trace_endpos;
 395                 e.velocity_z -= dt * g;
 396                 if(trace_fraction >= 1)
 397                         break;
 398                 if(trace_ent.classname != "trigger_warpzone")
 399                         break;
 400                 if(trace_ent == wz)
 401                 {
 402                         // FIXME can this check be removed? Do we really need it?
 403                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
 404                         trace_ent = world;
 405                         break;
 406                 }
 407                 wz = trace_ent;
 408                 if(!WarpZone_trace_firstzone)
 409                         WarpZone_trace_firstzone = wz;
 410                 WarpZone_trace_lastzone = wz;
 411                 if(zone && wz != zone)
 412                         break;
 413                 WarpZone_Trace_AddTransform(wz);
 414                 // we hit a warpzone... so, let's perform the trace after the warp again
 415                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 416                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 417
 418                 // we got warped, so let's step back a bit
 419                 e.velocity = -e.velocity;
 420                 tracetoss(e, WarpZone_trace_forent);
 421                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 422                 WarpZone_tracetoss_time -= dt;
 423                 e.origin = trace_endpos;
 424                 e.velocity = -e.velocity;
 425         }
 426         WarpZone_MakeAllOther();
 427 :fail
 428         WarpZone_tracetoss_velocity = e.velocity;
 429         v_forward = vf;
 430         v_right = vr;
 431         v_up = vu;
 432         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 433         e.velocity = v0;
 434         e.origin = o0;
 435 }
 436
 437 void WarpZone_TraceToss(entity e, entity forent)
 438 {
 439         WarpZone_TraceToss_ThroughZone(e, forent, world, WarpZone_trace_callback_t_null);
 440 }
 441
 442 entity WarpZone_TrailParticles_trace_callback_own;
 443 float WarpZone_TrailParticles_trace_callback_eff;
 444 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 445 {
 446         trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 447 }
 448
 449 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 450 {
 451         WarpZone_TrailParticles_trace_callback_own = own;
 452         WarpZone_TrailParticles_trace_callback_eff = eff;
 453         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_trace_callback);
 454 }
 455
 456 #ifdef CSQC
 457 float WarpZone_TrailParticles_trace_callback_f;
 458 float WarpZone_TrailParticles_trace_callback_flags;
 459 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
 460 {
 461         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
 462 }
 463
 464 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, float boxflags)
 465 {
 466         WarpZone_TrailParticles_trace_callback_own = own;
 467         WarpZone_TrailParticles_trace_callback_eff = eff;
 468         WarpZone_TrailParticles_trace_callback_f = f;
 469         WarpZone_TrailParticles_trace_callback_flags = boxflags;
 470         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_WithMultiplier_trace_callback);
 471 }
 472 #endif
 473
 474 float WarpZone_PlaneDist(entity wz, vector v)
 475 {
 476         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 477 }
 478
 479 float WarpZone_TargetPlaneDist(entity wz, vector v)
 480 {
 481         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 482 }
 483
 484 vector WarpZone_TransformOrigin(entity wz, vector v)
 485 {
 486         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 487 }
 488
 489 vector WarpZone_TransformVelocity(entity wz, vector v)
 490 {
 491         return AnglesTransform_Apply(wz.warpzone_transform, v);
 492 }
 493
 494 vector WarpZone_TransformAngles(entity wz, vector v)
 495 {
 496         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 497 }
 498
 499 vector WarpZone_TransformVAngles(entity wz, vector ang)
 500 {
 501 #ifdef KEEP_ROLL
 502         float roll;
 503         roll = ang_z;
 504         ang_z = 0;
 505 #endif
 506
 507         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 508
 509 #ifdef KEEP_ROLL
 510         ang = AnglesTransform_Normalize(ang, TRUE);
 511         ang = AnglesTransform_CancelRoll(ang);
 512         ang_z = roll;
 513 #else
 514         ang = AnglesTransform_Normalize(ang, FALSE);
 515 #endif
 516
 517         return ang;
 518 }
 519
 520 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 521 {
 522         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 523 }
 524
 525 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 526 {
 527         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 528 }
 529
 530 vector WarpZone_UnTransformAngles(entity wz, vector v)
 531 {
 532         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 533 }
 534
 535 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 536 {
 537         float roll;
 538
 539         roll = ang_z;
 540         ang_z = 0;
 541
 542         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 543         ang = AnglesTransform_Normalize(ang, TRUE);
 544         ang = AnglesTransform_CancelRoll(ang);
 545
 546         ang_z = roll;
 547         return ang;
 548 }
 549
 550 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 551 {
 552         vector nearest;
 553         nearest_x = bound(mi_x, org_x, ma_x);
 554         nearest_y = bound(mi_y, org_y, ma_y);
 555         nearest_z = bound(mi_z, org_z, ma_z);
 556         return nearest;
 557 }
 558
 559 .float WarpZone_findradius_hit;
 560 .entity WarpZone_findradius_next;
 561 void WarpZone_FindRadius_Recurse(vector org, float rad,        vector org0,               vector transform, vector shift, float needlineofsight)
 562 //                               blast origin of current search   original blast origin   how to untransform (victim to blast system)
 563 {
 564         vector org_new;
 565         vector org0_new;
 566         vector shift_new, transform_new;
 567         vector p;
 568         entity e, e0;
 569         entity wz;
 570         if(rad <= 0)
 571                 return;
 572         e0 = findradius(org, rad);
 573         wz = world;
 574
 575         for(e = e0; e; e = e.chain)
 576         {
 577                 p = WarpZoneLib_NearestPointOnBox(e.origin + e.mins, e.origin + e.maxs, org0);
 578                 if(needlineofsight)
 579                 {
 580                         traceline(org, p, MOVE_NOMONSTERS, e);
 581                         if(trace_fraction < 1)
 582                                 continue;
 583                 }
 584                 if(!e.WarpZone_findradius_hit || vlen(e.WarpZone_findradius_dist) > vlen(org0 - p))
 585                 {
 586                         e.WarpZone_findradius_nearest = p;
 587                         e.WarpZone_findradius_dist = org0 - p;
 588                         e.WarpZone_findradius_findorigin = org;
 589                         e.WarpZone_findradius_findradius = rad;
 590                         if(e.classname == "warpzone_refsys")
 591                         {
 592                                 // ignore, especially: do not overwrite the refsys parameters
 593                         }
 594                         else if(e.classname == "trigger_warpzone")
 595                         {
 596                                 e.WarpZone_findradius_next = wz;
 597                                 wz = e;
 598                                 e.WarpZone_findradius_hit = 1;
 599                                 e.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 600                                 e.enemy.WarpZone_findradius_hit = 1;
 601                         }
 602                         else
 603                         {
 604                                 e.warpzone_transform = transform;
 605                                 e.warpzone_shift = shift;
 606                                 e.WarpZone_findradius_hit = 1;
 607                         }
 608                 }
 609         }
 610         for(e = wz; e; e = e.WarpZone_findradius_next)
 611         {
 612                 org0_new = WarpZone_TransformOrigin(e, org);
 613                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 614                 org_new = trace_endpos;
 615
 616                 transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 617                 shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 618                 WarpZone_FindRadius_Recurse(
 619                         org_new,
 620                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 621                         org0_new,
 622                         transform_new, shift_new,
 623                         needlineofsight);
 624                 e.WarpZone_findradius_hit = 0;
 625                 e.enemy.WarpZone_findradius_hit = 0;
 626         }
 627 }
 628 entity WarpZone_FindRadius(vector org, float rad, float needlineofsight)
 629 {
 630         entity e0, e;
 631         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 632         e0 = findchainfloat(WarpZone_findradius_hit, 1);
 633         for(e = e0; e; e = e.chain)
 634                 e.WarpZone_findradius_hit = 0;
 635         return e0;
 636 }
 637
 638 .entity WarpZone_refsys;
 639 void WarpZone_RefSys_GC()
 640 {
 641         // garbage collect unused reference systems
 642         self.nextthink = time + 1;
 643         if(self.owner.WarpZone_refsys != self)
 644                 remove(self);
 645 }
 646 void WarpZone_RefSys_Add(entity me, entity wz)
 647 {
 648         if(me.WarpZone_refsys.owner != me)
 649         {
 650                 me.WarpZone_refsys = spawn();
 651                 me.WarpZone_refsys.classname = "warpzone_refsys";
 652                 me.WarpZone_refsys.owner = me;
 653                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
 654                 me.WarpZone_refsys.nextthink = time + 1;
 655                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 656         }
 657         if(wz)
 658                 WarpZone_Accumulator_Add(me.WarpZone_refsys, wz);
 659 }
 660 .vector WarpZone_refsys_incremental_shift;
 661 .vector WarpZone_refsys_incremental_transform;
 662 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 663 {
 664         vector t, s;
 665         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 666         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 667                 return;
 668         if(me.WarpZone_refsys.owner != me)
 669         {
 670                 me.WarpZone_refsys = spawn();
 671                 me.WarpZone_refsys.classname = "warpzone_refsys";
 672                 me.WarpZone_refsys.owner = me;
 673                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
 674                 me.WarpZone_refsys.nextthink = time + 1;
 675                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 676         }
 677         t = AnglesTransform_Invert(me.WarpZone_refsys_incremental_transform);
 678         s = AnglesTransform_PrePostShift_GetPostShift(me.WarpZone_refsys_incremental_shift, t, '0 0 0');
 679         WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 680         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref.WarpZone_refsys);
 681         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 682         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 683 }
 684 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 685 {
 686         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 687         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 688 }
 689 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 690 {
 691         if(from.WarpZone_refsys)
 692                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 693         if(to.WarpZone_refsys)
 694                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 695         return org;
 696 }
 697 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 698 {
 699         if(from.WarpZone_refsys)
 700                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 701         if(to.WarpZone_refsys)
 702                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 703         return vel;
 704 }
 705 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 706 {
 707         if(from.WarpZone_refsys)
 708                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 709         if(to.WarpZone_refsys)
 710                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 711         return ang;
 712 }
 713 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 714 {
 715         if(from.WarpZone_refsys)
 716                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 717         if(to.WarpZone_refsys)
 718                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 719         return ang;
 720 }
 721 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 722 {
 723         entity e;
 724         e = spawn();
 725         if(me.WarpZone_refsys)
 726         {
 727                 e.WarpZone_refsys = spawn();
 728                 e.WarpZone_refsys.classname = "warpzone_refsys";
 729                 e.WarpZone_refsys.owner = e;
 730                 e.WarpZone_refsys.think = WarpZone_RefSys_GC;
 731                 e.WarpZone_refsys.nextthink = time + 1;
 732                 e.WarpZone_refsys.warpzone_shift = me.WarpZone_refsys.warpzone_shift;
 733                 e.WarpZone_refsys.warpzone_transform = me.WarpZone_refsys.warpzone_transform;
 734         }
 735         return e;
 736 }