qcsrc/warpzonelib/common.qc

   1 float trace_dphitcontents;
   2 .float dphitcontents;
   3
   4 void WarpZone_Accumulator_Clear(entity acc)
   5 {
   6         acc.warpzone_transform = '0 0 0';
   7         acc.warpzone_shift = '0 0 0';
   8 }
   9 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  10 {
  11         vector tr, st;
  12         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  13         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  14         acc.warpzone_transform = tr;
  15         acc.warpzone_shift = st;
  16 }
  17 void WarpZone_Accumulator_Add(entity acc, entity wz)
  18 {
  19         vector t, st;
  20         t = AnglesTransform_Multiply(wz.warpzone_transform, acc.warpzone_transform);
  21         st = AnglesTransform_Multiply_GetPostShift(wz.warpzone_transform, wz.warpzone_shift, acc.warpzone_transform, acc.warpzone_shift);
  22         acc.warpzone_transform = t;
  23         acc.warpzone_shift = st;
  24 }
  25
  26 .vector(vector, vector) camera_transform;
  27 var float autocvar_cl_warpzone_usetrace = 1;
  28 vector WarpZone_camera_transform(vector org, vector ang)
  29 {
  30         vector vf, vr, vu;
  31         vf = v_forward;
  32         vr = v_right;
  33         vu = v_up;
  34         org = WarpZone_TransformOrigin(self, org);
  35         vf = WarpZone_TransformVelocity(self, vf);
  36         vr = WarpZone_TransformVelocity(self, vr);
  37         vu = WarpZone_TransformVelocity(self, vu);
  38         if(autocvar_cl_warpzone_usetrace)
  39                 traceline(self.warpzone_targetorigin, org, MOVE_NOMONSTERS, world);
  40         else
  41                 trace_endpos = self.warpzone_targetorigin;
  42         v_forward = vf;
  43         v_right = vr;
  44         v_up = vu;
  45         return org;
  46 }
  47
  48 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  49 {
  50         e.warpzone_transform = AnglesTransform_Divide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  51         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  52         e.warpzone_origin = my_org;
  53         e.warpzone_targetorigin = other_org;
  54         e.warpzone_angles = my_ang;
  55         e.warpzone_targetangles = other_ang;
  56         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
  57         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
  58         e.camera_transform = WarpZone_camera_transform;
  59 }
  60
  61 vector WarpZone_Camera_camera_transform(vector org, vector ang)
  62 {
  63         // a fixed camera view
  64         trace_endpos = self.warpzone_origin;
  65         makevectors(self.warpzone_angles);
  66         return self.warpzone_origin;
  67 }
  68
  69 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  70 {
  71         e.warpzone_origin = my_org;
  72         e.warpzone_angles = my_ang;
  73         e.camera_transform = WarpZone_Camera_camera_transform;
  74 }
  75
  76 .entity enemy;
  77
  78 vector WarpZoneLib_BoxTouchesBrush_mins;
  79 vector WarpZoneLib_BoxTouchesBrush_maxs;
  80 entity WarpZoneLib_BoxTouchesBrush_ent;
  81 entity WarpZoneLib_BoxTouchesBrush_ignore;
  82 float WarpZoneLib_BoxTouchesBrush_Recurse()
  83 {
  84         float s;
  85         entity se;
  86         float f;
  87
  88         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
  89 #ifdef CSQC
  90         if (trace_networkentity)
  91         {
  92                 dprint("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush\n");
  93                 // we cannot continue, as a player blocks us...
  94                 // so, abort
  95                 return 0;
  96         }
  97 #endif
  98         if not(trace_ent)
  99                 return 0;
 100         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
 101                 return 1;
 102
 103         se = trace_ent;
 104         s = se.solid;
 105         se.solid = SOLID_NOT;
 106         f = WarpZoneLib_BoxTouchesBrush_Recurse();
 107         se.solid = s;
 108
 109         return f;
 110 }
 111
 112 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 113 {
 114     float f, s;
 115
 116     if(!e.modelindex || e.warpzone_isboxy)
 117         return 1;
 118
 119     s = e.solid;
 120     e.solid = SOLID_BSP;
 121     WarpZoneLib_BoxTouchesBrush_mins = mi;
 122     WarpZoneLib_BoxTouchesBrush_maxs = ma;
 123     WarpZoneLib_BoxTouchesBrush_ent = e;
 124     WarpZoneLib_BoxTouchesBrush_ignore = ig;
 125     f = WarpZoneLib_BoxTouchesBrush_Recurse();
 126     e.solid = s;
 127
 128     return f;
 129 }
 130
 131 entity WarpZone_Find(vector mi, vector ma)
 132 {
 133         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 134         entity e;
 135         if(!warpzone_warpzones_exist)
 136                 return world;
 137         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 138                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
 139                         return e;
 140         return world;
 141 }
 142
 143 void WarpZone_MakeAllSolid()
 144 {
 145         entity e;
 146         if(!warpzone_warpzones_exist)
 147                 return;
 148         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 149                 e.solid = SOLID_BSP;
 150 }
 151
 152 void WarpZone_MakeAllOther()
 153 {
 154         entity e;
 155         if(!warpzone_warpzones_exist)
 156                 return;
 157         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 158                 e.solid = SOLID_TRIGGER;
 159 }
 160
 161 void WarpZone_Trace_InitTransform()
 162 {
 163         if(!WarpZone_trace_transform)
 164         {
 165                 WarpZone_trace_transform = spawn();
 166                 WarpZone_trace_transform.classname = "warpzone_trace_transform";
 167         }
 168         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 169 }
 170 void WarpZone_Trace_AddTransform(entity wz)
 171 {
 172         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 173 }
 174
 175 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 176 {
 177         float nomonsters_adjusted;
 178         float frac, sol, i;
 179         float contentshack;
 180         vector o0, e0;
 181         entity wz;
 182         vector vf, vr, vu;
 183
 184         WarpZone_Trace_InitTransform();
 185         if(!warpzone_warpzones_exist)
 186         {
 187                 if(nomonsters == MOVE_NOTHING)
 188                 {
 189                         trace_endpos = end;
 190                         trace_fraction = 1;
 191                         if(cb)
 192                                 cb(org, trace_endpos, end);
 193                         return;
 194                 }
 195                 else
 196                 {
 197                         tracebox(org, mi, ma, end, nomonsters, forent);
 198                         if(cb)
 199                                 cb(org, trace_endpos, end);
 200                         return;
 201                 }
 202         }
 203
 204         vf = v_forward;
 205         vr = v_right;
 206         vu = v_up;
 207         o0 = org;
 208         e0 = end;
 209
 210         switch(nomonsters)
 211         {
 212                 case MOVE_WORLDONLY:
 213                 case MOVE_NOTHING:
 214                         nomonsters_adjusted = MOVE_NOMONSTERS;
 215                         break;
 216                 default:
 217                         nomonsters_adjusted = nomonsters;
 218                         break;
 219         }
 220         if((contentshack = (forent.dphitcontentsmask && !(forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 221                 forent.dphitcontentsmask |= DPCONTENTS_SOLID;
 222
 223         // if starting in warpzone, first transform
 224         wz = WarpZone_Find(org + mi, org + ma);
 225         if(wz)
 226         {
 227                 if(zone && wz != zone)
 228                 {
 229                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 230                         sol = 1;
 231                         trace_fraction = 0;
 232                         trace_endpos = org;
 233                         goto fail;
 234                 }
 235                 WarpZone_Trace_AddTransform(wz);
 236                 org = WarpZone_TransformOrigin(wz, org);
 237                 end = WarpZone_TransformOrigin(wz, end);
 238         }
 239         WarpZone_MakeAllSolid();
 240         sol = -1;
 241         frac = 0;
 242         i = 16;
 243         for(;;)
 244         {
 245                 if(--i < 1)
 246                 {
 247                         dprint("Too many warpzones in sequence, aborting trace.\n");
 248                         trace_ent = world;
 249                         break;
 250                 }
 251                 tracebox(org, mi, ma, end, nomonsters_adjusted, forent);
 252                 if(cb)
 253                         cb(org, trace_endpos, end);
 254                 if(sol < 0)
 255                         sol = trace_startsolid;
 256
 257                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 258                 if(trace_fraction >= 1)
 259                         break;
 260                 if(trace_ent.classname != "trigger_warpzone")
 261                 {
 262                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 263                         {
 264                                 // continue the trace, ignoring this hit (we only care for warpzones)
 265                                 org = trace_endpos + normalize(end - org);
 266                                 continue;
 267                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 268                                 // otherwise, players could block entrances that way
 269                         }
 270                         break;
 271                 }
 272                 if(trace_ent == wz)
 273                 {
 274                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
 275                         trace_ent = world;
 276                         break;
 277                 }
 278                 wz = trace_ent;
 279                 if(zone && wz != zone)
 280                         break;
 281                 WarpZone_Trace_AddTransform(wz);
 282                 // we hit a warpzone... so, let's perform the trace after the warp again
 283                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 284                 end = WarpZone_TransformOrigin(wz, end);
 285         }
 286         WarpZone_MakeAllOther();
 287 :fail
 288         if(contentshack)
 289                 forent.dphitcontentsmask &~= DPCONTENTS_SOLID;
 290         trace_startsolid = sol;
 291         v_forward = vf;
 292         v_right = vr;
 293         v_up = vu;
 294 }
 295
 296 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 297 {
 298         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, world, WarpZone_trace_callback_t_null);
 299 }
 300
 301 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 302 {
 303         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 304 }
 305
 306 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 307 {
 308         float g, dt, i;
 309         vector vf, vr, vu, v0, o0;
 310         entity wz;
 311
 312         o0 = e.origin;
 313         v0 = e.velocity;
 314
 315         WarpZone_Trace_InitTransform();
 316         WarpZone_tracetoss_time = 0;
 317         if(!warpzone_warpzones_exist)
 318         {
 319                 tracetoss(e, forent);
 320                 if(cb)
 321                         cb(e.origin, trace_endpos, trace_endpos);
 322                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 323                 WarpZone_tracetoss_time += dt;
 324                 e.velocity_z -= dt * g;
 325                 WarpZone_tracetoss_velocity = e.velocity;
 326                 e.velocity = v0;
 327                 return;
 328         }
 329
 330         vf = v_forward;
 331         vr = v_right;
 332         vu = v_up;
 333
 334         // if starting in warpzone, first transform
 335         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 336         if(wz)
 337         {
 338                 if(zone && wz != zone)
 339                 {
 340                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 341
 342                         WarpZone_tracetoss_time = 0;
 343                         trace_endpos = o0;
 344                         goto fail;
 345                 }
 346                 WarpZone_Trace_AddTransform(wz);
 347                 setorigin(e, WarpZone_TransformOrigin(wz, e.origin));
 348                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 349         }
 350         WarpZone_MakeAllSolid();
 351         g = cvar("sv_gravity") * e.gravity;
 352         i = 16;
 353         for(;;)
 354         {
 355                 if(--i < 1)
 356                 {
 357                         dprint("Too many warpzones in sequence, aborting trace.\n");
 358                         trace_ent = world;
 359                         break;
 360                 }
 361                 tracetoss(e, forent);
 362                 if(cb)
 363                         cb(e.origin, trace_endpos, trace_endpos);
 364                 e.origin = trace_endpos;
 365                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 366                 WarpZone_tracetoss_time += dt;
 367                 e.velocity_z -= dt * g;
 368                 if(trace_fraction >= 1)
 369                         break;
 370                 if(trace_ent.classname != "trigger_warpzone")
 371                         break;
 372                 if(trace_ent == wz)
 373                 {
 374                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
 375                         trace_ent = world;
 376                         break;
 377                 }
 378                 wz = trace_ent;
 379                 if(zone && wz != zone)
 380                         break;
 381                 WarpZone_Trace_AddTransform(wz);
 382                 // we hit a warpzone... so, let's perform the trace after the warp again
 383                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 384                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 385         }
 386         WarpZone_MakeAllOther();
 387 :fail
 388         WarpZone_tracetoss_velocity = e.velocity;
 389         v_forward = vf;
 390         v_right = vr;
 391         v_up = vu;
 392         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 393         e.velocity = v0;
 394         e.origin = o0;
 395 }
 396
 397 void WarpZone_TraceToss(entity e, entity forent)
 398 {
 399         WarpZone_TraceToss_ThroughZone(e, forent, world, WarpZone_trace_callback_t_null);
 400 }
 401
 402 entity WarpZone_TrailParticles_trace_callback_own;
 403 float WarpZone_TrailParticles_trace_callback_eff;
 404 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 405 {
 406         trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 407 }
 408
 409 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 410 {
 411         WarpZone_TrailParticles_trace_callback_own = own;
 412         WarpZone_TrailParticles_trace_callback_eff = eff;
 413         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_trace_callback);
 414 }
 415
 416 float WarpZone_PlaneDist(entity wz, vector v)
 417 {
 418         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 419 }
 420
 421 float WarpZone_TargetPlaneDist(entity wz, vector v)
 422 {
 423         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 424 }
 425
 426 vector WarpZone_TransformOrigin(entity wz, vector v)
 427 {
 428         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 429 }
 430
 431 vector WarpZone_TransformVelocity(entity wz, vector v)
 432 {
 433         return AnglesTransform_Apply(wz.warpzone_transform, v);
 434 }
 435
 436 vector WarpZone_TransformAngles(entity wz, vector v)
 437 {
 438         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 439 }
 440
 441 vector WarpZone_TransformVAngles(entity wz, vector ang)
 442 {
 443 #ifdef KEEP_ROLL
 444         float roll;
 445         roll = ang_z;
 446         ang_z = 0;
 447 #endif
 448
 449         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 450
 451 #ifdef KEEP_ROLL
 452         ang = AnglesTransform_Normalize(ang, TRUE);
 453         ang = AnglesTransform_CancelRoll(ang);
 454         ang_z = roll;
 455 #else
 456         ang = AnglesTransform_Normalize(ang, FALSE);
 457 #endif
 458
 459         return ang;
 460 }
 461
 462 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 463 {
 464         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 465 }
 466
 467 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 468 {
 469         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 470 }
 471
 472 vector WarpZone_UnTransformAngles(entity wz, vector v)
 473 {
 474         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 475 }
 476
 477 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 478 {
 479         float roll;
 480
 481         roll = ang_z;
 482         ang_z = 0;
 483
 484         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 485         ang = AnglesTransform_Normalize(ang, TRUE);
 486         ang = AnglesTransform_CancelRoll(ang);
 487
 488         ang_z = roll;
 489         return ang;
 490 }
 491
 492 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 493 {
 494         vector nearest;
 495         nearest_x = bound(mi_x, org_x, ma_x);
 496         nearest_y = bound(mi_y, org_y, ma_y);
 497         nearest_z = bound(mi_z, org_z, ma_z);
 498         return nearest;
 499 }
 500
 501 .float WarpZone_findradius_hit;
 502 .entity WarpZone_findradius_next;
 503 void WarpZone_FindRadius_Recurse(vector org, float rad,        vector org0,               vector transform, vector shift, float needlineofsight)
 504 //                               blast origin of current search   original blast origin   how to untransform (victim to blast system)
 505 {
 506         vector org_new;
 507         vector org0_new;
 508         vector shift_new, transform_new;
 509         vector p;
 510         entity e, e0;
 511         entity wz;
 512         if(rad <= 0)
 513                 return;
 514         e0 = findradius(org, rad);
 515         wz = world;
 516
 517         for(e = e0; e; e = e.chain)
 518         {
 519                 p = WarpZoneLib_NearestPointOnBox(e.origin + e.mins, e.origin + e.maxs, org0);
 520                 if(needlineofsight)
 521                 {
 522                         traceline(org, p, MOVE_NOMONSTERS, e);
 523                         if(trace_fraction < 1)
 524                                 continue;
 525                 }
 526                 if(!e.WarpZone_findradius_hit || vlen(e.WarpZone_findradius_dist) > vlen(org0 - p))
 527                 {
 528                         e.WarpZone_findradius_nearest = p;
 529                         e.WarpZone_findradius_dist = org0 - p;
 530                         e.WarpZone_findradius_findorigin = org;
 531                         e.WarpZone_findradius_findradius = rad;
 532                         if(e.classname == "warpzone_refsys")
 533                         {
 534                                 // ignore, especially: do not overwrite the refsys parameters
 535                         }
 536                         else if(e.classname == "trigger_warpzone")
 537                         {
 538                                 e.WarpZone_findradius_next = wz;
 539                                 wz = e;
 540                                 e.WarpZone_findradius_hit = 1;
 541                                 e.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 542                                 e.enemy.WarpZone_findradius_hit = 1;
 543                         }
 544                         else
 545                         {
 546                                 e.warpzone_transform = transform;
 547                                 e.warpzone_shift = shift;
 548                                 e.WarpZone_findradius_hit = 1;
 549                         }
 550                 }
 551         }
 552         for(e = wz; e; e = e.WarpZone_findradius_next)
 553         {
 554                 org0_new = WarpZone_TransformOrigin(e, org);
 555                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 556                 org_new = trace_endpos;
 557
 558                 transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 559                 shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 560                 WarpZone_FindRadius_Recurse(
 561                         org_new,
 562                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 563                         org0_new,
 564                         transform_new, shift_new,
 565                         needlineofsight);
 566                 e.WarpZone_findradius_hit = 0;
 567                 e.enemy.WarpZone_findradius_hit = 0;
 568         }
 569 }
 570 entity WarpZone_FindRadius(vector org, float rad, float needlineofsight)
 571 {
 572         entity e0, e;
 573         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 574         e0 = findchainfloat(WarpZone_findradius_hit, 1);
 575         for(e = e0; e; e = e.chain)
 576                 e.WarpZone_findradius_hit = 0;
 577         return e0;
 578 }
 579
 580 .entity WarpZone_refsys;
 581 void WarpZone_RefSys_GC()
 582 {
 583         // garbage collect unused reference systems
 584         self.nextthink = time + 1;
 585         if(self.owner.WarpZone_refsys != self)
 586                 remove(self);
 587 }
 588 void WarpZone_RefSys_Add(entity me, entity wz)
 589 {
 590         if(me.WarpZone_refsys.owner != me)
 591         {
 592                 me.WarpZone_refsys = spawn();
 593                 me.WarpZone_refsys.classname = "warpzone_refsys";
 594                 me.WarpZone_refsys.owner = me;
 595                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
 596                 me.WarpZone_refsys.nextthink = time + 1;
 597                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 598         }
 599         if(wz)
 600                 WarpZone_Accumulator_Add(me.WarpZone_refsys, wz);
 601 }
 602 .vector WarpZone_refsys_incremental_shift;
 603 .vector WarpZone_refsys_incremental_transform;
 604 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 605 {
 606         vector t, s;
 607         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 608         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 609                 return;
 610         if(me.WarpZone_refsys.owner != me)
 611         {
 612                 me.WarpZone_refsys = spawn();
 613                 me.WarpZone_refsys.classname = "warpzone_refsys";
 614                 me.WarpZone_refsys.owner = me;
 615                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
 616                 me.WarpZone_refsys.nextthink = time + 1;
 617                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 618         }
 619         t = AnglesTransform_Invert(me.WarpZone_refsys_incremental_transform);
 620         s = AnglesTransform_PrePostShift_GetPostShift(me.WarpZone_refsys_incremental_shift, t, '0 0 0');
 621         WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 622         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref);
 623         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 624         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 625 }
 626 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 627 {
 628         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 629         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 630 }
 631 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 632 {
 633         if(from.WarpZone_refsys)
 634                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 635         if(to.WarpZone_refsys)
 636                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 637         return org;
 638 }
 639 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 640 {
 641         if(from.WarpZone_refsys)
 642                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 643         if(to.WarpZone_refsys)
 644                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 645         return vel;
 646 }
 647 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 648 {
 649         if(from.WarpZone_refsys)
 650                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 651         if(to.WarpZone_refsys)
 652                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 653         return ang;
 654 }
 655 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 656 {
 657         if(from.WarpZone_refsys)
 658                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 659         if(to.WarpZone_refsys)
 660                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 661         return ang;
 662 }
 663 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 664 {
 665         entity e;
 666         e = spawn();
 667         if(me.WarpZone_refsys)
 668         {
 669                 e.WarpZone_refsys = spawn();
 670                 e.WarpZone_refsys.classname = "warpzone_refsys";
 671                 e.WarpZone_refsys.owner = e;
 672                 e.WarpZone_refsys.think = WarpZone_RefSys_GC;
 673                 e.WarpZone_refsys.nextthink = time + 1;
 674                 e.WarpZone_refsys.warpzone_shift = me.WarpZone_refsys.warpzone_shift;
 675                 e.WarpZone_refsys.warpzone_transform = me.WarpZone_refsys.warpzone_transform;
 676         }
 677         return e;
 678 }