qcsrc/warpzonelib/server.qc

   1 #include "server.qh"
   2
   3 #include "common.qh"
   4 #if defined(CSQC)
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7         #include "../common/constants.qh"
   8         #include "../common/triggers/subs.qh"
   9         #include "../common/util.qh"
  10         #include "../dpdefs/dpextensions.qh"
  11         #include "../dpdefs/progsdefs.qh"
  12         #include "../server/command/common.qh"
  13         #include "../server/constants.qh"
  14         #include "../server/defs.qh"
  15 #endif
  16
  17 #ifdef WARPZONELIB_KEEPDEBUG
  18 #define WARPZONELIB_REMOVEHACK
  19 #endif
  20
  21 // for think function
  22 .vector warpzone_save_origin;
  23 .vector warpzone_save_angles;
  24 .vector warpzone_save_eorigin;
  25 .vector warpzone_save_eangles;
  26
  27 // for all entities
  28 .vector warpzone_oldorigin, warpzone_oldvelocity, warpzone_oldangles;
  29 .float warpzone_teleport_time;
  30 .float warpzone_teleport_finishtime;
  31 .entity warpzone_teleport_zone;
  32
  33 void WarpZone_StoreProjectileData(entity e)
  34 {
  35         e.warpzone_oldorigin = e.origin;
  36         e.warpzone_oldvelocity = e.velocity;
  37         e.warpzone_oldangles = e.angles;
  38 }
  39
  40 void WarpZone_TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity)
  41 {
  42         setorigin (player, to); // NOTE: this also aborts the move, when this is called by touch
  43         player.oldorigin = to; // for DP's unsticking
  44         player.angles = to_angles;
  45         player.fixangle = true;
  46         player.velocity = to_velocity;
  47
  48         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
  49
  50         if(IS_PLAYER(player))
  51                 BITCLR_ASSIGN(player.flags, FL_ONGROUND);
  52
  53         WarpZone_PostTeleportPlayer_Callback(player);
  54 }
  55
  56 bool WarpZone_Teleported_Send(entity to, int sf)
  57 {SELFPARAM();
  58         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE_TELEPORTED);
  59         WriteCoord(MSG_ENTITY, self.angles.x);
  60         WriteCoord(MSG_ENTITY, self.angles.y);
  61         WriteCoord(MSG_ENTITY, self.angles.z);
  62         return true;
  63 }
  64
  65 float WarpZone_Teleport(entity wz, entity player, float f0, float f1)
  66 {
  67         vector o0, a0, v0, o1, a1, v1, o10;
  68
  69         o0 = player.origin + player.view_ofs;
  70         v0 = player.velocity;
  71         a0 = player.angles;
  72
  73         o10 = o1 = WarpZone_TransformOrigin(wz, o0);
  74         v1 = WarpZone_TransformVelocity(wz, v0);
  75         if (!IS_NOT_A_CLIENT(player))
  76                 a1 = WarpZone_TransformVAngles(wz, player.v_angle);
  77         else
  78                 a1 = WarpZone_TransformAngles(wz, a0);
  79
  80         if(f0 != 0 || f1 != 0)
  81         {
  82                 // retry last move but behind the warpzone!
  83                 // we must first go back as far as we can, then forward again, to not cause double touch events!
  84
  85                 tracebox(o1 - player.view_ofs + v1 * frametime * f1, player.mins, player.maxs, o1 - player.view_ofs + v1 * frametime * f0, MOVE_WORLDONLY, player);
  86                 {
  87                         entity own;
  88                         own = player.owner;
  89                         player.owner = world;
  90                         tracebox(trace_endpos, player.mins, player.maxs, o1 - player.view_ofs + v1 * frametime * f1, MOVE_NORMAL, player); // this should get us through the warpzone
  91                         player.owner = own;
  92                 }
  93                 o1 = trace_endpos + player.view_ofs;
  94
  95                 float d, dv, md;
  96                 md = max(vlen(player.mins), vlen(player.maxs));
  97                 d = WarpZone_TargetPlaneDist(wz, o1);
  98                 dv = WarpZone_TargetPlaneDist(wz, v1);
  99                 if(d < 0)
 100                         o1 = o1 - v1 * (d / dv);
 101         }
 102
 103         // put him out of solid
 104         tracebox(o1 - player.view_ofs, player.mins, player.maxs, o1 - player.view_ofs, MOVE_NOMONSTERS, player);
 105         if(trace_startsolid)
 106         {
 107                 setorigin(player, o1 - player.view_ofs);
 108                 if(WarpZoneLib_MoveOutOfSolid(player))
 109                 {
 110                         o1 = player.origin + player.view_ofs;
 111                         setorigin(player, o0 - player.view_ofs);
 112                 }
 113                 else
 114                 {
 115                         LOG_INFO("would have to put player in solid, won't do that\n");
 116                         setorigin(player, o0 - player.view_ofs);
 117                         return 0;
 118                 }
 119         }
 120
 121         // do the teleport
 122         WarpZone_RefSys_Add(player, wz);
 123         WarpZone_TeleportPlayer(wz, player, o1 - player.view_ofs, a1, v1);
 124         WarpZone_StoreProjectileData(player);
 125         player.warpzone_teleport_time = time;
 126         player.warpzone_teleport_finishtime = time;
 127         player.warpzone_teleport_zone = wz;
 128
 129         // prevent further teleports back
 130         float dt = (o1 - o10) * v1 * (1 / (v1 * v1));
 131         if(dt < sys_frametime)
 132                 player.warpzone_teleport_finishtime += sys_frametime - dt;
 133
 134 #ifndef WARPZONE_USE_FIXANGLE
 135         if(IS_VEHICLE(player) && player.owner)
 136                 player = player.owner; // hax
 137         if(IS_PLAYER(player))
 138         {
 139                 // instead of fixangle, send the transform to the client for smoother operation
 140                 player.fixangle = false;
 141
 142                 entity ts = spawn();
 143                 setmodel(ts, MDL_Null);
 144                 ts.SendEntity = WarpZone_Teleported_Send;
 145                 ts.SendFlags = 0xFFFFFF;
 146                 ts.drawonlytoclient = player;
 147                 ts.think = SUB_Remove;
 148                 ts.nextthink = time + 1;
 149                 ts.owner = player;
 150                 ts.enemy = wz;
 151                 ts.effects = EF_NODEPTHTEST;
 152                 ts.classname = "warpzone_teleported";
 153                 ts.angles = wz.warpzone_transform;
 154         }
 155 #endif
 156
 157         return 1;
 158 }
 159
 160 void WarpZone_Touch (void)
 161 {SELFPARAM();
 162         if(other.classname == "trigger_warpzone")
 163                 return;
 164
 165         if(time <= other.warpzone_teleport_finishtime) // already teleported this frame
 166                 return;
 167
 168         // FIXME needs a better check to know what is safe to teleport and what not
 169         if(other.movetype == MOVETYPE_NONE || other.movetype == MOVETYPE_FOLLOW || other.tag_entity)
 170                 return;
 171
 172         if(WarpZoneLib_ExactTrigger_Touch())
 173                 return;
 174
 175         if(WarpZone_PlaneDist(self, other.origin + other.view_ofs) >= 0) // wrong side of the trigger_warpzone (don't teleport yet)
 176                 return;
 177
 178         float f;
 179         // number of frames we need to go back:
 180         //   dist = 16*sqrt(2) qu
 181         //   dist ~ 24 qu
 182         //   24 qu = v*t
 183         //   24 qu = v*frametime*n
 184         //       n = 24 qu/(v*frametime)
 185         // for clients go only one frame though, may be too irritating otherwise
 186         // but max 0.25 sec = 0.25/frametime frames
 187         //       24/(0.25/frametime)
 188         //       96*frametime
 189         float d;
 190         d = 24 + max(vlen(other.mins), vlen(other.maxs));
 191         if(IS_NOT_A_CLIENT(other))
 192                 f = -d / bound(frametime * d * 1, frametime * vlen(other.velocity), d);
 193         else
 194                 f = -1;
 195         if(WarpZone_Teleport(self, other, f, 0))
 196         {
 197                 string save1, save2;
 198                 activator = other;
 199
 200                 save1 = self.target; self.target = string_null;
 201                 save2 = self.target3; self.target3 = string_null;
 202                 SUB_UseTargets();
 203                 if (!self.target) self.target = save1;
 204                 if (!self.target3) self.target3 = save2;
 205
 206                 setself(self.enemy);
 207                 save1 = self.target; self.target = string_null;
 208                 save2 = self.target2; self.target2 = string_null;
 209                 SUB_UseTargets();
 210                 if (!self.target) self.target = save1;
 211                 if (!self.target2) self.target2 = save2;
 212                 setself(this);
 213         }
 214         else
 215         {
 216                 LOG_TRACE("WARPZONE FAIL AHAHAHAHAH))\n");
 217         }
 218 }
 219
 220 bool WarpZone_Send(entity to, int sendflags)
 221 {SELFPARAM();
 222         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE);
 223
 224         // we must send this flag for clientside to match properly too
 225         int f = 0;
 226         if(self.warpzone_isboxy)
 227                 BITSET_ASSIGN(f, 1);
 228         if(self.warpzone_fadestart)
 229                 BITSET_ASSIGN(f, 2);
 230         if(self.origin != '0 0 0')
 231                 BITSET_ASSIGN(f, 4);
 232         WriteByte(MSG_ENTITY, f);
 233
 234         // we need THESE to render the warpzone (and cull properly)...
 235         if(f & 4)
 236         {
 237                 WriteCoord(MSG_ENTITY, self.origin.x);
 238                 WriteCoord(MSG_ENTITY, self.origin.y);
 239                 WriteCoord(MSG_ENTITY, self.origin.z);
 240         }
 241
 242         WriteShort(MSG_ENTITY, self.modelindex);
 243         WriteCoord(MSG_ENTITY, self.mins.x);
 244         WriteCoord(MSG_ENTITY, self.mins.y);
 245         WriteCoord(MSG_ENTITY, self.mins.z);
 246         WriteCoord(MSG_ENTITY, self.maxs.x);
 247         WriteCoord(MSG_ENTITY, self.maxs.y);
 248         WriteCoord(MSG_ENTITY, self.maxs.z);
 249         WriteByte(MSG_ENTITY, bound(1, self.scale * 16, 255));
 250
 251         // we need THESE to calculate the proper transform
 252         WriteCoord(MSG_ENTITY, self.warpzone_origin.x);
 253         WriteCoord(MSG_ENTITY, self.warpzone_origin.y);
 254         WriteCoord(MSG_ENTITY, self.warpzone_origin.z);
 255         WriteCoord(MSG_ENTITY, self.warpzone_angles.x);
 256         WriteCoord(MSG_ENTITY, self.warpzone_angles.y);
 257         WriteCoord(MSG_ENTITY, self.warpzone_angles.z);
 258         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin.x);
 259         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin.y);
 260         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin.z);
 261         WriteCoord(MSG_ENTITY, self.warpzone_targetangles.x);
 262         WriteCoord(MSG_ENTITY, self.warpzone_targetangles.y);
 263         WriteCoord(MSG_ENTITY, self.warpzone_targetangles.z);
 264
 265         if(f & 2)
 266         {
 267                 WriteShort(MSG_ENTITY, self.warpzone_fadestart);
 268                 WriteShort(MSG_ENTITY, self.warpzone_fadeend);
 269         }
 270
 271         return true;
 272 }
 273
 274 bool WarpZone_Camera_Send(entity to, int sendflags)
 275 {SELFPARAM();
 276         int f = 0;
 277         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE_CAMERA);
 278
 279         if(self.warpzone_fadestart)
 280                 BITSET_ASSIGN(f, 2);
 281         if(self.origin != '0 0 0')
 282                 BITSET_ASSIGN(f, 4);
 283         WriteByte(MSG_ENTITY, f);
 284
 285         // we need THESE to render the warpzone (and cull properly)...
 286         if(f & 4)
 287         {
 288                 WriteCoord(MSG_ENTITY, self.origin.x);
 289                 WriteCoord(MSG_ENTITY, self.origin.y);
 290                 WriteCoord(MSG_ENTITY, self.origin.z);
 291         }
 292
 293         WriteShort(MSG_ENTITY, self.modelindex);
 294         WriteCoord(MSG_ENTITY, self.mins.x);
 295         WriteCoord(MSG_ENTITY, self.mins.y);
 296         WriteCoord(MSG_ENTITY, self.mins.z);
 297         WriteCoord(MSG_ENTITY, self.maxs.x);
 298         WriteCoord(MSG_ENTITY, self.maxs.y);
 299         WriteCoord(MSG_ENTITY, self.maxs.z);
 300         WriteByte(MSG_ENTITY, bound(1, self.scale * 16, 255));
 301
 302         // we need THESE to calculate the proper transform
 303         WriteCoord(MSG_ENTITY, self.enemy.origin.x);
 304         WriteCoord(MSG_ENTITY, self.enemy.origin.y);
 305         WriteCoord(MSG_ENTITY, self.enemy.origin.z);
 306         WriteCoord(MSG_ENTITY, self.enemy.angles.x);
 307         WriteCoord(MSG_ENTITY, self.enemy.angles.y);
 308         WriteCoord(MSG_ENTITY, self.enemy.angles.z);
 309
 310         if(f & 2)
 311         {
 312                 WriteShort(MSG_ENTITY, self.warpzone_fadestart);
 313                 WriteShort(MSG_ENTITY, self.warpzone_fadeend);
 314         }
 315
 316         return true;
 317 }
 318
 319 #ifdef WARPZONELIB_KEEPDEBUG
 320 float WarpZone_CheckProjectileImpact(entity player)
 321 {SELFPARAM();
 322         vector o0, v0;
 323
 324         o0 = player.origin + player.view_ofs;
 325         v0 = player.velocity;
 326
 327         // if we teleported shortly before, abort
 328         if(time <= player.warpzone_teleport_finishtime + 0.1)
 329                 return 0;
 330
 331         // if player hit a warpzone, abort
 332         entity wz;
 333         wz = WarpZone_Find(o0 + player.mins, o0 + player.maxs);
 334         if(!wz)
 335                 return 0;
 336
 337 #ifdef WARPZONELIB_REMOVEHACK
 338         LOG_INFO("impactfilter found something - and it no longer gets handled correctly - please tell divVerent whether anything behaves broken now\n");
 339 #else
 340         LOG_INFO("impactfilter found something - and it even gets handled correctly - please tell divVerent that this code apparently gets triggered again\n");
 341 #endif
 342         LOG_INFO("Entity type: ", player.classname, "\n");
 343         LOG_INFO("Origin: ", vtos(player.origin), "\n");
 344         LOG_INFO("Velocity: ", vtos(player.velocity), "\n");
 345
 346 #ifdef WARPZONELIB_REMOVEHACK
 347         return 0;
 348 #else
 349         // retry previous move
 350         setorigin(player, player.warpzone_oldorigin);
 351         player.velocity = player.warpzone_oldvelocity;
 352         if(WarpZone_Teleport(wz, player, 0, 1))
 353         {
 354                 entity oldself;
 355                 string save1, save2;
 356
 357                 oldself = self;
 358                 self = wz;
 359                 other = player;
 360                 activator = player;
 361
 362                 save1 = self.target; self.target = string_null;
 363                 save2 = self.target3; self.target3 = string_null;
 364                 SUB_UseTargets();
 365                 if (!self.target) self.target = save1;
 366                 if (!self.target3) self.target3 = save2;
 367
 368                 self = self.enemy;
 369                 save1 = self.target; self.target = string_null;
 370                 save2 = self.target2; self.target2 = string_null;
 371                 SUB_UseTargets();
 372                 if (!self.target) self.target = save1;
 373                 if (!self.target2) self.target2 = save2;
 374                 self = oldself;
 375         }
 376         else
 377         {
 378                 setorigin(player, o0 - player.view_ofs);
 379                 player.velocity = v0;
 380         }
 381
 382         return +1;
 383 #endif
 384 }
 385 #endif
 386
 387 float WarpZone_Projectile_Touch()
 388 {SELFPARAM();
 389         if(other.classname == "trigger_warpzone")
 390                 return true;
 391
 392         // no further impacts if we teleported this frame!
 393         // this is because even if we did teleport, the engine still may raise
 394         // touch events for the previous location
 395         // engine now aborts moves on teleport, so this SHOULD not happen any more
 396         // but if this is called from TouchAreaGrid of the projectile moving,
 397         // then this won't do
 398         if(time == self.warpzone_teleport_time)
 399                 return true;
 400
 401 #ifdef WARPZONELIB_KEEPDEBUG
 402         // this SEEMS to not happen at the moment, but if it did, it would be more reliable
 403         {
 404                 float save_dpstartcontents;
 405                 float save_dphitcontents;
 406                 float save_dphitq3surfaceflags;
 407                 string save_dphittexturename;
 408                 float save_allsolid;
 409                 float save_startsolid;
 410                 float save_fraction;
 411                 vector save_endpos;
 412                 vector save_plane_normal;
 413                 float save_plane_dist;
 414                 entity save_ent;
 415                 float save_inopen;
 416                 float save_inwater;
 417                 save_dpstartcontents = trace_dpstartcontents;
 418                 save_dphitcontents = trace_dphitcontents;
 419                 save_dphitq3surfaceflags = trace_dphitq3surfaceflags;
 420                 save_dphittexturename = trace_dphittexturename;
 421                 save_allsolid = trace_allsolid;
 422                 save_startsolid = trace_startsolid;
 423                 save_fraction = trace_fraction;
 424                 save_endpos = trace_endpos;
 425                 save_plane_normal = trace_plane_normal;
 426                 save_plane_dist = trace_plane_dist;
 427                 save_ent = trace_ent;
 428                 save_inopen = trace_inopen;
 429                 save_inwater = trace_inwater;
 430                 float f;
 431                 if((f = WarpZone_CheckProjectileImpact(self)) != 0)
 432                         return (f > 0);
 433                 trace_dpstartcontents = save_dpstartcontents;
 434                 trace_dphitcontents = save_dphitcontents;
 435                 trace_dphitq3surfaceflags = save_dphitq3surfaceflags;
 436                 trace_dphittexturename = save_dphittexturename;
 437                 trace_allsolid = save_allsolid;
 438                 trace_startsolid = save_startsolid;
 439                 trace_fraction = save_fraction;
 440                 trace_endpos = save_endpos;
 441                 trace_plane_normal = save_plane_normal;
 442                 trace_plane_dist = save_plane_dist;
 443                 trace_ent = save_ent;
 444                 trace_inopen = save_inopen;
 445                 trace_inwater = save_inwater;
 446         }
 447 #endif
 448
 449         if(WarpZone_Projectile_Touch_ImpactFilter_Callback())
 450                 return true;
 451
 452         return false;
 453 }
 454
 455 void WarpZone_InitStep_FindOriginTarget()
 456 {SELFPARAM();
 457         if(self.killtarget != "")
 458         {
 459                 self.aiment = find(world, targetname, self.killtarget);
 460                 if(self.aiment == world)
 461                 {
 462                         error("Warp zone with nonexisting killtarget");
 463                         return;
 464                 }
 465                 self.killtarget = string_null;
 466         }
 467 }
 468
 469 void WarpZonePosition_InitStep_FindTarget()
 470 {SELFPARAM();
 471         if(self.target == "")
 472         {
 473                 error("Warp zone position with no target");
 474                 return;
 475         }
 476         self.enemy = find(world, targetname, self.target);
 477         if(self.enemy == world)
 478         {
 479                 error("Warp zone position with nonexisting target");
 480                 return;
 481         }
 482         if(self.enemy.aiment)
 483         {
 484                 // already is positioned
 485                 error("Warp zone position targeting already oriented warpzone");
 486                 return;
 487         }
 488         self.enemy.aiment = self;
 489 }
 490
 491 void WarpZoneCamera_Think(void)
 492 {SELFPARAM();
 493         if(self.warpzone_save_origin != self.origin
 494         || self.warpzone_save_angles != self.angles
 495         || self.warpzone_save_eorigin != self.enemy.origin
 496         || self.warpzone_save_eangles != self.enemy.angles)
 497         {
 498                 WarpZone_Camera_SetUp(self, self.enemy.origin, self.enemy.angles);
 499                 self.warpzone_save_origin = self.origin;
 500                 self.warpzone_save_angles = self.angles;
 501                 self.warpzone_save_eorigin = self.enemy.origin;
 502                 self.warpzone_save_eangles = self.enemy.angles;
 503         }
 504         self.nextthink = time;
 505 }
 506
 507 void WarpZoneCamera_InitStep_FindTarget()
 508 {SELFPARAM();
 509         entity e;
 510         float i;
 511         if(self.target == "")
 512         {
 513                 error("Camera with no target");
 514                 return;
 515         }
 516         self.enemy = world;
 517         for(e = world, i = 0; (e = find(e, targetname, self.target)); )
 518                 if(random() * ++i < 1)
 519                         self.enemy = e;
 520         if(self.enemy == world)
 521         {
 522                 error("Camera with nonexisting target");
 523                 return;
 524         }
 525         warpzone_cameras_exist = 1;
 526         WarpZone_Camera_SetUp(self, self.enemy.origin, self.enemy.angles);
 527         self.SendFlags = 0xFFFFFF;
 528         if(self.spawnflags & 1)
 529         {
 530                 self.think = WarpZoneCamera_Think;
 531                 self.nextthink = time;
 532         }
 533         else
 534                 self.nextthink = 0;
 535 }
 536
 537 void WarpZone_InitStep_UpdateTransform()
 538 {SELFPARAM();
 539         vector org, ang, norm, point;
 540         float area;
 541         vector tri, a, b, c, n;
 542         float i_s, i_t, n_t;
 543         string tex;
 544
 545         org = self.origin;
 546         if(org == '0 0 0')
 547                 org = 0.5 * (self.mins + self.maxs);
 548
 549         norm = point = '0 0 0';
 550         area = 0;
 551         for(i_s = 0; ; ++i_s)
 552         {
 553                 tex = getsurfacetexture(self, i_s);
 554                 if (!tex)
 555                         break; // this is beyond the last one
 556                 if(tex == "textures/common/trigger" || tex == "trigger")
 557                         continue;
 558                 n_t = getsurfacenumtriangles(self, i_s);
 559                 for(i_t = 0; i_t < n_t; ++i_t)
 560                 {
 561                         tri = getsurfacetriangle(self, i_s, i_t);
 562                         a = getsurfacepoint(self, i_s, tri.x);
 563                         b = getsurfacepoint(self, i_s, tri.y);
 564                         c = getsurfacepoint(self, i_s, tri.z);
 565                         n = cross(c - a, b - a);
 566                         area = area + vlen(n);
 567                         norm = norm + n;
 568                         point = point + vlen(n) * (a + b + c);
 569                 }
 570         }
 571         if(area > 0)
 572         {
 573                 norm = norm * (1 / area);
 574                 point = point * (1 / (3 * area));
 575                 if(vlen(norm) < 0.99)
 576                 {
 577                         LOG_INFO("trigger_warpzone near ", vtos(self.aiment.origin), " is nonplanar. BEWARE.\n");
 578                         area = 0; // no autofixing in this case
 579                 }
 580                 norm = normalize(norm);
 581         }
 582
 583         ang = '0 0 0';
 584         if(self.aiment)
 585         {
 586                 org = self.aiment.origin;
 587                 ang = self.aiment.angles;
 588                 if(area > 0)
 589                 {
 590                         org = org - ((org - point) * norm) * norm; // project to plane
 591                         makevectors(ang);
 592                         if(norm * v_forward < 0)
 593                         {
 594                                 LOG_INFO("Position target of trigger_warpzone near ", vtos(self.aiment.origin), " points into trigger_warpzone. BEWARE.\n");
 595                                 norm = -1 * norm;
 596                         }
 597                         ang = vectoangles2(norm, v_up); // keep rotation, but turn exactly against plane
 598                         ang.x = -ang.x;
 599                         if(norm * v_forward < 0.99)
 600                                 LOG_INFO("trigger_warpzone near ", vtos(self.aiment.origin), " has been turned to match plane orientation (", vtos(self.aiment.angles), " -> ", vtos(ang), "\n");
 601                         if(vlen(org - self.aiment.origin) > 0.5)
 602                                 LOG_INFO("trigger_warpzone near ", vtos(self.aiment.origin), " has been moved to match the plane (", vtos(self.aiment.origin), " -> ", vtos(org), ").\n");
 603                 }
 604         }
 605         else if(area > 0)
 606         {
 607                 org = point;
 608                 ang = vectoangles(norm);
 609                 ang.x = -ang.x;
 610         }
 611         else
 612                 error("cannot infer origin/angles for this warpzone, please use a killtarget or a trigger_warpzone_position");
 613
 614         self.warpzone_origin = org;
 615         self.warpzone_angles = ang;
 616 }
 617
 618 void WarpZone_InitStep_ClearTarget()
 619 {SELFPARAM();
 620         if(self.enemy)
 621                 self.enemy.enemy = world;
 622         self.enemy = world;
 623 }
 624
 625 entity warpzone_first; .entity warpzone_next;
 626 void WarpZone_InitStep_FindTarget()
 627 {SELFPARAM();
 628         float i;
 629         entity e, e2;
 630
 631         if(self.enemy)
 632                 return;
 633
 634         // this way only one of the two ents needs to target
 635         if(self.target != "")
 636         {
 637                 self.enemy = self; // so the if(!e.enemy) check also skips self, saves one IF
 638
 639                 e2 = world;
 640                 for(e = world, i = 0; (e = find(e, targetname, self.target)); )
 641                         if(!e.enemy)
 642                                 if(e.classname == self.classname) // possibly non-warpzones may use the same targetname!
 643                                         if(random() * ++i < 1)
 644                                                 e2 = e;
 645                 if(!e2)
 646                 {
 647                         self.enemy = world;
 648                         error("Warpzone with non-existing target");
 649                         return;
 650                 }
 651                 self.enemy = e2;
 652                 e2.enemy = self;
 653         }
 654 }
 655
 656 void WarpZone_Think();
 657 void WarpZone_InitStep_FinalizeTransform()
 658 {SELFPARAM();
 659         if(!self.enemy || self.enemy.enemy != self)
 660         {
 661                 error("Invalid warp zone detected. Killed.");
 662                 return;
 663         }
 664
 665         warpzone_warpzones_exist = 1;
 666         WarpZone_SetUp(self, self.warpzone_origin, self.warpzone_angles, self.enemy.warpzone_origin, self.enemy.warpzone_angles);
 667         self.touch = WarpZone_Touch;
 668         self.SendFlags = 0xFFFFFF;
 669         if(self.spawnflags & 1)
 670         {
 671                 self.think = WarpZone_Think;
 672                 self.nextthink = time;
 673         }
 674         else
 675                 self.nextthink = 0;
 676 }
 677
 678 float warpzone_initialized;
 679 //entity warpzone_first;
 680 entity warpzone_position_first;
 681 entity warpzone_camera_first;
 682 .entity warpzone_next;
 683 void spawnfunc_misc_warpzone_position(void)
 684 {SELFPARAM();
 685         // "target", "angles", "origin"
 686         self.warpzone_next = warpzone_position_first;
 687         warpzone_position_first = self;
 688 }
 689 void spawnfunc_trigger_warpzone_position(void)
 690 {
 691         spawnfunc_misc_warpzone_position();
 692 }
 693 void spawnfunc_trigger_warpzone(void)
 694 {SELFPARAM();
 695         // warp zone entities must have:
 696         // "killtarget" pointing to a target_position with a direction arrow
 697         //              that points AWAY from the warp zone, and that is inside
 698         //              the warp zone trigger
 699         // "target"     pointing to an identical warp zone at another place in
 700         //              the map, with another killtarget to designate its
 701         //              orientation
 702
 703         if(!self.scale)
 704                 self.scale = self.modelscale;
 705         if(!self.scale)
 706                 self.scale = 1;
 707         string m;
 708         m = self.model;
 709         WarpZoneLib_ExactTrigger_Init();
 710         if(m != "")
 711         {
 712                 precache_model(m);
 713                 _setmodel(self, m); // no precision needed
 714         }
 715         setorigin(self, self.origin);
 716         if(self.scale)
 717                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
 718         else
 719                 setsize(self, self.mins, self.maxs);
 720         self.SendEntity = WarpZone_Send;
 721         self.SendFlags = 0xFFFFFF;
 722         BITSET_ASSIGN(self.effects, EF_NODEPTHTEST);
 723         self.warpzone_next = warpzone_first;
 724         warpzone_first = self;
 725 }
 726 void spawnfunc_func_camera(void)
 727 {SELFPARAM();
 728         if(!self.scale)
 729                 self.scale = self.modelscale;
 730         if(!self.scale)
 731                 self.scale = 1;
 732         if(self.model != "")
 733         {
 734                 precache_model(self.model);
 735                 _setmodel(self, self.model); // no precision needed
 736         }
 737         setorigin(self, self.origin);
 738         if(self.scale)
 739                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
 740         else
 741                 setsize(self, self.mins, self.maxs);
 742         if(!self.solid)
 743                 self.solid = SOLID_BSP;
 744         else if(self.solid < 0)
 745                 self.solid = SOLID_NOT;
 746         self.SendEntity = WarpZone_Camera_Send;
 747         self.SendFlags = 0xFFFFFF;
 748         self.warpzone_next = warpzone_camera_first;
 749         warpzone_camera_first = self;
 750 }
 751 void WarpZones_Reconnect()
 752 {SELFPARAM();
 753         for(setself(warpzone_first); self; setself(self.warpzone_next))
 754                 WarpZone_InitStep_ClearTarget();
 755         for(setself(warpzone_first); self; setself(self.warpzone_next))
 756                 WarpZone_InitStep_FindTarget();
 757         for(setself(warpzone_camera_first); self; setself(self.warpzone_next))
 758                 WarpZoneCamera_InitStep_FindTarget();
 759         for(setself(warpzone_first); self; setself(self.warpzone_next))
 760                 WarpZone_InitStep_FinalizeTransform();
 761         setself(this);
 762 }
 763
 764 void WarpZone_Think()
 765 {SELFPARAM();
 766         if(self.warpzone_save_origin != self.origin
 767         || self.warpzone_save_angles != self.angles
 768         || self.warpzone_save_eorigin != self.enemy.origin
 769         || self.warpzone_save_eangles != self.enemy.angles)
 770         {
 771                 WarpZone_InitStep_UpdateTransform();
 772                 setself(self.enemy);
 773                 WarpZone_InitStep_UpdateTransform();
 774                 setself(this);
 775                 WarpZone_InitStep_FinalizeTransform();
 776                 setself(self.enemy);
 777                 WarpZone_InitStep_FinalizeTransform();
 778                 setself(this);
 779                 self.warpzone_save_origin = self.origin;
 780                 self.warpzone_save_angles = self.angles;
 781                 self.warpzone_save_eorigin = self.enemy.origin;
 782                 self.warpzone_save_eangles = self.enemy.angles;
 783         }
 784         self.nextthink = time;
 785 }
 786
 787 void WarpZone_StartFrame()
 788 {SELFPARAM();
 789         entity e;
 790         if(warpzone_initialized == 0)
 791         {
 792                 warpzone_initialized = 1;
 793                 for(setself(warpzone_first); self; setself(self.warpzone_next))
 794                         WarpZone_InitStep_FindOriginTarget();
 795                 for(setself(warpzone_position_first); self; setself(self.warpzone_next))
 796                         WarpZonePosition_InitStep_FindTarget();
 797                 for(setself(warpzone_first); self; setself(self.warpzone_next))
 798                         WarpZone_InitStep_UpdateTransform();
 799                 setself(this);
 800                 WarpZones_Reconnect();
 801                 WarpZone_PostInitialize_Callback();
 802         }
 803
 804         entity oldother;
 805         oldother = other;
 806         for(e = world; (e = nextent(e)); )
 807         {
 808                 if(warpzone_warpzones_exist) { WarpZone_StoreProjectileData(e); }
 809
 810                 if(IS_REAL_CLIENT(e))
 811                 {
 812                         if(e.solid == SOLID_NOT) // not spectating?
 813                         if(e.movetype == MOVETYPE_NOCLIP || e.movetype == MOVETYPE_FLY || e.movetype == MOVETYPE_FLY_WORLDONLY) // not spectating? (this is to catch observers)
 814                         {
 815                                 other = e; // player
 816
 817                                 // warpzones
 818                                 if(warpzone_warpzones_exist) {
 819                                 setself(WarpZone_Find(e.origin + e.mins, e.origin + e.maxs));
 820                                 if(self)
 821                                 if(!WarpZoneLib_ExactTrigger_Touch())
 822                                         if(WarpZone_PlaneDist(self, e.origin + e.view_ofs) <= 0)
 823                                                 WarpZone_Teleport(self, e, -1, 0); } // NOT triggering targets by this!
 824
 825                                 // teleporters
 826                                 setself(Teleport_Find(e.origin + e.mins, e.origin + e.maxs));
 827                                 if(self)
 828                                 if(!WarpZoneLib_ExactTrigger_Touch())
 829                                         Simple_TeleportPlayer(self, other); // NOT triggering targets by this!
 830                         }
 831                 }
 832
 833                 if(IS_NOT_A_CLIENT(e))
 834                 {
 835                         if(warpzone_warpzones_exist)
 836                                 for (; (e = nextent(e)); )
 837                                         WarpZone_StoreProjectileData(e);
 838                         break;
 839                 }
 840         }
 841         setself(this);
 842         other = oldother;
 843 }
 844
 845 .float warpzone_reconnecting;
 846 float visible_to_some_client(entity ent)
 847 {
 848         entity e;
 849         for(e = nextent(world); !IS_NOT_A_CLIENT(e); e = nextent(e))
 850                 if(IS_PLAYER(e) && IS_REAL_CLIENT(e))
 851                         if(checkpvs(e.origin + e.view_ofs, ent))
 852                                 return 1;
 853         return 0;
 854 }
 855 void trigger_warpzone_reconnect_use()
 856 {SELFPARAM();
 857         entity e;
 858         e = self;
 859         // NOTE: this matches for target, not targetname, but of course
 860         // targetname must be set too on the other entities
 861         for(setself(warpzone_first); self; setself(self.warpzone_next))
 862                 self.warpzone_reconnecting = ((e.target == "" || self.target == e.target) && !((e.spawnflags & 1) && (visible_to_some_client(self) || visible_to_some_client(self.enemy))));
 863         for(setself(warpzone_camera_first); self; setself(self.warpzone_next))
 864                 self.warpzone_reconnecting = ((e.target == "" || self.target == e.target) && !((e.spawnflags & 1) && visible_to_some_client(self)));
 865         for(setself(warpzone_first); self; setself(self.warpzone_next))
 866                 if(self.warpzone_reconnecting)
 867                         WarpZone_InitStep_ClearTarget();
 868         for(setself(warpzone_first); self; setself(self.warpzone_next))
 869                 if(self.warpzone_reconnecting)
 870                         WarpZone_InitStep_FindTarget();
 871         for(setself(warpzone_camera_first); self; setself(self.warpzone_next))
 872                 if(self.warpzone_reconnecting)
 873                         WarpZoneCamera_InitStep_FindTarget();
 874         for(setself(warpzone_first); self; setself(self.warpzone_next))
 875                 if(self.warpzone_reconnecting || self.enemy.warpzone_reconnecting)
 876                         WarpZone_InitStep_FinalizeTransform();
 877         setself(e);
 878 }
 879
 880 void spawnfunc_trigger_warpzone_reconnect()
 881 {SELFPARAM();
 882         self.use = trigger_warpzone_reconnect_use;
 883 }
 884
 885 void spawnfunc_target_warpzone_reconnect()
 886 {
 887         spawnfunc_trigger_warpzone_reconnect(); // both names make sense here :(
 888 }
 889
 890 void WarpZone_PlayerPhysics_FixVAngle(void)
 891 {SELFPARAM();
 892 #ifndef WARPZONE_DONT_FIX_VANGLE
 893         if(IS_REAL_CLIENT(self))
 894         if(self.v_angle.z <= 360) // if not already adjusted
 895         if(time - self.ping * 0.001 < self.warpzone_teleport_time)
 896         {
 897                 self.v_angle = WarpZone_TransformVAngles(self.warpzone_teleport_zone, self.v_angle);
 898                 self.v_angle_z += 720; // mark as adjusted
 899         }
 900 #endif
 901 }