void turret_remove(entity this)
{
	remove(this.tur_head);
	//remove(this.enemy);
	this.tur_head = world;
}

.vector glowmod;
void turret_changeteam(entity this)
{
	this.glowmod = Team_ColorRGB(this.team - 1) * 2;
	this.teamradar_color = Team_ColorRGB(this.team - 1);

	if(this.team)
		this.colormap = 1024 + (this.team - 1) * 17;

	this.tur_head.colormap = this.colormap;
	this.tur_head.glowmod = this.glowmod;

}

void turret_head_draw()
{SELFPARAM();
	self.drawmask = MASK_NORMAL;
}

void turret_draw(entity this)
{
	float dt;

	dt = time - this.move_time;
	this.move_time = time;
	if(dt <= 0)
		return;

	this.tur_head.angles += dt * this.tur_head.move_avelocity;

	if (this.health < 127)
	{
		dt = random();

		if(dt < 0.03)
			te_spark(this.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
	}

	if(this.health < 85)
	if(dt < 0.01)
		pointparticles(EFFECT_SMOKE_LARGE, (this.origin + (randomvec() * 80)), '0 0 0', 1);

	if(this.health < 32)
	if(dt < 0.015)
		pointparticles(EFFECT_SMOKE_SMALL, (this.origin + (randomvec() * 80)), '0 0 0', 1);

}

void turret_draw2d(entity this)
{
	if(this.netname == "")
		return;

	if(!autocvar_g_waypointsprite_turrets)
		return;

	if(autocvar_cl_hidewaypoints)
		return;

	float dist = vlen(this.origin - view_origin);
	float t = (entcs_GetTeam(player_localnum) + 1);

	vector o;
	string txt;

	if(autocvar_cl_vehicles_hud_tactical)
	if(dist < 10240 && t != this.team)
	{
		// TODO: Vehicle tactical hud
		o = project_3d_to_2d(this.origin + '0 0 32');
		if(o_z < 0
		|| o_x < (vid_conwidth * waypointsprite_edgeoffset_left)
		|| o_y < (vid_conheight * waypointsprite_edgeoffset_top)
		|| o_x > (vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right))
		|| o_y > (vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)))
			return; // Dont draw wp's for turrets out of view
		o_z = 0;
		if(hud != HUD_NORMAL)
		{
			if((get_turretinfo(this.m_id)).spawnflags & TUR_FLAG_MOVE)
				txt = "gfx/vehicles/turret_moving.tga";
			else
				txt = "gfx/vehicles/turret_stationary.tga";

			vector pz = drawgetimagesize(txt) * autocvar_cl_vehicles_crosshair_size;
			drawpic(o - pz * 0.5, txt, pz , '1 1 1', 0.7, DRAWFLAG_NORMAL);
		}
	}

	if(dist > this.maxdistance)
		return;

	string spriteimage = this.netname;
	float a = this.alpha * autocvar_hud_panel_fg_alpha;
	vector rgb = spritelookupcolor(this, spriteimage, this.teamradar_color);


	if(this.maxdistance > waypointsprite_normdistance)
		a *= pow(bound(0, (this.maxdistance - dist) / (this.maxdistance - waypointsprite_normdistance), 1), waypointsprite_distancealphaexponent);
	else if(this.maxdistance > 0)
		a *= pow(bound(0, (waypointsprite_fadedistance - dist) / (waypointsprite_fadedistance - waypointsprite_normdistance), 1), waypointsprite_distancealphaexponent) * (1 - waypointsprite_minalpha) + waypointsprite_minalpha;

	if(rgb == '0 0 0')
	{
		this.teamradar_color = '1 0 1';
		LOG_INFOF("WARNING: sprite of name %s has no color, using pink so you notice it\n", spriteimage);
	}

	txt = this.netname;
	if(autocvar_g_waypointsprite_spam && waypointsprite_count >= autocvar_g_waypointsprite_spam)
		txt = _("Spam");
	else
		txt = spritelookuptext(this, spriteimage);

	if(time - floor(time) > 0.5 && t == this.team)
	{
		if(this.helpme && time < this.helpme)
		{
			a *= SPRITE_HELPME_BLINK;
			txt = sprintf(_("%s under attack!"), txt);
		}
		else
			a *= spritelookupblinkvalue(this, spriteimage);
	}

	if(autocvar_g_waypointsprite_uppercase)
		txt = strtoupper(txt);

	if(a > 1)
	{
		rgb *= a;
		a = 1;
	}

	if(a <= 0)
		return;

	rgb = fixrgbexcess(rgb);

	o = project_3d_to_2d(this.origin + '0 0 64');
	if(o_z < 0
	|| o_x < (vid_conwidth * waypointsprite_edgeoffset_left)
	|| o_y < (vid_conheight * waypointsprite_edgeoffset_top)
	|| o_x > (vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right))
	|| o_y > (vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)))
		return; // Dont draw wp's for turrets out of view

	o_z = 0;

	float edgedistance_min, crosshairdistance;
		edgedistance_min = min((o_y - (vid_conheight * waypointsprite_edgeoffset_top)),
	(o_x - (vid_conwidth * waypointsprite_edgeoffset_left)),
	(vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right)) - o_x,
	(vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)) - o_y);

	float vidscale = max(vid_conwidth / vid_width, vid_conheight / vid_height);

	crosshairdistance = sqrt( pow(o_x - vid_conwidth/2, 2) + pow(o_y - vid_conheight/2, 2) );

	t = waypointsprite_scale * vidscale;
	a *= waypointsprite_alpha;

	{
		a = a * (1 - (1 - waypointsprite_distancefadealpha) * (bound(0, dist/waypointsprite_distancefadedistance, 1)));
		t = t * (1 - (1 - waypointsprite_distancefadescale) * (bound(0, dist/waypointsprite_distancefadedistance, 1)));
	}
	if (edgedistance_min < waypointsprite_edgefadedistance) {
		a = a * (1 - (1 - waypointsprite_edgefadealpha) * (1 - bound(0, edgedistance_min/waypointsprite_edgefadedistance, 1)));
		t = t * (1 - (1 - waypointsprite_edgefadescale) * (1 - bound(0, edgedistance_min/waypointsprite_edgefadedistance, 1)));
	}
	if(crosshairdistance < waypointsprite_crosshairfadedistance) {
		a = a * (1 - (1 - waypointsprite_crosshairfadealpha) * (1 - bound(0, crosshairdistance/waypointsprite_crosshairfadedistance, 1)));
		t = t * (1 - (1 - waypointsprite_crosshairfadescale) * (1 - bound(0, crosshairdistance/waypointsprite_crosshairfadedistance, 1)));
	}

	o = drawspritearrow(o, M_PI, rgb, a, SPRITE_ARROW_SCALE * t);
	o = drawspritetext(o, M_PI, (SPRITE_HEALTHBAR_WIDTH + 2 * SPRITE_HEALTHBAR_BORDER) * t, rgb, a, waypointsprite_fontsize * '1 1 0', txt);
	drawhealthbar(
			o,
			0,
			this.health / 255,
			'0 0 0',
			'0 0 0',
			0.5 * SPRITE_HEALTHBAR_WIDTH * t,
			0.5 * SPRITE_HEALTHBAR_HEIGHT * t,
			SPRITE_HEALTHBAR_MARGIN * t + 0.5 * waypointsprite_fontsize,
			SPRITE_HEALTHBAR_BORDER * t,
			0,
			rgb,
			a * SPRITE_HEALTHBAR_BORDERALPHA,
			rgb,
			a * SPRITE_HEALTHBAR_HEALTHALPHA,
			DRAWFLAG_NORMAL
			);
}

void turret_construct()
{SELFPARAM();
	entity tur = get_turretinfo(self.m_id);

	if(self.tur_head == world)
		self.tur_head = spawn();

	self.netname = tur.turret_name;

	setorigin(self, self.origin);
	_setmodel(self, tur.model);
	_setmodel(self.tur_head, tur.head_model);
	setsize(self, tur.mins, tur.maxs);
	setsize(self.tur_head, '0 0 0', '0 0 0');

	if(self.m_id == TUR_EWHEEL.m_id)
		setattachment(self.tur_head, self, "");
	else
		setattachment(self.tur_head, self, "tag_head");

	self.tur_head.classname			= "turret_head";
	self.tur_head.owner				= self;
	self.tur_head.move_movetype		= MOVETYPE_NOCLIP;
	self.move_movetype				= MOVETYPE_NOCLIP;
	self.tur_head.angles			= self.angles;
	self.health						= 255;
	self.solid						= SOLID_BBOX;
	self.tur_head.solid				= SOLID_NOT;
	self.movetype					= MOVETYPE_NOCLIP;
	self.tur_head.movetype			= MOVETYPE_NOCLIP;
	self.draw						= turret_draw;
	self.entremove					= turret_remove;
	self.drawmask					= MASK_NORMAL;
	self.tur_head.drawmask			= MASK_NORMAL;
	self.anim_start_time			= 0;
	self.draw2d = turret_draw2d;
	self.maxdistance = autocvar_g_waypointsprite_turrets_maxdist;
	self.teamradar_color = '1 0 0';
	self.alpha = 1;

	tur.tr_setup(tur, self);
}

entity turret_gibtoss(string _model, vector _from, vector _to, vector _cmod, float _explode);
void turret_gibboom(entity this);
void turret_gib_draw(entity this)
{
	Movetype_Physics_MatchTicrate(this, autocvar_cl_gibs_ticrate, autocvar_cl_gibs_sloppy);

	this.drawmask = MASK_NORMAL;

	if(this.cnt)
	{
		if(time >= this.nextthink)
		{
			turret_gibboom(this);
			remove(this);
		}
	}
	else
	{
		this.alpha = bound(0, this.nextthink - time, 1);
		if(this.alpha < ALPHA_MIN_VISIBLE)
			remove(this);
	}
}

void turret_gibboom(entity this)
{
	sound (this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
	pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);

	for (int j = 1; j < 5; j = j + 1)
		turret_gibtoss(strcat("models/turrets/head-gib", ftos(j), ".md3"), this.origin + '0 0 2', this.velocity + randomvec() * 700, '0 0 0', false);
}

entity turret_gibtoss(string _model, vector _from, vector _to, vector _cmod, float _explode)
{
	entity gib;

	traceline(_from, _to, MOVE_NOMONSTERS, world);
	if(trace_startsolid)
		return world;

	gib = new(turret_gib);
	setorigin(gib, _from);
	_setmodel(gib, _model);
	gib.colormod	= _cmod;
	gib.solid	   = SOLID_CORPSE;
	gib.draw		= turret_gib_draw;
	gib.cnt		 = _explode;
	setsize(gib, '-1 -1 -1', '1 1 1');
	if(_explode)
	{
		gib.nextthink = time + 0.2 * (autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15));
		gib.effects = EF_FLAME;
	}
	else
		gib.nextthink = time + autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15);

	gib.gravity		 = 1;
	gib.move_movetype   = MOVETYPE_BOUNCE;
	gib.move_origin	 = _from;
	setorigin(gib,		_from);
	gib.move_velocity   = _to;
	gib.move_avelocity  = prandomvec() * 32;
	gib.move_time	   = time;
	gib.damageforcescale = 1;

	return gib;
}

void turret_die(entity this)
{
	sound (self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
	pointparticles(EFFECT_ROCKET_EXPLODE, self.origin, '0 0 0', 1);
	if (!autocvar_cl_nogibs)
	{
		// Base
		if(self.m_id == TUR_EWHEEL.m_id)
			turret_gibtoss((get_turretinfo(self.m_id)).model, self.origin + '0 0 18', self.velocity + '0 0 400' + '0.1 0.1 1' * (random() * 400), '-1 -1 -1', true);
		else if (self.m_id == TUR_WALKER.m_id)
			turret_gibtoss((get_turretinfo(self.m_id)).model, self.origin + '0 0 18', self.velocity + '0 0 300' + '0.1 0.1 1' * (random() * 200), '-1 -1 -1', true);
		else if (self.m_id == TUR_TESLA.m_id)
			turret_gibtoss((get_turretinfo(self.m_id)).model, self.origin + '0 0 18', '0 0 200', '-1 -1 -1', false);
		else
		{
			if (random() > 0.5)
			{
				turret_gibtoss("models/turrets/base-gib2.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', false);
				turret_gibtoss("models/turrets/base-gib3.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', false);
				turret_gibtoss("models/turrets/base-gib4.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', false);
			}
			else
				turret_gibtoss("models/turrets/base-gib1.md3", self.origin + '0 0 8', '0 0 0', '0 0 0', true);

			entity headgib = turret_gibtoss((get_turretinfo(self.m_id)).head_model, self.origin + '0 0 32', '0 0 200' + randomvec() * 200, '-1 -1 -1', true);
			if(headgib)
			{
				headgib.angles = headgib.move_angles = self.tur_head.angles;
				headgib.avelocity = headgib.move_avelocity = self.tur_head.move_avelocity + randomvec() * 45;
				headgib.avelocity_y = headgib.move_avelocity_y = headgib.move_avelocity_y * 5;
				headgib.gravity = 0.5;
			}
		}
	}

	setmodel(self, MDL_Null);
	setmodel(self.tur_head, MDL_Null);
}

NET_HANDLE(ENT_CLIENT_TURRET, bool isnew)
{
	float sf;
	sf = ReadByte();

	if(sf & TNSF_SETUP)
	{
		this.m_id = ReadByte();

		this.origin_x = ReadCoord();
		this.origin_y = ReadCoord();
		this.origin_z = ReadCoord();
		setorigin(this, this.origin);

		this.angles_x = ReadAngle();
		this.angles_y = ReadAngle();

		turret_construct();
		this.colormap = 1024;
		this.glowmod = '0 1 1';
		this.tur_head.colormap = this.colormap;
		this.tur_head.glowmod = this.glowmod;
	}

	if(sf & TNSF_ANG)
	{
		if(this.tur_head == world) // aparenly this can happpen before TNSF_SETUP. great.
			this.tur_head = spawn();

		this.tur_head.move_angles_x = ReadShort();
		this.tur_head.move_angles_y = ReadShort();
		//this.tur_head.angles = this.angles + this.tur_head.move_angles;
		this.tur_head.angles = this.tur_head.move_angles;
	}

	if(sf & TNSF_AVEL)
	{
		if(this.tur_head == world) // aparenly this can happpen before TNSF_SETUP. great.
			this.tur_head = spawn();

		this.tur_head.move_avelocity_x = ReadShort();
		this.tur_head.move_avelocity_y = ReadShort();
	}

	if(sf & TNSF_MOVE)
	{
		this.origin_x = ReadShort();
		this.origin_y = ReadShort();
		this.origin_z = ReadShort();
		setorigin(this, this.origin);

		this.velocity_x = ReadShort();
		this.velocity_y = ReadShort();
		this.velocity_z = ReadShort();

		this.move_angles_y = ReadShort();

		this.move_time	 = time;
		this.move_velocity = this.velocity;
		this.move_origin   = this.origin;
	}

	if(sf & TNSF_ANIM)
	{
		this.frame1time = ReadCoord();
		this.frame	  = ReadByte();
	}

	if(sf & TNSF_STATUS)
	{
		float _tmp;
		_tmp = ReadByte();
		if(_tmp != this.team)
		{
			this.team = _tmp;
			turret_changeteam(this);
		}

		_tmp = ReadByte();
		if(_tmp == 0 && this.health != 0)
			turret_die(this);
		else if(this.health && this.health != _tmp)
			this.helpme = servertime + 10;

		this.health = _tmp;
	}
	//this.enemy.health = this.health / 255;
	return true;
}