float Violence_GibSplash_SendEntity(entity to, float sf)
{
	WriteByte(MSG_ENTITY, ENT_CLIENT_GIBSPLASH);
	WriteByte(MSG_ENTITY, self.state); // actually type
	WriteByte(MSG_ENTITY, bound(1, self.cnt * 16, 255)); // gibbage amount multiplier
	WriteByte(MSG_ENTITY, self.team); // player num
	WriteShort(MSG_ENTITY, floor(self.origin_x / 4)); // not using a coord here, as gibs don't need this accuracy
	WriteShort(MSG_ENTITY, floor(self.origin_y / 4)); // not using a coord here, as gibs don't need this accuracy
	WriteShort(MSG_ENTITY, floor(self.origin_z / 4)); // not using a coord here, as gibs don't need this accuracy
	WriteShort(MSG_ENTITY, self.oldorigin_x); // acrually compressed velocity
	return TRUE;
}

// TODO maybe convert this to a TE?
void Violence_GibSplash_At(vector org, vector dir, float type, float amount, entity gibowner, entity attacker)
{
	if(g_cts) // no gibs in CTS
		return;

	entity e;

	e = spawn();
	e.classname = "gibsplash";
	e.cnt = amount;
	e.state = type; // should stay smaller than 15
	if(!sound_allowed(MSG_BROADCAST, gibowner) || !sound_allowed(MSG_BROADCAST, attacker))
		e.state |= 0x40; // "silence" bit
	e.state |= 8 * self.species; // gib type, ranges from 0 to 15

	// if this is a copied dead body, send the num of its player instead
	if(self.classname == "body")
		e.team = num_for_edict(self.owner);
	else
		e.team = num_for_edict(self);

	setorigin(e, org);
	e.velocity = dir;

	e.oldorigin_x = compressShortVector(e.velocity);

	Net_LinkEntity(e, FALSE, 0.2, Violence_GibSplash_SendEntity);
}

void Violence_GibSplash(entity source, float type, float amount, entity attacker)
{
	Violence_GibSplash_At(source.origin + source.view_ofs, source.velocity, type, amount, source, attacker);
}

// damage effect

.float damageeffect_lifetime;
.entity damageeffect_repeater;

float Violence_DamageEffect_SendEntity(entity to, float sf)
{
	// if the client doesn't have the effect enabled, don't send to him and waste bandwidth
	if not(to.cvar_cl_damageeffect)
		return FALSE;
	// if the client cannot see the damaged player, avoid sending and further save bandwidth
	if not(checkpvs(to.origin + to.view_ofs, self))
		return FALSE;

	WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEEFFECT);
	WriteByte(MSG_ENTITY, self.cnt); // damage weapon
	WriteByte(MSG_ENTITY, self.state); // player species
	WriteByte(MSG_ENTITY, self.team); // player entnum
	WriteCoord(MSG_ENTITY, floor(self.origin_x));
	WriteCoord(MSG_ENTITY, floor(self.origin_y));
	WriteCoord(MSG_ENTITY, floor(self.origin_z));
	return TRUE;
}

void Violence_DamageEffect(entity pl, float type)
{
	entity e;

	e = spawn();
	e.classname = "damageeffect";
	e.cnt = type;
	e.state |= 8 * pl.species; // gib type, ranges from 0 to 15

	// if this is a copied dead body, send the num of its player instead
	if(pl.classname == "body")
		e.team = num_for_edict(pl.owner);
	else
		e.team = num_for_edict(pl);

	// if the player is dead, show the effect lower, else it appears floating above the body
	if(pl.health <= 0)
		setorigin(e, pl.origin - '0 0 25');
	else
		setorigin(e, pl.origin);

	Net_LinkEntity(e, FALSE, 0.2, Violence_DamageEffect_SendEntity);
}

void Violence_DamageEffect_Remove(entity pl);
void Violence_DamageEffect_DoRepeat()
{
	if(time > self.damageeffect_lifetime || (self.owner.classname != "player" && self.owner.classname != "body"))
	{
		Violence_DamageEffect_Remove(self.owner);
		return;
	}

	Violence_DamageEffect(self.owner, self.cnt);
	self.nextthink = time + autocvar_sv_damageeffect_tick;
}

void Violence_DamageEffect_SetRepeat(entity pl, float damage, float type)
{
	if not(autocvar_sv_damageeffect_tick && autocvar_sv_damageeffect_lifetime)
		return;
	if(sv_gentle || !type)
		return; // return if gentle mode is enabled or the damage was not caused by a weapon

	// if a repeater doesn't exist, spawn one, else update the existing one
	if(pl.damageeffect_repeater == world)
	{
		pl.damageeffect_repeater = spawn();
		pl.damageeffect_repeater.classname = "damageeffect_repeater";
		pl.damageeffect_repeater.owner = pl;
		pl.damageeffect_repeater.think = Violence_DamageEffect_DoRepeat;

		pl.damageeffect_repeater.damageeffect_lifetime = time + (autocvar_sv_damageeffect_lifetime * damage);
	}
	else
	{
		// if the repeater is being updated, increase its lifetime instead of re-setting it entirely
		// this fixes the shotgun among other things, where only the damage of one bullet would be taken into account
		pl.damageeffect_repeater.damageeffect_lifetime += (autocvar_sv_damageeffect_lifetime * damage);
	}

	if(autocvar_sv_damageeffect_lifetime_max)
		pl.damageeffect_repeater.damageeffect_lifetime = bound(0, pl.damageeffect_repeater.damageeffect_lifetime, time + autocvar_sv_damageeffect_lifetime_max);

	pl.damageeffect_repeater.cnt = type;
	pl.damageeffect_repeater.nextthink = time;
}

void Violence_DamageEffect_Remove(entity pl)
{
	pl.damageeffect_repeater.nextthink = 0;
	remove(pl.damageeffect_repeater);
	pl.damageeffect_repeater = world;
}

void Violence_DamageEffect_Copy(entity old_pl, entity pl)
{
	if(pl.damageeffect_repeater != world)
		Violence_DamageEffect_Remove(pl);

	Violence_DamageEffect_SetRepeat(pl, 0, old_pl.damageeffect_repeater.cnt); // spawn a new repeater
	pl.damageeffect_repeater.damageeffect_lifetime = old_pl.damageeffect_repeater.damageeffect_lifetime; // copy the lifetime
}