release.cmake

   1 # release requirements:
   2 # a graphical environment
   3 # vorbis-tools: vorbiscomment, oggdec, oggenc
   4 # imagemagick: convert
   5 # https://github.com/divVerent/s2tc.git: s2tc_compress
   6
   7 add_custom_target(release)
   8
   9 string(TIMESTAMP stamp "%Y%m%d")
  10 string(TIMESTAMP filestamp "%Y-%m-%d")
  11
  12 file(STRINGS data/xonotic-data.pk3dir/xonotic-common.cfg _contents REGEX "^gameversion ")
  13 if (NOT _contents)
  14     message(FATAL_ERROR "xonotic-common.cfg does not contain gameversion")
  15 else ()
  16     string(REGEX REPLACE ".*gameversion ([0-9]+).*" "\\1" versionstr "${_contents}")
  17     math(EXPR versionstr_major "${versionstr} / 10000")
  18     math(EXPR versionstr_minor "${versionstr} / 100 - ${versionstr_major} * 100")
  19     math(EXPR versionstr_patch "${versionstr} - ${versionstr_major} * 10000 - ${versionstr_minor} * 100")
  20     set(versionstr "${versionstr_major}.${versionstr_minor}.${versionstr_patch}")
  21     message("game version: ${versionstr}")
  22 endif ()
  23
  24 # foreach repo: git tag "xonotic-v${versionstr}"
  25
  26 function(getbinary artifact)
  27     find_package(Git REQUIRED)
  28     get_filename_component(dpname ${artifact} NAME)
  29     string(REGEX REPLACE "^xonotic" "darkplaces" dpname ${dpname})
  30     execute_process(
  31             COMMAND ${GIT_EXECUTABLE} rev-parse HEAD
  32             WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/darkplaces
  33             OUTPUT_VARIABLE rev
  34             OUTPUT_STRIP_TRAILING_WHITESPACE)
  35     message(STATUS "Downloading http://beta.xonotic.org/autobuild-bin/${rev}/${dpname}")
  36     file(DOWNLOAD "http://beta.xonotic.org/autobuild-bin/${rev}/${dpname}"
  37             "${PROJECT_BINARY_DIR}/${artifact}"
  38             SHOW_PROGRESS)
  39 endfunction()
  40
  41 if (0)
  42     # TODO: build from source
  43     message(STATUS "Downloading NetRadiant")
  44
  45     file(DOWNLOAD http://www.icculus.org/netradiant/files/netradiant-1.5.0-20120301.tar.bz2
  46             "${PROJECT_BINARY_DIR}/netradiant-1.5.0-20120301.tar.bz2"
  47             SHOW_PROGRESS
  48             EXPECTED_HASH SHA256=5e720cd8ebd2379ee5d388dfb8f2613bfd5798fb33d16bc7415d44a11fb4eadb)
  49
  50     file(DOWNLOAD http://www.icculus.org/netradiant/files/netradiant-1.5.0-20120301-win32-7z.exe
  51             "${PROJECT_BINARY_DIR}/netradiant-1.5.0-20120301-win32-7z.exe"
  52             SHOW_PROGRESS
  53             EXPECTED_HASH SHA256=c4bb30b6f14c3f71f1ed29fa38cddac209a7bc2ab5b38e5bf5b442106279b5c4)
  54 endif ()
  55
  56 if (0)
  57     # TODO: build from source
  58     message(STATUS "Downloading Darkplaces")
  59
  60     getbinary(Xonotic/xonotic-x86.exe)
  61     getbinary(Xonotic/xonotic-x86-dedicated.exe)
  62     getbinary(Xonotic/xonotic.exe)
  63     getbinary(Xonotic/xonotic-dedicated.exe)
  64
  65     getbinary(Xonotic/Xonotic.app/Contents/MacOS/xonotic-osx-sdl-bin) # +x
  66     getbinary(Xonotic/xonotic-osx-dedicated) # +x
  67
  68     getbinary(Xonotic/xonotic-linux64-sdl) # +x
  69     getbinary(Xonotic/xonotic-linux64-dedicated) # +x
  70 endif ()
  71
  72 function(buildpk3s src)
  73     set(dir data/${src})
  74     string(REGEX REPLACE "\\.pk3dir$" "" name ${src})
  75     if (name MATCHES "^xonotic-")
  76         string(REGEX REPLACE "^xonotic-" "xonotic-${stamp}-" name ${name})
  77     else ()
  78         set(name "${name}-${stamp}")
  79     endif ()
  80     file(GLOB_RECURSE files RELATIVE "${PROJECT_SOURCE_DIR}/${dir}" "${dir}/*")
  81     string(REGEX REPLACE "\\.git/[^;]+;?" "" files "${files}")
  82     #    string(REGEX REPLACE "[^;]+(qh|inc|txt|cfg|sh|po|pl|yml|cmake);?" "" files "${files}")
  83     foreach (pair ${ARGN})
  84         list(GET pair 0 filter)
  85         list(GET pair 1 flavor)
  86         buildpk3(${name}${flavor}.pk3)
  87     endforeach ()
  88 endfunction()
  89
  90 function(buildpk3 pk3)
  91     message("registered pk3 ${pk3}")
  92     set(deps)
  93     foreach (file IN LISTS files)
  94         set(marker "done.data/${pk3}dir/${file}")
  95         string(REPLACE "#" "_" marker ${marker})  # OUTPUT cannot contain '#'
  96         list(APPEND deps "${marker}")
  97         get_filename_component(rel ${file} DIRECTORY)
  98         add_custom_command(OUTPUT ${marker}
  99                 DEPENDS "${dir}/${file}"
 100                 COMMAND ${CMAKE_COMMAND}
 101                 "-Dsrc=${PROJECT_SOURCE_DIR}/${dir}/${file}"
 102                 "-Ddst=data/${pk3}dir/${rel}"
 103                 "-Dconv=data/${pk3}dir/${file}"
 104                 -P "transform-${filter}.cmake"
 105                 VERBATIM)
 106     endforeach ()
 107     add_custom_target(${pk3}dir DEPENDS ${deps})
 108     add_custom_target(${pk3}dir-zip DEPENDS ${pk3})
 109     add_dependencies(release ${pk3}dir-zip)
 110     add_custom_command(OUTPUT ${pk3}
 111             DEPENDS ${pk3}dir
 112             COMMAND ${CMAKE_COMMAND} -E tar cvf "../../${pk3}" --mtime=${filestamp} --format=zip -- *  # TODO: no wildcard
 113             WORKING_DIRECTORY "data/${pk3}dir")
 114 endfunction()
 115
 116 function(deftransform name)
 117     file(WRITE ${PROJECT_BINARY_DIR}/transform-${name}.cmake "")
 118     set(pairs "${ARGN}")
 119     list(APPEND pairs "del_src\;true")
 120     foreach (pair IN LISTS pairs)
 121         list(GET pair 0 k)
 122         list(GET pair 1 v)
 123         file(APPEND ${PROJECT_BINARY_DIR}/transform-${name}.cmake "set(ENV{${k}} \"${v}\")\n")
 124     endforeach ()
 125     file(APPEND ${PROJECT_BINARY_DIR}/transform-${name}.cmake
 126             "execute_process(\n"
 127             "        COMMAND ${CMAKE_COMMAND} -E copy \${src} \${conv}\n"
 128             "        COMMAND ${PROJECT_SOURCE_DIR}/misc/tools/cached-converter.sh \${conv}\n"
 129             "        COMMAND ${CMAKE_COMMAND} -E make_directory done.\${conv}\n"
 130             "        COMMAND ${CMAKE_COMMAND} -E touch done.\${conv}\n"
 131             "        RESULT_VARIABLE res_var\n"
 132             ")")
 133 endfunction()
 134 file(WRITE ${PROJECT_BINARY_DIR}/transform-raw.cmake
 135         "execute_process(\n"
 136         "        COMMAND ${CMAKE_COMMAND} -E copy \${src} \${conv}\n"
 137         "        COMMAND ${CMAKE_COMMAND} -E make_directory done.\${conv}\n"
 138         "        COMMAND ${CMAKE_COMMAND} -E touch done.\${conv}\n"
 139         ")")
 140
 141 # default to "del_src\;true"
 142 deftransform(normal
 143         # texture: convert to jpeg and dds
 144         "do_jpeg\;true"
 145         "jpeg_qual_rgb\;97"
 146         "jpeg_qual_a\;99"
 147         "do_dds\;false"
 148         "do_ogg\;true"
 149         "ogg_ogg\;false")
 150 deftransform(normaldds
 151         # texture: convert to jpeg and dds
 152         # music: reduce bitrate
 153         "do_jpeg\;false"
 154         "do_jpeg_if_not_dds\;true"
 155         "jpeg_qual_rgb\;95"
 156         "jpeg_qual_a\;99"
 157         "do_dds\;true"
 158         "dds_flags\;"
 159         "do_ogg\;true"
 160         "ogg_ogg\;false")
 161 deftransform(low
 162         # texture: convert to jpeg and dds
 163         # music: reduce bitrate
 164         "do_jpeg\;true"
 165         "jpeg_qual_rgb\;80"
 166         "jpeg_qual_a\;97"
 167         "do_dds\;false"
 168         "do_ogg\;true"
 169         "ogg_qual\;1")
 170 deftransform(webp
 171         # texture: convert to jpeg and dds
 172         "do_jpeg\;false"
 173         "do_webp\;true"
 174         "do_dds\;false"
 175         "do_ogg\;false"
 176         "ogg_ogg\;false")
 177 deftransform(lowdds
 178         # texture: convert to jpeg and dds
 179         # music: reduce bitrate
 180         "do_jpeg\;false"
 181         "do_jpeg_if_not_dds\;true"
 182         "jpeg_qual_rgb\;80"
 183         "jpeg_qual_a\;99"
 184         "do_dds\;true"
 185         "dds_flags\;"
 186         "do_ogg\;true"
 187         "ogg_qual\;1")
 188 deftransform(mapping
 189         # texture: convert to jpeg and dds
 190         # music: reduce bitrate
 191         "do_jpeg\;true"
 192         "jpeg_qual_rgb\;80"
 193         "jpeg_qual_a\;97"
 194         "do_dds\;false"
 195         "do_ogg\;true"
 196         "ogg_qual\;1"
 197         )
 198
 199 ## remove stuff radiant has no use for
 200 #verbose find . -name \*_norm.\* -exec rm -f {} \;
 201 #verbose find . -name \*_bump.\* -exec rm -f {} \;
 202 #verbose find . -name \*_glow.\* -exec rm -f {} \;
 203 #verbose find . -name \*_gloss.\* -exec rm -f {} \;
 204 #verbose find . -name \*_pants.\* -exec rm -f {} \;
 205 #verbose find . -name \*_shirt.\* -exec rm -f {} \;
 206 #verbose find . -name \*_reflect.\* -exec rm -f {} \;
 207 #verbose find . -not \( -name \*.tga -o -name \*.png -o -name \*.jpg \) -exec rm -f {} \;
 208
 209 buildpk3s(font-unifont.pk3dir "raw\;")
 210 buildpk3s(font-xolonium.pk3dir "raw\;")
 211 buildpk3s(xonotic-data.pk3dir "low\;-low" "normaldds\;" "normal\;-high")
 212 buildpk3s(xonotic-maps.pk3dir "low\;-low" "normaldds\;" "normal\;-high" "mapping\;-mapping")
 213 buildpk3s(xonotic-music.pk3dir "raw\;" "low\;-low")
 214 buildpk3s(xonotic-nexcompat.pk3dir "normaldds\;")
 215
 216 message("CMake may appear to halt at '-- Configuring done', this is not the case")