CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
   2
   3 project(NetRadiant C CXX)
   4
   5 #-----------------------------------------------------------------------
   6 # Builtins: configuration
   7 #-----------------------------------------------------------------------
   8
   9 set(BUILTINS_INSTALL_DIR "${CMAKE_BINARY_DIR}/builtins")
  10 set(BUILTINS_INCLUDE_DIR "${BUILTINS_INSTALL_DIR}/include")
  11 set(BUILTINS_LIB_DIR "${BUILTINS_INSTALL_DIR}/lib")
  12 set(BUILTINS_PKGCONFIG_DIR "${BUILTINS_INSTALL_DIR}/lib/pkgconfig")
  13
  14 option(BUILTIN_GTKGLEXT "Builtin GtkGLExt" OFF)
  15
  16 set(BUILTIN_GTKGLEXT_BUILT OFF CACHE INTERNAL "...")
  17 if (EXISTS "${BUILTINS_INSTALL_DIR}/lib/pkgconfig/gtkglext-1.0.pc")
  18     set(BUILTIN_GTKGLEXT_BUILT ON)
  19 endif ()
  20
  21 if (EXISTS "${BUILTINS_INCLUDE_DIR}")
  22     include_directories("${BUILTINS_INCLUDE_DIR}")
  23 endif ()
  24
  25 if (EXISTS "${BUILTINS_LIB_DIR}")
  26     set(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}:${BUILTINS_LIB_DIR}")
  27     link_directories("${BUILTINS_LIB_DIR}")
  28 endif ()
  29
  30 if (EXISTS "${BUILTINS_PKGCONFIG_DIR}")
  31     set(ENV{PKG_CONFIG_PATH} "$ENV{PKG_CONFIG_PATH}:${BUILTINS_PKGCONFIG_DIR}")
  32 endif ()
  33
  34 #-----------------------------------------------------------------------
  35 # CMake modules
  36 #-----------------------------------------------------------------------
  37
  38 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
  39
  40 #-----------------------------------------------------------------------
  41 # Submodules
  42 #-----------------------------------------------------------------------
  43
  44 if (EXISTS "${PROJECT_SOURCE_DIR}/libs/crunch/inc/crn_decomp.h")
  45     set(DEFAULT_BUILD_CRUNCH ON CACHE INTERNAL "...")
  46 else ()
  47     set(DEFAULT_BUILD_CRUNCH OFF CACHE INTERNAL "...")
  48 endif ()
  49
  50 if (EXISTS "${PROJECT_SOURCE_DIR}/tools/unvanquished/daemonmap/tools/quake3/q3map2/main.c")
  51     set(DEFAULT_BUILD_DAEMONMAP ON CACHE INTERNAL "...")
  52 else ()
  53     set(DEFAULT_BUILD_DAEMONMAP OFF CACHE INTERNAL "...")
  54 endif ()
  55
  56 #-----------------------------------------------------------------------
  57 # Build options
  58 #-----------------------------------------------------------------------
  59
  60 option(BUILD_RADIANT "Build the GUI" ON)
  61 option(BUILD_TOOLS "Build the tools" ON)
  62 option(BUILD_CRUNCH "Build Crunch image support" ${DEFAULT_BUILD_CRUNCH})
  63 option(BUILD_DAEMONMAP "Build daemonmap navigation mesh generator" ${DEFAULT_BUILD_DAEMONMAP})
  64 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
  65 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  66 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  67
  68 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  69 if (BUILD_RADIANT OR BUILD_TOOLS)
  70     set(BUILD_BINARIES ON)
  71 endif ()
  72
  73 #-----------------------------------------------------------------------
  74 # Paths
  75 #-----------------------------------------------------------------------
  76
  77 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  78     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
  79 endif ()
  80
  81 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
  82 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
  83 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
  84 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
  85
  86 set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  87 set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  88 set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  89
  90 if (FHS_INSTALL AND NOT BUNDLE_LIBRARIES)
  91     set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX}/lib/${RADIANT_BASENAME})
  92     set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX}/bin)
  93     set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX}/share/${RADIANT_BASENAME})
  94 endif ()
  95
  96 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
  97
  98 #-----------------------------------------------------------------------
  99 # Version
 100 #-----------------------------------------------------------------------
 101
 102 # CMake 3.0+ would allow this in project()
 103 set(RADIANT_VERSION_MAJOR 1)
 104 set(RADIANT_VERSION_MINOR 5)
 105 set(RADIANT_VERSION_PATCH 0)
 106 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
 107
 108 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
 109
 110 find_package(Git REQUIRED)
 111
 112 execute_process(
 113      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
 114      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
 115      OUTPUT_VARIABLE GIT_VERSION
 116      OUTPUT_STRIP_TRAILING_WHITESPACE
 117 )
 118
 119 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
 120
 121 if (GIT_VERSION)
 122     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
 123 endif ()
 124
 125 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
 126
 127 #-----------------------------------------------------------------------
 128 # Language standard
 129 #-----------------------------------------------------------------------
 130
 131 if (BUILD_BINARIES)
 132     set(CMAKE_CXX_STANDARD 11)
 133     set(CMAKE_CXX_STANDARD_REQUIRED ON)
 134     set(CMAKE_CXX_EXTENSIONS OFF)
 135
 136     if (CMAKE_VERSION VERSION_LESS "3.1")
 137         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
 138             include(CheckCXXCompilerFlag)
 139             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
 140             if (STD_CXX)
 141                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
 142             else ()
 143                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
 144             endif ()
 145         else ()
 146             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
 147         endif ()
 148     endif ()
 149 endif ()
 150
 151 #-----------------------------------------------------------------------
 152 # Flags
 153 #-----------------------------------------------------------------------
 154
 155 if (BUILD_BINARIES)
 156     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 157
 158     macro (addflags_c args)
 159         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 160     endmacro ()
 161
 162     macro (addflags_cxx args)
 163         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 164     endmacro ()
 165
 166     macro (addflags args)
 167         addflags_c("${args}")
 168         addflags_cxx("${args}")
 169     endmacro ()
 170
 171     addflags("-fno-strict-aliasing")
 172     if (NOT WIN32)
 173         addflags("-fvisibility=hidden")
 174     endif ()
 175
 176     if (USE_WERROR)
 177         addflags("-Werror")
 178         addflags("-pedantic-errors")
 179     endif ()
 180
 181     addflags("-Wall")
 182     addflags("-Wextra")
 183     addflags("-pedantic")
 184
 185     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 186
 187     addflags("-Wno-unused-function")
 188     addflags("-Wno-unused-variable")
 189     addflags("-Wno-unused-parameter")
 190
 191     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 192 endif ()
 193
 194 if (BUILD_RADIANT)
 195     set(GTK_TARGET 2 CACHE STRING "GTK target")
 196     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 197
 198     if (WIN32)
 199         add_definitions(-DWORKAROUND_WINDOWS_FLOATING_WINDOW=1)
 200
 201         if (GTK_TARGET EQUAL 2)
 202             add_definitions(-DWORKAROUND_WINDOWS_GTK2_GLWIDGET=1)
 203         endif ()
 204     endif ()
 205 endif ()
 206
 207 #-----------------------------------------------------------------------
 208 # Defs
 209 #-----------------------------------------------------------------------
 210
 211 if (BUILD_BINARIES)
 212     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 213     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 214
 215     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 216         add_definitions(-D_DEBUG=1)
 217     endif ()
 218 endif ()
 219
 220 if (BUILD_RADIANT)
 221     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 222
 223     macro (disable_deprecated name gtk2only)
 224         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 225         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 226             add_definitions(-D${name}_DISABLE_DEPRECATED)
 227         endif ()
 228     endmacro ()
 229
 230     disable_deprecated(ATK 0)
 231     disable_deprecated(G 0)
 232     disable_deprecated(GDK 0)
 233     disable_deprecated(GDK_PIXBUF 0)
 234     disable_deprecated(GTK 1)
 235     disable_deprecated(PANGO 0)
 236 endif ()
 237
 238 if (BUILD_BINARIES)
 239     add_custom_target(binaries ALL)
 240
 241     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 242         link_directories(
 243             /usr/local/lib
 244         )
 245     endif ()
 246
 247     if (WIN32)
 248         add_definitions(
 249             -DWIN32=1
 250             -D_WIN32=1
 251         )
 252     else ()
 253         add_definitions(
 254             -DPOSIX=1
 255         )
 256     endif ()
 257 endif ()
 258
 259 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 260     set(XWINDOWS ON)
 261     find_package(X11 REQUIRED)
 262     include_directories(${X11_INCLUDE_DIR})
 263     add_definitions(-DXWINDOWS=1)
 264 endif ()
 265
 266 if (BUILD_BINARIES)
 267     include_directories("${PROJECT_SOURCE_DIR}/include")
 268     include_directories("${PROJECT_SOURCE_DIR}/libs")
 269
 270     if (WIN32 OR "${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 271         set(BUNDLING_SUPPORTED ON)
 272     endif()
 273
 274     if (BUNDLING_SUPPORTED)
 275         if(WIN32 AND NOT CMAKE_CROSSCOMPILING)
 276             set(BUNDLE_LIBRARIES_DEFAULT ON)
 277         else ()
 278             set(BUNDLE_LIBRARIES_DEFAULT OFF)
 279         endif ()
 280
 281         option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 282     endif ()
 283
 284     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 285         add_subdirectory(bundle)
 286
 287         set(FHS_INSTALL OFF CACHE PATH "Disabled because of BUNDLE_LIBRARIES" FORCE)
 288     endif ()
 289
 290     macro (copy_dlls target)
 291         if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 292             add_custom_command(TARGET ${target} POST_BUILD
 293                 COMMAND "${PROJECT_SOURCE_DIR}/library-bundler"
 294                 "register" "${PROJECT_BINARY_DIR}" "$<TARGET_FILE:${target}>"
 295                 VERBATIM
 296             )
 297             add_dependencies(bundle ${target})
 298         endif ()
 299     endmacro ()
 300 endif ()
 301
 302 #-----------------------------------------------------------------------
 303 # Builtins: targets
 304 #-----------------------------------------------------------------------
 305
 306 add_custom_target(builtins)
 307
 308 if (BUILTIN_GTKGLEXT)
 309     include(${CMAKE_ROOT}/Modules/ExternalProject.cmake)
 310
 311     execute_process(COMMAND pkg-config --libs gdk-2.0 gtk+-2.0 glib-2.0 gl
 312         OUTPUT_VARIABLE GTKGLEXT_LDFLAGS
 313         OUTPUT_STRIP_TRAILING_WHITESPACE
 314     )
 315     set(GTKGLEXT_LDFLAGS "$ENV{LDFLAGS} -lm ${GTKGLEXT_LDFLAGS}")
 316
 317     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 318                 set(GTKGLEXT_CFLAGS "$ENV{CFLAGS} -g")
 319         else ()
 320                 set(GTKGLEXT_CFLAGS "$ENV{CFLAGS}")
 321         endif()
 322
 323     set(CONFIGURE_OPTIONS --disable-gtk-doc --disable-gtk-doc-html --disable-gtk-doc-pdf)
 324
 325     if (APPLE)
 326         set(GTKGLEXT_GIT_TAG macos)
 327     else ()
 328         set(GTKGLEXT_GIT_TAG fixes)
 329     endif ()
 330
 331     ExternalProject_Add(gtkglext
 332         GIT_REPOSITORY https://gitlab.gnome.org/illwieckz/gtkglext.git
 333         GIT_TAG ${GTKGLEXT_GIT_TAG}
 334         BUILD_IN_SOURCE ON
 335         CONFIGURE_COMMAND export LDFLAGS=${GTKGLEXT_LDFLAGS}
 336         CONFIGURE_COMMAND && NOCONFIGURE=1 ./autogen.sh
 337         CONFIGURE_COMMAND && ./configure --prefix "${BUILTINS_INSTALL_DIR}" ${CONFIGURE_OPTIONS}
 338         BUILD_COMMAND $(MAKE) CFLAGS=${GTKGLEXT_CFLAGS} LDFLAGS=${GTKGLEXT_LDFLAGS}
 339         INSTALL_COMMAND $(MAKE) install
 340     )
 341
 342     include_directories("${BUILTINS_INSTALL_DIR}/lib/gtkglext-1.0/include")
 343     include_directories("${BUILTINS_INSTALL_DIR}/include/gtkglext-1.0")
 344
 345     add_dependencies(builtins gtkglext)
 346     set_target_properties(gtkglext PROPERTIES EXCLUDE_FROM_ALL ON)
 347 endif ()
 348
 349 if (BUNDLE_LIBRARIES AND EXISTS ${BUILTINS_LIB_DIR})
 350     set(CMAKE_SKIP_BUILD_RPATH ON)
 351 endif()
 352
 353 #-----------------------------------------------------------------------
 354 # Libraries
 355 #-----------------------------------------------------------------------
 356
 357 if (BUILD_BINARIES)
 358     add_subdirectory(libs)
 359 endif ()
 360
 361 if (BUILD_RADIANT)
 362     add_subdirectory(include)
 363 endif ()
 364
 365 #-----------------------------------------------------------------------
 366 # Plugins
 367 #-----------------------------------------------------------------------
 368
 369 if (BUILD_RADIANT)
 370     add_subdirectory(contrib)
 371 endif ()
 372
 373 #-----------------------------------------------------------------------
 374 # Modules
 375 #-----------------------------------------------------------------------
 376
 377 if (BUILD_RADIANT)
 378     add_subdirectory(plugins)
 379 endif ()
 380
 381 #-----------------------------------------------------------------------
 382 # Radiant
 383 #-----------------------------------------------------------------------
 384
 385 if (BUILD_BINARIES)
 386     macro (radiant_tool name)
 387         add_dependencies(binaries ${name})
 388
 389         if (WIN32)
 390             add_executable(${name} ${ARGN} ${PROJECT_SOURCE_DIR}/include/lib.rc)
 391         else ()
 392             add_executable(${name} ${ARGN})
 393         endif()
 394
 395         copy_dlls(${name})
 396
 397         install(
 398             TARGETS ${name}
 399             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 400         )
 401     endmacro ()
 402
 403     if (BUILD_RADIANT)
 404         add_subdirectory(radiant)
 405     endif ()
 406 endif ()
 407
 408 #-----------------------------------------------------------------------
 409 # Tools
 410 #-----------------------------------------------------------------------
 411
 412 if (BUILD_TOOLS)
 413     add_subdirectory(tools)
 414
 415     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 416
 417     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 418         # Copy data files from sources to the build directory
 419         message(STATUS "Copying data files")
 420         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 421     endif ()
 422 endif ()
 423
 424 #-----------------------------------------------------------------------
 425 # Game packs
 426 #-----------------------------------------------------------------------
 427
 428 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 429 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 430
 431 if (DOWNLOAD_GAMEPACKS)
 432     add_custom_target(gamepacks ALL
 433        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 434        COMMENT "Downloading game packs"
 435     )
 436 endif ()
 437
 438 #-----------------------------------------------------------------------
 439 # Install
 440 #-----------------------------------------------------------------------
 441
 442 if (BUILD_BINARIES)
 443     install(DIRECTORY
 444         setup/data/tools/base
 445         setup/data/tools/bitmaps
 446         setup/data/tools/gl
 447         setup/data/tools/plugins
 448         docs
 449         DESTINATION ${RADIANT_DATA_DIR}
 450     )
 451
 452     install(FILES
 453         setup/data/tools/global.xlink
 454         DESTINATION ${RADIANT_DATA_DIR}
 455     )
 456 endif ()
 457
 458 if (DOWNLOAD_GAMEPACKS)
 459     if (FHS_INSTALL)
 460        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/share/netradiant")
 461     else ()
 462        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
 463     endif ()
 464
 465     install(DIRECTORY
 466         ${PROJECT_BINARY_DIR}/gamepacks
 467         DESTINATION ${RADIANT_DATA_DIR}
 468     )
 469 endif ()
 470
 471 if(BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 472     install(FILES
 473         ${PROJECT_SOURCE_DIR}/icons/netradiant.png
 474         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/pixmaps
 475     )
 476     install(FILES
 477         ${PROJECT_SOURCE_DIR}/icons/netradiant.desktop
 478         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications
 479     )
 480     install(FILES
 481         ${PROJECT_SOURCE_DIR}/icons/mime/map.xml
 482         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/mime/model
 483     )
 484 endif ()
 485
 486 include(cmake/scripts/package.cmake)