data/qcsrc/client/shownames.qc

   1 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
   2 // self.origin = player origin TODO: should maybe move this so it's the origin of the shownames tag already in SSQC for culling?
   3 // self.healthvalue
   4 // self.armorvalue
   5 // self.eaten
   6 //
   7 const float SHOWNAMES_FADESPEED = 4;
   8 void Draw_ShowNames(entity ent)
   9 {
  10         if(!cvar("hud_shownames"))
  11                 return;
  12
  13         if(ent.sv_entnum == player_localentnum && !cvar("chase_active"))
  14                 return;
  15
  16         if(ent.predator) // don't show names for prey
  17                 return;
  18
  19         float sameteam;
  20         if(teamplay && (GetPlayerColor(player_localentnum - 1) == GetPlayerColor(ent.sv_entnum - 1)))
  21                 sameteam = TRUE;
  22
  23         if(sameteam || (!sameteam && cvar("hud_shownames") > 1))
  24         {
  25                 ent.origin_z += cvar("hud_shownames_offset");
  26
  27                 // offset the name by player scale, decided by health
  28                 if(g_healthsize)
  29                         ent.origin_z -= (g_healthsize - ent.healthvalue) * cvar("hud_shownames_offset_healthsize");
  30
  31                 if(!sameteam)
  32                         traceline(ent.origin, view_origin, 1, ent);
  33
  34                 vector o, eo;
  35                 o = project_3d_to_2d(ent.origin);
  36                 float overlap;
  37
  38                 if(cvar("hud_shownames_antioverlap"))
  39                 {
  40                         // fade tag out if another tag that is closer to you overlaps
  41                         entity e;
  42                         for(e = world; (e = find(e, classname, "shownames_tag")); )
  43                         {
  44                                 if(e == ent)
  45                                         continue;
  46                                 eo = project_3d_to_2d(e.origin);
  47                                 if not(eo_z < 0 || eo_x < 0 || eo_y < 0 || eo_x > vid_conwidth || eo_y > vid_conheight)
  48                                 {
  49                                         eo_z = 0;
  50                                         if(vlen(('1 0 0' * o_x + '0 1 0' * o_y) - eo) < cvar("hud_shownames_antioverlap_distance") && vlen(ent.origin - view_origin) > vlen(e.origin - view_origin))
  51                                         {
  52                                                 overlap = TRUE;
  53                                                 break;
  54                                         }
  55                                 }
  56                         }
  57                 }
  58
  59                 if(!sameteam && trace_endpos != view_origin) // out of view, fade out
  60                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  61                 else if(ent.healthvalue < 1) // dead player, fade out slowly
  62                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  63                 else if(overlap) // tag overlap detected, fade out
  64                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  65                 else // fade in
  66                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
  67
  68                 if(!ent.alpha)
  69                         return;
  70
  71                 float dist;
  72                 dist = vlen(ent.origin - view_origin);
  73
  74                 float a;
  75                 a = cvar("hud_shownames_alpha");
  76                 a *= ent.alpha;
  77                 if(cvar("hud_shownames_maxdistance"))
  78                 {
  79                         if(dist >= cvar("hud_shownames_maxdistance"))
  80                                 return;
  81                         a *= ((cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance")) - max(0, dist - cvar("hud_shownames_mindistance"))) / (cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance"));
  82                 }
  83
  84                 if(!a)
  85                         return;
  86
  87                 float resize;
  88                 resize = 1;
  89                 if(cvar("hud_shownames_resize")) // limit resize so its never smaller than 0.5... gets unreadable
  90                         resize = 0.5 + 0.5 * ((cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance")) - max(0, dist - cvar("hud_shownames_mindistance"))) / (cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance"));
  91
  92                 // draw the sprite image
  93                 if not(o_z < 0 || o_x < 0 || o_y < 0 || o_x > vid_conwidth || o_y > vid_conheight)
  94                 {
  95                         o_z = 0;
  96
  97                         vector myPos, mySize;
  98                         mySize = ('1 0 0' * cvar("hud_shownames_aspect") + '0 1 0') * cvar("hud_shownames_fontsize");
  99                         myPos = o - '0.5 0 0' * mySize_x - '0 1 0' * mySize_y;
 100
 101                         // size scaling
 102                         mySize_x *= resize;
 103                         mySize_y *= resize;
 104
 105                         myPos_x += 0.5 * (mySize_x / resize - mySize_x);
 106                         myPos_y += (mySize_y / resize - mySize_y);
 107
 108                         vector namepos; // this is where the origin of the string
 109                         float namewidth;
 110
 111                         namepos = myPos;
 112                         namewidth = mySize_x;
 113
 114                         string s;
 115                         s = GetPlayerName(ent.sv_entnum-1);
 116                         if((cvar("hud_shownames_decolorize") == 1 && teamplay) || cvar("hud_shownames_decolorize") == 2)
 117                                 s = playername(s, GetPlayerColor(ent.sv_entnum-1));
 118
 119                         drawfontscale = '1 1 0' * resize;
 120                         s = textShortenToWidth(s, namewidth, '1 1 0' * cvar("hud_shownames_fontsize"), stringwidth_colors);
 121
 122                         if(sameteam && ent.healthvalue > 0)
 123                         {
 124                                 if(cvar("hud_shownames_status") > 2 && ent.armorvalue)
 125                                         s = strcat(s, "^7 (^1+", ftos(ent.healthvalue), "^7|^2*", ftos(ent.armorvalue), "^7)");
 126                                 else if(cvar("hud_shownames_status") > 1)
 127                                         s = strcat(s, "^7 (^1+", ftos(ent.healthvalue), "^7)");
 128
 129                                 // if team healing is enabled, mark the team mate as possible to heal
 130                                 if(cvar("hud_shownames_status") && ent.healthvalue < teamheal_max)
 131                                         s = strcat(s, "^7 [^5HEAL^7]");
 132                         }
 133
 134                         float width;
 135                         width = stringwidth(s, TRUE, '1 1 0' * cvar("hud_shownames_fontsize"));
 136
 137                         if (width != namewidth)
 138                                 namepos_x += (namewidth - width) / 2;
 139                         drawcolorcodedstring(namepos, s, '1 1 0' * cvar("hud_shownames_fontsize"), a, DRAWFLAG_NORMAL);
 140                         drawfontscale = '1 1 0';
 141                 }
 142         }
 143 }
 144
 145 entity shownames_ent[255];
 146 void Draw_ShowNames_All()
 147 {
 148         float i;
 149         for(i = 0; i < maxclients; ++i)
 150         {
 151                 float t;
 152                 t = GetPlayerColor(i);
 153                 if(t == COLOR_SPECTATOR)
 154                         continue;
 155
 156                 entity e;
 157                 e = shownames_ent[i];
 158                 if(!e)
 159                 {
 160                         e = spawn();
 161                         e.classname = "shownames_tag";
 162                         e.sv_entnum = i+1;
 163                         shownames_ent[i] = e;
 164                 }
 165
 166                 entity entcs;
 167                 entcs = entcs_receiver[i];
 168                 if(entcs)
 169                 {
 170                         e.healthvalue = entcs.healthvalue;
 171                         e.armorvalue = entcs.armorvalue;
 172                         e.predator = entcs.predator;
 173                 }
 174                 else
 175                 {
 176                         e.healthvalue = 2342;
 177                         e.armorvalue = 0;
 178                         e.predator = 0;
 179                 }
 180
 181                 e.origin = getplayerorigin(i);
 182                 if(e.origin == GETPLAYERORIGIN_ERROR)
 183                         continue;
 184
 185                 Draw_ShowNames(e);
 186         }
 187 }