data/qcsrc/client/shownames.qc

   1 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
   2 // self.origin = player origin TODO: should maybe move this so it's the origin of the shownames tag already in SSQC for culling?
   3 // self.healthvalue
   4 // self.armorvalue
   5 // self.eaten
   6 //
   7 const float SHOWNAMES_FADESPEED = 4;
   8 void Draw_ShowNames(entity ent)
   9 {
  10         if(!cvar("hud_shownames"))
  11                 return;
  12         if(ent.sv_entnum == player_localentnum && !cvar("chase_active"))
  13                 return;
  14         if(getstati(STAT_VORE_EATEN) && cvar("cl_vore_stomachmodel") >= 1 && !cvar("chase_active"))
  15                 return;
  16
  17         float sameteam;
  18         if(teamplay && (GetPlayerColor(player_localentnum - 1) == GetPlayerColor(ent.sv_entnum - 1)))
  19                 sameteam = TRUE;
  20
  21         if(sameteam || (!sameteam && cvar("hud_shownames") > 1))
  22         {
  23                 ent.origin_z += cvar("hud_shownames_offset");
  24
  25                 // offset the name by player scale, decided by health
  26                 if(g_healthsize_center >= 0)
  27                         ent.origin_z -= (g_healthsize_center - bound(g_healthsize_min, ent.healthvalue, g_healthsize_max)) * cvar("hud_shownames_offset_healthsize");
  28
  29                 traceline(ent.origin, view_origin, TRUE, ent);
  30
  31                 vector o, eo;
  32                 o = project_3d_to_2d(ent.origin);
  33                 float overlap;
  34
  35                 if(cvar("hud_shownames_antioverlap"))
  36                 {
  37                         // fade tag out if another tag that is closer to you overlaps
  38                         entity e;
  39                         for(e = world; (e = find(e, classname, "shownames_tag")); )
  40                         {
  41                                 if(e == ent)
  42                                         continue;
  43                                 eo = project_3d_to_2d(e.origin);
  44                                 if not(eo_z < 0 || eo_x < 0 || eo_y < 0 || eo_x > vid_conwidth || eo_y > vid_conheight)
  45                                 {
  46                                         eo_z = 0;
  47                                         if(vlen(('1 0 0' * o_x + '0 1 0' * o_y) - eo) < cvar("hud_shownames_antioverlap_distance") && vlen(ent.origin - view_origin) > vlen(e.origin - view_origin))
  48                                         {
  49                                                 overlap = TRUE;
  50                                                 break;
  51                                         }
  52                                 }
  53                         }
  54                 }
  55
  56                 if(trace_endpos != view_origin) // out of view, fade out
  57                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  58                 else if(ent.healthvalue < 1) // dead player, fade out slowly
  59                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  60                 else if(overlap) // tag overlap detected, fade out
  61                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  62                 else // fade in
  63                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
  64
  65                 if(!ent.alpha)
  66                         return;
  67
  68                 float dist;
  69                 dist = vlen(ent.origin - view_origin);
  70
  71                 float a;
  72                 a = cvar("hud_shownames_alpha");
  73                 a *= ent.alpha;
  74                 if(cvar("hud_shownames_maxdistance"))
  75                 {
  76                         if(dist >= cvar("hud_shownames_maxdistance"))
  77                                 return;
  78                         a *= ((cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance")) - max(0, dist - cvar("hud_shownames_mindistance"))) / (cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance"));
  79                 }
  80
  81                 if(!a)
  82                         return;
  83
  84                 float resize;
  85                 resize = 1;
  86                 if(cvar("hud_shownames_resize")) // limit resize so its never smaller than 0.5... gets unreadable
  87                         resize = 0.5 + 0.5 * ((cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance")) - max(0, dist - cvar("hud_shownames_mindistance"))) / (cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance"));
  88
  89                 // draw the sprite image
  90                 if not(o_z < 0 || o_x < 0 || o_y < 0 || o_x > vid_conwidth || o_y > vid_conheight)
  91                 {
  92                         o_z = 0;
  93
  94                         vector myPos, mySize;
  95                         mySize = ('1 0 0' * cvar("hud_shownames_aspect") + '0 1 0') * cvar("hud_shownames_fontsize");
  96                         myPos = o - '0.5 0 0' * mySize_x - '0 1 0' * mySize_y;
  97
  98                         // size scaling
  99                         mySize_x *= resize;
 100                         mySize_y *= resize;
 101
 102                         myPos_x += 0.5 * (mySize_x / resize - mySize_x);
 103                         myPos_y += (mySize_y / resize - mySize_y);
 104
 105                         vector namepos; // this is where the origin of the string
 106                         float namewidth;
 107
 108                         namepos = myPos;
 109                         namewidth = mySize_x;
 110
 111                         string s;
 112                         s = GetPlayerName(ent.sv_entnum-1);
 113                         if((cvar("hud_shownames_decolorize") == 1 && teamplay) || cvar("hud_shownames_decolorize") == 2)
 114                                 s = playername(s, GetPlayerColor(ent.sv_entnum-1));
 115
 116                         drawfontscale = '1 1 0' * resize;
 117                         s = textShortenToWidth(s, namewidth, '1 1 0' * cvar("hud_shownames_fontsize"), stringwidth_colors);
 118
 119                         if(sameteam && ent.healthvalue > 0)
 120                         {
 121                                 if(cvar("hud_shownames_status") > 2 && ent.armorvalue)
 122                                         s = strcat(s, "^7 (^1+", ftos(ent.healthvalue), "^7|^2*", ftos(ent.armorvalue), "^7)");
 123                                 else if(cvar("hud_shownames_status") > 1)
 124                                         s = strcat(s, "^7 (^1+", ftos(ent.healthvalue), "^7)");
 125
 126                                 // if team healing is enabled, mark the team mate as possible to heal
 127                                 if(cvar("hud_shownames_status") && ent.healthvalue < teamheal_max)
 128                                         s = strcat(s, "^7 [^5HEAL^7]");
 129                         }
 130
 131                         float width;
 132                         width = stringwidth(s, TRUE, '1 1 0' * cvar("hud_shownames_fontsize"));
 133
 134                         if (width != namewidth)
 135                                 namepos_x += (namewidth - width) / 2;
 136                         drawcolorcodedstring(namepos, s, '1 1 0' * cvar("hud_shownames_fontsize"), a, DRAWFLAG_NORMAL);
 137                         drawfontscale = '1 1 0';
 138                 }
 139         }
 140 }
 141
 142 entity shownames_ent[255];
 143 void Draw_ShowNames_All()
 144 {
 145         float i;
 146         for(i = 0; i < maxclients; ++i)
 147         {
 148                 float t;
 149                 t = GetPlayerColor(i);
 150                 if(t == COLOR_SPECTATOR)
 151                         continue;
 152
 153                 entity e;
 154                 e = shownames_ent[i];
 155                 if(!e)
 156                 {
 157                         e = spawn();
 158                         e.classname = "shownames_tag";
 159                         e.sv_entnum = i+1;
 160                         shownames_ent[i] = e;
 161                 }
 162
 163                 entity entcs;
 164                 entcs = entcs_receiver[i];
 165                 if(entcs)
 166                 {
 167                         e.healthvalue = entcs.healthvalue;
 168                         e.armorvalue = entcs.armorvalue;
 169                 }
 170                 else
 171                 {
 172                         e.healthvalue = 2342;
 173                         e.armorvalue = 0;
 174                 }
 175
 176                 e.origin = getplayerorigin(i);
 177                 if(e.origin == GETPLAYERORIGIN_ERROR)
 178                         continue;
 179
 180                 Draw_ShowNames(e);
 181         }
 182 }