data/qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10\r
   2 \r
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)\r
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter\r
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))\r
   6         // range: 10 .. respawntime + respawntimejitter\r
   7 \r
   8 floatfield Item_CounterField(float it)\r
   9 {\r
  10         switch(it)\r
  11         {\r
  12                 case IT_FUEL:        return ammo_fuel;\r
  13                 case IT_5HP:         return health;\r
  14                 case IT_25HP:        return health;\r
  15                 case IT_HEALTH:      return health;\r
  16                 case IT_ARMOR_SHARD: return armorvalue;\r
  17                 case IT_ARMOR:       return armorvalue;\r
  18                 // add more things here (health, armor)\r
  19                 default:             error("requested item has no counter field");\r
  20         }\r
  21 }\r
  22 \r
  23 string Item_CounterFieldName(float it)\r
  24 {\r
  25         switch(it)\r
  26         {\r
  27                 case IT_FUEL:        return "fuel";\r
  28 \r
  29                 // add more things here (health, armor)\r
  30                 default:             error("requested item has no counter field name");\r
  31         }\r
  32 }\r
  33 \r
  34 .float max_armorvalue;\r
  35 \r
  36 float Item_Customize()\r
  37 {\r
  38         if(self.spawnshieldtime)\r
  39                 return TRUE;\r
  40         if(self.weapons != (self.weapons & other.weapons))\r
  41         {\r
  42                 self.colormod = '0 0 0';\r
  43                 self.glowmod = self.colormod;\r
  44                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha\r
  45                 return TRUE;\r
  46         }\r
  47         else\r
  48         {\r
  49                 if(g_ghost_items)\r
  50                 {\r
  51                         self.colormod = stov(cvar_string("g_ghost_items_color"));\r
  52                         self.glowmod = self.colormod;\r
  53                         self.alpha = g_ghost_items;\r
  54                         return TRUE;\r
  55                 }\r
  56                 else\r
  57                         return FALSE;\r
  58         }\r
  59 }\r
  60 \r
  61 void Item_Show (entity e, float mode)\r
  62 {\r
  63         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;\r
  64         if (mode > 0)\r
  65         {\r
  66                 // make the item look normal, and be touchable\r
  67                 e.model = e.mdl;\r
  68                 e.solid = SOLID_TRIGGER;\r
  69                 e.colormod = '0 0 0';\r
  70                 e.glowmod = e.colormod;\r
  71                 e.alpha = 0;\r
  72                 e.customizeentityforclient = func_null;\r
  73 \r
  74                 e.spawnshieldtime = 1;\r
  75         }\r
  76         else if (mode < 0)\r
  77         {\r
  78                 // hide the item completely\r
  79                 e.model = string_null;\r
  80                 e.solid = SOLID_NOT;\r
  81                 e.colormod = '0 0 0';\r
  82                 e.glowmod = e.colormod;\r
  83                 e.alpha = 0;\r
  84                 e.customizeentityforclient = func_null;\r
  85 \r
  86                 e.spawnshieldtime = 1;\r
  87         }\r
  88         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))\r
  89         {\r
  90                 // make the item translucent green and not touchable\r
  91                 e.model = e.mdl;\r
  92                 e.solid = SOLID_TRIGGER; // can STILL be picked up!\r
  93                 e.colormod = '0 0 0';\r
  94                 e.glowmod = e.colormod;\r
  95                 e.effects |= EF_STARDUST;\r
  96                 e.customizeentityforclient = Item_Customize;\r
  97 \r
  98                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon\r
  99         }\r
 100         else if(g_ghost_items)\r
 101         {\r
 102                 // make the item translucent green and not touchable\r
 103                 e.model = e.mdl;\r
 104                 e.solid = SOLID_NOT;\r
 105                 e.colormod = stov(cvar_string("g_ghost_items_color"));\r
 106                 e.glowmod = e.colormod;\r
 107                 e.alpha = g_ghost_items;\r
 108                 e.customizeentityforclient = func_null;\r
 109 \r
 110                 e.spawnshieldtime = 1;\r
 111         }\r
 112         else\r
 113         {\r
 114                 // hide the item completely\r
 115                 e.model = string_null;\r
 116                 e.solid = SOLID_NOT;\r
 117                 e.colormod = stov(cvar_string("g_ghost_items_color"));\r
 118                 e.glowmod = e.colormod;\r
 119                 e.alpha = 0;\r
 120                 e.customizeentityforclient = func_null;\r
 121 \r
 122                 e.spawnshieldtime = 1;\r
 123         }\r
 124 \r
 125         if (e.strength_finished || e.invincible_finished)\r
 126                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;\r
 127         if (cvar("g_nodepthtestitems"))\r
 128                 e.effects |= EF_NODEPTHTEST;\r
 129         if (cvar("g_fullbrightitems"))\r
 130                 e.effects |= EF_FULLBRIGHT;\r
 131 \r
 132         // relink entity (because solid may have changed)\r
 133         setorigin(e, e.origin);\r
 134 }\r
 135 \r
 136 void Item_Respawn (void)\r
 137 {\r
 138         Item_Show(self, 1);\r
 139         if(self.items == IT_STRENGTH)\r
 140                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound\r
 141         else if(self.items == IT_INVINCIBLE)\r
 142                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound\r
 143         else\r
 144                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound\r
 145         setorigin (self, self.origin);\r
 146 \r
 147         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);\r
 148 }\r
 149 \r
 150 void Item_RespawnCountdown (void)\r
 151 {\r
 152         if(self.count >= ITEM_RESPAWN_TICKS)\r
 153         {\r
 154                 if(self.waypointsprite_attached)\r
 155                         WaypointSprite_Kill(self.waypointsprite_attached);\r
 156                 Item_Respawn();\r
 157         }\r
 158         else\r
 159         {\r
 160                 self.nextthink = time + 1;\r
 161                 self.count += 1;\r
 162                 if(self.count == 1)\r
 163                 {\r
 164                         string name;\r
 165                         vector rgb;\r
 166                         name = string_null;\r
 167                         switch(self.items)\r
 168                         {\r
 169                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;\r
 170                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;\r
 171                         }\r
 172                         if(name)\r
 173                         {\r
 174                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);\r
 175                                 if(self.waypointsprite_attached)\r
 176                                 {\r
 177                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);\r
 178                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);\r
 179                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);\r
 180                                 }\r
 181                         }\r
 182                 }\r
 183                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound\r
 184                 if(self.waypointsprite_attached)\r
 185                 {\r
 186                         WaypointSprite_Ping(self.waypointsprite_attached);\r
 187                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);\r
 188                 }\r
 189         }\r
 190 }\r
 191 \r
 192 void Item_ScheduleRespawnIn(entity e, float t)\r
 193 {\r
 194         if(e.flags & FL_POWERUP)\r
 195         {\r
 196                 e.think = Item_RespawnCountdown;\r
 197                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);\r
 198                 e.count = 0;\r
 199         }\r
 200         else\r
 201         {\r
 202                 e.think = Item_Respawn;\r
 203                 e.nextthink = time + t;\r
 204         }\r
 205 }\r
 206 \r
 207 void Item_ScheduleRespawn(entity e)\r
 208 {\r
 209         Item_Show(e, 0);\r
 210         if(e.respawntime > 0) // if respawntime is -1, this item does not respawn\r
 211                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));\r
 212         else\r
 213                 remove(e);\r
 214 }\r
 215 \r
 216 void Item_ScheduleInitialRespawn(entity e)\r
 217 {\r
 218         Item_Show(e, 0);\r
 219         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));\r
 220 }\r
 221 \r
 222 .float inithealth, initdmg;\r
 223 .float item_digestion_step;\r
 224 void Item_Consumable_Think()\r
 225 {\r
 226         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 227         {\r
 228                 self.predator.regurgitate_prepare = 0;\r
 229                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 230                 Item_Consumable_Remove(self, TRUE);\r
 231                 return;\r
 232         }\r
 233         if(self.predator.stat_eaten)\r
 234         {\r
 235                 // prey can't hold consumable items\r
 236                 Item_Consumable_Remove(self, TRUE);\r
 237                 return;\r
 238         }\r
 239 \r
 240         self.scale = self.health / self.inithealth; // scale matches the item's digestion progress\r
 241         self.dmg = self.initdmg * self.scale;\r
 242         if(self.health <= 0)\r
 243         {\r
 244                 // this item is done\r
 245                 Item_Consumable_Remove(self, FALSE);\r
 246                 return;\r
 247         }\r
 248 \r
 249         if(self.predator.digesting)\r
 250         {\r
 251                 if(time > self.item_digestion_step)\r
 252                 {\r
 253                         // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 254                         float damage, damage_offset;\r
 255 \r
 256                         damage_offset = 1;\r
 257                         if(cvar("g_balance_vore_digestion_distribute")) // apply distributed digestion damage\r
 258                                 damage_offset /= (1 - (self.predator.stomach_load / self.predator.stomach_maxload) * bound(0, cvar("g_balance_vore_digestion_distribute"), 1));\r
 259                         damage = ceil(cvar("g_balance_vore_digestion_damage_item") / damage_offset);\r
 260 \r
 261                         self.health -= damage;\r
 262                         if(self.predator.health + damage <= self.max_health)\r
 263                                 self.predator.health += damage;\r
 264                         else if(self.predator.health < self.max_health)\r
 265                                 self.predator.health = self.max_health;\r
 266                         self.predator.pauserothealth_finished = max(self.predator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));\r
 267 \r
 268                         self.item_digestion_step = time + vore_steptime;\r
 269                 }\r
 270 \r
 271                 if(stov(cvar_string("g_vore_regurgitatecolor_color_digest")))\r
 272                         self.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_digest"));\r
 273         }\r
 274 \r
 275         self.nextthink = time;\r
 276 }\r
 277 \r
 278 float Item_Consumable_Customizeentityforclient()\r
 279 {\r
 280         if(cvar("g_vore_neighborprey_distance_item") && self.predator == other.predator && !(other.cvar_chase_active || other.classname == "observer"))\r
 281         {\r
 282                 self.alpha = default_player_alpha; // allow seeing neighboring items\r
 283                 self.effects |= EF_NODEPTHTEST; // don't hide behind the stomach's own EF_NODEPTHTEST\r
 284         }\r
 285         else\r
 286                 self.alpha = -1; // hide item\r
 287         return TRUE;\r
 288 }\r
 289 \r
 290 void Item_DroppedConsumable_Spawn(entity e);\r
 291 void Item_Consumable_Remove(entity e, float regurgitate)\r
 292 {\r
 293         if(regurgitate)\r
 294         {\r
 295                 // predator effects, some common to those in Vore_Regurgitate\r
 296                 PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 297                 setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 298                 pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 299                 e.predator.punchangle_x = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle_item");\r
 300                 e.predator.punchangle_y = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle_item");\r
 301                 e.predator.punchangle_z = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle_item");\r
 302                 e.predator.regurgitate_prepare = 0;\r
 303                 e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 304 \r
 305                 Item_DroppedConsumable_Spawn(e);\r
 306         }\r
 307 \r
 308         e.nextthink = 0;\r
 309         remove(e);\r
 310         e = world;\r
 311 }\r
 312 \r
 313 void Item_Consumable_Spawn(entity e, entity pl)\r
 314 {\r
 315         entity item;\r
 316         item = spawn();\r
 317         item.owner = e;\r
 318         item.classname = "consumable";\r
 319         item.movetype = MOVETYPE_FOLLOW;\r
 320         item.solid = SOLID_NOT;\r
 321         setmodel(item, e.model);\r
 322         item.health = e.health;\r
 323         if(e.inithealth)\r
 324         {\r
 325                 item.inithealth = e.inithealth;\r
 326                 item.initdmg = e.initdmg;\r
 327         }\r
 328         else\r
 329         {\r
 330                 item.inithealth = e.health;\r
 331                 item.initdmg = e.dmg;\r
 332         }\r
 333         item.max_health = e.max_health;\r
 334 \r
 335         item.predator = pl;\r
 336         item.aiment = pl;\r
 337         item.view_ofs_x = CONSUMABLE_VIEW_OFS_x + crandom() * cvar("g_vore_neighborprey_distance_item");\r
 338         item.view_ofs_y = CONSUMABLE_VIEW_OFS_y + crandom() * cvar("g_vore_neighborprey_distance_item");\r
 339         item.view_ofs_z = CONSUMABLE_VIEW_OFS_z + crandom() * cvar("g_vore_neighborprey_distance_item");\r
 340         item.angles = randomvec() * 360;\r
 341 \r
 342         item.customizeentityforclient = Item_Consumable_Customizeentityforclient;\r
 343         item.think = Item_Consumable_Think;\r
 344         item.nextthink = time;\r
 345 \r
 346         if(stov(cvar_string("g_vore_regurgitatecolor_color_normal")))\r
 347                 item.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_normal"));\r
 348 \r
 349         // predator effects, some common to those in Vore_Swallow\r
 350         PlayerSound(pl, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 351         setanim(pl, pl.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 352         pl.punchangle_x = crandom() * cvar("g_balance_vore_swallow_predator_punchangle_item");\r
 353         pl.punchangle_y = crandom() * cvar("g_balance_vore_swallow_predator_punchangle_item");\r
 354         pl.punchangle_z = crandom() * cvar("g_balance_vore_swallow_predator_punchangle_item");\r
 355         pl.regurgitate_prepare = 0;\r
 356         pl.action_delay = time + cvar("g_balance_vore_action_delay");\r
 357 }\r
 358 \r
 359 void Item_DroppedConsumable_Touch()\r
 360 {\r
 361         if(time < self.cnt)\r
 362                 return;\r
 363 \r
 364         // give the consumable item to the player touching it\r
 365         if not(other.stomach_load + self.dmg > other.stomach_maxload || other.stomach_load + self.initdmg > other.stomach_maxload)\r
 366         if not(!cvar("g_balance_health_consumable_alwayspickup") && other.health >= self.max_health)\r
 367         {\r
 368                 Item_Consumable_Spawn(self, other);\r
 369                 remove(self);\r
 370                 self = world;\r
 371         }\r
 372 }\r
 373 \r
 374 void Item_DroppedConsumable_Spawn(entity e)\r
 375 {\r
 376         entity item;\r
 377         item = spawn();\r
 378         item.owner = world;\r
 379         item.classname = "droppedconsumable";\r
 380         item.movetype = MOVETYPE_TOSS;\r
 381         item.solid = SOLID_TRIGGER;\r
 382         setmodel(item, e.model);\r
 383         item.health = e.health;\r
 384         item.inithealth = e.inithealth;\r
 385         item.initdmg = e.initdmg;\r
 386         item.max_health = e.max_health;\r
 387         item.scale = e.scale;\r
 388         item.colormod = e.colormod;\r
 389 \r
 390         setorigin(item, e.predator.origin);\r
 391         item.angles_y = e.predator.angles_y;\r
 392         makevectors(e.predator.v_angle);\r
 393         item.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 394         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 395 \r
 396         item.touch = Item_DroppedConsumable_Touch;\r
 397         item.cnt = time + 1; // 1 second delay\r
 398         SUB_SetFade(item, time + 20, 1);\r
 399 }\r
 400 \r
 401 float Item_GiveTo(entity item, entity player)\r
 402 {\r
 403         float _switchweapon;\r
 404         float pickedup;\r
 405         float it;\r
 406         float i;\r
 407         entity e;\r
 408 \r
 409         // if nothing happens to player, just return without taking the item\r
 410         pickedup = FALSE;\r
 411         _switchweapon = FALSE;\r
 412 \r
 413         if (g_weapon_stay == 1)\r
 414         if not(item.flags & FL_NO_WEAPON_STAY)\r
 415         if (item.flags & FL_WEAPON)\r
 416         {\r
 417                 if(item.classname == "droppedweapon")\r
 418                 {\r
 419                         if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons\r
 420                                 goto skip;\r
 421                 }\r
 422                 else\r
 423                 {\r
 424                         if (player.weapons & item.weapons)\r
 425                                 goto skip;\r
 426                 }\r
 427         }\r
 428 \r
 429         // in case the player has autoswitch enabled do the following:\r
 430         // if the player is using their best weapon before items are given, they\r
 431         // probably want to switch to an even better weapon after items are given\r
 432         if (player.autoswitch)\r
 433         if (player.switchweapon == w_getbestweapon(player))\r
 434                 _switchweapon = TRUE;\r
 435 \r
 436         if not(player.weapons & W_WeaponBit(player.switchweapon))\r
 437                 _switchweapon = TRUE;\r
 438 \r
 439         if(item.spawnshieldtime)\r
 440         {\r
 441                 if (item.ammo_fuel)\r
 442                 if (player.ammo_fuel < g_pickup_fuel_max)\r
 443                 {\r
 444                         pickedup = TRUE;\r
 445                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);\r
 446                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));\r
 447                 }\r
 448         }\r
 449 \r
 450         if (item.flags & FL_WEAPON)\r
 451         if ((it = item.weapons - (item.weapons & player.weapons)))\r
 452         {\r
 453                 pickedup = TRUE;\r
 454                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)\r
 455                 {\r
 456                         e = get_weaponinfo(i);\r
 457                         if(it & e.weapons)\r
 458                                 W_GiveWeapon (player, e.weapon, item.netname);\r
 459                 }\r
 460         }\r
 461 \r
 462         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))\r
 463         {\r
 464                 pickedup = TRUE;\r
 465                 player.items |= it;\r
 466                 sprint (player, strcat("You got the ^2", item.netname, "\n"));\r
 467         }\r
 468 \r
 469         if(item.spawnshieldtime)\r
 470         {\r
 471                 if (item.strength_finished)\r
 472                 {\r
 473                         pickedup = TRUE;\r
 474                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");\r
 475                 }\r
 476                 if (item.invincible_finished)\r
 477                 {\r
 478                         pickedup = TRUE;\r
 479                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");\r
 480                 }\r
 481 \r
 482                 if (item.health)\r
 483                 {\r
 484                         if(item.dmg && cvar("g_vore")) // consumable item, only if the vore system is enabled\r
 485                         {\r
 486                                 if(player.stomach_load + item.dmg <= player.stomach_maxload)\r
 487                                 if not(!cvar("g_balance_health_consumable_alwayspickup") && player.health >= item.max_health)\r
 488                                 {\r
 489                                         pickedup = TRUE;\r
 490                                         Item_Consumable_Spawn(self, player);\r
 491                                 }\r
 492                         }\r
 493                         else if (player.health < item.max_health)\r
 494                         {\r
 495                                 pickedup = TRUE;\r
 496                                 player.health = min(player.health + item.health, item.max_health);\r
 497                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));\r
 498                         }\r
 499                 }\r
 500                 if (item.armorvalue)\r
 501                 if (player.armorvalue < item.max_armorvalue)\r
 502                 {\r
 503                         pickedup = TRUE;\r
 504                         player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);\r
 505                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));\r
 506                 }\r
 507         }\r
 508 \r
 509 :skip\r
 510         // always eat teamed entities\r
 511         if(item.team)\r
 512                 pickedup = TRUE;\r
 513 \r
 514         if (!pickedup)\r
 515                 return 0;\r
 516 \r
 517         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);\r
 518         if (_switchweapon)\r
 519                 if (player.switchweapon != w_getbestweapon(player))\r
 520                         W_SwitchWeapon_Force(player, w_getbestweapon(player));\r
 521 \r
 522         return 1;\r
 523 }\r
 524 \r
 525 void Item_Touch (void)\r
 526 {\r
 527         entity e, head;\r
 528 \r
 529         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)\r
 530         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))\r
 531         {\r
 532                 remove(self);\r
 533                 return;\r
 534         }\r
 535         if (other.classname != "player")\r
 536                 return;\r
 537         if (other.deadflag)\r
 538                 return;\r
 539         if (self.solid != SOLID_TRIGGER)\r
 540                 return;\r
 541         if (self.owner == other)\r
 542                 return;\r
 543 \r
 544         if(!Item_GiveTo(self, other))\r
 545                 return;\r
 546 \r
 547         other.last_pickup = time;\r
 548 \r
 549         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);\r
 550 \r
 551         if (self.classname == "droppedweapon")\r
 552                 remove (self);\r
 553         else if not(self.spawnshieldtime)\r
 554                 return;\r
 555         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))\r
 556                 return;\r
 557         else\r
 558         {\r
 559                 if(self.team)\r
 560                 {\r
 561                         RandomSelection_Init();\r
 562                         for(head = world; (head = findfloat(head, team, self.team)); )\r
 563                         {\r
 564                                 if(head.flags & FL_ITEM)\r
 565                                 {\r
 566                                         Item_Show(head, -1);\r
 567                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);\r
 568                                 }\r
 569                         }\r
 570                         e = RandomSelection_chosen_ent;\r
 571                 }\r
 572                 else\r
 573                         e = self;\r
 574                 Item_ScheduleRespawn(e);\r
 575         }\r
 576 }\r
 577 \r
 578 void Item_FindTeam()\r
 579 {\r
 580         entity head, e;\r
 581 \r
 582         if(self.effects & EF_NODRAW)\r
 583         {\r
 584                 // marker for item team search\r
 585                 dprint("Initializing item team ", ftos(self.team), "\n");\r
 586                 RandomSelection_Init();\r
 587                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)\r
 588                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);\r
 589                 e = RandomSelection_chosen_ent;\r
 590                 e.state = 0;\r
 591                 Item_Show(e, 1);\r
 592 \r
 593                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)\r
 594                 {\r
 595                         if(head != e)\r
 596                         {\r
 597                                 // make it a non-spawned item\r
 598                                 Item_Show(head, -1);\r
 599                                 head.state = 1; // state 1 = initially hidden item\r
 600                         }\r
 601                         head.effects &~= EF_NODRAW;\r
 602                 }\r
 603 \r
 604                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!\r
 605                         Item_ScheduleInitialRespawn(e);\r
 606         }\r
 607 }\r
 608 \r
 609 void Item_Reset()\r
 610 {\r
 611         Item_Show(self, !self.state);\r
 612         setorigin (self, self.origin);\r
 613         self.think = SUB_Null;\r
 614         self.nextthink = 0;\r
 615 \r
 616         if(self.flags & FL_POWERUP) // do not spawn powerups initially!\r
 617                 Item_ScheduleInitialRespawn(self);\r
 618 }\r
 619 \r
 620 // Savage: used for item garbage-collection\r
 621 // TODO: perhaps nice special effect?\r
 622 void RemoveItem(void)\r
 623 {\r
 624         remove(self);\r
 625 }\r
 626 \r
 627 // pickup evaluation functions\r
 628 // these functions decide how desirable an item is to the bots\r
 629 \r
 630 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};\r
 631 \r
 632 float weapon_pickupevalfunc(entity player, entity item)\r
 633 {\r
 634         float c, i, j, position;\r
 635 \r
 636         // See if I have it already\r
 637         if(player.weapons & item.weapons == item.weapons)\r
 638         {\r
 639                 // If I can pick it up\r
 640                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)\r
 641                         c = 0;\r
 642                 else\r
 643                         c = 0;\r
 644         }\r
 645         else\r
 646                 c = 1;\r
 647 \r
 648         // If custom weapon priorities for bots is enabled rate most wanted weapons higher\r
 649         if( bot_custom_weapon && c )\r
 650         {\r
 651                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)\r
 652                 {\r
 653                         // Find weapon\r
 654                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )\r
 655                                 continue;\r
 656 \r
 657                         // Find the highest position on any range\r
 658                         position = -1;\r
 659                         for(j = 0; j < WEP_LAST ; ++j){\r
 660                                 if(\r
 661                                                 bot_weapons_far[j] == i ||\r
 662                                                 bot_weapons_mid[j] == i ||\r
 663                                                 bot_weapons_close[j] == i\r
 664                                   )\r
 665                                 {\r
 666                                         position = j;\r
 667                                         break;\r
 668                                 }\r
 669                         }\r
 670 \r
 671                         // Rate it\r
 672                         if (position >= 0 )\r
 673                         {\r
 674                                 position = WEP_LAST - position;\r
 675                                 // item.bot_pickupbasevalue is overwritten here\r
 676                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;\r
 677                         }\r
 678                 }\r
 679         }\r
 680 \r
 681         return item.bot_pickupbasevalue * c;\r
 682 };\r
 683 \r
 684 float commodity_pickupevalfunc(entity player, entity item)\r
 685 {\r
 686         float c, i;\r
 687         entity wi;\r
 688         c = 0;\r
 689 \r
 690         // Detect needed ammo\r
 691         for(i = WEP_FIRST; i < WEP_LAST ; ++i)\r
 692         {\r
 693                 wi = get_weaponinfo(i);\r
 694 \r
 695                 if not(wi.weapons & player.weapons)\r
 696                         continue;\r
 697         }\r
 698 \r
 699         if (item.armorvalue)\r
 700         if (player.armorvalue < item.max_armorvalue)\r
 701                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);\r
 702         if (item.health)\r
 703         if (player.health < item.max_health)\r
 704                 c = c + max(0, 1 - player.health / item.max_health);\r
 705 \r
 706         return item.bot_pickupbasevalue * c;\r
 707 };\r
 708 \r
 709 \r
 710 .float is_item;\r
 711 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)\r
 712 {\r
 713         startitem_failed = FALSE;\r
 714 \r
 715         // is it a dropped weapon?\r
 716         if (self.classname == "droppedweapon")\r
 717         {\r
 718                 self.reset = SUB_Remove;\r
 719                 // it's a dropped weapon\r
 720                 self.movetype = MOVETYPE_TOSS;\r
 721                 // Savage: remove thrown items after a certain period of time ("garbage collection")\r
 722                 self.think = RemoveItem;\r
 723                 self.nextthink = time + 60;\r
 724                 // don't drop if in a NODROP zone (such as lava)\r
 725                 traceline(self.origin, self.origin, MOVE_NORMAL, self);\r
 726                 if (trace_dpstartcontents & DPCONTENTS_NODROP)\r
 727                 {\r
 728                         startitem_failed = TRUE;\r
 729                         remove(self);\r
 730                         return;\r
 731                 }\r
 732         }\r
 733         else\r
 734         {\r
 735                 self.reset = Item_Reset;\r
 736                 // it's a level item\r
 737                 if(self.spawnflags & 1)\r
 738                         self.noalign = 1;\r
 739                 if (self.noalign)\r
 740                         self.movetype = MOVETYPE_NONE;\r
 741                 else\r
 742                         self.movetype = MOVETYPE_TOSS;\r
 743                 // do item filtering according to game mode and other things\r
 744                 if (!self.noalign)\r
 745                 {\r
 746                         // first nudge it off the floor a little bit to avoid math errors\r
 747                         setorigin(self, self.origin + '0 0 1');\r
 748                         // set item size before we spawn a spawnfunc_waypoint\r
 749                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)\r
 750                                 setsize (self, '-16 -16 0', '16 16 48');\r
 751                         else\r
 752                                 setsize (self, '-16 -16 0', '16 16 32');\r
 753                         // note droptofloor returns FALSE if stuck/or would fall too far\r
 754                         droptofloor();\r
 755                         waypoint_spawnforitem(self);\r
 756                 }\r
 757 \r
 758                 if(teams_matter)\r
 759                 {\r
 760                         if(self.notteam)\r
 761                         {\r
 762                                 print("removed non-teamplay ", self.classname, "\n");\r
 763                                 startitem_failed = TRUE;\r
 764                                 remove (self);\r
 765                                 return;\r
 766                         }\r
 767                 }\r
 768                 else\r
 769                 {\r
 770                         if(self.notfree)\r
 771                         {\r
 772                                 print("removed non-FFA ", self.classname, "\n");\r
 773                                 startitem_failed = TRUE;\r
 774                                 remove (self);\r
 775                                 return;\r
 776                         }\r
 777                 }\r
 778 \r
 779                 if(self.notq3a)\r
 780                 {\r
 781                         // We aren't TA or something like that, so we keep the Q3A entities\r
 782                         print("removed non-Q3A ", self.classname, "\n");\r
 783                         startitem_failed = TRUE;\r
 784                         remove (self);\r
 785                         return;\r
 786                 }\r
 787 \r
 788                 /*\r
 789                  * can't do it that way, as it would break maps\r
 790                  * TODO make a target_give like entity another way, that perhaps has\r
 791                  * the weapon name in a key\r
 792                 if(self.targetname)\r
 793                 {\r
 794                         // target_give not yet supported; maybe later\r
 795                         print("removed targeted ", self.classname, "\n");\r
 796                         startitem_failed = TRUE;\r
 797                         remove (self);\r
 798                         return;\r
 799                 }\r
 800                 */\r
 801 \r
 802                 if(cvar("spawn_debug") >= 2)\r
 803                 {\r
 804                         entity otheritem;\r
 805                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)\r
 806                         {\r
 807                                 if(otheritem.is_item)\r
 808                                 {\r
 809                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));\r
 810                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");\r
 811                                         error("Mapper sucks.");\r
 812                                 }\r
 813                         }\r
 814                         self.is_item = TRUE;\r
 815                 }\r
 816 \r
 817                 weaponsInMap |= weaponid;\r
 818 \r
 819                 if(g_lms)\r
 820                 {\r
 821                         startitem_failed = TRUE;\r
 822                         remove(self);\r
 823                         return;\r
 824                 }\r
 825                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)\r
 826                 {\r
 827                         startitem_failed = TRUE;\r
 828                         remove (self);\r
 829                         return;\r
 830                 }\r
 831 \r
 832                 precache_model (itemmodel);\r
 833                 precache_sound (pickupsound);\r
 834                 precache_sound ("misc/itemrespawn.wav");\r
 835                 precache_sound ("misc/itemrespawncountdown.wav");\r
 836 \r
 837                 if(itemid == IT_STRENGTH)\r
 838                         precache_sound ("misc/strength_respawn.wav");\r
 839                 if(itemid == IT_INVINCIBLE)\r
 840                         precache_sound ("misc/shield_respawn.wav");\r
 841 \r
 842                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))\r
 843                         self.target = "###item###"; // for finding the nearest item using find()\r
 844         }\r
 845 \r
 846         self.bot_pickup = TRUE;\r
 847         self.bot_pickupevalfunc = pickupevalfunc;\r
 848         self.bot_pickupbasevalue = pickupbasevalue;\r
 849         self.mdl = itemmodel;\r
 850         self.item_pickupsound = pickupsound;\r
 851         // let mappers override respawntime\r
 852         if(!self.respawntime) // both set\r
 853         {\r
 854                 self.respawntime = defaultrespawntime;\r
 855                 self.respawntimejitter = defaultrespawntimejitter;\r
 856         }\r
 857         self.netname = itemname;\r
 858         self.items = itemid;\r
 859         self.weapons = weaponid;\r
 860         self.flags = FL_ITEM | itemflags;\r
 861         self.touch = Item_Touch;\r
 862         setmodel (self, self.mdl); // precision set below\r
 863         self.effects |= EF_LOWPRECISION;\r
 864         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)\r
 865                 setsize (self, '-16 -16 0', '16 16 48');\r
 866         else\r
 867                 setsize (self, '-16 -16 0', '16 16 32');\r
 868         if(itemflags & FL_WEAPON)\r
 869                 self.modelflags |= MF_ROTATE;\r
 870 \r
 871         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely\r
 872         if (itemflags & FL_WEAPON)\r
 873         {\r
 874                 // neutral team color for pickup weapons\r
 875                 self.colormap = 1024; // color shirt=0 pants=0 grey\r
 876         }\r
 877 \r
 878         Item_Show(self, 1);\r
 879         self.state = 0;\r
 880         if(self.team)\r
 881         {\r
 882                 if(!self.cnt)\r
 883                         self.cnt = 1; // item probability weight\r
 884                 self.effects = self.effects | EF_NODRAW; // marker for item team search\r
 885                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);\r
 886         }\r
 887         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!\r
 888                 Item_ScheduleInitialRespawn(self);\r
 889 }\r
 890 \r
 891 float minst_no_auto_cells;\r
 892 void minst_remove_item (void) {\r
 893         if(minst_no_auto_cells)\r
 894                 remove(self);\r
 895 }\r
 896 \r
 897 float internalteam;\r
 898 \r
 899 void weapon_defaultspawnfunc(float wpn)\r
 900 {\r
 901         entity e;\r
 902         float t;\r
 903         var .float ammofield;\r
 904         string s;\r
 905         entity oldself;\r
 906         float i, j;\r
 907 \r
 908         // set the respawntime in advance (so replaced weapons can copy it)\r
 909 \r
 910         if(!self.respawntime)\r
 911         {\r
 912                 e = get_weaponinfo(wpn);\r
 913                 if(e.items == IT_SUPERWEAPON)\r
 914                 {\r
 915                         self.respawntime = g_pickup_respawntime_powerup;\r
 916                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;\r
 917                 }\r
 918                 else\r
 919                 {\r
 920                         self.respawntime = g_pickup_respawntime_weapon;\r
 921                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;\r
 922                 }\r
 923         }\r
 924 \r
 925         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")\r
 926         {\r
 927                 e = get_weaponinfo(wpn);\r
 928                 s = cvar_string(strcat("g_weaponreplace_", e.netname));\r
 929                 if(s == "0")\r
 930                 {\r
 931                         remove(self);\r
 932                         startitem_failed = TRUE;\r
 933                         return;\r
 934                 }\r
 935                 t = tokenize_console(s);\r
 936                 if(t >= 2)\r
 937                 {\r
 938                         self.team = --internalteam;\r
 939                         oldself = self;\r
 940                         for(i = 1; i < t; ++i)\r
 941                         {\r
 942                                 s = argv(i);\r
 943                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)\r
 944                                 {\r
 945                                         e = get_weaponinfo(j);\r
 946                                         if(e.netname == s)\r
 947                                         {\r
 948                                                 self = spawn();\r
 949                                                 copyentity(oldself, self);\r
 950                                                 self.classname = "replacedweapon";\r
 951                                                 weapon_defaultspawnfunc(j);\r
 952                                                 break;\r
 953                                         }\r
 954                                 }\r
 955                                 if(j > WEP_LAST)\r
 956                                 {\r
 957                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");\r
 958                                 }\r
 959                         }\r
 960                         self = oldself;\r
 961                 }\r
 962                 if(t >= 1)\r
 963                 {\r
 964                         s = argv(0);\r
 965                         wpn = 0;\r
 966                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)\r
 967                         {\r
 968                                 e = get_weaponinfo(j);\r
 969                                 if(e.netname == s)\r
 970                                 {\r
 971                                         wpn = j;\r
 972                                         break;\r
 973                                 }\r
 974                         }\r
 975                         if(j > WEP_LAST)\r
 976                         {\r
 977                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");\r
 978                         }\r
 979                 }\r
 980                 if(wpn == 0)\r
 981                 {\r
 982                         remove(self);\r
 983                         startitem_failed = TRUE;\r
 984                         return;\r
 985                 }\r
 986         }\r
 987 \r
 988         e = get_weaponinfo(wpn);\r
 989 \r
 990         if(e.items && e.items != IT_SUPERWEAPON)\r
 991         {\r
 992                 for(i = 0, j = 1; i < 24; ++i, j *= 2)\r
 993                 {\r
 994                         if(e.items & j)\r
 995                         {\r
 996                                 ammofield = Item_CounterField(j);\r
 997                                 if(!self.ammofield)\r
 998                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));\r
 999                         }\r
1000                 }\r
1001         }\r
1002         else\r
1003         {\r
1004                 self.flags |= FL_NO_WEAPON_STAY;\r
1005         }\r
1006 \r
1007         // weapon stay isn't supported for teamed weapons\r
1008         if(self.team)\r
1009                 self.flags |= FL_NO_WEAPON_STAY;\r
1010 \r
1011         if(g_weapon_stay == 2 && self.classname != "droppedweapon")\r
1012         {\r
1013                 self.ammo_fuel = 0;\r
1014                 // weapon stay 2: don't use ammo on weapon pickups; instead\r
1015                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*\r
1016         }\r
1017 \r
1018         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);\r
1019         if (self.modelindex) // don't precache if self was removed\r
1020                 weapon_action(e.weapon, WR_PRECACHE);\r
1021 }\r
1022 \r
1023 void spawnfunc_item_armor_small (void) {\r
1024         if(!self.armorvalue)\r
1025                 self.armorvalue = g_pickup_armorsmall;\r
1026         if(!self.max_armorvalue)\r
1027                 self.max_armorvalue = g_pickup_armorsmall_max;\r
1028         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);\r
1029 }\r
1030 \r
1031 void spawnfunc_item_armor_medium (void) {\r
1032         if(!self.armorvalue)\r
1033                 self.armorvalue = g_pickup_armormedium;\r
1034         if(!self.max_armorvalue)\r
1035                 self.max_armorvalue = g_pickup_armormedium_max;\r
1036         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);\r
1037 }\r
1038 \r
1039 void spawnfunc_item_armor_big (void) {\r
1040         if(!self.armorvalue)\r
1041                 self.armorvalue = g_pickup_armorbig;\r
1042         if(!self.max_armorvalue)\r
1043                 self.max_armorvalue = g_pickup_armorbig_max;\r
1044         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);\r
1045 }\r
1046 \r
1047 void spawnfunc_item_armor_large (void) {\r
1048         if(!self.armorvalue)\r
1049                 self.armorvalue = g_pickup_armorlarge;\r
1050         if(!self.max_armorvalue)\r
1051                 self.max_armorvalue = g_pickup_armorlarge_max;\r
1052         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);\r
1053 }\r
1054 \r
1055 void spawnfunc_item_health_small (void) {\r
1056         if(!self.max_health)\r
1057                 self.max_health = g_pickup_healthsmall_max;\r
1058         if(!self.health)\r
1059                 self.health = g_pickup_healthsmall;\r
1060         self.dmg = g_pickup_healthsmall_consumable;\r
1061         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);\r
1062 }\r
1063 \r
1064 void spawnfunc_item_health_medium (void) {\r
1065         if(!self.max_health)\r
1066                 self.max_health = g_pickup_healthmedium_max;\r
1067         if(!self.health)\r
1068                 self.health = g_pickup_healthmedium;\r
1069         self.dmg = g_pickup_healthmedium_consumable;\r
1070         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);\r
1071 }\r
1072 \r
1073 void spawnfunc_item_health_large (void) {\r
1074         if(!self.max_health)\r
1075                 self.max_health = g_pickup_healthlarge_max;\r
1076         if(!self.health)\r
1077                 self.health = g_pickup_healthlarge;\r
1078         self.dmg = g_pickup_healthlarge_consumable;\r
1079         StartItem ("models/items/g_h50.md3", "misc/largehealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);\r
1080 }\r
1081 \r
1082 void spawnfunc_item_health_mega (void) {\r
1083         if(!cvar("g_powerup_superhealth"))\r
1084                 return;\r
1085 \r
1086         if((g_arena || g_ca) && !cvar("g_arena_powerups"))\r
1087                 return;\r
1088 \r
1089         if(!self.max_health)\r
1090                 self.max_health = g_pickup_healthmega_max;\r
1091         if(!self.health)\r
1092                 self.health = g_pickup_healthmega;\r
1093         self.dmg = g_pickup_healthmega_consumable;\r
1094         StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);\r
1095 }\r
1096 \r
1097 // support old misnamed entities\r
1098 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Voretournament maps it is an armor shard\r
1099 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }\r
1100 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }\r
1101 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }\r
1102 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }\r
1103 \r
1104 void spawnfunc_item_strength (void) {\r
1105         if(!cvar("g_powerup_strength"))\r
1106                 return;\r
1107 \r
1108         if((g_arena || g_ca) && !cvar("g_arena_powerups"))\r
1109                 return;\r
1110 \r
1111         precache_sound("weapons/strength_fire.wav");\r
1112         self.strength_finished = 30;\r
1113         StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);\r
1114 }\r
1115 \r
1116 void spawnfunc_item_invincible (void) {\r
1117         if(!cvar("g_powerup_shield"))\r
1118                 return;\r
1119 \r
1120         if((g_arena || g_ca) && !cvar("g_arena_powerups"))\r
1121                 return;\r
1122 \r
1123         self.invincible_finished = 30;\r
1124         StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);\r
1125 }\r
1126 \r
1127 // compatibility:\r
1128 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}\r
1129 \r
1130 float GiveItems(entity e, float beginarg, float endarg);\r
1131 void target_items_use (void)\r
1132 {\r
1133         if(activator.classname == "droppedweapon")\r
1134         {\r
1135                 EXACTTRIGGER_TOUCH;\r
1136                 remove(activator);\r
1137                 return;\r
1138         }\r
1139 \r
1140         if(activator.classname != "player")\r
1141                 return;\r
1142         if(activator.deadflag != DEAD_NO)\r
1143                 return;\r
1144         EXACTTRIGGER_TOUCH;\r
1145 \r
1146         entity e;\r
1147         for(e = world; (e = find(e, classname, "droppedweapon")); )\r
1148                 if(e.enemy == activator)\r
1149                         remove(e);\r
1150 \r
1151         if(GiveItems(activator, 0, tokenize_console(self.netname)))\r
1152                 centerprint(activator, self.message);\r
1153 }\r
1154 \r
1155 void spawnfunc_target_items (void)\r
1156 {\r
1157         float n, i, j;\r
1158         entity e;\r
1159 \r
1160         self.use = target_items_use;\r
1161         if(!self.strength_finished)\r
1162                 self.strength_finished = cvar("g_balance_powerup_strength_time");\r
1163         if(!self.invincible_finished)\r
1164                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");\r
1165 \r
1166         precache_sound("misc/itempickup.wav");\r
1167         precache_sound("misc/itempickup.wav");\r
1168         precache_sound("misc/itempickup.wav");\r
1169         precache_sound("misc/itempickup.wav");\r
1170         precache_sound("misc/megahealth.wav");\r
1171         precache_sound("misc/armor25.wav");\r
1172         precache_sound("misc/powerup.wav");\r
1173         precache_sound("misc/poweroff.wav");\r
1174         precache_sound("weapons/weaponpickup.wav");\r
1175 \r
1176         n = tokenize_console(self.netname);\r
1177         if(argv(0) == "give")\r
1178         {\r
1179                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));\r
1180         }\r
1181         else\r
1182         {\r
1183                 for(i = 0; i < n; ++i)\r
1184                 {\r
1185                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;\r
1186                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;\r
1187                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;\r
1188                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;\r
1189                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;\r
1190                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;\r
1191                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;\r
1192                         else\r
1193                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)\r
1194                         {\r
1195                                 e = get_weaponinfo(j);\r
1196                                 if(argv(i) == e.netname)\r
1197                                 {\r
1198                                         self.weapons |= e.weapons;\r
1199                                         if(self.spawnflags == 0 || self.spawnflags == 2)\r
1200                                                 weapon_action(e.weapon, WR_PRECACHE);\r
1201                                         break;\r
1202                                 }\r
1203                         }\r
1204                         if(j > WEP_LAST)\r
1205                                 print("target_items: invalid item ", argv(i), "\n");\r
1206                 }\r
1207 \r
1208                 string itemprefix, valueprefix;\r
1209                 if(self.spawnflags == 0)\r
1210                 {\r
1211                         itemprefix = "";\r
1212                         valueprefix = "";\r
1213                 }\r
1214                 else if(self.spawnflags == 1)\r
1215                 {\r
1216                         itemprefix = "max ";\r
1217                         valueprefix = "max ";\r
1218                 }\r
1219                 else if(self.spawnflags == 2)\r
1220                 {\r
1221                         itemprefix = "min ";\r
1222                         valueprefix = "min ";\r
1223                 }\r
1224                 else if(self.spawnflags == 4)\r
1225                 {\r
1226                         itemprefix = "minus ";\r
1227                         valueprefix = "max ";\r
1228                 }\r
1229                 else\r
1230                         error("invalid spawnflags");\r
1231 \r
1232                 self.netname = "";\r
1233                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");\r
1234                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");\r
1235                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");\r
1236                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");\r
1237                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");\r
1238                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");\r
1239                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");\r
1240                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");\r
1241                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");\r
1242                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)\r
1243                 {\r
1244                         e = get_weaponinfo(j);\r
1245                         if(e.weapons)\r
1246                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);\r
1247                 }\r
1248         }\r
1249         self.netname = strzone(self.netname);\r
1250         //print(self.netname, "\n");\r
1251 \r
1252         n = tokenize_console(self.netname);\r
1253         for(i = 0; i < n; ++i)\r
1254         {\r
1255                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)\r
1256                 {\r
1257                         e = get_weaponinfo(j);\r
1258                         if(argv(i) == e.netname)\r
1259                         {\r
1260                                 weapon_action(e.weapon, WR_PRECACHE);\r
1261                                 break;\r
1262                         }\r
1263                 }\r
1264         }\r
1265 }\r
1266 \r
1267 void spawnfunc_item_fuel(void)\r
1268 {\r
1269         if(!self.ammo_fuel)\r
1270                 self.ammo_fuel = g_pickup_fuel;\r
1271         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);\r
1272 }\r
1273 \r
1274 void spawnfunc_item_fuel_regen(void)\r
1275 {\r
1276         if(start_items & IT_FUEL_REGEN)\r
1277         {\r
1278                 spawnfunc_item_fuel();\r
1279                 return;\r
1280         }\r
1281         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel regenerator", IT_FUEL_REGEN, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);\r
1282 }\r
1283 \r
1284 void spawnfunc_item_jetpack(void)\r
1285 {\r
1286         if(!self.ammo_fuel)\r
1287                 self.ammo_fuel = g_pickup_fuel_jetpack;\r
1288         if(start_items & IT_JETPACK)\r
1289         {\r
1290                 spawnfunc_item_fuel();\r
1291                 return;\r
1292         }\r
1293         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_weapon, g_pickup_respawntimejitter_weapon, "Jet pack", IT_JETPACK, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);\r
1294 }\r
1295 \r
1296 #define OP_SET 0\r
1297 #define OP_MIN 1\r
1298 #define OP_MAX 2\r
1299 #define OP_PLUS 3\r
1300 #define OP_MINUS 4\r
1301 \r
1302 float GiveBit(entity e, .float fld, float bit, float op, float val)\r
1303 {\r
1304         float v0, v1;\r
1305         v0 = (e.fld & bit);\r
1306         switch(op)\r
1307         {\r
1308                 case OP_SET:\r
1309                         if(val > 0)\r
1310                                 e.fld |= bit;\r
1311                         else\r
1312                                 e.fld &~= bit;\r
1313                         break;\r
1314                 case OP_MIN:\r
1315                 case OP_PLUS:\r
1316                         if(val > 0)\r
1317                                 e.fld |= bit;\r
1318                         break;\r
1319                 case OP_MAX:\r
1320                         if(val <= 0)\r
1321                                 e.fld &~= bit;\r
1322                         break;\r
1323                 case OP_MINUS:\r
1324                         if(val > 0)\r
1325                                 e.fld &~= bit;\r
1326                         break;\r
1327         }\r
1328         v1 = (e.fld & bit);\r
1329         return (v0 != v1);\r
1330 }\r
1331 \r
1332 float GiveValue(entity e, .float fld, float op, float val)\r
1333 {\r
1334         float v0, v1;\r
1335         v0 = e.fld;\r
1336         switch(op)\r
1337         {\r
1338                 case OP_SET:\r
1339                         e.fld = val;\r
1340                         break;\r
1341                 case OP_MIN:\r
1342                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells\r
1343                         break;\r
1344                 case OP_MAX:\r
1345                         e.fld = min(e.fld, val);\r
1346                         break;\r
1347                 case OP_PLUS:\r
1348                         e.fld += val;\r
1349                         break;\r
1350                 case OP_MINUS:\r
1351                         e.fld -= val;\r
1352                         break;\r
1353         }\r
1354         v1 = e.fld;\r
1355         return (v0 != v1);\r
1356 }\r
1357 \r
1358 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)\r
1359 {\r
1360         if(v1 == v0)\r
1361                 return;\r
1362         if(v1 <= v0 - t)\r
1363         {\r
1364                 if(snd_decr != "")\r
1365                         sound (e, CHAN_AUTO, snd_decr, VOL_BASE, ATTN_NORM);\r
1366         }\r
1367         else if(v0 >= v0 + t)\r
1368         {\r
1369                 if(snd_incr != "")\r
1370                         sound (e, CHAN_AUTO, snd_incr, VOL_BASE, ATTN_NORM);\r
1371         }\r
1372 }\r
1373 \r
1374 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)\r
1375 {\r
1376         if(v0 < v1)\r
1377                 e.rotfield = max(e.rotfield, time + rottime);\r
1378         else if(v0 > v1)\r
1379                 e.regenfield = max(e.regenfield, time + regentime);\r
1380 }\r
1381 \r
1382 #define PREGIVE(e,f) float save_##f; save_##f = (e).f\r
1383 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)\r
1384 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)\r
1385 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)\r
1386 \r
1387 float GiveItems(entity e, float beginarg, float endarg)\r
1388 {\r
1389         float got, i, j, val, op;\r
1390         float _switchweapon;\r
1391         entity wi;\r
1392         string cmd;\r
1393 \r
1394         val = 999;\r
1395         op = OP_SET;\r
1396 \r
1397         got = 0;\r
1398 \r
1399         _switchweapon = FALSE;\r
1400         if (e.autoswitch)\r
1401                 if (e.switchweapon == w_getbestweapon(e))\r
1402                         _switchweapon = TRUE;\r
1403 \r
1404         e.strength_finished = max(0, e.strength_finished - time);\r
1405         e.invincible_finished = max(0, e.invincible_finished - time);\r
1406         \r
1407         PREGIVE(e, items);\r
1408         PREGIVE(e, weapons);\r
1409         PREGIVE(e, strength_finished);\r
1410         PREGIVE(e, invincible_finished);\r
1411         PREGIVE(e, ammo_fuel);\r
1412         PREGIVE(e, armorvalue);\r
1413         PREGIVE(e, health);\r
1414 \r
1415         for(i = beginarg; i < endarg; ++i)\r
1416         {\r
1417                 cmd = argv(i);\r
1418 \r
1419                 if(cmd == "0" || stof(cmd))\r
1420                 {\r
1421                         val = stof(cmd);\r
1422                         continue;\r
1423                 }\r
1424                 switch(cmd)\r
1425                 {\r
1426                         case "no":\r
1427                                 op = OP_MAX;\r
1428                                 val = 0;\r
1429                                 continue;\r
1430                         case "max":\r
1431                                 op = OP_MAX;\r
1432                                 continue;\r
1433                         case "min":\r
1434                                 op = OP_MIN;\r
1435                                 continue;\r
1436                         case "plus":\r
1437                                 op = OP_PLUS;\r
1438                                 continue;\r
1439                         case "minus":\r
1440                                 op = OP_MINUS;\r
1441                                 continue;\r
1442                         case "ALL":\r
1443                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);\r
1444                                 got += GiveValue(e, strength_finished, op, time + val);\r
1445                                 got += GiveValue(e, invincible_finished, op, time + val);\r
1446                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);\r
1447                         case "all":\r
1448                                 got += GiveBit(e, items, IT_JETPACK, op, val);\r
1449                                 got += GiveValue(e, health, op, val);\r
1450                                 got += GiveValue(e, armorvalue, op, val);\r
1451                         case "allweapons":\r
1452                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)\r
1453                                 {\r
1454                                         wi = get_weaponinfo(j);\r
1455                                         if(wi.weapons)\r
1456                                                 got += GiveBit(e, weapons, wi.weapons, op, val);\r
1457                                 }\r
1458                         case "allammo":\r
1459                                 got += GiveValue(e, ammo_fuel, op, val);\r
1460                                 break;\r
1461                         case "unlimited_ammo":\r
1462                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);\r
1463                                 break;\r
1464                         case "unlimited_weapon_ammo":\r
1465                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);\r
1466                                 break;\r
1467                         case "unlimited_superweapons":\r
1468                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);\r
1469                                 break;\r
1470                         case "jetpack":\r
1471                                 got += GiveBit(e, items, IT_JETPACK, op, val);\r
1472                                 break;\r
1473                         case "fuel_regen":\r
1474                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);\r
1475                                 break;\r
1476                         case "strength":\r
1477                                 got += GiveValue(e, strength_finished, op, val);\r
1478                                 break;\r
1479                         case "invincible":\r
1480                                 got += GiveValue(e, invincible_finished, op, val);\r
1481                                 break;\r
1482                         case "health":\r
1483                                 got += GiveValue(e, health, op, val);\r
1484                                 break;\r
1485                         case "armor":\r
1486                                 got += GiveValue(e, armorvalue, op, val);\r
1487                                 break;\r
1488                         case "fuel":\r
1489                                 got += GiveValue(e, ammo_fuel, op, val);\r
1490                                 break;\r
1491                         default:\r
1492                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)\r
1493                                 {\r
1494                                         wi = get_weaponinfo(j);\r
1495                                         if(cmd == wi.netname)\r
1496                                         {\r
1497                                                 got += GiveBit(e, weapons, wi.weapons, op, val);\r
1498                                                 break;\r
1499                                         }\r
1500                                 }\r
1501                                 if(j > WEP_LAST)\r
1502                                         print("give: invalid item ", cmd, "\n");\r
1503                                 break;\r
1504                 }\r
1505                 val = 999;\r
1506                 op = OP_SET;\r
1507         }\r
1508 \r
1509         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);\r
1510         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");\r
1511         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");\r
1512         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);\r
1513         for(j = WEP_FIRST; j <= WEP_LAST; ++j)\r
1514         {\r
1515                 wi = get_weaponinfo(j);\r
1516                 if(wi.weapons)\r
1517                 {\r
1518                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);\r
1519                         if not(save_weapons & wi.weapons)\r
1520                                 if(e.weapons & wi.weapons)\r
1521                                         weapon_action(wi.weapon, WR_PRECACHE);\r
1522                 }\r
1523         }\r
1524         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");\r
1525         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");\r
1526         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, cvar("g_balance_pause_fuel_rot"), pauseregenhealth_finished, cvar("g_balance_pause_fuel_regen"), "misc/itempickup.wav", string_null);\r
1527         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, cvar("g_balance_pause_armor_rot"), pauseregenarmor_finished, cvar("g_balance_pause_armor_regen"), "misc/armor25.wav", string_null);\r
1528         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, cvar("g_balance_pause_health_rot"), pauseregenhealth_finished, cvar("g_balance_pause_health_regen"), "misc/megahealth.wav", string_null);\r
1529 \r
1530         if(e.strength_finished <= 0)\r
1531                 e.strength_finished = 0;\r
1532         else\r
1533                 e.strength_finished += time;\r
1534         if(e.invincible_finished <= 0)\r
1535                 e.invincible_finished = 0;\r
1536         else\r
1537                 e.invincible_finished += time;\r
1538 \r
1539         if not(e.weapons & W_WeaponBit(e.switchweapon))\r
1540                 _switchweapon = TRUE;\r
1541         if(_switchweapon)\r
1542                 W_SwitchWeapon_Force(e, w_getbestweapon(e));\r
1543 \r
1544         return got;\r
1545 }\r