data/qcsrc/server/vore.qc

   1 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   2 .float complain_vore;\r
   3 .float vore_oldmovetype, vore_oldsolid;\r
   4 \r
   5 const float system_delay_time = 0.1;\r
   6 const float complain_delay_time = 1;\r
   7 const float button_delay_time = 0.5;\r
   8 \r
   9 entity Swallow_player_check()\r
  10 {\r
  11         // check if we can swallow a player instead of firing our weapon\r
  12 \r
  13         float swallow_range;\r
  14         vector vore_w_shotorg, vore_w_shotdir;\r
  15 \r
  16         swallow_range = cvar("g_balance_vore_swallow_range");\r
  17         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  18                 swallow_range *= self.scale;\r
  19         makevectors(self.angles);\r
  20         vore_w_shotorg = self.origin;\r
  21         vore_w_shotdir = v_forward;\r
  22 \r
  23         if(self.antilag_debug)\r
  24                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  25         else\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  27         if(trace_fraction < 1)\r
  28         if(trace_ent.classname == "player")\r
  29                 return trace_ent;\r
  30         return world;\r
  31 }\r
  32 \r
  33 float Swallow_condition_check(entity prey)\r
  34 {\r
  35         // checks the necessary conditions for swallowing a player\r
  36 \r
  37         if(prey != self)\r
  38         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  39         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  40         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  41         {\r
  42                 float prey_mass;\r
  43                 prey_mass = cvar("g_balance_vore_load_prey_mass");\r
  44                 if(cvar("g_healthsize"))\r
  45                         prey_mass *= prey.scale;\r
  46 \r
  47                 string swallow_complain;\r
  48                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  49                         swallow_complain = "You cannot swallow your team mates\n";\r
  50                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  51                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  52                 else if(self.stomach_load + prey_mass > self.stomach_maxload)\r
  53                         swallow_complain = strcat("You don't have any room to swallow this player. Their mass is ^3", ftos(prey_mass), "^7 and your remaining capacity is ^3", ftos(self.stomach_maxload - self.stomach_load), "\n");\r
  54                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  55                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  56                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  57                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  58 \r
  59                 if(swallow_complain != "")\r
  60                 {\r
  61                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  62                         {\r
  63                                 play2(self, "misc/forbidden.wav");\r
  64                                 sprint(self, swallow_complain);\r
  65                                 self.complain_vore = time + complain_delay_time;\r
  66                         }\r
  67                         return FALSE;\r
  68                 }\r
  69                 return TRUE;\r
  70         }\r
  71         return FALSE;\r
  72 }\r
  73 \r
  74 float Stomach_TeamMates_check(entity pred)\r
  75 {\r
  76         // checks if a player's stomach contains any team mates\r
  77 \r
  78         entity head;\r
  79         if(teams_matter)\r
  80         {\r
  81                 FOR_EACH_PLAYER(head)\r
  82                 {\r
  83                         if(head.predator == pred && head.team == pred.team)\r
  84                                 return TRUE;\r
  85                 }\r
  86         }\r
  87         return FALSE;\r
  88 }\r
  89 \r
  90 float Stomach_HasLivePrey(entity pred)\r
  91 {\r
  92         entity head;\r
  93         FOR_EACH_PLAYER(head)\r
  94         {\r
  95                 if(head.predator == pred)\r
  96                 if(head.deadflag == DEAD_NO)\r
  97                         return TRUE;\r
  98         }\r
  99         return FALSE;\r
 100 }\r
 101 \r
 102 float Vore_CanLeave()\r
 103 {\r
 104         if(self.stat_eaten)\r
 105         {\r
 106                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 107                         return TRUE;\r
 108                 if(teams_matter && self.team == self.predator.team)\r
 109                         return TRUE;\r
 110                 if(g_rpg && cvar("g_rpg_canleave"))\r
 111                         return TRUE;\r
 112         }\r
 113         return FALSE;\r
 114 }\r
 115 \r
 116 // position the camera properly for prey\r
 117 void Vore_SetPreyPositions(entity pred)\r
 118 {\r
 119         // pred is the predator and head is the prey\r
 120 \r
 121         local entity head;\r
 122 \r
 123         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 124         // else all players overlap in the center. To do this, we use a random origin on all players in the same stomach.\r
 125         FOR_EACH_PLAYER(head)\r
 126         {\r
 127                 if(head.predator == pred)\r
 128                 {\r
 129                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 130                         head.view_ofs_x = PL_PREY_VIEW_OFS_x + crandom() * cvar("g_vore_neighborprey_distance");\r
 131                         head.view_ofs_y = PL_PREY_VIEW_OFS_y + crandom() * cvar("g_vore_neighborprey_distance");\r
 132                         head.view_ofs_z = PL_PREY_VIEW_OFS_z;\r
 133                 }\r
 134         }\r
 135 }\r
 136 \r
 137 .float gurgle_oldstomachload;\r
 138 void Vore_GurgleSound()\r
 139 {\r
 140         if(time > self.gurglesound_finished || (self.gurgle_oldstomachload != self.stomach_load && !self.digesting))\r
 141         {\r
 142                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE, VOL_BASE);\r
 143 \r
 144                 // yes, hard coded sound length. I know it's bad but what can I do?\r
 145                 if(cvar("g_healthsize") && cvar("g_healthsize_pitch"))\r
 146                         self.gurglesound_finished = time + 11 * pow(self.scale, -cvar("g_healthsize_pitch")); // modified sound pitch, based on player scale\r
 147                 else\r
 148                         self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 149 \r
 150                 self.gurgle_oldstomachload = self.stomach_load;\r
 151         }\r
 152 }\r
 153 \r
 154 void Vore_AutoDigest(entity e)\r
 155 {\r
 156         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 157 \r
 158         if(!cvar("g_vore_digestion") || e.digesting)\r
 159                 return;\r
 160         if(g_rpg)\r
 161                 return; // RPG is choice based, so don't do things automatically there\r
 162         if(clienttype(e) != CLIENTTYPE_REAL)\r
 163                 return; // this feature is only for players, not bots\r
 164         if(Stomach_TeamMates_check(e))\r
 165                 return; // never begin automatic digestion if we've swallowed a team mate\r
 166 \r
 167         e.digesting = TRUE;\r
 168 }\r
 169 \r
 170 void Vore_StomachLoad_Apply()\r
 171 {\r
 172         // apply stomach weight that makes you heavier and larger the more you eat\r
 173         // slowing the player is done in cl_physics.qc\r
 174         if(self.classname != "player")\r
 175                 return;\r
 176 \r
 177         entity e;\r
 178         float prey_mass, final_load;\r
 179 \r
 180         // apply the stomach capacity of the predator\r
 181         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 182         if(cvar("g_healthsize"))\r
 183                 self.stomach_maxload *= self.scale;\r
 184         self.stomach_maxload = ceil(self.stomach_maxload);\r
 185 \r
 186         FOR_EACH_PLAYER(e)\r
 187         {\r
 188                 if(e.predator == self)\r
 189                 {\r
 190                         prey_mass = cvar("g_balance_vore_load_prey_mass");\r
 191                         if(cvar("g_healthsize"))\r
 192                                 prey_mass *= e.scale;\r
 193                         final_load += ceil(prey_mass);\r
 194                         if(self.cvar_cl_vore_autodigest > 1)\r
 195                                 Vore_AutoDigest(self);\r
 196                 }\r
 197         }\r
 198         for(e = world; (e = find(e, classname, "consumable")); )\r
 199         {\r
 200                 if(e.predator == self)\r
 201                 {\r
 202                         final_load += ceil(e.dmg);\r
 203                         if(self.cvar_cl_vore_autodigest > 0)\r
 204                                 Vore_AutoDigest(self);\r
 205                 }\r
 206         }\r
 207         self.stomach_load = final_load;\r
 208 \r
 209         // apply weight\r
 210         self.gravity = 1 + (self.stomach_load / self.stomach_maxload) * cvar("g_balance_vore_load_pred_weight");\r
 211         if(!self.gravity && self.stomach_load)\r
 212                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 213 }\r
 214 \r
 215 .entity swallow_model;\r
 216 float Vore_SwallowModel_CustomizeEntityForClient()\r
 217 {\r
 218         // use the same system as the weapon model\r
 219 \r
 220         self.viewmodelforclient = self.owner;\r
 221         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 222 \r
 223         if(other.classname == "spectator")\r
 224         if(other.enemy == self.owner)\r
 225         {\r
 226                 self.viewmodelforclient = other;\r
 227                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 228         }\r
 229 \r
 230         return TRUE;\r
 231 }\r
 232 \r
 233 void Vore_SwallowModel_Think()\r
 234 {\r
 235         // update the position of the swallow model to match our swallow progress\r
 236         float dist;\r
 237         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 238         if(cvar("g_healthsize"))\r
 239                 dist *= self.scale;\r
 240         self.view_ofs = '1 0 0' * dist;\r
 241 \r
 242         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 243         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 244         {\r
 245                 remove(self.owner.swallow_model);\r
 246                 self.owner.swallow_model = world;\r
 247                 return;\r
 248         }\r
 249 \r
 250         // properties that should update whenever possible, but when the predator is not available\r
 251         self.nextthink = time;\r
 252 }\r
 253 \r
 254 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 255 {\r
 256         // if we don't have a swallow model already, spawn one\r
 257         if(!prey.swallow_model)\r
 258         {\r
 259                 prey.swallow_model = spawn();\r
 260                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 261                 prey.swallow_model.solid = SOLID_NOT;\r
 262                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 263                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 264                 prey.swallow_model.owner = prey;\r
 265                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 266                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 267                 prey.swallow_model.nextthink = time;\r
 268         }\r
 269 \r
 270         // properties that should update whenever possible, but when the predator is available\r
 271         string player_swallowmodel;\r
 272         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 273         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 274                 setmodel(prey.swallow_model, player_swallowmodel);\r
 275         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 276                 prey.swallow_model.skin = pred.skin;\r
 277         if(cvar("g_healthsize"))\r
 278                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 279         if(prey.swallow_model.enemy != pred)\r
 280                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 281         if(prey.swallow_model.colormap != pred.colormap)\r
 282                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 283         if(prey.swallow_model.glowmod != pred.glowmod)\r
 284                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 285 }\r
 286 \r
 287 .entity pusher;\r
 288 .float pushltime;\r
 289 void Vore_Swallow(entity e)\r
 290 {\r
 291         // this player is being swallowed by another player, apply the proper changes\r
 292 \r
 293         e.vore_oldmovetype = e.movetype;\r
 294         e.vore_oldsolid = e.solid;\r
 295         e.punchvector_z = cvar("g_balance_vore_swallow_prey_punchvector");\r
 296 \r
 297         e.predator = self;\r
 298         setorigin(e, e.predator.origin);\r
 299         e.velocity = '0 0 0';\r
 300         e.movetype = MOVETYPE_FOLLOW;\r
 301         e.solid = SOLID_NOT;\r
 302         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 303 \r
 304         float scalediff;\r
 305         scalediff = cvar("g_healthsize") ? e.scale / e.predator.scale : 1; // the tighter the gut, the greater the effect\r
 306 \r
 307         // drop keys (KH) and flags (CTF) when we get swallowed\r
 308         kh_Key_DropAll(e, FALSE);\r
 309         if(e.flagcarried)\r
 310                 DropFlag(e.flagcarried, world, e.predator);\r
 311 \r
 312         if(stov(cvar_string("g_vore_regurgitatecolor_color_normal")))\r
 313                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_normal"));\r
 314 \r
 315         if(teams_matter && e.team == e.predator.team)\r
 316         {\r
 317                 if(cvar("g_vore_kick"))\r
 318                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 319                 if(cvar("g_vore_digestion"))\r
 320                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 321         }\r
 322 \r
 323         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 324         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 325         e.predator.punchangle_x = crandom() * cvar("g_balance_vore_swallow_predator_punchangle") * scalediff;\r
 326         e.predator.punchangle_y = crandom() * cvar("g_balance_vore_swallow_predator_punchangle") * scalediff;\r
 327         e.predator.punchangle_z = crandom() * cvar("g_balance_vore_swallow_predator_punchangle") * scalediff;\r
 328         e.predator.regurgitate_prepare = 0;\r
 329         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 330         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 331         Vore_SetPreyPositions(e.predator);\r
 332 \r
 333         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 334         e.predator.weapon_delay = time + button_delay_time;\r
 335         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 336         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 337         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 338 }\r
 339 \r
 340 void Vore_SwallowStep(entity e)\r
 341 {\r
 342         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 343         {\r
 344                 Vore_Swallow(e);\r
 345                 return;\r
 346         }\r
 347 \r
 348         // when the predator starts swallowing, play his grab sound\r
 349         if(!self.swallow_progress_pred)\r
 350                 PlayerSound(self, playersound_grab, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 351 \r
 352         Vore_SwallowModel_Update(e, self);\r
 353 \r
 354         // increase the progress value until it reaches 1, then swallow the player\r
 355         if(e.swallow_progress_prey < 1)\r
 356         {\r
 357                 float fill;\r
 358                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 359                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 360                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 361                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 362                         fill *= (1 - ((e.stomach_load / e.stomach_maxload) * bound(0, cvar("g_balance_vore_swallow_speed_fill_stomachload"), 1)));\r
 363 \r
 364                 // skill-based speed offset for bots\r
 365                 if(skill && cvar("skill_offset"))\r
 366                 {\r
 367                         float ofs;\r
 368                         ofs = pow(skill / cvar("skill_offset_center"), cvar("skill_offset"));\r
 369                         if(clienttype(self) == CLIENTTYPE_BOT)\r
 370                                 fill *= ofs;\r
 371                         if(clienttype(e) == CLIENTTYPE_BOT)\r
 372                                 fill /= ofs;\r
 373                 }\r
 374 \r
 375                 e.swallow_progress_prey += fill;\r
 376         }\r
 377         else\r
 378         {\r
 379                 Vore_Swallow(e);\r
 380                 e.swallow_progress_prey = 0;\r
 381         }\r
 382 \r
 383         // the predator's progress is how much the prey got swallowed\r
 384         self.swallow_progress_pred = e.swallow_progress_prey;\r
 385 }\r
 386 \r
 387 void Vore_Regurgitate(entity e)\r
 388 {\r
 389         // this player is being regurgitated by their predator, apply the proper changes\r
 390 \r
 391         e.movetype = e.vore_oldmovetype;\r
 392         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 393                 e.solid = e.vore_oldsolid;\r
 394         e.view_ofs_z = PL_VIEW_OFS_z;\r
 395         e.punchvector_z = -cvar("g_balance_vore_regurgitate_prey_punchvector");\r
 396 \r
 397         // if the prey has been fully digested, silently detach them\r
 398         if(cvar("g_balance_vore_regurgitate_death_silent"))\r
 399         if(e.deadflag != DEAD_NO && e.health <= cvar("g_balance_vore_digestion_limit"))\r
 400         {\r
 401                 e.predator = world;\r
 402                 e.modelindex = 0; // hide the dead body\r
 403                 return;\r
 404         }\r
 405 \r
 406         float scalediff;\r
 407         scalediff = cvar("g_healthsize") ? e.scale / e.predator.scale : 1; // the tighter the gut, the greater the effect\r
 408 \r
 409         // apply velocities\r
 410         makevectors(e.predator.v_angle);\r
 411         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force") * scalediff;\r
 412         e.predator.velocity = e.predator.velocity + (-v_forward * cvar("g_balance_vore_regurgitate_predatorforce") * scalediff); // don't use += here to avoid a fteqcc bug\r
 413         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 414         e.pushltime = time + cvar("g_maxpushtime");\r
 415 \r
 416         // if the dead body of the prey is below gibbing health, gib it\r
 417         e.stat_eaten = 0; // necessary for gibs to show\r
 418         PlayerGib(e, e.predator);\r
 419 \r
 420         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 421         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 422         {\r
 423                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 424                 Vore_SwallowModel_Update(e, e.predator);\r
 425         }\r
 426 \r
 427         // apply regurgitation damage to the predator\r
 428         if(cvar("g_balance_vore_regurgitate_damage"))\r
 429         {\r
 430                 float regurgitate_dmg;\r
 431                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 432                 if(cvar("g_healthsize"))\r
 433                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 434                 Damage(e.predator, e, e, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 435         }\r
 436 \r
 437         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 438         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 439         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', floor(scalediff * PARTICLE_MULTIPLIER));\r
 440         e.predator.punchangle_x = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle") * scalediff;\r
 441         e.predator.punchangle_y = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle") * scalediff;\r
 442         e.predator.punchangle_z = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle") * scalediff;\r
 443         e.predator.regurgitate_prepare = 0;\r
 444         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 445         Vore_SetPreyPositions(e.predator);\r
 446 \r
 447         // block firing for a small amount of time, or we'll be firing the next frame\r
 448         e.weapon_delay = time + button_delay_time;\r
 449         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 450         e.predator = world;\r
 451 }\r
 452 \r
 453 void Vore_Disconnect(float consumables)\r
 454 {\r
 455         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 456         entity e;\r
 457 \r
 458         // prey disconnects or goes spectating while inside someone's belly\r
 459         if(self.stat_eaten)\r
 460                 Vore_Regurgitate(self);\r
 461 \r
 462         // pred disconnects or goes spectating with players in their belly\r
 463         entity head;\r
 464         FOR_EACH_PLAYER(head)\r
 465         {\r
 466                 if(head.predator == self)\r
 467                         Vore_Regurgitate(head);\r
 468         }\r
 469         // remove consumable items when we disconnect\r
 470         if(consumables)\r
 471         {\r
 472                 for(e = world; (e = find(e, classname, "consumable")); )\r
 473                 {\r
 474                         if(e.predator == self)\r
 475                                 Item_Consumable_Remove(e, TRUE);\r
 476                 }\r
 477         }\r
 478 \r
 479         self.stomach_load = self.gravity = 0; // prevents a bug\r
 480         Vore_GurgleSound(); // stop the gurgling sound\r
 481 }\r
 482 \r
 483 .float digestion_step;\r
 484 void Vore_Digest()\r
 485 {\r
 486         // apply digestion to prey\r
 487 \r
 488         if(self.predator.deadflag != DEAD_NO) // dead predators don't digest\r
 489         {\r
 490                 self.predator.digesting = FALSE;\r
 491                 return;\r
 492         }\r
 493         if(self.health <= cvar("g_balance_vore_digestion_limit")) // don't digest below this amount of health\r
 494                 return;\r
 495 \r
 496         if(time > self.digestion_step)\r
 497         {\r
 498                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 499                 float damage, damage_offset;\r
 500 \r
 501                 damage_offset = 1;\r
 502                 if(cvar("g_balance_vore_digestion_distribute")) // apply distributed digestion damage\r
 503                         damage_offset /= (1 - (self.predator.stomach_load / self.predator.stomach_maxload) * bound(0, cvar("g_balance_vore_digestion_distribute"), 1));\r
 504                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff")) // apply player scale to digestion damage\r
 505                         damage_offset *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 506 \r
 507                 if(self.deadflag != DEAD_NO)\r
 508                         damage = cvar("g_balance_vore_digestion_damage_death") / damage_offset;\r
 509                 else\r
 510                         damage = cvar("g_balance_vore_digestion_damage") / damage_offset;\r
 511 \r
 512                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 513                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 514                 {\r
 515                         self.predator.health += damage * cvar("g_balance_vore_digestion_vampire");\r
 516                         self.predator.pauserothealth_finished = max(self.predator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));\r
 517                 }\r
 518 \r
 519                 self.digestion_step = time + vore_steptime;\r
 520         }\r
 521 \r
 522         if(stov(cvar_string("g_vore_regurgitatecolor_color_digest")))\r
 523                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_digest"));\r
 524 }\r
 525 \r
 526 .float teamheal_step;\r
 527 void Vore_Teamheal()\r
 528 {\r
 529         // apply teamheal\r
 530 \r
 531         if(self.deadflag != DEAD_NO)\r
 532                 return;\r
 533 \r
 534         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 535         if(time > self.teamheal_step)\r
 536         {\r
 537                 self.health += cvar("g_balance_vore_teamheal");\r
 538                 self.teamheal_step = time + vore_steptime;\r
 539 \r
 540                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 541                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 542                 {\r
 543                         play2(self, "misc/beep.wav");\r
 544                         play2(self.predator, "misc/beep.wav");\r
 545                 }\r
 546         }\r
 547 }\r
 548 \r
 549 .float kick_pressed;\r
 550 void Vore_StomachKick()\r
 551 {\r
 552         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 553 \r
 554         if(self.deadflag != DEAD_NO)\r
 555                 return;\r
 556 \r
 557         float scalediff;\r
 558         scalediff = pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 559 \r
 560         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 561         {\r
 562                 float damage, vol, pitch;\r
 563                 vector force;\r
 564                 damage = cvar("g_balance_vore_kick_damage");\r
 565                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 566                 vol = VOL_BASE;\r
 567 \r
 568                 // modified sound pitch, based on player scale\r
 569                 if(cvar("g_healthsize") && cvar("g_healthsize_pitch"))\r
 570                         pitch = pow(self.predator.scale, -cvar("g_healthsize_pitch"));\r
 571 \r
 572                 // apply player scale to the damage / force of the kick\r
 573                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 574                 {\r
 575                         damage *= scalediff;\r
 576                         force *= scalediff;\r
 577                         vol *= scalediff; // kick sound volume based on the same scale\r
 578                 }\r
 579                 vol = bound(0, vol, 1);\r
 580 \r
 581                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 582                 sound7(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM, 100 * pitch, 0);\r
 583                 self.predator.punchangle_x = crandom() * cvar("g_balance_vore_kick_predator_punchangle") * scalediff;\r
 584                 self.predator.punchangle_y = crandom() * cvar("g_balance_vore_kick_predator_punchangle") * scalediff;\r
 585                 self.predator.punchangle_z = crandom() * cvar("g_balance_vore_kick_predator_punchangle") * scalediff;\r
 586                 self.punchangle_x = crandom() * cvar("g_balance_vore_kick_prey_punchangle") * scalediff;\r
 587                 self.punchangle_y = crandom() * cvar("g_balance_vore_kick_prey_punchangle") * scalediff;\r
 588                 self.punchangle_z = crandom() * cvar("g_balance_vore_kick_prey_punchangle") * scalediff;\r
 589 \r
 590                 // abort the predator's scheduled regurgitation\r
 591                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 592                         self.predator.regurgitate_prepare = 0;\r
 593 \r
 594                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 595                 if(cvar("g_balance_vore_kick_repress"))\r
 596                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 597                         self.kick_pressed = TRUE;\r
 598         }\r
 599 }\r
 600 \r
 601 void Vore_StomachLeave()\r
 602 {\r
 603         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 604 \r
 605         if(self.deadflag != DEAD_NO)\r
 606                 return;\r
 607 \r
 608         if(Vore_CanLeave())\r
 609                 Vore_Regurgitate(self);\r
 610         else if(time > self.complain_vore)\r
 611         {\r
 612                 play2(self, "misc/forbidden.wav");\r
 613                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 614                 self.complain_vore = time + complain_delay_time;\r
 615         }\r
 616 }\r
 617 \r
 618 void Vore_AutoTaunt()\r
 619 {\r
 620         // triggers ambient vore taunts, for both pred and prey\r
 621 \r
 622         float taunt_time;\r
 623 \r
 624         // predator taunts\r
 625         if((self.swallow_progress_pred || (self.stomach_load && Stomach_HasLivePrey(self))) && !Stomach_TeamMates_check(self))\r
 626         {\r
 627                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 628                 {\r
 629                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 630                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 631                 }\r
 632         }\r
 633         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 634         {\r
 635                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 636                 SetAutoTaunt(self, 0, 0);\r
 637         }\r
 638 \r
 639         // prey taunts\r
 640         if((self.swallow_progress_prey || (self.stat_eaten && !(teams_matter && self.team == self.predator.team))) && self.deadflag == DEAD_NO)\r
 641         {\r
 642                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 643                 {\r
 644                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 645                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 646                 }\r
 647         }\r
 648         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 649         {\r
 650                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 651                 SetAutoTaunt(self, 0, 0);\r
 652         }\r
 653 }\r
 654 \r
 655 void Vore_SetSbarRings()\r
 656 {\r
 657         // first clear the ring stats, then configure them if needed\r
 658         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 659         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 660 \r
 661         if(self.stat_eaten)\r
 662         {\r
 663                 if(time <= self.stomachkick_delay)\r
 664                 {\r
 665                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 666                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 667                 }\r
 668         }\r
 669         else\r
 670         {\r
 671                 if(self.swallow_progress_pred)\r
 672                 {\r
 673                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 674                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 675                 }\r
 676                 else if(time <= self.action_delay)\r
 677                 {\r
 678                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 679                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 680                 }\r
 681 \r
 682                 if(self.swallow_progress_prey)\r
 683                 {\r
 684                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 685                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 686                 }\r
 687                 else if(time <= self.regurgitate_prepare)\r
 688                 {\r
 689                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 690                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 691                 }\r
 692         }\r
 693 }\r
 694 \r
 695 .float regurgitatecolor_particles_tick;\r
 696 void Vore()\r
 697 {\r
 698         // main vore code, this is where it all happens\r
 699 \r
 700         Vore_AutoTaunt();\r
 701 \r
 702         if(!self.stat_eaten)\r
 703         if(self.modelindex) // not if we're a gibbed dead body or not visible any more\r
 704         if(self.colormod)\r
 705         if(self.colormod != '1 1 1')\r
 706         {\r
 707                 // slowly wash stomach fluids off players once they're out of the stomach\r
 708                 if(cvar("g_vore_regurgitatecolor_fade"))\r
 709                 if(self.deadflag == DEAD_NO) // not for dead bodies\r
 710                 {\r
 711                         float goo_fade;\r
 712                         goo_fade = cvar("g_vore_regurgitatecolor_fade") * frametime;\r
 713                         goo_fade *= 1 + self.waterlevel; // fade faster when underwater\r
 714 \r
 715                         self.colormod_x += goo_fade;\r
 716                         if(self.colormod_x > 1)\r
 717                                 self.colormod_x = 1;\r
 718                         self.colormod_y += goo_fade;\r
 719                         if(self.colormod_y > 1)\r
 720                                 self.colormod_y = 1;\r
 721                         self.colormod_z += goo_fade;\r
 722                         if(self.colormod_z > 1)\r
 723                                 self.colormod_z = 1;\r
 724                 }\r
 725 \r
 726                 // constant particles falling off dirty players\r
 727                 if(cvar("g_vore_regurgitatecolor_particles"))\r
 728                 if(self.regurgitatecolor_particles_tick < time)\r
 729                 {\r
 730                         pointparticles(particleeffectnum("vore_regurgitate_constant"), self.origin, '0 0 0', floor((cvar("g_healthsize") ? self.scale : 1) * PARTICLE_MULTIPLIER));\r
 731                         self.regurgitatecolor_particles_tick = time + cvar("g_vore_regurgitatecolor_particles") * vlen(self.colormod); // particle time depends on how dirty the player is\r
 732                 }\r
 733         }\r
 734 \r
 735         // set all vore stats\r
 736         Vore_SetSbarRings();\r
 737         if(self.predator.classname == "player")\r
 738         {\r
 739                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 740                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 741                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 742                 self.stat_eaten = num_for_edict(self.predator);\r
 743         }\r
 744         else\r
 745         {\r
 746                 self.stat_stomachload = self.stomach_load;\r
 747                 self.stat_stomachmaxload = self.stomach_maxload;\r
 748                 self.stat_digesting = self.digesting;\r
 749                 self.stat_eaten = 0;\r
 750         }\r
 751         self.stat_canleave = Vore_CanLeave();\r
 752 \r
 753         // don't allow a player inside a player inside another player :)\r
 754         // prevent this by checking if such has happened, and taking the proper measures\r
 755         // this code has a high priority and must not be stopped by any delay, so run it here\r
 756         if(self.predator.stat_eaten)\r
 757                 Vore_Regurgitate(self);\r
 758 \r
 759         // the swallow progress of prey and preds idly decrease by this amount\r
 760         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 761         {\r
 762                 if(self.swallow_progress_pred)\r
 763                 {\r
 764                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 765                         if(self.swallow_progress_pred < 0)\r
 766                                 self.swallow_progress_pred = 0;\r
 767                 }\r
 768                 if(self.swallow_progress_prey)\r
 769                 {\r
 770                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 771                         if(self.swallow_progress_prey < 0)\r
 772                                 self.swallow_progress_prey = 0;\r
 773                 }\r
 774         }\r
 775 \r
 776         // set the predator's stomach load and capacity\r
 777         Vore_StomachLoad_Apply();\r
 778 \r
 779         // apply delays and skip the vore system under some circumstances\r
 780         if(!cvar("g_vore")) // the vore system is disabled\r
 781         {\r
 782                 Vore_Disconnect(TRUE);\r
 783                 return;\r
 784         }\r
 785         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 786         {\r
 787                 Vore_Disconnect(FALSE);\r
 788                 return;\r
 789         }\r
 790         if(self.spectatee_status)\r
 791                 return;\r
 792         if(time < self.system_delay)\r
 793                 return;\r
 794 \r
 795 // --------------------------------\r
 796 // Code that addresses predators:\r
 797 // --------------------------------\r
 798 \r
 799         entity prey;\r
 800         prey = Swallow_player_check();\r
 801 \r
 802         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 803         self.stat_canswallow = 0;\r
 804         if(Swallow_condition_check(prey))\r
 805         {\r
 806                 // canswallow stat, used by the HUD\r
 807                 if(teams_matter && prey.team == self.team)\r
 808                         self.stat_canswallow = 2;\r
 809                 else\r
 810                         self.stat_canswallow = 1;\r
 811 \r
 812                 if(self.BUTTON_ATCK)\r
 813                         Vore_SwallowStep(prey);\r
 814         }\r
 815         else if(prey != world)\r
 816                 self.stat_canswallow = -1;\r
 817 \r
 818         // toggle digestion, if the player has someone in their stomach\r
 819         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 820         {\r
 821                 if(self.stomach_load)\r
 822                 {\r
 823                         if(time > self.digest_button_delay_time)\r
 824                         {\r
 825                                 self.digesting = !self.digesting;\r
 826                                 self.digest_button_delay_time = time + button_delay_time;\r
 827                         }\r
 828                 }\r
 829                 else if(time > self.complain_vore)\r
 830                 {\r
 831                         play2(self, "misc/forbidden.wav");\r
 832                         sprint(self, "There is nothing to digest\n");\r
 833                         self.complain_vore = time + complain_delay_time;\r
 834                 }\r
 835         }\r
 836         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 837                 self.digesting = FALSE;\r
 838 \r
 839         // predator wishes to regurgitate his prey\r
 840         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 841         if(!self.regurgitate_prepare)\r
 842         {\r
 843                 if(self.stomach_load)\r
 844                 {\r
 845                         if(time > self.regurgitate_button_delay_time)\r
 846                         {\r
 847                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 848                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 849                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 850                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 851                         }\r
 852                 }\r
 853                 else if(time > self.complain_vore)\r
 854                 {\r
 855                         play2(self, "misc/forbidden.wav");\r
 856                         sprint(self, "There is nothing to regurgitate\n");\r
 857                         self.complain_vore = time + complain_delay_time;\r
 858                 }\r
 859         }\r
 860 \r
 861         if(self.stomach_load > self.stomach_maxload) // the predator got beyond his capacity after eating, so some prey must pop out\r
 862         {\r
 863                 self.regurgitate_prepare = -1;\r
 864                 return;\r
 865         }\r
 866         if(cvar("g_balance_vore_load_pred_speedcap") && self.stomach_load)\r
 867         if(vlen(self.velocity) >= cvar("g_balance_vore_load_pred_speedcap") / (self.stomach_load / self.stomach_maxload)) // predator's going too fast, gets sick and throws up\r
 868         {\r
 869                 self.regurgitate_prepare = -1;\r
 870                 return;\r
 871         }\r
 872 \r
 873         if (self.digesting && self.digestsound_finished < time)\r
 874         {\r
 875                 PlayerSound (self, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 876                 self.digestsound_finished = time + 0.5;\r
 877         }\r
 878         if(cvar("g_vore_gurglesound"))\r
 879                 Vore_GurgleSound();\r
 880 \r
 881 // --------------------------------\r
 882 // Code that addresses the prey:\r
 883 // --------------------------------\r
 884 \r
 885         if(!self.stat_eaten)\r
 886                 return;\r
 887 \r
 888         if(self.deadflag != DEAD_NO && self.health < cvar("g_balance_vore_digestion_limit")) // make sure health doesn't go below the limit\r
 889                 self.health = cvar("g_balance_vore_digestion_limit");\r
 890 \r
 891         // automatically regurgitate prey that has reached their digestion limit\r
 892         if(cvar("g_balance_vore_digestion_limit_regurgitate"))\r
 893         if(self.health <= cvar("g_balance_vore_digestion_limit"))\r
 894         {\r
 895                 Vore_Regurgitate(self);\r
 896                 return;\r
 897         }\r
 898 \r
 899         // do we stick around inside dead furries? x_x\r
 900         if(self.predator.deadflag != DEAD_NO)\r
 901         {\r
 902                 if(!cvar("g_balance_vore_deadpredator") || !self.predator.modelindex) // if the predator is gibbed, we are out\r
 903                 {\r
 904                         Vore_Regurgitate(self);\r
 905                         return;\r
 906                 }\r
 907                 if(self.predator.regurgitate_prepare) // abort scheduled regurgitation\r
 908                         self.predator.regurgitate_prepare = 0;\r
 909         }\r
 910 \r
 911         // apply delayed regurgitating if it was scheduled\r
 912         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 913         {\r
 914                 Vore_Regurgitate(self);\r
 915                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 916         }\r
 917 \r
 918         // execute digesting and team healing\r
 919         if(self.predator.digesting == TRUE)\r
 920                 Vore_Digest();\r
 921         if(teams_matter && self.team == self.predator.team)\r
 922         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 923                 Vore_Teamheal();\r
 924 \r
 925         // execute prey commands\r
 926         if(self.BUTTON_ATCK)\r
 927         {\r
 928                 if(cvar("g_vore_kick"))\r
 929                         Vore_StomachKick();\r
 930         }\r
 931         else\r
 932                 self.kick_pressed = FALSE;\r
 933         if(self.BUTTON_JUMP)\r
 934                 Vore_StomachLeave();\r
 935 \r
 936         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 937         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 938         kh_Key_DropAll(self, FALSE);\r
 939 \r
 940         // always position camera at the center of the stomach, to reduce probability of the view poking out\r
 941         self.view_ofs_z = PL_PREY_VIEW_OFS_z * self.predator.scale;\r
 942 }