data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= g_balance_vore_swallow_limit)\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", ftos(g_balance_vore_swallow_limit), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetPreyPositions()\r
 100 {\r
 101         // self is the predator and head is the prey\r
 102 \r
 103         local entity head;\r
 104         local vector origin_apply;\r
 105         local float position_counter;\r
 106 \r
 107         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 108         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 109         // For each player, the origin is updated, then a new origin is used for the next player.\r
 110         // This requires that no more than 9 players may be in the stomach at a time!\r
 111         FOR_EACH_PLAYER(head)\r
 112         {\r
 113                 if(head.predator == self)\r
 114                 {\r
 115                         switch(position_counter)\r
 116                         {\r
 117                                 case 0:\r
 118                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 119                                         break;\r
 120                                 case 1:\r
 121                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 122                                         break;\r
 123                                 case 2:\r
 124                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 125                                         break;\r
 126                                 case 3:\r
 127                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 128                                         break;\r
 129                                 case 4:\r
 130                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 131                                         break;\r
 132                                 case 5:\r
 133                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 134                                         break;\r
 135                                 case 6:\r
 136                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 137                                         break;\r
 138                                 case 7:\r
 139                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 140                                         break;\r
 141                                 case 8:\r
 142                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 143                                         break;\r
 144                                 default:\r
 145                                         break;\r
 146                         }\r
 147 \r
 148                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 149                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 150                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 151 \r
 152                         // change prey height based on scale\r
 153                         float prey_height;\r
 154                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 155                         head.view_ofs_z += prey_height;\r
 156 \r
 157                         position_counter += 1;\r
 158                 }\r
 159         }\r
 160 }\r
 161 \r
 162 .float gurgle_oldstomachload;\r
 163 void Vore_GurgleSound()\r
 164 {\r
 165         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 166         {\r
 167                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 168 \r
 169                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 170                 self.gurgle_oldstomachload = self.stomach_load;\r
 171         }\r
 172 }\r
 173 \r
 174 void Vore_WeightApply(entity e)\r
 175 {\r
 176         // apply stomach weight that makes you heavier the more you eat\r
 177         // slowing the player is done in cl_physics.qc\r
 178 \r
 179         if(e.stomach_load != e.vore_oldstomachload)\r
 180                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 181         if(e.gravity == 0)\r
 182                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 183         e.vore_oldstomachload = e.stomach_load;\r
 184 }\r
 185 \r
 186 void Vore_AutoDigest(entity e)\r
 187 {\r
 188         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 189 \r
 190         if(!cvar("g_vore_digestion") || e.digesting)\r
 191                 return;\r
 192         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 193                 return; // this feature is only for players, not bots\r
 194         if(e.stomach_load > 1)\r
 195                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 196         if(Stomach_TeamMates_check(e))\r
 197                 return; // never begin automatic digestion if we've swallowed a team mate\r
 198 \r
 199         e.digesting = TRUE;\r
 200 }\r
 201 \r
 202 void Vore_SwallowModel_Think()\r
 203 {\r
 204         //update the necessary angles to match our view\r
 205         self.angles_x = self.owner.angles_x;\r
 206 \r
 207         // if our swallow progress is gone, the swallow model must also go\r
 208         if(!self.owner.swallow_progress_prey)\r
 209         {\r
 210                 self.nextthink = 0;\r
 211                 remove(self);\r
 212                 self = world;\r
 213                 return;\r
 214         }\r
 215 \r
 216         self.nextthink = time;\r
 217 }\r
 218 \r
 219 .entity swallow_model;\r
 220 void Vore_SwallowModel_Spawn(entity prey)\r
 221 {\r
 222         entity e;\r
 223         e = spawn();\r
 224         \r
 225         e.movetype = MOVETYPE_FOLLOW;\r
 226         e.solid = SOLID_NOT;\r
 227         e.alpha = prey.cvar_cl_vore_stomachmodel;\r
 228 \r
 229         // apply the properties of the predator\r
 230         setmodel(e, strcat(substring(self.playermodel, 0, strlen(self.playermodel) - 4), "_swallow.md3")); // 4 is the extension length\r
 231         //e.skin = self.skin;\r
 232         e.scale = self.scale;\r
 233 \r
 234         // apply the properties of the prey\r
 235         e.angles_x = prey.angles_x;\r
 236         e.aiment = prey;\r
 237         e.origin += prey.view_ofs;\r
 238 \r
 239         e.owner = prey; // owned by the prey\r
 240         e.enemy = self; // enemy is the predator\r
 241         e.think = Vore_SwallowModel_Think;\r
 242         e.nextthink = time;\r
 243 }\r
 244 \r
 245 .entity pusher;\r
 246 .float pushltime;\r
 247 void Vore_Swallow(entity e)\r
 248 {\r
 249         // this player is being swallowed by another player, apply the proper changes\r
 250 \r
 251         e.vore_oldmovetype = e.movetype;\r
 252         e.vore_oldsolid = e.solid;\r
 253 \r
 254         e.predator = self;\r
 255         setorigin(e, e.predator.origin);\r
 256         e.velocity = '0 0 0';\r
 257         e.movetype = MOVETYPE_FOLLOW;\r
 258         e.solid = SOLID_NOT;\r
 259         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 260 \r
 261         // drop keys (KH) and flags (CTF) when we get swallowed\r
 262         kh_Key_DropAll(e, FALSE);\r
 263         if(e.flagcarried)\r
 264                 DropFlag(e.flagcarried, world, e.predator);\r
 265 \r
 266         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 267                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 268 \r
 269         if(teams_matter && e.team == e.predator.team)\r
 270         {\r
 271                 if(cvar("g_vore_kick"))\r
 272                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 273                 if(cvar("g_vore_digestion"))\r
 274                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 275         }\r
 276 \r
 277         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 278         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 279         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 280         e.predator.stomach_load += 1;\r
 281         e.predator.regurgitate_prepare = 0;\r
 282         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 283         Vore_WeightApply(e.predator);\r
 284         Vore_AutoDigest(e.predator);\r
 285 \r
 286         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 287         e.predator.weapon_delay = time + button_delay_time;\r
 288         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 289         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 290         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 291 }\r
 292 \r
 293 void Vore_SwallowStep(entity e)\r
 294 {\r
 295         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 296         {\r
 297                 Vore_Swallow(e);\r
 298                 return;\r
 299         }\r
 300 \r
 301         // if the predator swallowing me has changed, remove the swallow model\r
 302         if(e.swallow_model && e.swallow_model.enemy != self)\r
 303         {\r
 304                 e.swallow_model.nextthink = 0;\r
 305                 remove(e.swallow_model);\r
 306                 e.swallow_model = world;\r
 307         }\r
 308         //set the swallow model for the prey\r
 309         if(!e.swallow_model)\r
 310                 Vore_SwallowModel_Spawn(e);\r
 311 \r
 312         // increase the progress value until it reaches 1, then swallow the player\r
 313         if(e.swallow_progress_prey < 1)\r
 314         {\r
 315                 float fill;\r
 316                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 317                 if(cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 318                         fill *= (self.scale / e.scale);\r
 319                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 320                         fill /= e.stomach_load;\r
 321 \r
 322                 e.swallow_progress_prey += fill;\r
 323         }\r
 324         else\r
 325         {\r
 326                 Vore_Swallow(e);\r
 327                 e.swallow_progress_prey = 0;\r
 328         }\r
 329 \r
 330         // the predator's progress is how much the prey got swallowed\r
 331         self.swallow_progress_pred = e.swallow_progress_prey;\r
 332 }\r
 333 \r
 334 void Vore_Regurgitate(entity e)\r
 335 {\r
 336         // this player is being regurgitated by their predator, apply the proper changes\r
 337 \r
 338         e.movetype = e.vore_oldmovetype;\r
 339         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 340                 e.solid = e.vore_oldsolid;\r
 341         e.view_ofs_z = PL_VIEW_OFS_z;\r
 342 \r
 343         // apply velocities\r
 344         local vector oldforward, oldright, oldup;\r
 345         oldforward = v_forward;\r
 346         oldright = v_right;\r
 347         oldup = v_up;\r
 348         makevectors(e.predator.v_angle);\r
 349         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 350         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 351         v_forward = oldforward;\r
 352         v_right = oldright;\r
 353         v_up = oldup;\r
 354 \r
 355         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 356         e.pushltime = time + cvar("g_maxpushtime");\r
 357 \r
 358         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 359         if(cvar("g_balance_vore_swallow_speed_fill"))\r
 360                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 361 \r
 362         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 363         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 364         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 365         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 366         e.predator.stomach_load -= 1;\r
 367         e.predator.regurgitate_prepare = 0;\r
 368         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 369         Vore_WeightApply(e.predator);\r
 370 \r
 371         // block firing for a small amount of time, or we'll be firing the next frame\r
 372         e.weapon_delay = time + button_delay_time;\r
 373         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 374         e.predator = world;\r
 375 }\r
 376 \r
 377 void Vore_DeadPrey_Configure(entity e)\r
 378 {\r
 379         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 380 \r
 381         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 382                 return;\r
 383 \r
 384         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 385         e.fakepredator = e.predator;\r
 386         e.fakeprey = TRUE;\r
 387 \r
 388         // first release the prey from the predator, as dead prey needs to be attached differently\r
 389         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 390         e.predator.stomach_load -= 1;\r
 391         Vore_WeightApply(e.predator);\r
 392         e.predator = world;\r
 393 \r
 394         // now put our dead prey inside the predator's stomach, but only as an effect\r
 395         e.movetype = MOVETYPE_FOLLOW;\r
 396         e.takedamage = DAMAGE_NO;\r
 397         e.solid = SOLID_NOT;\r
 398         e.aiment = e.fakepredator;\r
 399 }\r
 400 \r
 401 void Vore_DeadPrey_Detach(entity e)\r
 402 {\r
 403         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 404         // should only execute after Vore_DeadPrey_Configure has ran first\r
 405 \r
 406         if not(cvar("g_vore_keepdeadprey"))\r
 407                 return;\r
 408 \r
 409         e.fakepredator = world;\r
 410         e.fakeprey = TRUE; // keep fakeprey status\r
 411         e.stat_eaten = 0;\r
 412         e.aiment = world;\r
 413         e.movetype = MOVETYPE_TOSS;\r
 414 }\r
 415 \r
 416 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 417 {\r
 418         if(pred_disconnect)\r
 419         {\r
 420                 if(e.fakeprey)\r
 421                         Vore_DeadPrey_Detach(e);\r
 422                 else\r
 423                         Vore_Regurgitate(e);\r
 424         }\r
 425         else if(self.stat_eaten && !self.fakeprey)\r
 426         {\r
 427                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 428                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 429                         Vore_DeadPrey_Configure(e);\r
 430                 else\r
 431                         Vore_Regurgitate(e);\r
 432         }\r
 433 }\r
 434 \r
 435 void Vore_Disconnect()\r
 436 {\r
 437         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 438 \r
 439         // prey disconnects or goes spectating while inside someone's belly\r
 440         if(self.stat_eaten)\r
 441                 Vore_PreyRelease(self, TRUE);\r
 442 \r
 443         // pred disconnects or goes spectating with players in their belly\r
 444         entity head;\r
 445         FOR_EACH_PLAYER(head)\r
 446         {\r
 447                 if(head.predator == self || head.fakepredator == self)\r
 448                         Vore_PreyRelease(head, TRUE);\r
 449         }\r
 450         Vore_GurgleSound(); // stop the gurgling sound\r
 451 \r
 452         self.stomach_load = self.gravity = 0; // prevents a bug\r
 453 }\r
 454 \r
 455 .float digestion_step;\r
 456 void Vore_Digest()\r
 457 {\r
 458         // apply digestion to prey\r
 459 \r
 460         if(time > self.digestion_step)\r
 461         {\r
 462                 // if distributed digestion is enabled, reduce digestion strength by the number of prey in our stomach\r
 463                 float reduce;\r
 464                 if(cvar("g_balance_vore_digestion_distribute"))\r
 465                         reduce = self.predator.stomach_load;\r
 466                 else\r
 467                         reduce = 1;\r
 468 \r
 469                 float damage;\r
 470                 damage = cvar("g_balance_vore_digestion_damage") / reduce;\r
 471 \r
 472                 // apply player scale to digestion damage\r
 473                 if(cvar("g_balance_vore_digestion_scalediff"))\r
 474                         damage *= (self.predator.scale / self.scale);\r
 475 \r
 476                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 477                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 478                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / reduce;\r
 479 \r
 480                 if (self.predator.digestsound_finished < time)\r
 481                 {\r
 482                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 483                         self.predator.digestsound_finished = time + 0.5;\r
 484                 }\r
 485                 self.digestion_step = time + steptime;\r
 486         }\r
 487 \r
 488         if(self.deadflag != DEAD_NO)\r
 489         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 490                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 491 }\r
 492 \r
 493 .float teamheal_step;\r
 494 void Vore_Teamheal()\r
 495 {\r
 496         // apply teamheal\r
 497 \r
 498         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 499         if(time > self.teamheal_step)\r
 500         {\r
 501                 self.health += cvar("g_balance_vore_teamheal");\r
 502                 self.teamheal_step = time + steptime;\r
 503 \r
 504                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 505                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 506                 {\r
 507                         play2(self, "misc/beep.wav");\r
 508                         play2(self.predator, "misc/beep.wav");\r
 509                 }\r
 510         }\r
 511 }\r
 512 \r
 513 void Vore_StomachKick()\r
 514 {\r
 515         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 516 \r
 517         if(time > self.stomachkick_delay)\r
 518         {\r
 519                 float damage;\r
 520                 vector force;\r
 521                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 522                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 523 \r
 524                 // apply player scale to the damage / force of the kick\r
 525                 if(cvar("g_balance_vore_kick_scalediff"))\r
 526                 {\r
 527                         damage *= (self.scale / self.predator.scale);\r
 528                         force *= (self.scale / self.predator.scale);\r
 529                 }\r
 530 \r
 531                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 532                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), VOL_BASE, ATTN_NORM);\r
 533                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 534                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 535 \r
 536                 // abort the predator's scheduled regurgitation\r
 537                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 538                         self.predator.regurgitate_prepare = 0;\r
 539 \r
 540                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 541         }\r
 542 }\r
 543 \r
 544 void Vore_StomachLeave()\r
 545 {\r
 546         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 547 \r
 548         if(Vore_CanLeave())\r
 549                 Vore_Regurgitate(self);\r
 550         else if(time > self.complain_vore)\r
 551         {\r
 552                 play2(self, "misc/forbidden.wav");\r
 553                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 554                 self.complain_vore = time + complain_delay_time;\r
 555         }\r
 556 }\r
 557 \r
 558 void Vore_AutoTaunt()\r
 559 {\r
 560         // triggers ambient vore taunts, for both pred and prey\r
 561 \r
 562         float taunt_time;\r
 563 \r
 564         // predator taunts\r
 565         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 566         {\r
 567                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 568                 {\r
 569                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 570                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 571                 }\r
 572         }\r
 573         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 574         {\r
 575                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 576                 SetAutoTaunt(self, 0, 0);\r
 577         }\r
 578 \r
 579         // prey taunts\r
 580         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 581         {\r
 582                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 583                 {\r
 584                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 585                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 586                 }\r
 587         }\r
 588         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 589         {\r
 590                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 591                 SetAutoTaunt(self, 0, 0);\r
 592         }\r
 593 }\r
 594 \r
 595 void Vore_SetSbarRings()\r
 596 {\r
 597         // first clear the ring stats, then configure them if needed\r
 598         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 599         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 600 \r
 601         if(self.stat_eaten)\r
 602         {\r
 603                 if(time <= self.stomachkick_delay)\r
 604                 {\r
 605                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 606                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 607                 }\r
 608         }\r
 609         else\r
 610         {\r
 611                 if(self.swallow_progress_pred)\r
 612                 {\r
 613                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 614                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 615                 }\r
 616                 else if(time <= self.action_delay)\r
 617                 {\r
 618                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 619                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 620                 }\r
 621 \r
 622                 if(self.swallow_progress_prey)\r
 623                 {\r
 624                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 625                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 626                 }\r
 627                 else if(time <= self.regurgitate_prepare)\r
 628                 {\r
 629                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 630                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 631                 }\r
 632         }\r
 633 }\r
 634 \r
 635 void Vore()\r
 636 {\r
 637         // main vore code, this is where it all happens\r
 638 \r
 639         if(!cvar("g_vore")) // the vore system is disabled\r
 640         {\r
 641                 Vore_Disconnect();\r
 642                 return;\r
 643         }\r
 644 \r
 645         Vore_AutoTaunt();\r
 646 \r
 647         // wash the goo away from players once they leave the stomach\r
 648         if(!self.stat_eaten)\r
 649         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 650         if(self.colormod)\r
 651         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 652         {\r
 653                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 654                 if(self.colormod_x > 1)\r
 655                         self.colormod_x = 1;\r
 656                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 657                 if(self.colormod_y > 1)\r
 658                         self.colormod_y = 1;\r
 659                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 660                 if(self.colormod_z > 1)\r
 661                         self.colormod_z = 1;\r
 662         }\r
 663 \r
 664         // set all vore stats\r
 665         Vore_SetSbarRings();\r
 666         if(self.fakepredator.classname == "player")\r
 667                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 668         else if(self.predator.classname == "player")\r
 669         {\r
 670                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 671                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 672                 self.stat_eaten = num_for_edict(self.predator);\r
 673         }\r
 674         else\r
 675         {\r
 676                 self.stat_stomachload = self.stomach_load;\r
 677                 self.stat_digesting = self.digesting;\r
 678                 self.stat_eaten = 0;\r
 679         }\r
 680         self.stat_canleave = Vore_CanLeave();\r
 681 \r
 682         // don't allow a player inside a player inside another player :)\r
 683         // prevent this by checking if such has happened, and taking the proper measures\r
 684         // this code has a high priority and must not be stopped by any delay, so run it here\r
 685         if(self.predator.stat_eaten)\r
 686         {\r
 687                 entity target_predator, target_predator_predator, oldself;\r
 688                 target_predator = self.predator;\r
 689                 target_predator_predator = self.predator.predator;\r
 690 \r
 691                 Vore_Regurgitate(self);\r
 692 \r
 693                 // now steal our prey's prey if this probability applies\r
 694                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 695                 {\r
 696                         oldself = self;\r
 697                         self = target_predator_predator;\r
 698                         if(Swallow_condition_check(oldself))\r
 699                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 700                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 701                                 Vore_Swallow(oldself);\r
 702                         self = oldself;\r
 703                 }\r
 704         }\r
 705 \r
 706         // the swallow progress of prey and preds idly decrease by this amount\r
 707         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 708         {\r
 709                 if(self.swallow_progress_pred)\r
 710                 {\r
 711                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 712                         if(self.swallow_progress_pred < 0)\r
 713                                 self.swallow_progress_pred = 0;\r
 714                 }\r
 715                 if(self.swallow_progress_prey)\r
 716                 {\r
 717                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 718                         if(self.swallow_progress_prey < 0)\r
 719                                 self.swallow_progress_prey = 0;\r
 720                 }\r
 721         }\r
 722 \r
 723         // apply delays and skip the vore system under some circumstances\r
 724         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 725         {\r
 726                 Vore_Disconnect();\r
 727                 return;\r
 728         }\r
 729         if(self.spectatee_status)\r
 730                 return;\r
 731         if(time < self.system_delay)\r
 732                 return;\r
 733 \r
 734 // --------------------------------\r
 735 // Code that addresses predators:\r
 736 // --------------------------------\r
 737 \r
 738         entity prey;\r
 739         prey = Swallow_player_check();\r
 740 \r
 741         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 742         self.stat_canswallow = 0;\r
 743         if(Swallow_condition_check(prey))\r
 744         {\r
 745                 // canswallow stat, used by the HUD\r
 746                 if(teams_matter && prey.team == self.team)\r
 747                         self.stat_canswallow = 2;\r
 748                 else\r
 749                         self.stat_canswallow = 1;\r
 750 \r
 751                 if(self.BUTTON_ATCK)\r
 752                         Vore_SwallowStep(prey);\r
 753         }\r
 754         else if(prey != world)\r
 755                 self.stat_canswallow = -1;\r
 756 \r
 757         // toggle digestion, if the player has someone in their stomach\r
 758         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 759         {\r
 760                 if(self.stomach_load)\r
 761                 {\r
 762                         if(time > self.digest_button_delay_time)\r
 763                         {\r
 764                                 self.digesting = !self.digesting;\r
 765                                 self.digest_button_delay_time = time + button_delay_time;\r
 766                         }\r
 767                 }\r
 768                 else if(time > self.complain_vore)\r
 769                 {\r
 770                         play2(self, "misc/forbidden.wav");\r
 771                         sprint(self, "There is nothing to digest\n");\r
 772                         self.complain_vore = time + complain_delay_time;\r
 773                 }\r
 774         }\r
 775         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 776                 self.digesting = FALSE;\r
 777 \r
 778         // predator wishes to regurgitate his prey\r
 779         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 780         {\r
 781                 if(self.stomach_load)\r
 782                 {\r
 783                         if(time > self.regurgitate_button_delay_time)\r
 784                         {\r
 785                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 786                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 787                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 788                         }\r
 789                 }\r
 790                 else if(time > self.complain_vore)\r
 791                 {\r
 792                         play2(self, "misc/forbidden.wav");\r
 793                         sprint(self, "There is nothing to regurgitate\n");\r
 794                         self.complain_vore = time + complain_delay_time;\r
 795                 }\r
 796         }\r
 797 \r
 798         if(cvar("g_vore_gurglesound"))\r
 799                 Vore_GurgleSound();\r
 800 \r
 801 // --------------------------------\r
 802 // Code that addresses the prey:\r
 803 // --------------------------------\r
 804 \r
 805         Vore_SetPreyPositions();\r
 806 \r
 807         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 808         if(self.fakeprey)\r
 809         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 810                 Vore_DeadPrey_Detach(self);\r
 811 \r
 812         if(!self.stat_eaten)\r
 813                 return;\r
 814 \r
 815         if(self.deadflag != DEAD_NO)\r
 816         {\r
 817                 Vore_PreyRelease(self, FALSE);\r
 818                 return;\r
 819         }\r
 820 \r
 821         if(self.predator.deadflag != DEAD_NO)\r
 822                 Vore_Regurgitate(self);\r
 823         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 824                 Vore_Regurgitate(self);\r
 825 \r
 826         // apply delayed regurgitating if it was scheduled\r
 827         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 828         {\r
 829                 self.predator.regurgitate_prepare = 0;\r
 830                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 831                 Vore_Regurgitate(self);\r
 832         }\r
 833 \r
 834         // execute digesting and team healing\r
 835         if(self.predator.digesting == TRUE)\r
 836                 Vore_Digest();\r
 837         if(teams_matter && self.team == self.predator.team)\r
 838         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 839                 Vore_Teamheal();\r
 840 \r
 841         // execute prey commands\r
 842         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 843                 Vore_StomachKick();\r
 844         if(self.BUTTON_JUMP)\r
 845                 Vore_StomachLeave();\r
 846 \r
 847         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 848         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 849         kh_Key_DropAll(self, FALSE);\r
 850 }