qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38
  39 #include "../common/vehicles/all.qh"
  40
  41 #include "weapons/hitplot.qh"
  42 #include "weapons/weaponsystem.qh"
  43
  44 #include "../common/net_notice.qh"
  45 #include "../common/net_linked.qh"
  46 #include "../common/physics/player.qh"
  47
  48 #include "../common/items/_mod.qh"
  49
  50 #include "../common/mutators/mutator/waypoints/all.qh"
  51
  52 #include "../common/triggers/subs.qh"
  53 #include "../common/triggers/triggers.qh"
  54 #include "../common/triggers/trigger/secret.qh"
  55
  56 #include "../common/minigames/sv_minigames.qh"
  57
  58 #include "../common/items/inventory.qh"
  59
  60 #include "../common/monsters/sv_monsters.qh"
  61
  62 #include "../lib/warpzone/server.qh"
  63
  64 STATIC_METHOD(Client, Add, void(Client this, int _team))
  65 {
  66     ClientConnect(this);
  67     TRANSMUTE(Player, this);
  68     this.frame = 12; // 7
  69     this.team = _team;
  70     PutClientInServer(this);
  71 }
  72
  73 void PutObserverInServer(entity this);
  74
  75 STATIC_METHOD(Client, Remove, void(Client this))
  76 {
  77     TRANSMUTE(Observer, this);
  78     PutClientInServer(this);
  79     ClientDisconnect(this);
  80 }
  81
  82 void send_CSQC_teamnagger() {
  83         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  84 }
  85
  86 int CountSpectators(entity player, entity to)
  87 {
  88         if(!player) { return 0; } // not sure how, but best to be safe
  89
  90         int spec_count = 0;
  91
  92         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  93         {
  94                 spec_count++;
  95         });
  96
  97         return spec_count;
  98 }
  99
 100 void WriteSpectators(entity player, entity to)
 101 {
 102         if(!player) { return; } // not sure how, but best to be safe
 103
 104         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 105         {
 106                 WriteByte(MSG_ENTITY, num_for_edict(it));
 107         });
 108 }
 109
 110 bool ClientData_Send(entity this, entity to, int sf)
 111 {
 112         assert(to == this.owner, return false);
 113
 114         entity e = to;
 115         if (IS_SPEC(e)) e = e.enemy;
 116
 117         sf = 0;
 118         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 119         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 120         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 121         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 122
 123         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 124         WriteByte(MSG_ENTITY, sf);
 125
 126         if (sf & BIT(1))
 127                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 128
 129         if(sf & BIT(4))
 130         {
 131                 float specs = CountSpectators(e, to);
 132                 WriteByte(MSG_ENTITY, specs);
 133                 WriteSpectators(e, to);
 134         }
 135
 136         return true;
 137 }
 138
 139 void ClientData_Attach(entity this)
 140 {
 141         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 142         CS(this).clientdata.drawonlytoclient = this;
 143         CS(this).clientdata.owner = this;
 144 }
 145
 146 void ClientData_Detach(entity this)
 147 {
 148         delete(CS(this).clientdata);
 149         CS(this).clientdata = NULL;
 150 }
 151
 152 void ClientData_Touch(entity e)
 153 {
 154         CS(e).clientdata.SendFlags = 1;
 155
 156         // make it spectatable
 157         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 158 }
 159
 160 void SetSpectatee(entity this, entity spectatee);
 161 void SetSpectatee_status(entity this, int spectatee_num);
 162
 163
 164 /*
 165 =============
 166 CheckPlayerModel
 167
 168 Checks if the argument string can be a valid playermodel.
 169 Returns a valid one in doubt.
 170 =============
 171 */
 172 string FallbackPlayerModel;
 173 string CheckPlayerModel(string plyermodel) {
 174         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 175         {
 176                 // note: we cannot summon Don Strunzone here, some player may
 177                 // still have the model string set. In case anyone manages how
 178                 // to change a cvar default, we'll have a small leak here.
 179                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 180         }
 181         // only in right path
 182         if( substring(plyermodel,0,14) != "models/player/")
 183                 return FallbackPlayerModel;
 184         // only good file extensions
 185         if(substring(plyermodel,-4,4) != ".zym")
 186         if(substring(plyermodel,-4,4) != ".dpm")
 187         if(substring(plyermodel,-4,4) != ".iqm")
 188         if(substring(plyermodel,-4,4) != ".md3")
 189         if(substring(plyermodel,-4,4) != ".psk")
 190                 return FallbackPlayerModel;
 191         // forbid the LOD models
 192         if(substring(plyermodel, -9,5) == "_lod1")
 193                 return FallbackPlayerModel;
 194         if(substring(plyermodel, -9,5) == "_lod2")
 195                 return FallbackPlayerModel;
 196         if(plyermodel != strtolower(plyermodel))
 197                 return FallbackPlayerModel;
 198         // also, restrict to server models
 199         if(autocvar_sv_servermodelsonly)
 200         {
 201                 if(!fexists(plyermodel))
 202                         return FallbackPlayerModel;
 203         }
 204         return plyermodel;
 205 }
 206
 207 void setplayermodel(entity e, string modelname)
 208 {
 209         precache_model(modelname);
 210         _setmodel(e, modelname);
 211         player_setupanimsformodel(e);
 212         if(!autocvar_g_debug_globalsounds)
 213                 UpdatePlayerSounds(e);
 214 }
 215
 216 void FixPlayermodel(entity player);
 217 /** putting a client as observer in the server */
 218 void PutObserverInServer(entity this)
 219 {
 220     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 221         PlayerState_detach(this);
 222
 223         if (IS_PLAYER(this))
 224         {
 225                 if(this.health >= 1)
 226                 {
 227                         // despawn effect
 228                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 229                 }
 230
 231                 // was a player, recount votes and ready status
 232                 if(IS_REAL_CLIENT(this))
 233                 {
 234                         if (vote_called) { VoteCount(false); }
 235                         ReadyCount();
 236                 }
 237     }
 238
 239     {
 240         entity spot = SelectSpawnPoint(this, true);
 241         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 242         this.angles = vec2(spot.angles);
 243         this.fixangle = true;
 244         // offset it so that the spectator spawns higher off the ground, looks better this way
 245         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 246         if (IS_REAL_CLIENT(this))
 247         {
 248             msg_entity = this;
 249             WriteByte(MSG_ONE, SVC_SETVIEW);
 250             WriteEntity(MSG_ONE, this);
 251         }
 252         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 253         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 254         if(!autocvar_g_debug_globalsounds)
 255         {
 256                 // needed for player sounds
 257                 this.model = "";
 258                 FixPlayermodel(this);
 259         }
 260         setmodel(this, MDL_Null);
 261         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 262         this.view_ofs = '0 0 0';
 263     }
 264
 265     RemoveGrapplingHooks(this);
 266         Portal_ClearAll(this);
 267         Unfreeze(this);
 268         SetSpectatee(this, NULL);
 269
 270         if (this.alivetime)
 271         {
 272                 if (!warmup_stage)
 273                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 274                 this.alivetime = 0;
 275         }
 276
 277         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 278
 279         WaypointSprite_PlayerDead(this);
 280
 281         if (mutator_returnvalue) {
 282             // mutator prevents resetting teams+score
 283         } else {
 284                 int oldteam = this.team;
 285                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 286                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 287         this.frags = FRAGS_SPECTATOR;
 288         PlayerScore_Clear(this);  // clear scores when needed
 289     }
 290
 291         if (CS(this).killcount != FRAGS_SPECTATOR)
 292         {
 293                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 294                 if(!game_stopped)
 295                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 296                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 297
 298                 if(!CS(this).just_joined)
 299                         LogTeamchange(this.playerid, -1, 4);
 300                 else
 301                         CS(this).just_joined = false;
 302         }
 303
 304         accuracy_resend(this);
 305
 306         CS(this).spectatortime = time;
 307         if(this.bot_attack)
 308                 IL_REMOVE(g_bot_targets, this);
 309         this.bot_attack = false;
 310     this.hud = HUD_NORMAL;
 311         TRANSMUTE(Observer, this);
 312         this.iscreature = false;
 313         this.teleportable = TELEPORT_SIMPLE;
 314         if(this.damagedbycontents)
 315                 IL_REMOVE(g_damagedbycontents, this);
 316         this.damagedbycontents = false;
 317         this.health = FRAGS_SPECTATOR;
 318         SetSpectatee_status(this, etof(this));
 319         this.takedamage = DAMAGE_NO;
 320         this.solid = SOLID_NOT;
 321         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 322         this.flags = FL_CLIENT | FL_NOTARGET;
 323         this.armorvalue = 666;
 324         this.effects = 0;
 325         this.armorvalue = autocvar_g_balance_armor_start;
 326         this.pauserotarmor_finished = 0;
 327         this.pauserothealth_finished = 0;
 328         this.pauseregen_finished = 0;
 329         this.damageforcescale = 0;
 330         this.death_time = 0;
 331         this.respawn_flags = 0;
 332         this.respawn_time = 0;
 333         this.stat_respawn_time = 0;
 334         this.alpha = 0;
 335         this.scale = 0;
 336         this.fade_time = 0;
 337         this.pain_frame = 0;
 338         this.pain_finished = 0;
 339         this.strength_finished = 0;
 340         this.invincible_finished = 0;
 341         this.superweapons_finished = 0;
 342         this.pushltime = 0;
 343         this.istypefrag = 0;
 344         setthink(this, func_null);
 345         this.nextthink = 0;
 346         this.deadflag = DEAD_NO;
 347         this.crouch = false;
 348         this.revive_progress = 0;
 349         this.revival_time = 0;
 350
 351         this.items = 0;
 352         this.weapons = '0 0 0';
 353         this.drawonlytoclient = this;
 354
 355         this.weaponmodel = "";
 356         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 357         {
 358                 this.weaponentities[slot] = NULL;
 359         }
 360         this.exteriorweaponentity = NULL;
 361         CS(this).killcount = FRAGS_SPECTATOR;
 362         this.velocity = '0 0 0';
 363         this.avelocity = '0 0 0';
 364         this.punchangle = '0 0 0';
 365         this.punchvector = '0 0 0';
 366         this.oldvelocity = this.velocity;
 367         this.fire_endtime = -1;
 368         this.event_damage = func_null;
 369
 370         for(int slot = 0; slot < MAX_AXH; ++slot)
 371         {
 372                 entity axh = this.(AuxiliaryXhair[slot]);
 373                 this.(AuxiliaryXhair[slot]) = NULL;
 374
 375                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 376                         delete(axh);
 377         }
 378 }
 379
 380 int player_getspecies(entity this)
 381 {
 382         get_model_parameters(this.model, this.skin);
 383         int s = get_model_parameters_species;
 384         get_model_parameters(string_null, 0);
 385         if (s < 0) return SPECIES_HUMAN;
 386         return s;
 387 }
 388
 389 .float model_randomizer;
 390 void FixPlayermodel(entity player)
 391 {
 392         string defaultmodel = "";
 393         int defaultskin = 0;
 394         if(autocvar_sv_defaultcharacter)
 395         {
 396                 if(teamplay)
 397                 {
 398                         switch(player.team)
 399                         {
 400                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 401                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 402                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 403                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 404                         }
 405                 }
 406
 407                 if(defaultmodel == "")
 408                 {
 409                         defaultmodel = autocvar_sv_defaultplayermodel;
 410                         defaultskin = autocvar_sv_defaultplayerskin;
 411                 }
 412
 413                 int n = tokenize_console(defaultmodel);
 414                 if(n > 0)
 415                 {
 416                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 417                         // However, do NOT randomize if the player-selected model is in the list.
 418                         for (int i = 0; i < n; ++i)
 419                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 420                                         defaultmodel = argv(i);
 421                 }
 422
 423                 int i = strstrofs(defaultmodel, ":", 0);
 424                 if(i >= 0)
 425                 {
 426                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 427                         defaultmodel = substring(defaultmodel, 0, i);
 428                 }
 429         }
 430         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 431         {
 432                 if(teamplay)
 433                 {
 434                         switch(player.team)
 435                         {
 436                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 437                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 438                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 439                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 440                         }
 441                 }
 442
 443                 if(!defaultskin)
 444                         defaultskin = autocvar_sv_defaultplayerskin;
 445         }
 446
 447         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 448         defaultmodel = M_ARGV(0, string);
 449         defaultskin = M_ARGV(1, int);
 450
 451         bool chmdl = false;
 452         int oldskin;
 453         if(defaultmodel != "")
 454         {
 455                 if (defaultmodel != player.model)
 456                 {
 457                         vector m1 = player.mins;
 458                         vector m2 = player.maxs;
 459                         setplayermodel (player, defaultmodel);
 460                         setsize (player, m1, m2);
 461                         chmdl = true;
 462                 }
 463
 464                 oldskin = player.skin;
 465                 player.skin = defaultskin;
 466         } else {
 467                 if (player.playermodel != player.model || player.playermodel == "")
 468                 {
 469                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 470                         vector m1 = player.mins;
 471                         vector m2 = player.maxs;
 472                         setplayermodel (player, player.playermodel);
 473                         setsize (player, m1, m2);
 474                         chmdl = true;
 475                 }
 476
 477                 if(!autocvar_sv_defaultcharacterskin)
 478                 {
 479                         oldskin = player.skin;
 480                         player.skin = stof(player.playerskin);
 481                 }
 482                 else
 483                 {
 484                         oldskin = player.skin;
 485                         player.skin = defaultskin;
 486                 }
 487         }
 488
 489         if(chmdl || oldskin != player.skin) // model or skin has changed
 490         {
 491                 player.species = player_getspecies(player); // update species
 492                 if(!autocvar_g_debug_globalsounds)
 493                         UpdatePlayerSounds(player); // update skin sounds
 494         }
 495
 496         if(!teamplay)
 497                 if(strlen(autocvar_sv_defaultplayercolors))
 498                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 499                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 500 }
 501
 502 void PutPlayerInServer(entity this)
 503 {
 504         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 505
 506         PlayerState_attach(this);
 507         accuracy_resend(this);
 508
 509         if (this.team < 0)
 510                 JoinBestTeam(this, true);
 511
 512         entity spot = SelectSpawnPoint(this, false);
 513         if (!spot) {
 514                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 515                 return; // spawn failed
 516         }
 517
 518         TRANSMUTE(Player, this);
 519
 520         CS(this).wasplayer = true;
 521         this.iscreature = true;
 522         this.teleportable = TELEPORT_NORMAL;
 523         if(!this.damagedbycontents)
 524                 IL_PUSH(g_damagedbycontents, this);
 525         this.damagedbycontents = true;
 526         set_movetype(this, MOVETYPE_WALK);
 527         this.solid = SOLID_SLIDEBOX;
 528         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 529         if (autocvar_g_playerclip_collisions)
 530                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 531         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 532                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 533         this.frags = FRAGS_PLAYER;
 534         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 535         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 536         if (autocvar__notarget)
 537                 this.flags |= FL_NOTARGET;
 538         this.takedamage = DAMAGE_AIM;
 539         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 540
 541         if (warmup_stage) {
 542                 this.ammo_shells = warmup_start_ammo_shells;
 543                 this.ammo_nails = warmup_start_ammo_nails;
 544                 this.ammo_rockets = warmup_start_ammo_rockets;
 545                 this.ammo_cells = warmup_start_ammo_cells;
 546                 this.ammo_plasma = warmup_start_ammo_plasma;
 547                 this.ammo_fuel = warmup_start_ammo_fuel;
 548                 this.health = warmup_start_health;
 549                 this.armorvalue = warmup_start_armorvalue;
 550                 this.weapons = WARMUP_START_WEAPONS;
 551         } else {
 552                 this.ammo_shells = start_ammo_shells;
 553                 this.ammo_nails = start_ammo_nails;
 554                 this.ammo_rockets = start_ammo_rockets;
 555                 this.ammo_cells = start_ammo_cells;
 556                 this.ammo_plasma = start_ammo_plasma;
 557                 this.ammo_fuel = start_ammo_fuel;
 558                 this.health = start_health;
 559                 this.armorvalue = start_armorvalue;
 560                 this.weapons = start_weapons;
 561                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 562                 {
 563                         GiveRandomWeapons(this, random_start_weapons_count,
 564                                 autocvar_g_random_start_weapons, random_start_ammo);
 565                 }
 566         }
 567         SetSpectatee_status(this, 0);
 568
 569         PS(this).dual_weapons = '0 0 0';
 570
 571         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 572
 573         this.items = start_items;
 574
 575         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 576         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 577         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 578         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 579         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 580         // extend the pause of rotting if client was reset at the beginning of the countdown
 581         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 582                 float f = game_starttime - time;
 583                 this.spawnshieldtime += f;
 584                 this.pauserotarmor_finished += f;
 585                 this.pauserothealth_finished += f;
 586                 this.pauseregen_finished += f;
 587         }
 588         this.damageforcescale = 2;
 589         this.death_time = 0;
 590         this.respawn_flags = 0;
 591         this.respawn_time = 0;
 592         this.stat_respawn_time = 0;
 593         this.scale = autocvar_sv_player_scale;
 594         this.fade_time = 0;
 595         this.pain_frame = 0;
 596         this.pain_finished = 0;
 597         this.pushltime = 0;
 598         setthink(this, func_null); // players have no think function
 599         this.nextthink = 0;
 600         this.dmg_team = 0;
 601         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 602
 603         this.deadflag = DEAD_NO;
 604
 605         this.angles = spot.angles;
 606         this.angles_z = 0; // never spawn tilted even if the spot says to
 607         if (IS_BOT_CLIENT(this))
 608                 this.v_angle = this.angles;
 609         this.fixangle = true; // turn this way immediately
 610         this.oldvelocity = this.velocity = '0 0 0';
 611         this.avelocity = '0 0 0';
 612         this.punchangle = '0 0 0';
 613         this.punchvector = '0 0 0';
 614
 615         this.strength_finished = 0;
 616         this.invincible_finished = 0;
 617         this.fire_endtime = -1;
 618         this.revive_progress = 0;
 619         this.revival_time = 0;
 620
 621         this.air_finished = time + 12;
 622         this.waterlevel = WATERLEVEL_NONE;
 623         this.watertype = CONTENT_EMPTY;
 624
 625         entity spawnevent = new_pure(spawnevent);
 626         spawnevent.owner = this;
 627         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 628
 629         // Cut off any still running player sounds.
 630         stopsound(this, CH_PLAYER_SINGLE);
 631
 632         this.model = "";
 633         FixPlayermodel(this);
 634         this.drawonlytoclient = NULL;
 635
 636         this.viewloc = NULL;
 637
 638         this.crouch = false;
 639         this.view_ofs = STAT(PL_VIEW_OFS, this);
 640         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 641         this.spawnorigin = spot.origin;
 642         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 643         // don't reset back to last position, even if new position is stuck in solid
 644         this.oldorigin = this.origin;
 645         if(this.conveyor)
 646                 IL_REMOVE(g_conveyed, this);
 647         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 648         this.hud = HUD_NORMAL;
 649
 650         this.event_damage = PlayerDamage;
 651
 652         if(!this.bot_attack)
 653                 IL_PUSH(g_bot_targets, this);
 654         this.bot_attack = true;
 655         if(!this.monster_attack)
 656                 IL_PUSH(g_monster_targets, this);
 657         this.monster_attack = true;
 658         navigation_dynamicgoal_init(this, false);
 659
 660         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 661
 662         // player was spectator
 663         if (CS(this).killcount == FRAGS_SPECTATOR) {
 664                 PlayerScore_Clear(this);
 665                 CS(this).killcount = 0;
 666                 CS(this).startplaytime = time;
 667         }
 668
 669         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 670         {
 671                 .entity weaponentity = weaponentities[slot];
 672                 entity oldwep = this.(weaponentity);
 673                 CL_SpawnWeaponentity(this, weaponentity);
 674                 if(oldwep && oldwep.owner == this)
 675                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 676         }
 677         this.alpha = default_player_alpha;
 678         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 679         this.exteriorweaponentity.alpha = default_weapon_alpha;
 680
 681         this.speedrunning = false;
 682
 683         target_voicescript_clear(this);
 684
 685         // reset fields the weapons may use
 686         FOREACH(Weapons, true, {
 687                 it.wr_resetplayer(it, this);
 688                         // reload all reloadable weapons
 689                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 690                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 691                         {
 692                                 .entity weaponentity = weaponentities[slot];
 693                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 694                         }
 695                 }
 696         });
 697
 698         {
 699                 string s = spot.target;
 700                 spot.target = string_null;
 701                 SUB_UseTargets(spot, this, NULL);
 702                 spot.target = s;
 703         }
 704
 705         Unfreeze(this);
 706
 707         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 708
 709         if (autocvar_spawn_debug)
 710         {
 711                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 712                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 713         }
 714
 715         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 716         {
 717                 .entity weaponentity = weaponentities[slot];
 718                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 719                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 720                 else
 721                         this.(weaponentity).m_switchweapon = WEP_Null;
 722                 this.(weaponentity).m_weapon = WEP_Null;
 723                 this.(weaponentity).weaponname = "";
 724                 this.(weaponentity).m_switchingweapon = WEP_Null;
 725                 this.(weaponentity).cnt = -1;
 726         }
 727
 728         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 729
 730         if (!warmup_stage && !this.alivetime)
 731                 this.alivetime = time;
 732
 733         antilag_clear(this, CS(this));
 734 }
 735
 736 /** Called when a client spawns in the server */
 737 void PutClientInServer(entity this)
 738 {
 739         if (IS_BOT_CLIENT(this)) {
 740                 TRANSMUTE(Player, this);
 741         } else if (IS_REAL_CLIENT(this)) {
 742                 msg_entity = this;
 743                 WriteByte(MSG_ONE, SVC_SETVIEW);
 744                 WriteEntity(MSG_ONE, this);
 745         }
 746         if (game_stopped)
 747                 TRANSMUTE(Observer, this);
 748
 749         SetSpectatee(this, NULL);
 750
 751         // reset player keys
 752         if(PS(this))
 753                 PS(this).itemkeys = 0;
 754
 755         MUTATOR_CALLHOOK(PutClientInServer, this);
 756
 757         if (IS_OBSERVER(this)) {
 758                 PutObserverInServer(this);
 759         } else if (IS_PLAYER(this)) {
 760                 PutPlayerInServer(this);
 761         }
 762 }
 763
 764 void ClientInit_misc(entity this);
 765
 766 // TODO do we need all these fields, or should we stop autodetecting runtime
 767 // changes and just have a console command to update this?
 768 bool ClientInit_SendEntity(entity this, entity to, int sf)
 769 {
 770         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 771         return = true;
 772         msg_entity = to;
 773         // MSG_INIT replacement
 774         // TODO: make easier to use
 775         Registry_send_all();
 776         W_PROP_reload(MSG_ONE, to);
 777         ClientInit_misc(this);
 778         MUTATOR_CALLHOOK(Ent_Init);
 779 }
 780 void ClientInit_misc(entity this)
 781 {
 782         int channel = MSG_ONE;
 783         WriteHeader(channel, ENT_CLIENT_INIT);
 784         WriteByte(channel, g_nexball_meter_period * 32);
 785         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 786         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 787         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 788         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 789         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 790         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 791         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 792         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 793
 794         if(sv_foginterval && world.fog != "")
 795                 WriteString(channel, world.fog);
 796         else
 797                 WriteString(channel, "");
 798         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 799         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 800         WriteByte(channel, serverflags);
 801         WriteCoord(channel, autocvar_g_trueaim_minrange);
 802 }
 803
 804 void ClientInit_CheckUpdate(entity this)
 805 {
 806         this.nextthink = time;
 807         if(this.count != autocvar_g_balance_armor_blockpercent)
 808         {
 809                 this.count = autocvar_g_balance_armor_blockpercent;
 810                 this.SendFlags |= 1;
 811         }
 812         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 813         {
 814                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 815                 this.SendFlags |= 1;
 816         }
 817 }
 818
 819 void ClientInit_Spawn()
 820 {
 821         entity e = new_pure(clientinit);
 822         setthink(e, ClientInit_CheckUpdate);
 823         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 824
 825         ClientInit_CheckUpdate(e);
 826 }
 827
 828 /*
 829 =============
 830 SetNewParms
 831 =============
 832 */
 833 void SetNewParms ()
 834 {
 835         // initialize parms for a new player
 836         parm1 = -(86400 * 366);
 837
 838         MUTATOR_CALLHOOK(SetNewParms);
 839 }
 840
 841 /*
 842 =============
 843 SetChangeParms
 844 =============
 845 */
 846 void SetChangeParms (entity this)
 847 {
 848         // save parms for level change
 849         parm1 = CS(this).parm_idlesince - time;
 850
 851         MUTATOR_CALLHOOK(SetChangeParms);
 852 }
 853
 854 /*
 855 =============
 856 DecodeLevelParms
 857 =============
 858 */
 859 void DecodeLevelParms(entity this)
 860 {
 861         // load parms
 862         CS(this).parm_idlesince = parm1;
 863         if (CS(this).parm_idlesince == -(86400 * 366))
 864                 CS(this).parm_idlesince = time;
 865
 866         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 867         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 868
 869         MUTATOR_CALLHOOK(DecodeLevelParms);
 870 }
 871
 872 /*
 873 =============
 874 ClientKill
 875
 876 Called when a client types 'kill' in the console
 877 =============
 878 */
 879
 880 .float clientkill_nexttime;
 881 void ClientKill_Now_TeamChange(entity this)
 882 {
 883         if(this.killindicator_teamchange == -1)
 884         {
 885                 JoinBestTeam( this, true );
 886         }
 887         else if(this.killindicator_teamchange == -2)
 888         {
 889                 if(blockSpectators)
 890                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 891                 PutObserverInServer(this);
 892         }
 893         else
 894                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 895         this.killindicator_teamchange = 0;
 896 }
 897
 898 void ClientKill_Now(entity this)
 899 {
 900         if(this.vehicle)
 901         {
 902             vehicles_exit(this.vehicle, VHEF_RELEASE);
 903             if(!this.killindicator_teamchange)
 904             {
 905             this.vehicle_health = -1;
 906             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 907             }
 908         }
 909
 910         if(this.killindicator && !wasfreed(this.killindicator))
 911                 delete(this.killindicator);
 912
 913         this.killindicator = NULL;
 914
 915         if(this.killindicator_teamchange)
 916                 ClientKill_Now_TeamChange(this);
 917
 918         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 919         {
 920                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 921         }
 922
 923         // now I am sure the player IS dead
 924 }
 925 void KillIndicator_Think(entity this)
 926 {
 927         if (game_stopped)
 928         {
 929                 this.owner.killindicator = NULL;
 930                 delete(this);
 931                 return;
 932         }
 933
 934         if (this.owner.alpha < 0 && !this.owner.vehicle)
 935         {
 936                 this.owner.killindicator = NULL;
 937                 delete(this);
 938                 return;
 939         }
 940
 941         if(this.cnt <= 0)
 942         {
 943                 ClientKill_Now(this.owner);
 944                 return;
 945         }
 946     else if(this.health == 1) // health == 1 means that it's silent
 947     {
 948         this.nextthink = time + 1;
 949         this.cnt -= 1;
 950     }
 951         else
 952         {
 953                 if(this.cnt <= 10)
 954                         setmodel(this, MDL_NUM(this.cnt));
 955                 if(IS_REAL_CLIENT(this.owner))
 956                 {
 957                         if(this.cnt <= 10)
 958                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 959                 }
 960                 this.nextthink = time + 1;
 961                 this.cnt -= 1;
 962         }
 963 }
 964
 965 float clientkilltime;
 966 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 967 {
 968         float killtime;
 969         float starttime;
 970
 971         if (game_stopped)
 972                 return;
 973
 974         killtime = autocvar_g_balance_kill_delay;
 975
 976     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 977         return;
 978     killtime = M_ARGV(1, float);
 979
 980         this.killindicator_teamchange = targetteam;
 981
 982     if(!this.killindicator)
 983         {
 984                 if(!IS_DEAD(this))
 985                 {
 986                         killtime = max(killtime, this.clientkill_nexttime - time);
 987                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 988                 }
 989
 990                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 991                 {
 992                         ClientKill_Now(this);
 993                 }
 994                 else
 995                 {
 996                         starttime = max(time, clientkilltime);
 997
 998                         this.killindicator = spawn();
 999                         this.killindicator.owner = this;
1000                         this.killindicator.scale = 0.5;
1001                         setattachment(this.killindicator, this, "");
1002                         setorigin(this.killindicator, '0 0 52');
1003                         setthink(this.killindicator, KillIndicator_Think);
1004                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1005                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1006                         this.killindicator.cnt = ceil(killtime);
1007                         this.killindicator.count = bound(0, ceil(killtime), 10);
1008                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1009
1010                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1011                         {
1012                                 it.killindicator = spawn();
1013                                 it.killindicator.owner = it;
1014                                 it.killindicator.scale = 0.5;
1015                                 setattachment(it.killindicator, it, "");
1016                                 setorigin(it.killindicator, '0 0 52');
1017                                 setthink(it.killindicator, KillIndicator_Think);
1018                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1019                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1020                                 it.killindicator.cnt = ceil(killtime);
1021                         });
1022                         this.lip = 0;
1023                 }
1024         }
1025         if(this.killindicator)
1026         {
1027                 if(targetteam == 0) // just die
1028                 {
1029                         this.killindicator.colormod = '0 0 0';
1030                         if(IS_REAL_CLIENT(this))
1031                         if(this.killindicator.cnt > 0)
1032                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1033                 }
1034                 else if(targetteam == -1) // auto
1035                 {
1036                         this.killindicator.colormod = '0 1 0';
1037                         if(IS_REAL_CLIENT(this))
1038                         if(this.killindicator.cnt > 0)
1039                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1040                 }
1041                 else if(targetteam == -2) // spectate
1042                 {
1043                         this.killindicator.colormod = '0.5 0.5 0.5';
1044                         if(IS_REAL_CLIENT(this))
1045                         if(this.killindicator.cnt > 0)
1046                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1047                 }
1048                 else
1049                 {
1050                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1051                         if(IS_REAL_CLIENT(this))
1052                         if(this.killindicator.cnt > 0)
1053                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1054                 }
1055         }
1056
1057 }
1058
1059 void ClientKill (entity this)
1060 {
1061         if(game_stopped) return;
1062         if(this.player_blocked) return;
1063         if(STAT(FROZEN, this)) return;
1064
1065         ClientKill_TeamChange(this, 0);
1066 }
1067
1068 void FixClientCvars(entity e)
1069 {
1070         // send prediction settings to the client
1071         stuffcmd(e, "\nin_bindmap 0 0\n");
1072         if(autocvar_g_antilag == 3) // client side hitscan
1073                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1074         if(autocvar_sv_gentle)
1075                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1076
1077         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1078         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1079
1080         MUTATOR_CALLHOOK(FixClientCvars, e);
1081 }
1082
1083 bool findinlist_abbrev(string tofind, string list)
1084 {
1085         if(list == "" || tofind == "")
1086                 return false; // empty list or search, just return
1087
1088         // this function allows abbreviated strings!
1089         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1090         {
1091                 return true;
1092         });
1093
1094         return false;
1095 }
1096
1097 bool PlayerInIPList(entity p, string iplist)
1098 {
1099         // some safety checks (never allow local?)
1100         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1101                 return false;
1102
1103         return findinlist_abbrev(p.netaddress, iplist);
1104 }
1105
1106 bool PlayerInIDList(entity p, string idlist)
1107 {
1108         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1109         if(!p.crypto_idfp)
1110                 return false;
1111
1112         return findinlist_abbrev(p.crypto_idfp, idlist);
1113 }
1114
1115 bool PlayerInList(entity player, string list)
1116 {
1117         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1118 }
1119
1120 #ifdef DP_EXT_PRECONNECT
1121 /*
1122 =============
1123 ClientPreConnect
1124
1125 Called once (not at each match start) when a client begins a connection to the server
1126 =============
1127 */
1128 void ClientPreConnect(entity this)
1129 {
1130         if(autocvar_sv_eventlog)
1131         {
1132                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1133                         this.playerid,
1134                         etof(this),
1135                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1136                 ));
1137         }
1138 }
1139 #endif
1140
1141 /**
1142 =============
1143 ClientConnect
1144
1145 Called when a client connects to the server
1146 =============
1147 */
1148 void ClientConnect(entity this)
1149 {
1150         if (Ban_MaybeEnforceBanOnce(this)) return;
1151         assert(!IS_CLIENT(this), return);
1152         this.flags |= FL_CLIENT;
1153         assert(player_count >= 0, player_count = 0);
1154
1155 #ifdef WATERMARK
1156         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1157 #endif
1158         TRANSMUTE(Client, this);
1159         CS(this).version_nagtime = time + 10 + random() * 10;
1160
1161         // identify the right forced team
1162         if (autocvar_g_campaign)
1163         {
1164                 if (IS_REAL_CLIENT(this)) // only players, not bots
1165                 {
1166                         switch (autocvar_g_campaign_forceteam)
1167                         {
1168                                 case 1: this.team_forced = NUM_TEAM_1; break;
1169                                 case 2: this.team_forced = NUM_TEAM_2; break;
1170                                 case 3: this.team_forced = NUM_TEAM_3; break;
1171                                 case 4: this.team_forced = NUM_TEAM_4; break;
1172                                 default: this.team_forced = 0;
1173                         }
1174                 }
1175         }
1176         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1177         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1178         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1179         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1180         else switch (autocvar_g_forced_team_otherwise)
1181         {
1182                 default: this.team_forced = 0; break;
1183                 case "red": this.team_forced = NUM_TEAM_1; break;
1184                 case "blue": this.team_forced = NUM_TEAM_2; break;
1185                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1186                 case "pink": this.team_forced = NUM_TEAM_4; break;
1187                 case "spectate":
1188                 case "spectator":
1189                         this.team_forced = -1;
1190                         break;
1191         }
1192         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1193
1194         int playerid_save = this.playerid;
1195         this.playerid = 0; // silent
1196         JoinBestTeam(this, false); // if the team number is valid, keep it
1197         this.playerid = playerid_save;
1198
1199         TRANSMUTE(Observer, this);
1200
1201         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1202
1203         // always track bots, don't ask for cl_allow_uidtracking
1204         if (IS_BOT_CLIENT(this))
1205                 PlayerStats_GameReport_AddPlayer(this);
1206         else
1207                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1208
1209         if (autocvar_sv_eventlog)
1210                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1211
1212         LogTeamchange(this.playerid, this.team, 1);
1213
1214         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1215
1216         if(teamplay && IS_PLAYER(this))
1217                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1218         else
1219                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1220
1221         stuffcmd(this, clientstuff, "\n");
1222         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1223
1224         FixClientCvars(this);
1225
1226         // get version info from player
1227         stuffcmd(this, "cmd clientversion $gameversion\n");
1228
1229         // notify about available teams
1230         if (teamplay)
1231         {
1232                 CheckAllowedTeams(this);
1233                 int t = 0;
1234                 if (c1 >= 0) t |= BIT(0);
1235                 if (c2 >= 0) t |= BIT(1);
1236                 if (c3 >= 0) t |= BIT(2);
1237                 if (c4 >= 0) t |= BIT(3);
1238                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1239         }
1240         else
1241         {
1242                 stuffcmd(this, "set _teams_available 0\n");
1243         }
1244
1245         bot_relinkplayerlist();
1246
1247         CS(this).spectatortime = time;
1248         if (blockSpectators)
1249         {
1250                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1251         }
1252
1253         CS(this).jointime = time;
1254
1255         if (IS_REAL_CLIENT(this))
1256         {
1257                 if (g_weaponarena_weapons == WEPSET(TUBA))
1258                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1259         }
1260
1261         if (!sv_foginterval && world.fog != "")
1262                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1263
1264         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1265                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1266                         send_CSQC_teamnagger();
1267
1268         CSQCMODEL_AUTOINIT(this);
1269
1270         CS(this).model_randomizer = random();
1271
1272         if (IS_REAL_CLIENT(this))
1273                 sv_notice_join(this);
1274
1275         // update physics stats (players can spawn before physics runs)
1276         Physics_UpdateStats(this);
1277
1278         IL_EACH(g_initforplayer, it.init_for_player, {
1279                 it.init_for_player(it, this);
1280         });
1281
1282         Handicap_Initialize(this);
1283
1284         MUTATOR_CALLHOOK(ClientConnect, this);
1285
1286         if (IS_REAL_CLIENT(this))
1287         {
1288                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1289                 {
1290                         CS(this).motd_actived_time = -1;
1291                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1292                 }
1293         }
1294 }
1295 /*
1296 =============
1297 ClientDisconnect
1298
1299 Called when a client disconnects from the server
1300 =============
1301 */
1302 .entity chatbubbleentity;
1303 void ReadyCount();
1304 void ClientDisconnect(entity this)
1305 {
1306         assert(IS_CLIENT(this), return);
1307
1308         PlayerStats_GameReport_FinalizePlayer(this);
1309         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1310         if (CS(this).active_minigame) part_minigame(this);
1311         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1312
1313         if (autocvar_sv_eventlog)
1314                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1315
1316         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1317
1318         if(IS_SPEC(this))
1319                 SetSpectatee(this, NULL);
1320
1321     MUTATOR_CALLHOOK(ClientDisconnect, this);
1322
1323         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1324         ClientState_detach(this);
1325
1326         Portal_ClearAll(this);
1327
1328         Unfreeze(this);
1329
1330         RemoveGrapplingHooks(this);
1331
1332         // Here, everything has been done that requires this player to be a client.
1333
1334         this.flags &= ~FL_CLIENT;
1335
1336         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1337         if (this.killindicator) delete(this.killindicator);
1338
1339         WaypointSprite_PlayerGone(this);
1340
1341         bot_relinkplayerlist();
1342
1343         if (this.clientstatus) strunzone(this.clientstatus);
1344         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1345         if (this.personal) delete(this.personal);
1346
1347         this.playerid = 0;
1348         ReadyCount();
1349         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1350
1351         ONREMOVE(this);
1352 }
1353
1354 void ChatBubbleThink(entity this)
1355 {
1356         this.nextthink = time;
1357         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1358         {
1359                 if(this.owner) // but why can that ever be NULL?
1360                         this.owner.chatbubbleentity = NULL;
1361                 delete(this);
1362                 return;
1363         }
1364
1365         this.mdl = "";
1366
1367         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1368         {
1369                 if ( CS(this.owner).active_minigame )
1370                         this.mdl = "models/sprites/minigame_busy.iqm";
1371                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1372                         this.mdl = "models/misc/chatbubble.spr";
1373         }
1374
1375         if ( this.model != this.mdl )
1376                 _setmodel(this, this.mdl);
1377
1378 }
1379
1380 void UpdateChatBubble(entity this)
1381 {
1382         if (this.alpha < 0)
1383                 return;
1384         // spawn a chatbubble entity if needed
1385         if (!this.chatbubbleentity)
1386         {
1387                 this.chatbubbleentity = new(chatbubbleentity);
1388                 this.chatbubbleentity.owner = this;
1389                 this.chatbubbleentity.exteriormodeltoclient = this;
1390                 setthink(this.chatbubbleentity, ChatBubbleThink);
1391                 this.chatbubbleentity.nextthink = time;
1392                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1393                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1394                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1395                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1396                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1397                 //this.chatbubbleentity.model = "";
1398                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1399         }
1400 }
1401
1402
1403 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1404 // added to the model skins
1405 /*void UpdateColorModHack()
1406 {
1407         float c;
1408         c = this.clientcolors & 15;
1409         // LordHavoc: only bothering to support white, green, red, yellow, blue
1410              if (!teamplay) this.colormod = '0 0 0';
1411         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1412         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1413         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1414         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1415         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1416         else this.colormod = '1 1 1';
1417 }*/
1418
1419 void respawn(entity this)
1420 {
1421         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1422         {
1423                 this.solid = SOLID_NOT;
1424                 this.takedamage = DAMAGE_NO;
1425                 set_movetype(this, MOVETYPE_FLY);
1426                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1427                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1428                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1429                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1430                 if(autocvar_g_respawn_ghosts_maxtime)
1431                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1432         }
1433
1434         CopyBody(this, 1);
1435
1436         this.effects |= EF_NODRAW; // prevent another CopyBody
1437         PutClientInServer(this);
1438 }
1439
1440 void play_countdown(entity this, float finished, Sound samp)
1441 {
1442     TC(Sound, samp);
1443         if(IS_REAL_CLIENT(this))
1444                 if(floor(finished - time - frametime) != floor(finished - time))
1445                         if(finished - time < 6)
1446                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1447 }
1448
1449 void player_powerups(entity this)
1450 {
1451         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1452         int items_prev = this.items;
1453
1454         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1455                 this.modelflags |= MF_ROCKET;
1456         else
1457                 this.modelflags &= ~MF_ROCKET;
1458
1459         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1460
1461         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1462                 return;
1463
1464         Fire_ApplyDamage(this);
1465         Fire_ApplyEffect(this);
1466
1467         if (!g_instagib)
1468         {
1469                 if (this.items & ITEM_Strength.m_itemid)
1470                 {
1471                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1472                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1473                         if (time > this.strength_finished)
1474                         {
1475                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1476                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1477                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1478                         }
1479                 }
1480                 else
1481                 {
1482                         if (time < this.strength_finished)
1483                         {
1484                                 this.items = this.items | ITEM_Strength.m_itemid;
1485                                 if(!g_cts)
1486                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1487                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1488                         }
1489                 }
1490                 if (this.items & ITEM_Shield.m_itemid)
1491                 {
1492                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1493                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1494                         if (time > this.invincible_finished)
1495                         {
1496                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1497                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1498                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1499                         }
1500                 }
1501                 else
1502                 {
1503                         if (time < this.invincible_finished)
1504                         {
1505                                 this.items = this.items | ITEM_Shield.m_itemid;
1506                                 if(!g_cts)
1507                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1508                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1509                         }
1510                 }
1511                 if (this.items & IT_SUPERWEAPON)
1512                 {
1513                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1514                         {
1515                                 this.superweapons_finished = 0;
1516                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1517                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1518                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1519                         }
1520                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1521                         {
1522                                 // don't let them run out
1523                         }
1524                         else
1525                         {
1526                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1527                                 if (time > this.superweapons_finished)
1528                                 {
1529                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1530                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1531                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1532                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1533                                 }
1534                         }
1535                 }
1536                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1537                 {
1538                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1539                         {
1540                                 this.items = this.items | IT_SUPERWEAPON;
1541                                 if(!g_cts)
1542                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1543                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1544                         }
1545                         else
1546                         {
1547                                 this.superweapons_finished = 0;
1548                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1549                         }
1550                 }
1551                 else
1552                 {
1553                         this.superweapons_finished = 0;
1554                 }
1555         }
1556
1557         if(autocvar_g_nodepthtestplayers)
1558                 this.effects = this.effects | EF_NODEPTHTEST;
1559
1560         if(autocvar_g_fullbrightplayers)
1561                 this.effects = this.effects | EF_FULLBRIGHT;
1562
1563         if (time >= game_starttime)
1564         if (time < this.spawnshieldtime)
1565                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1566
1567         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1568 }
1569
1570 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1571 {
1572         if(current > stable)
1573                 return current;
1574         else if(current > stable - 0.25) // when close enough, "snap"
1575                 return stable;
1576         else
1577                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1578 }
1579
1580 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1581 {
1582         if(current < stable)
1583                 return current;
1584         else if(current < stable + 0.25) // when close enough, "snap"
1585                 return stable;
1586         else
1587                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1588 }
1589
1590 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1591 {
1592         if(current > rotstable)
1593         {
1594                 if(rotframetime > 0)
1595                 {
1596                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1597                         current = max(rotstable, current - rotlinear * rotframetime);
1598                 }
1599         }
1600         else if(current < regenstable)
1601         {
1602                 if(regenframetime > 0)
1603                 {
1604                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1605                         current = min(regenstable, current + regenlinear * regenframetime);
1606                 }
1607         }
1608
1609         if(current > limit)
1610                 current = limit;
1611
1612         return current;
1613 }
1614
1615 void player_regen(entity this)
1616 {
1617         float max_mod, regen_mod, rot_mod, limit_mod;
1618         max_mod = regen_mod = rot_mod = limit_mod = 1;
1619
1620         float regen_health = autocvar_g_balance_health_regen;
1621         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1622         float regen_health_rot = autocvar_g_balance_health_rot;
1623         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1624         float regen_health_stable = autocvar_g_balance_health_regenstable;
1625         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1626         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1627                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1628         max_mod = M_ARGV(1, float);
1629         regen_mod = M_ARGV(2, float);
1630         rot_mod = M_ARGV(3, float);
1631         limit_mod = M_ARGV(4, float);
1632         regen_health = M_ARGV(5, float);
1633         regen_health_linear = M_ARGV(6, float);
1634         regen_health_rot = M_ARGV(7, float);
1635         regen_health_rotlinear = M_ARGV(8, float);
1636         regen_health_stable = M_ARGV(9, float);
1637         regen_health_rotstable = M_ARGV(10, float);
1638
1639         if(!mutator_returnvalue)
1640         if(!STAT(FROZEN, this))
1641         {
1642                 float mina, maxa, limith, limita;
1643                 maxa = autocvar_g_balance_armor_rotstable;
1644                 mina = autocvar_g_balance_armor_regenstable;
1645                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1646                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1647
1648                 regen_health_rotstable = regen_health_rotstable * max_mod;
1649                 regen_health_stable = regen_health_stable * max_mod;
1650                 limith = limith * limit_mod;
1651                 limita = limita * limit_mod;
1652
1653                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1654                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1655         }
1656
1657         // if player rotted to death...  die!
1658         // check this outside above checks, as player may still be able to rot to death
1659         if(this.health < 1)
1660         {
1661                 if(this.vehicle)
1662                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1663                 if(this.event_damage)
1664                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1665         }
1666
1667         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1668         {
1669                 float minf, maxf, limitf;
1670
1671                 maxf = autocvar_g_balance_fuel_rotstable;
1672                 minf = autocvar_g_balance_fuel_regenstable;
1673                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1674
1675                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1676         }
1677         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1678         // TODO: Remove this hack when all code uses GivePlayerHealth and
1679         // GivePlayerArmor.
1680         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1681         {
1682                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1683         }
1684         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1685         {
1686                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1687         }
1688         // End hack.
1689 }
1690
1691 bool zoomstate_set;
1692 void SetZoomState(entity this, float newzoom)
1693 {
1694         if(newzoom != CS(this).zoomstate)
1695         {
1696                 CS(this).zoomstate = newzoom;
1697                 ClientData_Touch(this);
1698         }
1699         zoomstate_set = true;
1700 }
1701
1702 void GetPressedKeys(entity this)
1703 {
1704         MUTATOR_CALLHOOK(GetPressedKeys, this);
1705         int keys = STAT(PRESSED_KEYS, this);
1706         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1707         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1708         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1709         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1710
1711         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1712         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1713         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1714         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1715         CS(this).pressedkeys = keys; // store for other users
1716
1717         STAT(PRESSED_KEYS, this) = keys;
1718 }
1719
1720 /*
1721 ======================
1722 spectate mode routines
1723 ======================
1724 */
1725
1726 void SpectateCopy(entity this, entity spectatee)
1727 {
1728     TC(Client, this); TC(Client, spectatee);
1729
1730         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1731         PS(this) = PS(spectatee);
1732         this.armortype = spectatee.armortype;
1733         this.armorvalue = spectatee.armorvalue;
1734         this.ammo_cells = spectatee.ammo_cells;
1735         this.ammo_plasma = spectatee.ammo_plasma;
1736         this.ammo_shells = spectatee.ammo_shells;
1737         this.ammo_nails = spectatee.ammo_nails;
1738         this.ammo_rockets = spectatee.ammo_rockets;
1739         this.ammo_fuel = spectatee.ammo_fuel;
1740         this.clip_load = spectatee.clip_load;
1741         this.clip_size = spectatee.clip_size;
1742         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1743         this.health = spectatee.health;
1744         CS(this).impulse = 0;
1745         this.items = spectatee.items;
1746         this.last_pickup = spectatee.last_pickup;
1747         this.hit_time = spectatee.hit_time;
1748         this.strength_finished = spectatee.strength_finished;
1749         this.invincible_finished = spectatee.invincible_finished;
1750         this.superweapons_finished = spectatee.superweapons_finished;
1751         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1752         this.weapons = spectatee.weapons;
1753         this.vortex_charge = spectatee.vortex_charge;
1754         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1755         this.hagar_load = spectatee.hagar_load;
1756         this.arc_heat_percent = spectatee.arc_heat_percent;
1757         this.minelayer_mines = spectatee.minelayer_mines;
1758         this.punchangle = spectatee.punchangle;
1759         this.view_ofs = spectatee.view_ofs;
1760         this.velocity = spectatee.velocity;
1761         this.dmg_take = spectatee.dmg_take;
1762         this.dmg_save = spectatee.dmg_save;
1763         this.dmg_inflictor = spectatee.dmg_inflictor;
1764         this.v_angle = spectatee.v_angle;
1765         this.angles = spectatee.v_angle;
1766         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1767         this.revive_progress = spectatee.revive_progress;
1768         this.viewloc = spectatee.viewloc;
1769         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1770                 this.fixangle = true;
1771         setorigin(this, spectatee.origin);
1772         setsize(this, spectatee.mins, spectatee.maxs);
1773         SetZoomState(this, CS(spectatee).zoomstate);
1774
1775         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1776         {
1777                 .entity weaponentity = weaponentities[slot];
1778                 this.(weaponentity) = spectatee.(weaponentity);
1779         }
1780
1781         for(int slot = 0; slot < MAX_AXH; ++slot)
1782         {
1783                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1784         }
1785
1786     anticheat_spectatecopy(this, spectatee);
1787         this.hud = spectatee.hud;
1788         if(spectatee.vehicle)
1789     {
1790         this.angles = spectatee.v_angle;
1791
1792         //this.fixangle = false;
1793         //this.velocity = spectatee.vehicle.velocity;
1794         this.vehicle_health = spectatee.vehicle_health;
1795         this.vehicle_shield = spectatee.vehicle_shield;
1796         this.vehicle_energy = spectatee.vehicle_energy;
1797         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1798         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1799         this.vehicle_reload1 = spectatee.vehicle_reload1;
1800         this.vehicle_reload2 = spectatee.vehicle_reload2;
1801
1802         //msg_entity = this;
1803
1804        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1805             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1806            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1807            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1808
1809         //WriteByte (MSG_ONE, SVC_SETVIEW);
1810         //    WriteEntity(MSG_ONE, this);
1811         //makevectors(spectatee.v_angle);
1812         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1813     }
1814 }
1815
1816 bool SpectateUpdate(entity this)
1817 {
1818         if(!this.enemy)
1819                 return false;
1820
1821         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1822         {
1823                 SetSpectatee(this, NULL);
1824                 return false;
1825         }
1826
1827         SpectateCopy(this, this.enemy);
1828
1829         return true;
1830 }
1831
1832 bool SpectateSet(entity this)
1833 {
1834         if(!IS_PLAYER(this.enemy))
1835                 return false;
1836
1837         ClientData_Touch(this.enemy);
1838
1839         msg_entity = this;
1840         WriteByte(MSG_ONE, SVC_SETVIEW);
1841         WriteEntity(MSG_ONE, this.enemy);
1842         set_movetype(this, MOVETYPE_NONE);
1843         accuracy_resend(this);
1844
1845         if(!SpectateUpdate(this))
1846                 PutObserverInServer(this);
1847
1848         return true;
1849 }
1850
1851 void SetSpectatee_status(entity this, int spectatee_num)
1852 {
1853         int oldspectatee_status = CS(this).spectatee_status;
1854         CS(this).spectatee_status = spectatee_num;
1855
1856         if (CS(this).spectatee_status != oldspectatee_status)
1857         {
1858                 ClientData_Touch(this);
1859                 if (g_race || g_cts) race_InitSpectator();
1860         }
1861 }
1862
1863 void SetSpectatee(entity this, entity spectatee)
1864 {
1865         if(IS_BOT_CLIENT(this))
1866                 return; // bots abuse .enemy, this code is useless to them
1867
1868         entity old_spectatee = this.enemy;
1869
1870         this.enemy = spectatee;
1871
1872         // WEAPONTODO
1873         // these are required to fix the spectator bug with arc
1874         if(old_spectatee)
1875         {
1876                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1877                 {
1878                         .entity weaponentity = weaponentities[slot];
1879                         if(old_spectatee.(weaponentity).arc_beam)
1880                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1881                 }
1882         }
1883         if(this.enemy)
1884         {
1885                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1886                 {
1887                         .entity weaponentity = weaponentities[slot];
1888                         if(this.enemy.(weaponentity).arc_beam)
1889                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1890                 }
1891         }
1892
1893         if (this.enemy)
1894                 SetSpectatee_status(this, etof(this.enemy));
1895
1896         // needed to update spectator list
1897         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1898 }
1899
1900 bool Spectate(entity this, entity pl)
1901 {
1902         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1903                 return false;
1904         pl = M_ARGV(1, entity);
1905
1906         SetSpectatee(this, pl);
1907         return SpectateSet(this);
1908 }
1909
1910 bool SpectateNext(entity this)
1911 {
1912         entity ent = find(this.enemy, classname, STR_PLAYER);
1913
1914         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1915                 ent = M_ARGV(1, entity);
1916         else if (!ent)
1917                 ent = find(ent, classname, STR_PLAYER);
1918
1919         if(ent) { SetSpectatee(this, ent); }
1920
1921         return SpectateSet(this);
1922 }
1923
1924 bool SpectatePrev(entity this)
1925 {
1926         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1927         entity ent = findchain(classname, STR_PLAYER);
1928         if (!ent) // no player
1929                 return false;
1930
1931         entity first = ent;
1932         // skip players until current spectated player
1933         if(this.enemy)
1934         while(ent && ent != this.enemy)
1935                 ent = ent.chain;
1936
1937         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1938         {
1939                 case MUT_SPECPREV_FOUND:
1940                     ent = M_ARGV(1, entity);
1941                     break;
1942                 case MUT_SPECPREV_RETURN:
1943                     return true;
1944                 case MUT_SPECPREV_CONTINUE:
1945                 default:
1946                 {
1947                         if(ent.chain)
1948                                 ent = ent.chain;
1949                         else
1950                                 ent = first;
1951                         break;
1952                 }
1953         }
1954
1955         SetSpectatee(this, ent);
1956         return SpectateSet(this);
1957 }
1958
1959 /*
1960 =============
1961 ShowRespawnCountdown()
1962
1963 Update a respawn countdown display.
1964 =============
1965 */
1966 void ShowRespawnCountdown(entity this)
1967 {
1968         float number;
1969         if(!IS_DEAD(this)) // just respawned?
1970                 return;
1971         else
1972         {
1973                 number = ceil(this.respawn_time - time);
1974                 if(number <= 0)
1975                         return;
1976                 if(number <= this.respawn_countdown)
1977                 {
1978                         this.respawn_countdown = number - 1;
1979                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1980                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1981                 }
1982         }
1983 }
1984
1985 .bool team_selected;
1986 bool ShowTeamSelection(entity this)
1987 {
1988         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1989                 return false;
1990         stuffcmd(this, "menu_showteamselect\n");
1991         return true;
1992 }
1993 void Join(entity this)
1994 {
1995         TRANSMUTE(Player, this);
1996
1997         if(!this.team_selected)
1998         if(autocvar_g_campaign || autocvar_g_balance_teams)
1999                 JoinBestTeam(this, true);
2000
2001         if(autocvar_g_campaign)
2002                 campaign_bots_may_start = true;
2003
2004         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2005
2006         PutClientInServer(this);
2007
2008         if(IS_PLAYER(this))
2009         if(teamplay && this.team != -1)
2010                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2011         else
2012                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2013         this.team_selected = false;
2014 }
2015
2016 /**
2017  * Determines whether the player is allowed to join. This depends on cvar
2018  * g_maxplayers, if it isn't used this function always return true, otherwise
2019  * it checks whether the number of currently playing players exceeds g_maxplayers.
2020  * @return int number of free slots for players, 0 if none
2021  */
2022 int nJoinAllowed(entity this, entity ignore)
2023 {
2024         if(!ignore)
2025         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2026         // so report 0 free slots if restricted
2027         {
2028                 if(autocvar_g_forced_team_otherwise == "spectate")
2029                         return 0;
2030                 if(autocvar_g_forced_team_otherwise == "spectator")
2031                         return 0;
2032         }
2033
2034         if(this && this.team_forced < 0)
2035                 return 0; // forced spectators can never join
2036
2037         // TODO simplify this
2038         int totalClients = 0;
2039         int currentlyPlaying = 0;
2040         FOREACH_CLIENT(true, {
2041                 if(it != ignore)
2042                         ++totalClients;
2043                 if(IS_REAL_CLIENT(it))
2044                 if(IS_PLAYER(it) || it.caplayer)
2045                         ++currentlyPlaying;
2046         });
2047
2048         float free_slots = 0;
2049         if (!autocvar_g_maxplayers)
2050                 free_slots = maxclients - totalClients;
2051         else if(currentlyPlaying < autocvar_g_maxplayers)
2052                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2053
2054         static float join_prevent_msg_time = 0;
2055         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2056         {
2057                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2058                 join_prevent_msg_time = time + 3;
2059         }
2060
2061         return free_slots;
2062 }
2063
2064 /**
2065  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2066  * g_maxplayers_spectator_blocktime seconds
2067  */
2068 void checkSpectatorBlock(entity this)
2069 {
2070         if(IS_SPEC(this) || IS_OBSERVER(this))
2071         if(!this.caplayer)
2072         if(IS_REAL_CLIENT(this))
2073         {
2074                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2075                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2076                         dropclient(this);
2077                 }
2078         }
2079 }
2080
2081 void PrintWelcomeMessage(entity this)
2082 {
2083         if(CS(this).motd_actived_time == 0)
2084         {
2085                 if (autocvar_g_campaign) {
2086                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2087                                 CS(this).motd_actived_time = time;
2088                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2089                         }
2090                 } else {
2091                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2092                                 CS(this).motd_actived_time = time;
2093                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2094                         }
2095                 }
2096         }
2097         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2098         {
2099                 if (autocvar_g_campaign) {
2100                         if (PHYS_INPUT_BUTTON_INFO(this))
2101                                 CS(this).motd_actived_time = time;
2102                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2103                                 CS(this).motd_actived_time = 0;
2104                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2105                         }
2106                 } else {
2107                         if (PHYS_INPUT_BUTTON_INFO(this))
2108                                 CS(this).motd_actived_time = time;
2109                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2110                                 CS(this).motd_actived_time = 0;
2111                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2112                         }
2113                 }
2114         }
2115         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2116         {
2117                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2118                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2119                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2120                 {
2121                         // instanctly hide MOTD
2122                         CS(this).motd_actived_time = 0;
2123                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2124                 }
2125         }
2126 }
2127
2128 bool joinAllowed(entity this)
2129 {
2130         if (CS(this).version_mismatch) return false;
2131         if (!nJoinAllowed(this, this)) return false;
2132         if (teamplay && lockteams) return false;
2133         if (ShowTeamSelection(this)) return false;
2134         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2135         return true;
2136 }
2137
2138 .int items_added;
2139 bool PlayerThink(entity this)
2140 {
2141         if (game_stopped || intermission_running) {
2142                 this.modelflags &= ~MF_ROCKET;
2143                 if(intermission_running)
2144                         IntermissionThink(this);
2145                 return false;
2146         }
2147
2148         if (timeout_status == TIMEOUT_ACTIVE) {
2149         // don't allow the player to turn around while game is paused
2150                 // FIXME turn this into CSQC stuff
2151                 this.v_angle = this.lastV_angle;
2152                 this.angles = this.lastV_angle;
2153                 this.fixangle = true;
2154         }
2155
2156         if (frametime) player_powerups(this);
2157
2158         if (IS_DEAD(this)) {
2159                 if (this.personal && g_race_qualifying) {
2160                         if (time > this.respawn_time) {
2161                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2162                                 respawn(this);
2163                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2164                         }
2165                 } else {
2166                         if (frametime) player_anim(this);
2167
2168                         if (this.respawn_flags & RESPAWN_DENY)
2169                         {
2170                                 STAT(RESPAWN_TIME, this) = 0;
2171                                 return false;
2172                         }
2173
2174                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2175
2176                         switch(this.deadflag)
2177                         {
2178                                 case DEAD_DYING:
2179                                 {
2180                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2181                                                 this.deadflag = DEAD_RESPAWNING;
2182                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2183                                                 this.deadflag = DEAD_DEAD;
2184                                         break;
2185                                 }
2186                                 case DEAD_DEAD:
2187                                 {
2188                                         if (button_pressed)
2189                                                 this.deadflag = DEAD_RESPAWNABLE;
2190                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2191                                                 this.deadflag = DEAD_RESPAWNING;
2192                                         break;
2193                                 }
2194                                 case DEAD_RESPAWNABLE:
2195                                 {
2196                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2197                                                 this.deadflag = DEAD_RESPAWNING;
2198                                         break;
2199                                 }
2200                                 case DEAD_RESPAWNING:
2201                                 {
2202                                         if (time > this.respawn_time)
2203                                         {
2204                                                 this.respawn_time = time + 1; // only retry once a second
2205                                                 this.respawn_time_max = this.respawn_time;
2206                                                 respawn(this);
2207                                         }
2208                                         break;
2209                                 }
2210                         }
2211
2212                         ShowRespawnCountdown(this);
2213
2214                         if (this.respawn_flags & RESPAWN_SILENT)
2215                                 STAT(RESPAWN_TIME, this) = 0;
2216                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2217                         {
2218                                 if (time < this.respawn_time)
2219                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2220                                 else if (this.deadflag != DEAD_RESPAWNING)
2221                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2222                         }
2223                         else
2224                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2225                 }
2226
2227                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2228                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2229                         STAT(RESPAWN_TIME, this) *= -1;
2230
2231                 return false;
2232         }
2233
2234         bool have_hook = false;
2235         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2236         {
2237                 .entity weaponentity = weaponentities[slot];
2238                 if(this.(weaponentity).hook.state)
2239                 {
2240                         have_hook = true;
2241                         break;
2242                 }
2243         }
2244         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2245         if (have_hook) {
2246                 do_crouch = false;
2247         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2248                 do_crouch = false;
2249         } else if (this.vehicle) {
2250                 do_crouch = false;
2251         } else if (STAT(FROZEN, this)) {
2252                 do_crouch = false;
2253     }
2254
2255         if (do_crouch) {
2256                 if (!this.crouch) {
2257                         this.crouch = true;
2258                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2259                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2260                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2261                 }
2262         } else if (this.crouch) {
2263         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2264         if (!trace_startsolid) {
2265             this.crouch = false;
2266             this.view_ofs = STAT(PL_VIEW_OFS, this);
2267             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2268         }
2269         }
2270
2271         FixPlayermodel(this);
2272
2273         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2274         //if(frametime)
2275         {
2276                 this.items &= ~this.items_added;
2277
2278                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2279                 {
2280                         .entity weaponentity = weaponentities[slot];
2281                         W_WeaponFrame(this, weaponentity);
2282
2283                         if(slot == 0)
2284                         {
2285                                 this.clip_load = this.(weaponentity).clip_load;
2286                                 this.clip_size = this.(weaponentity).clip_size;
2287                         }
2288                 }
2289
2290                 this.items_added = 0;
2291                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2292             this.items_added |= IT_FUEL;
2293
2294                 this.items |= this.items_added;
2295         }
2296
2297         player_regen(this);
2298
2299         // WEAPONTODO: Add a weapon request for this
2300         // rot vortex charge to the charge limit
2301         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2302         {
2303                 .entity weaponentity = weaponentities[slot];
2304                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2305                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2306         }
2307
2308         if (frametime) player_anim(this);
2309
2310         // secret status
2311         secrets_setstatus(this);
2312
2313         // monsters status
2314         monsters_setstatus(this);
2315
2316         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2317
2318         return true;
2319 }
2320
2321 void ObserverThink(entity this)
2322 {
2323         if ( CS(this).impulse )
2324         {
2325                 MinigameImpulse(this, CS(this).impulse);
2326                 CS(this).impulse = 0;
2327         }
2328
2329         if (this.flags & FL_JUMPRELEASED) {
2330                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2331                         this.flags &= ~FL_JUMPRELEASED;
2332                         this.flags |= FL_SPAWNING;
2333                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2334                         this.flags &= ~FL_JUMPRELEASED;
2335                         if(SpectateNext(this)) {
2336                                 TRANSMUTE(Spectator, this);
2337                         }
2338                 } else {
2339                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2340                         set_movetype(this, preferred_movetype);
2341                 }
2342         } else {
2343                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2344                         this.flags |= FL_JUMPRELEASED;
2345                         if(this.flags & FL_SPAWNING)
2346                         {
2347                                 this.flags &= ~FL_SPAWNING;
2348                                 Join(this);
2349                                 return;
2350                         }
2351                 }
2352         }
2353 }
2354
2355 void SpectatorThink(entity this)
2356 {
2357         if ( CS(this).impulse )
2358         {
2359                 if(MinigameImpulse(this, CS(this).impulse))
2360                         CS(this).impulse = 0;
2361
2362                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2363                 {
2364                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2365                         CS(this).impulse = 0;
2366                         return;
2367                 }
2368         }
2369
2370         if (this.flags & FL_JUMPRELEASED) {
2371                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2372                         this.flags &= ~FL_JUMPRELEASED;
2373                         this.flags |= FL_SPAWNING;
2374                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2375                         this.flags &= ~FL_JUMPRELEASED;
2376                         if(SpectateNext(this)) {
2377                                 TRANSMUTE(Spectator, this);
2378                         } else {
2379                                 TRANSMUTE(Observer, this);
2380                                 PutClientInServer(this);
2381                         }
2382                         CS(this).impulse = 0;
2383                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2384                         this.flags &= ~FL_JUMPRELEASED;
2385                         if(SpectatePrev(this)) {
2386                                 TRANSMUTE(Spectator, this);
2387                         } else {
2388                                 TRANSMUTE(Observer, this);
2389                                 PutClientInServer(this);
2390                         }
2391                         CS(this).impulse = 0;
2392                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2393                         this.flags &= ~FL_JUMPRELEASED;
2394                         TRANSMUTE(Observer, this);
2395                         PutClientInServer(this);
2396                 } else {
2397                         if(!SpectateUpdate(this))
2398                                 PutObserverInServer(this);
2399                 }
2400         } else {
2401                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2402                         this.flags |= FL_JUMPRELEASED;
2403                         if(this.flags & FL_SPAWNING)
2404                         {
2405                                 this.flags &= ~FL_SPAWNING;
2406                                 Join(this);
2407                                 return;
2408                         }
2409                 }
2410                 if(!SpectateUpdate(this))
2411                         PutObserverInServer(this);
2412         }
2413
2414         this.flags |= FL_CLIENT | FL_NOTARGET;
2415 }
2416
2417 void vehicles_enter (entity pl, entity veh);
2418 void PlayerUseKey(entity this)
2419 {
2420         if (!IS_PLAYER(this))
2421                 return;
2422
2423         if(this.vehicle)
2424         {
2425                 if(!game_stopped)
2426                 {
2427                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2428                         return;
2429                 }
2430         }
2431         else if(autocvar_g_vehicles_enter)
2432         {
2433                 if(!STAT(FROZEN, this))
2434                 if(!IS_DEAD(this))
2435                 if(!game_stopped)
2436                 {
2437                         entity head, closest_target = NULL;
2438                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2439
2440                         while(head) // find the closest acceptable target to enter
2441                         {
2442                                 if(IS_VEHICLE(head))
2443                                 if(!IS_DEAD(head))
2444                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2445                                 if(head.takedamage != DAMAGE_NO)
2446                                 {
2447                                         if(closest_target)
2448                                         {
2449                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2450                                                 { closest_target = head; }
2451                                         }
2452                                         else { closest_target = head; }
2453                                 }
2454
2455                                 head = head.chain;
2456                         }
2457
2458                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2459                 }
2460         }
2461
2462         // a use key was pressed; call handlers
2463         MUTATOR_CALLHOOK(PlayerUseKey, this);
2464 }
2465
2466
2467 /*
2468 =============
2469 PlayerPreThink
2470
2471 Called every frame for each client before the physics are run
2472 =============
2473 */
2474 .float last_vehiclecheck;
2475 void PlayerPreThink (entity this)
2476 {
2477         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2478         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2479
2480         WarpZone_PlayerPhysics_FixVAngle(this);
2481
2482         if (frametime) {
2483                 // physics frames: update anticheat stuff
2484                 anticheat_prethink(this);
2485         }
2486
2487         if (blockSpectators && frametime) {
2488                 // WORKAROUND: only use dropclient in server frames (frametime set).
2489                 // Never use it in cl_movement frames (frametime zero).
2490                 checkSpectatorBlock(this);
2491         }
2492
2493         zoomstate_set = false;
2494
2495         // Check for nameless players
2496         if (this.netname == "" || this.netname != CS(this).netname_previous)
2497         {
2498                 bool assume_unchanged = (CS(this).netname_previous == "");
2499                 if (isInvisibleString(this.netname))
2500                 {
2501                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2502                         assume_unchanged = false;
2503                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2504                 }
2505                 if (!assume_unchanged && autocvar_sv_eventlog)
2506                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2507                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2508                 CS(this).netname_previous = strzone(this.netname);
2509         }
2510
2511         // version nagging
2512         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2513         CS(this).version_nagtime = 0;
2514         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2515             // git client
2516         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2517             // git server
2518             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2519         } else {
2520             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2521             if (r < 0) { // old client
2522                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2523             } else if (r > 0) { // old server
2524                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2525             }
2526         }
2527     }
2528
2529         // GOD MODE info
2530         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2531         {
2532                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2533                 this.max_armorvalue = 0;
2534         }
2535
2536         if(IS_PLAYER(this))
2537         {
2538                 if (STAT(FROZEN, this) == 2)
2539                 {
2540                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2541                         this.health = max(1, this.revive_progress * start_health);
2542                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2543
2544                         if (this.revive_progress >= 1)
2545                                 Unfreeze(this);
2546                 }
2547                 else if (STAT(FROZEN, this) == 3)
2548                 {
2549                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2550                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2551
2552                         if (this.health < 1)
2553                         {
2554                                 if (this.vehicle)
2555                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2556                                 if(this.event_damage)
2557                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2558                         }
2559                         else if (this.revive_progress <= 0)
2560                                 Unfreeze(this);
2561                 }
2562         }
2563
2564         MUTATOR_CALLHOOK(PlayerPreThink, this);
2565
2566         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2567         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2568         {
2569                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2570                 {
2571                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2572                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2573                         {
2574                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2575                         }
2576                         else if(!it.owner)
2577                         {
2578                                 if(!it.team || SAME_TEAM(this, it))
2579                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2580                                 else if(autocvar_g_vehicles_steal)
2581                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2582                         }
2583                 });
2584
2585                 this.last_vehiclecheck = time + 1;
2586         }
2587
2588         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2589         {
2590                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2591                         PlayerUseKey(this);
2592                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2593         }
2594
2595         if (IS_REAL_CLIENT(this))
2596                 PrintWelcomeMessage(this);
2597
2598         #define MIN_SPEC_TIME 1
2599         if (IS_PLAYER(this)) {
2600                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2601                         error("Client can't be spawned as player on connection!");
2602                 if(!PlayerThink(this))
2603                         return;
2604         }
2605         else if (game_stopped || intermission_running) {
2606                 if(intermission_running)
2607                         IntermissionThink(this);
2608                 return;
2609         }
2610         else if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME + 1)
2611         {
2612                 // don't do this in ClientConnect
2613                 // many things can go wrong if a client is spawned as player on connection
2614                 if (time > CS(this).jointime + MIN_SPEC_TIME)
2615                 {
2616                         if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2617                                 || (!(autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0)
2618                                         && (!teamplay || autocvar_g_balance_teams)))
2619                         {
2620                                 campaign_bots_may_start = true;
2621                                 Join(this);
2622                                 return;
2623                         }
2624                 }
2625         }
2626         else if (IS_OBSERVER(this)) {
2627                 ObserverThink(this);
2628         }
2629         else if (IS_SPEC(this)) {
2630                 SpectatorThink(this);
2631         }
2632
2633         // WEAPONTODO: Add weapon request for this
2634         if (!zoomstate_set) {
2635                 bool wep_zoomed = false;
2636                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2637                 {
2638                         .entity weaponentity = weaponentities[slot];
2639                         Weapon thiswep = this.(weaponentity).m_weapon;
2640                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2641                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2642                 }
2643                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2644     }
2645
2646         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2647         {
2648                 CS(this).teamkill_soundtime = 0;
2649
2650                 entity e = CS(this).teamkill_soundsource;
2651                 entity oldpusher = e.pusher;
2652                 e.pusher = this;
2653                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2654                 e.pusher = oldpusher;
2655         }
2656
2657         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2658                 CS(this).taunt_soundtime = 0;
2659                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2660         }
2661
2662         target_voicescript_next(this);
2663
2664         // WEAPONTODO: Move into weaponsystem somehow
2665         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2666         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2667         {
2668                 .entity weaponentity = weaponentities[slot];
2669                 if(this.(weaponentity).m_weapon == WEP_Null)
2670                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2671         }
2672 }
2673
2674 void DrownPlayer(entity this)
2675 {
2676         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2677                 return;
2678
2679         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2680         {
2681                 if(this.air_finished < time)
2682                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2683                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2684         }
2685         else if (this.air_finished < time)
2686         {       // drown!
2687                 if (this.pain_finished < time)
2688                 {
2689                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2690                         this.pain_finished = time + 0.5;
2691                 }
2692         }
2693 }
2694
2695 .bool move_qcphysics;
2696
2697 void Player_Physics(entity this)
2698 {
2699         set_movetype(this, this.move_movetype);
2700
2701         if(!this.move_qcphysics)
2702                 return;
2703
2704         if(!frametime && !CS(this).pm_frametime)
2705                 return;
2706
2707         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2708
2709         CS(this).pm_frametime = 0;
2710 }
2711
2712 /*
2713 =============
2714 PlayerPostThink
2715
2716 Called every frame for each client after the physics are run
2717 =============
2718 */
2719 void PlayerPostThink (entity this)
2720 {
2721         Player_Physics(this);
2722
2723         if (sv_maxidle > 0)
2724         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2725         if (IS_REAL_CLIENT(this))
2726         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2727         {
2728                 int totalClients = 0;
2729                 if(sv_maxidle_slots > 0)
2730                 {
2731                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2732                         {
2733                                 ++totalClients;
2734                         });
2735                 }
2736
2737                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2738                 { /* do nothing */ }
2739                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2740                 {
2741                         if (CS(this).idlekick_lasttimeleft)
2742                         {
2743                                 CS(this).idlekick_lasttimeleft = 0;
2744                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2745                         }
2746                 }
2747                 else
2748                 {
2749                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2750                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2751                                 if (!CS(this).idlekick_lasttimeleft)
2752                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2753                         }
2754                         if (timeleft <= 0) {
2755                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2756                                 dropclient(this);
2757                                 return;
2758                         }
2759                         else if (timeleft <= 10) {
2760                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2761                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2762                 }
2763                                 CS(this).idlekick_lasttimeleft = timeleft;
2764                         }
2765                 }
2766         }
2767
2768         CheatFrame(this);
2769
2770         if (game_stopped)
2771         {
2772                 this.solid = SOLID_NOT;
2773                 this.takedamage = DAMAGE_NO;
2774                 set_movetype(this, MOVETYPE_NONE);
2775         }
2776
2777         if (IS_PLAYER(this)) {
2778                 DrownPlayer(this);
2779                 UpdateChatBubble(this);
2780                 if (CS(this).impulse) ImpulseCommands(this);
2781                 if (game_stopped)
2782                 {
2783                         CSQCMODEL_AUTOUPDATE(this);
2784                         return;
2785                 }
2786                 GetPressedKeys(this);
2787         }
2788
2789         if (this.waypointsprite_attachedforcarrier) {
2790             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2791                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2792     }
2793
2794         playerdemo_write(this);
2795
2796         CSQCMODEL_AUTOUPDATE(this);
2797 }
2798
2799 // hack to copy the button fields from the client entity to the Client State
2800 void PM_UpdateButtons(entity this, entity store)
2801 {
2802         if(this.impulse)
2803                 store.impulse = this.impulse;
2804         this.impulse = 0;
2805
2806         store.button0 = this.button0;
2807         store.button2 = this.button2;
2808         store.button3 = this.button3;
2809         store.button4 = this.button4;
2810         store.button5 = this.button5;
2811         store.button6 = this.button6;
2812         store.button7 = this.button7;
2813         store.button8 = this.button8;
2814         store.button9 = this.button9;
2815         store.button10 = this.button10;
2816         store.button11 = this.button11;
2817         store.button12 = this.button12;
2818         store.button13 = this.button13;
2819         store.button14 = this.button14;
2820         store.button15 = this.button15;
2821         store.button16 = this.button16;
2822         store.buttonuse = this.buttonuse;
2823         store.buttonchat = this.buttonchat;
2824
2825         store.cursor_active = this.cursor_active;
2826         store.cursor_screen = this.cursor_screen;
2827         store.cursor_trace_start = this.cursor_trace_start;
2828         store.cursor_trace_endpos = this.cursor_trace_endpos;
2829         store.cursor_trace_ent = this.cursor_trace_ent;
2830
2831         store.ping = this.ping;
2832         store.ping_packetloss = this.ping_packetloss;
2833         store.ping_movementloss = this.ping_movementloss;
2834
2835         store.v_angle = this.v_angle;
2836         store.movement = this.movement;
2837 }