qcsrc/warpzonelib/client.qc

   1 void WarpZone_Fade_PreDraw()
   2 {
   3         if(self.warpzone_fadestart)
   4                 self.alpha = (self.warpzone_fadeend - vlen(view_origin - self.origin)) / (self.warpzone_fadeend - self.warpzone_fadestart);
   5         else
   6                 self.alpha = 1;
   7         if(self.alpha <= 0)
   8                 self.drawmask = 0;
   9         else
  10                 self.drawmask = MASK_NORMAL;
  11 }
  12
  13 void WarpZone_Read(float isnew)
  14 {
  15         float f;
  16
  17         ++warpzone_warpzones_exist;
  18         if not(self.enemy)
  19         {
  20                 self.enemy = spawn();
  21                 self.enemy.classname = "warpzone_from";
  22         }
  23         self.classname = "trigger_warpzone";
  24
  25         f = ReadByte();
  26         self.warpzone_isboxy = (f & 1);
  27         self.origin_x = ReadCoord();
  28         self.origin_y = ReadCoord();
  29         self.origin_z = ReadCoord();
  30         self.modelindex = ReadShort();
  31         self.mins_x = ReadCoord();
  32         self.mins_y = ReadCoord();
  33         self.mins_z = ReadCoord();
  34         self.maxs_x = ReadCoord();
  35         self.maxs_y = ReadCoord();
  36         self.maxs_z = ReadCoord();
  37         self.scale = ReadByte() / 16;
  38         self.enemy.oldorigin_x = ReadCoord();
  39         self.enemy.oldorigin_y = ReadCoord();
  40         self.enemy.oldorigin_z = ReadCoord();
  41         self.enemy.avelocity_x = ReadCoord();
  42         self.enemy.avelocity_y = ReadCoord();
  43         self.enemy.avelocity_z = ReadCoord();
  44         self.oldorigin_x = ReadCoord();
  45         self.oldorigin_y = ReadCoord();
  46         self.oldorigin_z = ReadCoord();
  47         self.avelocity_x = ReadCoord();
  48         self.avelocity_y = ReadCoord();
  49         self.avelocity_z = ReadCoord();
  50
  51         if(f & 2)
  52         {
  53                 self.warpzone_fadestart = ReadShort();
  54                 self.warpzone_fadeend = max(self.warpzone_fadestart + 1, ReadShort());
  55         }
  56         else
  57         {
  58                 self.warpzone_fadestart = 0;
  59                 self.warpzone_fadeend = 0;
  60         }
  61
  62         // common stuff
  63         WarpZone_SetUp(self, self.enemy.oldorigin, self.enemy.avelocity, self.oldorigin, self.avelocity);
  64
  65         // link me
  66         //setmodel(self, self.model);
  67         setorigin(self, self.origin);
  68         setsize(self, self.mins, self.maxs);
  69
  70         // how to draw
  71         // engine currently wants this
  72         if(self.warpzone_fadestart)
  73                 self.predraw = WarpZone_Fade_PreDraw;
  74         else
  75                 self.drawmask = MASK_NORMAL;
  76 }
  77
  78 void WarpZone_Camera_Read(float isnew)
  79 {
  80         float f;
  81         ++warpzone_cameras_exist;
  82         self.classname = "func_warpzone_camera";
  83
  84         f = ReadByte();
  85         self.origin_x = ReadCoord();
  86         self.origin_y = ReadCoord();
  87         self.origin_z = ReadCoord();
  88         self.modelindex = ReadShort();
  89         self.mins_x = ReadCoord();
  90         self.mins_y = ReadCoord();
  91         self.mins_z = ReadCoord();
  92         self.maxs_x = ReadCoord();
  93         self.maxs_y = ReadCoord();
  94         self.maxs_z = ReadCoord();
  95         self.scale = ReadByte() / 16;
  96         self.oldorigin_x = ReadCoord();
  97         self.oldorigin_y = ReadCoord();
  98         self.oldorigin_z = ReadCoord();
  99         self.avelocity_x = ReadCoord();
 100         self.avelocity_y = ReadCoord();
 101         self.avelocity_z = ReadCoord();
 102
 103         if(f & 2)
 104         {
 105                 self.warpzone_fadestart = ReadShort();
 106                 self.warpzone_fadeend = max(self.warpzone_fadestart + 1, ReadShort());
 107         }
 108         else
 109         {
 110                 self.warpzone_fadestart = 0;
 111                 self.warpzone_fadeend = 0;
 112         }
 113
 114         // common stuff
 115         WarpZone_Camera_SetUp(self, self.oldorigin, self.avelocity);
 116
 117         // engine currently wants this
 118         self.drawmask = MASK_NORMAL;
 119
 120         // link me
 121         //setmodel(self, self.model);
 122         setorigin(self, self.origin);
 123         setsize(self, self.mins, self.maxs);
 124
 125         // how to draw
 126         // engine currently wants this
 127         if(self.warpzone_fadestart)
 128                 self.predraw = WarpZone_Fade_PreDraw;
 129         else
 130                 self.drawmask = MASK_NORMAL;
 131 }
 132
 133 float warpzone_fixingview;
 134 float warpzone_fixingview_drawexteriormodel;
 135 //float warpzone_fixingview_sidespeed;
 136 //float warpzone_fixingview_forwardspeed;
 137 void WarpZone_Inside()
 138 {
 139         if(warpzone_fixingview)
 140                 return;
 141         warpzone_fixingview = 1;
 142         warpzone_fixingview_drawexteriormodel = cvar("r_drawexteriormodel");
 143         //warpzone_fixingview_sidespeed = cvar("cl_sidespeed");
 144         //warpzone_fixingview_forwardspeed = cvar("cl_forwardspeed");
 145         cvar_set("r_drawexteriormodel", "0");
 146         //cvar_set("cl_sidespeed", ftos(warpzone_fixingview_sidespeed / 100)); // just keep a bit of it in case player gets stuck
 147         //cvar_set("cl_forwardspeed", ftos(warpzone_fixingview_forwardspeed / 100)); // just keep a bit of it in case player gets stuck
 148 }
 149
 150 void WarpZone_Outside()
 151 {
 152         if(!warpzone_fixingview)
 153                 return;
 154         warpzone_fixingview = 0;
 155         cvar_set("r_drawexteriormodel", ftos(warpzone_fixingview_drawexteriormodel));
 156         //cvar_set("cl_sidespeed", ftos(warpzone_fixingview_sidespeed));
 157         //cvar_set("cl_forwardspeed", ftos(warpzone_fixingview_forwardspeed));
 158 }
 159
 160 vector WarpZone_FixNearClip(vector o, vector c0, vector c1, vector c2, vector c3)
 161 {
 162         float nearclipdistance;
 163         vector mi, ma;
 164         entity e;
 165         float pd;
 166
 167         mi_x = min5(o_x, c0_x, c1_x, c2_x, c3_x);
 168         ma_x = max5(o_x, c0_x, c1_x, c2_x, c3_x);
 169         mi_y = min5(o_y, c0_y, c1_y, c2_y, c3_y);
 170         ma_y = max5(o_y, c0_y, c1_y, c2_y, c3_y);
 171         mi_z = min5(o_z, c0_z, c1_z, c2_z, c3_z);
 172         ma_z = max5(o_z, c0_z, c1_z, c2_z, c3_z);
 173
 174         e = WarpZone_Find(mi, ma);
 175         if(e)
 176         {
 177                 if(WarpZone_PlaneDist(e, o) < 0)
 178                         return '0 0 0';
 179                         // can't really be, though, but if it is, this is not my warpzone, but a random different one in the same mins/maxs
 180                 pd = min4(
 181                                 WarpZone_PlaneDist(e, c0),
 182                                 WarpZone_PlaneDist(e, c1),
 183                                 WarpZone_PlaneDist(e, c2),
 184                                 WarpZone_PlaneDist(e, c3)
 185                         );
 186                 if(pd < 0)
 187                         return e.warpzone_forward * -pd;
 188         }
 189
 190         return '0 0 0';
 191 }
 192
 193 float warpzone_saved;
 194 vector warpzone_saved_origin;
 195 vector warpzone_saved_angles;
 196 vector warpzone_saved_cl_viewangles;
 197 #ifndef KEEP_ROLL
 198 var float autocvar_cl_rollkillspeed = 10;
 199 #endif
 200 void WarpZone_FixView()
 201 {
 202         float pd, f;
 203         vector o;
 204         entity e;
 205         vector corner0, corner1, corner2, corner3, nearclip;
 206
 207         warpzone_saved = 0;
 208         warpzone_saved_origin = warpzone_fixview_origin;
 209         warpzone_saved_angles = warpzone_fixview_angles;
 210         warpzone_saved_cl_viewangles = warpzone_fixview_cl_viewangles;
 211
 212         nearclip = '0 0 1' * (cvar("r_nearclip") * 1.125);
 213         corner0 = cs_unproject('0 0 0' + nearclip);
 214         corner1 = cs_unproject('1 0 0' * cvar("vid_conwidth") + nearclip);
 215         corner2 = cs_unproject('0 1 0' * cvar("vid_conheight") + nearclip);
 216         corner3 = cs_unproject('1 0 0' * cvar("vid_conwidth") + '0 1 0' * cvar("vid_conheight") + nearclip);
 217
 218 #ifndef KEEP_ROLL
 219         if(warpzone_fixview_angles_z != 0 || warpzone_fixview_cl_viewangles_z != 0)
 220         {
 221                 if(autocvar_cl_rollkillspeed)
 222                         f = max(0, (1 - frametime * autocvar_cl_rollkillspeed));
 223                 else
 224                         f = 0;
 225                 warpzone_fixview_angles_z *= f;
 226                 warpzone_fixview_cl_viewangles_z *= f;
 227                 warpzone_saved_angles_z *= f; // PERMANENTLY apply that change!
 228                 warpzone_saved_cl_viewangles_z *= f; // PERMANENTLY apply that change!
 229                 warpzone_saved = 2;
 230                 R_SetView(VF_CL_VIEWANGLES_Z, warpzone_fixview_angles_z);
 231         }
 232 #endif
 233
 234         e = WarpZone_Find(warpzone_fixview_origin, warpzone_fixview_origin);
 235         if(e)
 236         {
 237                 warpzone_saved = 1;
 238                 warpzone_fixview_origin = WarpZone_TransformOrigin(e, warpzone_fixview_origin);
 239                 corner0 = WarpZone_TransformOrigin(e, corner0);
 240                 corner1 = WarpZone_TransformOrigin(e, corner1);
 241                 corner2 = WarpZone_TransformOrigin(e, corner2);
 242                 corner3 = WarpZone_TransformOrigin(e, corner3);
 243                 warpzone_fixview_angles = WarpZone_TransformVAngles(e, warpzone_fixview_angles);
 244                 warpzone_fixview_cl_viewangles = WarpZone_TransformVAngles(e, warpzone_fixview_cl_viewangles);
 245                 WarpZone_Inside();
 246         }
 247         else
 248                 WarpZone_Outside();
 249
 250         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 251         o = WarpZone_FixNearClip(warpzone_fixview_origin, corner0, corner1, corner2, corner3);
 252         if(o != '0 0 0')
 253         {
 254                 warpzone_saved = 1;
 255                 warpzone_fixview_origin += o;
 256         }
 257
 258         if(warpzone_saved == 1)
 259         {
 260                 R_SetView(VF_ORIGIN, warpzone_fixview_origin);
 261                 R_SetView(VF_ANGLES, warpzone_fixview_cl_viewangles);
 262         }
 263 }
 264 void WarpZone_UnFixView()
 265 {
 266         if(warpzone_saved)
 267         {
 268                 warpzone_fixview_origin = warpzone_saved_origin;
 269                 warpzone_fixview_angles = warpzone_saved_angles;
 270                 warpzone_fixview_cl_viewangles = warpzone_saved_cl_viewangles;
 271                 R_SetView(VF_ORIGIN, warpzone_fixview_origin);
 272                 R_SetView(VF_ANGLES, warpzone_fixview_angles);
 273                 R_SetView(VF_CL_VIEWANGLES, warpzone_fixview_cl_viewangles);
 274         }
 275 }
 276
 277 void WarpZone_Init()
 278 {
 279 }
 280
 281 void WarpZone_Shutdown()
 282 {
 283         WarpZone_Outside();
 284 }