X-Git-Url: https://de.git.xonotic.org/?a=blobdiff_plain;f=data%2Fqcsrc%2Fserver%2Ft_items.qc;h=5517fa30dfedb8fa859a0eeb6604ce187737384d;hb=d4e403726d135d607a78196ffcf3b57b7bacbbdd;hp=2ad8336226f2e9f8c01c1efa7cb470087605a8cd;hpb=07ac1ce35983a1781435294f9e6ffd298acbb2bb;p=voretournament%2Fvoretournament.git

diff --git a/data/qcsrc/server/t_items.qc b/data/qcsrc/server/t_items.qc
index 2ad83362..5517fa30 100644
--- a/data/qcsrc/server/t_items.qc
+++ b/data/qcsrc/server/t_items.qc
@@ -144,7 +144,6 @@ void Item_Respawn (void)
 		sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);	// play respawn sound
 	setorigin (self, self.origin);
 
-	//pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 	pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 }
 
@@ -220,6 +219,191 @@ void Item_ScheduleInitialRespawn(entity e)
 	Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 }
 
+.float inithealth, initdmg;
+.float item_digestion_step;
+void Item_Consumable_Think()
+{
+	if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)
+	{
+		self.predator.regurgitate_prepare = 0;
+		self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach
+		Item_Consumable_Remove(self, TRUE);
+		return;
+	}
+	if(self.predator.stat_eaten)
+	{
+		// prey can't hold consumable items
+		Item_Consumable_Remove(self, TRUE);
+		return;
+	}
+
+	self.scale = self.health / self.inithealth; // scale matches the item's digestion progress
+	self.dmg = self.initdmg * self.scale;
+	if(self.health <= 0)
+	{
+		// this item is done
+		Item_Consumable_Remove(self, FALSE);
+		return;
+	}
+
+	if(self.predator.digesting)
+	{
+		if(time > self.item_digestion_step)
+		{
+			// if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach
+			float damage, damage_offset;
+
+			damage_offset = 1;
+			if(cvar("g_balance_vore_digestion_distribute")) // apply distributed digestion damage
+				damage_offset /= (1 - (self.predator.stomach_load / self.predator.stomach_maxload) * bound(0, cvar("g_balance_vore_digestion_distribute"), 1));
+			damage = ceil(cvar("g_balance_vore_digestion_damage_item") / damage_offset);
+
+			self.health -= damage;
+			if(self.predator.health + damage <= self.max_health)
+				self.predator.health += damage;
+			else if(self.predator.health < self.max_health)
+				self.predator.health = self.max_health;
+			self.predator.pauserothealth_finished = max(self.predator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
+
+			self.item_digestion_step = time + vore_steptime;
+		}
+
+		if(stov(cvar_string("g_vore_regurgitatecolor_color_digest")))
+			self.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_digest"));
+	}
+
+	self.nextthink = time;
+}
+
+float Item_Consumable_Customizeentityforclient()
+{
+	if(cvar("g_vore_neighborprey_distance_item") && self.predator == other.predator && !(other.cvar_chase_active || other.classname == "observer"))
+	{
+		self.alpha = default_player_alpha; // allow seeing neighboring items
+		self.effects |= EF_NODEPTHTEST; // don't hide behind the stomach's own EF_NODEPTHTEST
+	}
+	else
+		self.alpha = -1; // hide item
+	return TRUE;
+}
+
+void Item_DroppedConsumable_Spawn(entity e);
+void Item_Consumable_Remove(entity e, float regurgitate)
+{
+	if(regurgitate)
+	{
+		// predator effects, some common to those in Vore_Regurgitate
+		PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);
+		setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating
+		pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);
+		e.predator.punchangle_x = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle_item");
+		e.predator.punchangle_y = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle_item");
+		e.predator.punchangle_z = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle_item");
+		e.predator.regurgitate_prepare = 0;
+		e.predator.action_delay = time + cvar("g_balance_vore_action_delay");
+
+		Item_DroppedConsumable_Spawn(e);
+	}
+
+	e.nextthink = 0;
+	remove(e);
+	e = world;
+}
+
+void Item_Consumable_Spawn(entity e, entity pl)
+{
+	entity item;
+	item = spawn();
+	item.owner = e;
+	item.classname = "consumable";
+	item.movetype = MOVETYPE_FOLLOW;
+	item.solid = SOLID_NOT;
+	setmodel(item, e.model);
+	item.health = e.health;
+	if(e.inithealth)
+	{
+		item.inithealth = e.inithealth;
+		item.initdmg = e.initdmg;
+	}
+	else
+	{
+		item.inithealth = e.health;
+		item.initdmg = e.dmg;
+	}
+	item.max_health = e.max_health;
+
+	item.predator = pl;
+	item.aiment = pl;
+	item.view_ofs_x = CONSUMABLE_VIEW_OFS_x + crandom() * cvar("g_vore_neighborprey_distance_item");
+	item.view_ofs_y = CONSUMABLE_VIEW_OFS_y + crandom() * cvar("g_vore_neighborprey_distance_item");
+	item.view_ofs_z = CONSUMABLE_VIEW_OFS_z + crandom() * cvar("g_vore_neighborprey_distance_item");
+	item.angles = randomvec() * 360;
+
+	item.customizeentityforclient = Item_Consumable_Customizeentityforclient;
+	item.think = Item_Consumable_Think;
+	item.nextthink = time;
+
+	if(stov(cvar_string("g_vore_regurgitatecolor_color_normal")))
+		item.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_normal"));
+
+	// predator effects, some common to those in Vore_Swallow
+	PlayerSound(pl, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);
+	setanim(pl, pl.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating
+	pl.punchangle_x = crandom() * cvar("g_balance_vore_swallow_predator_punchangle_item");
+	pl.punchangle_y = crandom() * cvar("g_balance_vore_swallow_predator_punchangle_item");
+	pl.punchangle_z = crandom() * cvar("g_balance_vore_swallow_predator_punchangle_item");
+	pl.regurgitate_prepare = 0;
+	pl.action_delay = time + cvar("g_balance_vore_action_delay");
+}
+
+void Item_DroppedConsumable_Touch()
+{
+	if(time < self.cnt)
+		return;
+
+	// give the consumable item to the player touching it
+	if not(other.stomach_load + self.dmg > other.stomach_maxload || other.stomach_load + self.initdmg > other.stomach_maxload)
+	if not(!cvar("g_balance_health_consumable_alwayspickup") && other.health >= self.max_health)
+	{
+		Item_Consumable_Spawn(self, other);
+		remove(self);
+		self = world;
+	}
+}
+
+void Item_DroppedConsumable_Spawn(entity e)
+{
+	entity item;
+	item = spawn();
+	item.owner = world;
+	item.classname = "droppedconsumable";
+	item.movetype = MOVETYPE_TOSS;
+	item.solid = SOLID_TRIGGER;
+	setmodel(item, e.model);
+	item.health = e.health;
+	item.inithealth = e.inithealth;
+	item.initdmg = e.initdmg;
+	item.max_health = e.max_health;
+	item.scale = e.scale;
+	item.colormod = e.colormod;
+
+	if(cvar("g_nodepthtestitems"))
+		item.effects |= EF_NODEPTHTEST;
+
+	float scalediff, sz;
+	sz = e.scale; // the line below does not work if I define this directly (fteqcc bug?)
+	scalediff = cvar("g_healthsize") ? sz / e.predator.scale : sz; // the tighter the gut, the greater the velocity
+
+	setorigin(item, e.predator.origin);
+	item.angles_y = e.predator.angles_y;
+	makevectors(e.predator.v_angle);
+	item.velocity = v_forward * cvar("g_balance_vore_regurgitate_force") * scalediff;
+	e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce") * scalediff;
+	item.touch = Item_DroppedConsumable_Touch;
+	item.cnt = time + 1; // 1 second delay
+	SUB_SetFade(item, time + 20, 1);
+}
+
 float Item_GiveTo(entity item, entity player)
 {
 	float _switchweapon;
@@ -302,11 +486,22 @@ float Item_GiveTo(entity item, entity player)
 		}
 
 		if (item.health)
-		if (player.health < item.max_health)
 		{
-			pickedup = TRUE;
-			player.health = min(player.health + item.health, item.max_health);
-			player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
+			if(item.dmg && cvar("g_vore")) // consumable item, only if the vore system is enabled
+			{
+				if(player.stomach_load + item.dmg <= player.stomach_maxload)
+				if not(!cvar("g_balance_health_consumable_alwayspickup") && player.health >= item.max_health)
+				{
+					pickedup = TRUE;
+					Item_Consumable_Spawn(self, player);
+				}
+			}
+			else if (player.health < item.max_health)
+			{
+				pickedup = TRUE;
+				player.health = min(player.health + item.health, item.max_health);
+				player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
+			}
 		}
 		if (item.armorvalue)
 		if (player.armorvalue < item.max_armorvalue)
@@ -868,6 +1063,7 @@ void spawnfunc_item_health_small (void) {
 		self.max_health = g_pickup_healthsmall_max;
 	if(!self.health)
 		self.health = g_pickup_healthsmall;
+	self.dmg = g_pickup_healthsmall_consumable;
 	StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
 }
 
@@ -876,6 +1072,7 @@ void spawnfunc_item_health_medium (void) {
 		self.max_health = g_pickup_healthmedium_max;
 	if(!self.health)
 		self.health = g_pickup_healthmedium;
+	self.dmg = g_pickup_healthmedium_consumable;
 	StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
 }
 
@@ -884,6 +1081,7 @@ void spawnfunc_item_health_large (void) {
 		self.max_health = g_pickup_healthlarge_max;
 	if(!self.health)
 		self.health = g_pickup_healthlarge;
+	self.dmg = g_pickup_healthlarge_consumable;
 	StartItem ("models/items/g_h50.md3", "misc/largehealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
 }
 
@@ -898,6 +1096,7 @@ void spawnfunc_item_health_mega (void) {
 		self.max_health = g_pickup_healthmega_max;
 	if(!self.health)
 		self.health = g_pickup_healthmega;
+	self.dmg = g_pickup_healthmega_consumable;
 	StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 }