70b61f4daa05f1ac546029c7b9c63b24832fffd1
[voretournament/voretournament.git] / data / qcsrc / client / View.qc
1 #define rkt_size 32\r
2 #define rld_size_x 256\r
3 #define rld_size_y 16\r
4 \r
5 entity porto;\r
6 float trace_networkentity;\r
7 float Q3SURFACEFLAG_SLICK = 2; // low friction surface\r
8 float DPCONTENTS_SOLID = 1; // blocks player movement\r
9 float DPCONTENTS_BODY = 32; // blocks player movement\r
10 float DPCONTENTS_CORPSE = 64; // blocks player movement\r
11 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement\r
12 void Porto_Draw()\r
13 {\r
14         vector dir;\r
15 \r
16         if(spectatee_status)\r
17                 return;\r
18         if(intermission == 1)\r
19                 return;\r
20         if(intermission == 2)\r
21                 return;\r
22         if (getstati(STAT_HEALTH) <= 0)\r
23                 return;\r
24 \r
25         dir = view_forward;\r
26 \r
27         if(angles_held_status)\r
28         {\r
29                 makevectors(angles_held);\r
30                 dir = v_forward;\r
31         }\r
32 }\r
33 \r
34 /**\r
35  * Checks whether the server initiated a map restart (stat_game_starttime changed)\r
36  *\r
37  * TODO: Use a better solution where a common shared entitiy is used that contains\r
38  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT\r
39  * and STAT_FRAGLIMIT to be auto-sent)\r
40  */\r
41 void CheckForGamestartChange() {\r
42         float startTime;\r
43         startTime = getstatf(STAT_GAMESTARTTIME);\r
44         if (previous_game_starttime != startTime) {\r
45                 if ((time + 5.0) < startTime) {\r
46                         //if connecting to server while restart was active don't always play prepareforbattle\r
47                         sound(self, CHAN_VOICE, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);\r
48                 }\r
49                 if (time < startTime) {\r
50                         restartAnnouncer = spawn();\r
51                         restartAnnouncer.think = restartAnnouncer_Think;\r
52                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime\r
53                 }\r
54         }\r
55         previous_game_starttime = startTime;\r
56 }\r
57 \r
58 void Porto_Init()\r
59 {\r
60         porto = spawn();\r
61         porto.classname = "porto";\r
62         porto.draw = Porto_Draw;\r
63         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;\r
64 }\r
65 \r
66 float drawtime;\r
67 float avgspeed;\r
68 vector GetCurrentFov(float fov)\r
69 {\r
70         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;\r
71 \r
72         zoomsensitivity = cvar("cl_zoomsensitivity");\r
73         zoomfactor = cvar("cl_zoomfactor");\r
74         if(zoomfactor < 1 || zoomfactor > 16)\r
75                 zoomfactor = 2.5;\r
76         zoomspeed = cvar("cl_zoomspeed");\r
77         if(zoomspeed >= 0)\r
78                 if(zoomspeed < 0.5 || zoomspeed > 16)\r
79                         zoomspeed = 3.5;\r
80 \r
81         zoomdir = button_zoom;\r
82         if(spectatee_status > 0 || isdemo())\r
83         {\r
84                 if(spectatorbutton_zoom)\r
85                         zoomdir = 0 + !zoomdir;\r
86                 // do not even THINK about removing this 0\r
87                 // _I_ know what I am doing\r
88                 // fteqcc does not\r
89         }\r
90 \r
91         if(zoomdir)\r
92                 zoomin_effect = 0;\r
93 \r
94         if(zoomin_effect || camera_active)\r
95         {\r
96                 current_viewzoom = min(1, current_viewzoom + drawframetime);\r
97         }\r
98         else\r
99         {\r
100                 if(zoomspeed < 0) // instant zoom\r
101                 {\r
102                         if(zoomdir)\r
103                                 current_viewzoom = 1 / zoomfactor;\r
104                         else\r
105                                 current_viewzoom = 1;\r
106                 }\r
107                 else\r
108                 {\r
109                         if(zoomdir)\r
110                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);\r
111                         else\r
112                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);\r
113                 }\r
114         }\r
115 \r
116         if(almost_equals(current_viewzoom, 1))\r
117                 current_zoomfraction = 0;\r
118         else if(almost_equals(current_viewzoom, 1/zoomfactor))\r
119                 current_zoomfraction = 1;\r
120         else\r
121                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);\r
122 \r
123         if(zoomsensitivity < 1)\r
124                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));\r
125         else\r
126                 setsensitivityscale(1);\r
127 \r
128         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);\r
129         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;\r
130         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);\r
131 \r
132         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging\r
133 \r
134         float frustumx, frustumy, fovx, fovy;\r
135         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;\r
136         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;\r
137         fovx = atan2(frustumx, 1) / M_PI * 360.0;\r
138         fovy = atan2(frustumy, 1) / M_PI * 360.0;\r
139 \r
140         return '1 0 0' * fovx + '0 1 0' * fovy;\r
141 }\r
142 \r
143 // this function must match W_SetupShot!\r
144 float zoomscript_caught;\r
145 \r
146 vector wcross_origin;\r
147 float wcross_scale_prev, wcross_alpha_prev;\r
148 vector wcross_color_prev;\r
149 float wcross_scale_goal_prev, wcross_alpha_goal_prev;\r
150 vector wcross_color_goal_prev;\r
151 float wcross_changedonetime;\r
152 \r
153 string wcross_name_goal_prev, wcross_name_goal_prev_prev;\r
154 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;\r
155 float wcross_name_changestarttime, wcross_name_changedonetime;\r
156 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;\r
157 entity trueaim;\r
158 entity trueaim_rifle;\r
159 \r
160 #define SHOTTYPE_HITTEAM 1\r
161 #define SHOTTYPE_HITOBSTRUCTION 2\r
162 #define SHOTTYPE_HITWORLD 3\r
163 #define SHOTTYPE_HITENEMY 4\r
164 \r
165 void TrueAim_Init()\r
166 {\r
167         trueaim = spawn();\r
168         trueaim.classname = "trueaim";\r
169         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;\r
170         trueaim_rifle = spawn();\r
171         trueaim_rifle.classname = "trueaim_rifle";\r
172         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;\r
173 }\r
174 \r
175 float EnemyHitCheck()\r
176 {\r
177         float t;\r
178         wcross_origin = project_3d_to_2d(trace_endpos);\r
179         wcross_origin_z = 0;\r
180         if(trace_networkentity < 1)\r
181                 return SHOTTYPE_HITWORLD;\r
182         if(trace_networkentity > maxclients)\r
183                 return SHOTTYPE_HITWORLD;\r
184         t = GetPlayerColor(trace_networkentity - 1);\r
185         if(teamplay)\r
186                 if(t == myteam)\r
187                         return SHOTTYPE_HITTEAM;\r
188         if(t == COLOR_SPECTATOR)\r
189                 return SHOTTYPE_HITWORLD;\r
190         return SHOTTYPE_HITENEMY;\r
191 }\r
192 \r
193 float TrueAimCheck()\r
194 {\r
195         float nudge = 1; // added to traceline target and subtracted from result\r
196         vector vecs, trueaimpoint, w_shotorg;\r
197         vector mi, ma, dv;\r
198         float shottype;\r
199         entity ta;\r
200         float mv;\r
201 \r
202         mi = ma = '0 0 0';\r
203         ta = trueaim;\r
204         mv = MOVE_NOMONSTERS;\r
205 \r
206         switch(activeweapon)\r
207         {\r
208                 case WEP_GRABBER: // no trueaim\r
209         }\r
210 \r
211         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));\r
212 \r
213         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);\r
214         trueaimpoint = trace_endpos;\r
215 \r
216         if(vecs_x > 0)\r
217                 vecs_y = -vecs_y;\r
218         else\r
219                 vecs = '0 0 0';\r
220 \r
221         dv = view_right * vecs_y + view_up * vecs_z;\r
222         w_shotorg = view_origin + dv;\r
223 \r
224         // now move the vecs forward as much as requested if possible\r
225         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc\r
226         w_shotorg = trace_endpos - view_forward * nudge;\r
227 \r
228         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);\r
229         shottype = EnemyHitCheck();\r
230         if(shottype != SHOTTYPE_HITWORLD)\r
231                 return shottype;\r
232 \r
233 #if 0\r
234         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?\r
235         // or rather, I know why, but see no fix\r
236         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)\r
237                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace\r
238                 return SHOTTYPE_HITOBSTRUCTION;\r
239 #endif\r
240 \r
241         return SHOTTYPE_HITWORLD;\r
242 }\r
243 \r
244 void CSQC_common_hud(void);\r
245 \r
246 void CSQC_kh_hud(void);\r
247 void CSQC_ctf_hud(void);\r
248 void PostInit(void);\r
249 void CSQC_Demo_Camera();\r
250 float Sbar_WouldDrawScoreboard ();\r
251 float view_set;\r
252 float camera_mode;\r
253 float chase_active_old;\r
254 float artwork_fade;\r
255 string artwork_image;\r
256 string NextFrameCommand;\r
257 void CSQC_UpdateView(float w, float h)\r
258 {\r
259         entity e;\r
260         float fov;\r
261         float f, i, j;\r
262         vector v, vo;\r
263 \r
264         vector artwork_pos, artwork_size;\r
265 \r
266         WaypointSprite_Load();\r
267 \r
268         if(spectatee_status)\r
269                 myteam = GetPlayerColor(spectatee_status - 1);\r
270         else\r
271                 myteam = GetPlayerColor(player_localentnum - 1);\r
272 \r
273         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);\r
274         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);\r
275 \r
276         warpzone_fixview_origin = pmove_org + vo;\r
277         warpzone_fixview_angles = input_angles;\r
278         WarpZone_FixView();\r
279         pmove_org = warpzone_fixview_origin - vo;\r
280         input_angles = warpzone_fixview_angles;\r
281 \r
282         // Render the Scene\r
283         if(!intermission || !view_set)\r
284         {\r
285                 view_origin = pmove_org + vo;\r
286                 view_angles = input_angles;\r
287                 makevectors(view_angles);\r
288                 view_forward = v_forward;\r
289                 view_right = v_right;\r
290                 view_up = v_up;\r
291                 view_set = 1;\r
292         }\r
293 \r
294         vid_width = w;\r
295         vid_height = h;\r
296 \r
297 #ifdef BLURTEST\r
298         if(time > blurtest_time0 && time < blurtest_time1)\r
299         {\r
300                 float r, t;\r
301 \r
302                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);\r
303                 r = t * blurtest_radius;\r
304                 f = 1 / pow(t, blurtest_power) - 1;\r
305 \r
306                 cvar_set("r_glsl_postprocess", "1");\r
307                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));\r
308         }\r
309         else\r
310         {\r
311                 cvar_set("r_glsl_postprocess", "0");\r
312                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");\r
313         }\r
314 #endif\r
315 \r
316         TargetMusic_Advance();\r
317         Fog_Force();\r
318 \r
319         drawframetime = max(0.000001, time - drawtime);\r
320         drawtime = time;\r
321 \r
322         // watch for gametype changes here...\r
323         // in ParseStuffCMD the cmd isn't executed yet :/\r
324         // might even be better to add the gametype to TE_CSQC_INIT...?\r
325         if(!postinit)\r
326                 PostInit();\r
327 \r
328         if(intermission && !isdemo() && !(calledhooks & HOOK_END))\r
329                 if(calledhooks & HOOK_START)\r
330                 {\r
331                         localcmd("\ncl_hook_gameend;");\r
332                         if(g_campaign)\r
333                                 localcmd("\ncl_hook_campaign_gameend;");\r
334                         calledhooks |= HOOK_END;\r
335                 }\r
336 \r
337         CheckForGamestartChange();\r
338         serverAnnouncer();\r
339         maptimeAnnouncer();\r
340         carrierAnnouncer();\r
341 \r
342         fov = cvar("fov");\r
343         if(button_zoom || fov <= 59.5)\r
344         {\r
345                 if(!zoomscript_caught)\r
346                 {\r
347                         localcmd("+button4\n");\r
348                         zoomscript_caught = 1;\r
349                         ignore_plus_zoom += 1;\r
350                 }\r
351         }\r
352         else\r
353         {\r
354                 if(zoomscript_caught)\r
355                 {\r
356                         localcmd("-button4\n");\r
357                         zoomscript_caught = 0;\r
358                         ignore_minus_zoom += 1;\r
359                 }\r
360         }\r
361 \r
362         sbar_alpha_fg = cvar("sbar_alpha_fg" ) * (1 - cvar("_menu_alpha"));\r
363         sbar_hudselector = cvar("sbar_hudselector");\r
364         sbar_accuracy_hud = cvar_or("sbar_accuracy_hud", 1);\r
365         ColorTranslateMode = cvar("cl_stripcolorcodes");\r
366         activeweapon = getstati(STAT_SWITCHWEAPON);\r
367         f = cvar("teamplay");\r
368         if(f != teamplay)\r
369         {\r
370                 teamplay = f;\r
371                 Sbar_InitScores();\r
372         }\r
373 \r
374         if(last_weapon != activeweapon) {\r
375                 weapontime = time;\r
376                 last_weapon = activeweapon;\r
377         }\r
378 \r
379         // ALWAYS Clear Current Scene First\r
380         R_ClearScene();\r
381 \r
382         // Assign Standard Viewflags\r
383         // Draw the World (and sky)\r
384         R_SetView(VF_DRAWWORLD, 1);\r
385 \r
386         // Set the console size vars\r
387         vid_conwidth = cvar("vid_conwidth");\r
388         vid_conheight = cvar("vid_conheight");\r
389         vid_pixelheight = cvar("vid_pixelheight");\r
390 \r
391         R_SetView(VF_FOV, GetCurrentFov(fov));\r
392 \r
393         // Camera for demo playback\r
394         if(camera_active)\r
395         {\r
396                 if(cvar("camera_enable"))\r
397                         CSQC_Demo_Camera();\r
398                 else\r
399                 {\r
400                         cvar_set("chase_active", ftos(chase_active_backup));\r
401                         cvar_set("cl_demo_mousegrab", "0");\r
402                         camera_active = FALSE;\r
403                 }\r
404         }\r
405 #ifdef CAMERATEST\r
406         else if(cvar("camera_enable"))\r
407 #else\r
408         else if(cvar("camera_enable") && isdemo())\r
409 #endif\r
410         {\r
411                 // Enable required Darkplaces cvars\r
412                 chase_active_backup = cvar("chase_active");\r
413                 cvar_set("chase_active", "2");\r
414                 cvar_set("cl_demo_mousegrab", "1");\r
415                 camera_active = TRUE;\r
416                 camera_mode = FALSE;\r
417         }\r
418 \r
419         // Draw the Crosshair\r
420         float scoreboard_active;\r
421         scoreboard_active = Sbar_WouldDrawScoreboard();\r
422         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden\r
423 \r
424         // Draw the Engine Status Bar (the default Quake HUD)\r
425         R_SetView(VF_DRAWENGINESBAR, 0);\r
426 \r
427         // fetch this one only once per frame\r
428         sbar_showbinds = cvar("sbar_showbinds");\r
429         sbar_showbinds_limit = cvar("sbar_showbinds_limit");\r
430 \r
431         // Update the mouse position\r
432         /*\r
433            mousepos_x = vid_conwidth;\r
434            mousepos_y = vid_conheight;\r
435            mousepos = mousepos*0.5 + getmousepos();\r
436          */\r
437 \r
438         e = self;\r
439         for(self = world; (self = nextent(self)); )\r
440                 if(self.draw)\r
441                         self.draw();\r
442         self = e;\r
443 \r
444         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);\r
445         R_RenderScene();\r
446 \r
447         // now switch to 2D drawing mode by calling a 2D drawing function\r
448         // then polygon drawing will draw as 2D stuff, and NOT get queued until the\r
449         // next R_RenderScene call\r
450         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);\r
451 \r
452         // Draw the mouse cursor\r
453         // NOTE: drawpic must happen after R_RenderScene for some reason\r
454         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);\r
455         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);\r
456         //self = edict_num(player_localnum);\r
457         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);\r
458         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);\r
459         // as long as the ctf part isn't in, this is useless\r
460         if(menu_visible)\r
461                 menu_show();\r
462 \r
463         /*if(gametype == GAME_CTF)\r
464           {\r
465           ctf_view();\r
466           } else */\r
467 \r
468         // draw 2D entities\r
469         e = self;\r
470         for(self = world; (self = nextent(self)); )\r
471                 if(self.draw2d)\r
472                         self.draw2d();\r
473         self = e;\r
474 \r
475         // draw radar\r
476         if(\r
477                         ons_showmap\r
478                         ||\r
479                         (\r
480                          !scoreboard_active\r
481                          &&\r
482                          cvar_string("cl_teamradar") != "0"\r
483                          &&\r
484                          (\r
485                           cvar("cl_teamradar") == 2\r
486                           ||\r
487                           teamplay\r
488                          )\r
489                         )\r
490           )\r
491                 teamradar_view();\r
492 \r
493         // Draw Artwork\r
494         if(intermission && !isdemo()) // match has ended\r
495         {\r
496                 if(artwork_image == "")\r
497                 {\r
498                         if(getstati(STAT_WINNING))\r
499                         {\r
500                                 if(!cvar("cl_artwork_won"))\r
501                                         return;\r
502                                 artwork_image = strcat("gfx/artwork_won_", ftos(floor(1 + (random() * cvar("cl_artwork_won")))));\r
503                         }\r
504                         else\r
505                         {\r
506                                 if(!cvar("cl_artwork_lost"))\r
507                                         return;\r
508                                 artwork_image = strcat("gfx/artwork_lost_", ftos(floor(1 + (random() * cvar("cl_artwork_lost")))));\r
509                         }\r
510                         artwork_image = strzone(artwork_image);\r
511                 }\r
512 \r
513                 if(cvar("cl_artwork_stretch"))\r
514                 {\r
515                         artwork_size_x = vid_conwidth;\r
516                         artwork_size_y = vid_conheight;\r
517                         artwork_pos_x = 0;\r
518                         artwork_pos_y = 0;\r
519                 }\r
520                 else\r
521                 {\r
522                         artwork_size_x = max(vid_conwidth, vid_conheight);\r
523                         artwork_size_y = max(vid_conwidth, vid_conheight);\r
524                         artwork_pos_x = (vid_conwidth - artwork_size_x) / 2;\r
525                         artwork_pos_y = (vid_conheight - artwork_size_y) / 2;\r
526                 }\r
527 \r
528                 if(artwork_fade < 1)\r
529                         artwork_fade += frametime * cvar("cl_artwork_fadespeed");\r
530                 else\r
531                         artwork_fade = 1;\r
532 \r
533                 drawpic(artwork_pos, artwork_image, artwork_size, '1 1 1', artwork_fade, DRAWFLAG_NORMAL);\r
534         }\r
535         else\r
536         {\r
537                 if(artwork_image != "")\r
538                 {\r
539                         strunzone(artwork_image);\r
540                         artwork_image = "";\r
541                 }\r
542                 artwork_fade = 0;\r
543         }\r
544 \r
545         // draw sbar\r
546         if(cvar("r_letterbox") == 0) {\r
547                 if (cvar("cl_showpressedkeys")) { // draw pressed keys when spectating and playing\r
548                         if(spectatee_status > 0 || cvar("cl_showpressedkeys") >= 2)\r
549                                 Sbar_DrawPressedKeys();\r
550                 }\r
551 \r
552                 if (cvar("cl_showspeed"))\r
553                         Sbar_ShowSpeed();\r
554                 if (cvar("cl_showacceleration"))\r
555                         Sbar_ShowAcceleration();\r
556 \r
557                 Sbar_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120\r
558         }\r
559 \r
560         float hud;\r
561         hud = getstati(STAT_HUD);\r
562 \r
563         if(cvar("r_letterbox") == 0)\r
564                 if(cvar("viewsize") < 120)\r
565                         CSQC_common_hud();\r
566 \r
567         if not(getstati(STAT_VORE_EATEN)) // crosshair is useless if we're in the stomach\r
568         {\r
569                 // crosshair goes VERY LAST\r
570                 if(!scoreboard_active && !ons_showmap && !camera_active) {\r
571                         // TrueAim check\r
572                         float shottype;\r
573                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;\r
574                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);\r
575                         wcross_origin_z = 0;\r
576                         if(cvar("crosshair_hittest"))\r
577                         {\r
578                                 vector wcross_oldorigin;\r
579                                 wcross_oldorigin = wcross_origin;\r
580                                 shottype = TrueAimCheck();\r
581                                 if(shottype == SHOTTYPE_HITWORLD)\r
582                                 {\r
583                                         v = wcross_origin - wcross_oldorigin;\r
584                                         v_x /= vid_conwidth;\r
585                                         v_y /= vid_conheight;\r
586                                         if(vlen(v) > 0.01)\r
587                                                 shottype = SHOTTYPE_HITOBSTRUCTION;\r
588                                 }\r
589                                 if(!cvar("crosshair_hittest_showimpact"))\r
590                                         wcross_origin = wcross_oldorigin;\r
591                         }\r
592                         else\r
593                                 shottype = SHOTTYPE_HITWORLD;\r
594 \r
595                         string wcross_style;\r
596                         wcross_style = cvar_string("crosshair");\r
597 \r
598                         if (wcross_style != "0") {\r
599                                 vector wcross_color, wcross_size;\r
600                                 string wcross_name;\r
601                                 float wcross_alpha, wcross_scale, wcross_blur, wcross_resolution;\r
602 \r
603                                 wcross_color_x = cvar("crosshair_color_red");\r
604                                 wcross_color_y = cvar("crosshair_color_green");\r
605                                 wcross_color_z = cvar("crosshair_color_blue");\r
606                                 wcross_alpha = cvar("crosshair_color_alpha");\r
607                                 wcross_resolution = cvar("crosshair_size");\r
608 \r
609                                 wcross_name = strcat("gfx/crosshair", wcross_style);\r
610 \r
611                                 if(cvar("crosshair_effect_scalefade"))\r
612                                 {\r
613                                         wcross_scale = wcross_resolution;\r
614                                         wcross_resolution = 1;\r
615                                 }\r
616                                 else\r
617                                 {\r
618                                         wcross_scale = 1;\r
619                                 }\r
620 \r
621                                 if(shottype == SHOTTYPE_HITENEMY)\r
622                                         wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0\r
623                                 if(shottype == SHOTTYPE_HITTEAM)\r
624                                         wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0\r
625 \r
626                                 f = cvar("crosshair_effect_speed");\r
627                                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)\r
628                                 {\r
629                                         wcross_changedonetime = time + f;\r
630                                 }\r
631                                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)\r
632                                 {\r
633                                         wcross_name_changestarttime = time;\r
634                                         wcross_name_changedonetime = time + f;\r
635                                         if(wcross_name_goal_prev_prev)\r
636                                                 strunzone(wcross_name_goal_prev_prev);\r
637                                         wcross_name_goal_prev_prev = wcross_name_goal_prev;\r
638                                         wcross_name_goal_prev = strzone(wcross_name);\r
639                                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;\r
640                                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;\r
641                                         wcross_resolution_goal_prev = wcross_resolution;\r
642                                 }\r
643 \r
644                                 wcross_scale_goal_prev = wcross_scale;\r
645                                 wcross_alpha_goal_prev = wcross_alpha;\r
646                                 wcross_color_goal_prev = wcross_color;\r
647 \r
648                                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))\r
649                                 {\r
650                                         wcross_blur = 1;\r
651                                         wcross_alpha *= 0.75;\r
652                                 }\r
653                                 else\r
654                                         wcross_blur = 0;\r
655                                 // *_prev is at time-frametime\r
656                                 // * is at wcross_changedonetime+f\r
657                                 // what do we have at time?\r
658                                 if(time < wcross_changedonetime)\r
659                                 {\r
660                                         f = frametime / (wcross_changedonetime - time + frametime);\r
661                                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;\r
662                                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;\r
663                                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;\r
664                                 }\r
665 \r
666                                 wcross_scale_prev = wcross_scale;\r
667                                 wcross_alpha_prev = wcross_alpha;\r
668                                 wcross_color_prev = wcross_color;\r
669 \r
670                                 wcross_scale *= 1 - cvar("_menu_alpha");\r
671                                 wcross_alpha *= 1 - cvar("_menu_alpha");\r
672 \r
673 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \\r
674                                 do \\r
675                                 { \\r
676                                         if(wcross_blur > 0) \\r
677                                         { \\r
678                                                 for(i = -2; i <= 2; ++i) \\r
679                                                         for(j = -2; j <= 2; ++j) \\r
680                                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \\r
681                                         } \\r
682                                         else \\r
683                                         { \\r
684                                                 M(0,0,sz,wcross_name,wcross_alpha); \\r
685                                         } \\r
686                                 } \\r
687                                 while(0)\r
688 \r
689 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \\r
690                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)\r
691 \r
692 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \\r
693                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)\r
694 \r
695                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)\r
696                                 {\r
697                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);\r
698                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;\r
699                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);\r
700                                         f = 1 - f;\r
701                                 }\r
702                                 else\r
703                                 {\r
704                                         f = 1;\r
705                                 }\r
706 \r
707                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;\r
708                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);\r
709                                 wcross_name_alpha_goal_prev = f;\r
710                         }\r
711                 }\r
712                 else\r
713                 {\r
714                         wcross_scale_prev = 0;\r
715                         wcross_alpha_prev = 0;\r
716                         wcross_scale_goal_prev = 0;\r
717                         wcross_alpha_goal_prev = 0;\r
718                         wcross_changedonetime = 0;\r
719                         if(wcross_name_goal_prev)\r
720                                 strunzone(wcross_name_goal_prev);\r
721                         wcross_name_goal_prev = string_null;\r
722                         if(wcross_name_goal_prev_prev)\r
723                                 strunzone(wcross_name_goal_prev_prev);\r
724                         wcross_name_goal_prev_prev = string_null;\r
725                         wcross_name_changestarttime = 0;\r
726                         wcross_name_changedonetime = 0;\r
727                         wcross_name_alpha_goal_prev = 0;\r
728                         wcross_name_alpha_goal_prev_prev = 0;\r
729                         wcross_resolution_goal_prev = 0;\r
730                         wcross_resolution_goal_prev_prev = 0;\r
731                 }\r
732         }\r
733 \r
734         if(NextFrameCommand)\r
735         {\r
736                 localcmd("\n", NextFrameCommand, "\n");\r
737                 NextFrameCommand = string_null;\r
738         }\r
739 \r
740         // we must do this check AFTER a frame was rendered, or it won't work\r
741         if(cs_project_is_b0rked == 0)\r
742         {\r
743                 string w0, h0;\r
744                 w0 = cvar_string("vid_conwidth");\r
745                 h0 = cvar_string("vid_conheight");\r
746                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');\r
747                 //R_SetView(VF_FOV, '90 90 0');\r
748                 R_SetView(VF_ORIGIN, '0 0 0');\r
749                 R_SetView(VF_ANGLES, '0 0 0');\r
750                 R_SetView(VF_PERSPECTIVE, 1);\r
751                 makevectors('0 0 0');\r
752                 vector v1, v2;\r
753                 cvar_set("vid_conwidth", "800");\r
754                 cvar_set("vid_conheight", "600");\r
755                 v1 = cs_project(v_forward);\r
756                 cvar_set("vid_conwidth", "640");\r
757                 cvar_set("vid_conheight", "480");\r
758                 v2 = cs_project(v_forward);\r
759                 if(v1 == v2)\r
760                         cs_project_is_b0rked = 1;\r
761                 else\r
762                         cs_project_is_b0rked = -1;\r
763                 cvar_set("vid_conwidth", w0);\r
764                 cvar_set("vid_conheight", h0);\r
765         }\r
766 \r
767         // be safe against triggerbots until everyone has the fixed engine\r
768         // this call is meant to overwrite the trace globals by something\r
769         // unsuspicious\r
770         traceline('0 0 0', '0 0 0', MOVE_WORLDONLY, world);\r
771 \r
772         // this cvar must be constantly updated on the server\r
773         if(chase_active_old != cvar("chase_active"))\r
774         {\r
775                 localcmd("sendcvar chase_active\n");\r
776                 chase_active_old = cvar("chase_active");\r
777         }\r
778 }\r
779 \r
780 void Sbar_Draw();\r
781 \r
782 void CSQC_common_hud(void)\r
783 {\r
784         // Sbar_SortFrags(); done in Sbar_Draw\r
785         float hud;\r
786         hud = getstati(STAT_HUD);\r
787 \r
788         //hud = 10;\r
789         switch(hud)\r
790         {\r
791                 case HUD_NORMAL:\r
792                         Sbar_Draw();\r
793                         break;\r
794         }\r
795 }\r
796 \r
797 \r
798 // following vectors must be global to allow seamless switching between camera modes\r
799 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;\r
800 void CSQC_Demo_Camera()\r
801 {\r
802         float speed, attenuation, dimensions;\r
803         vector tmp, delta;\r
804 \r
805         if( cvar("camera_reset") || !camera_mode )\r
806         {\r
807                 camera_offset = '0 0 0';\r
808                 current_angles = '0 0 0';\r
809                 camera_direction = '0 0 0';\r
810                 camera_offset_z += 30;\r
811                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);\r
812                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);\r
813                 current_origin = view_origin;\r
814                 current_camera_offset  = camera_offset;\r
815                 cvar_set("camera_reset", "0");\r
816                 camera_mode = CAMERA_CHASE;\r
817         }\r
818 \r
819         // Camera angles\r
820         if( camera_roll )\r
821                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");\r
822 \r
823         if(cvar("camera_look_player"))\r
824         {\r
825                 local vector dir;\r
826                 local float n;\r
827 \r
828                 dir = normalize(view_origin - current_position);\r
829                 n = mouse_angles_z;\r
830                 mouse_angles = vectoangles(dir);\r
831                 mouse_angles_x = mouse_angles_x * -1;\r
832                 mouse_angles_z = n;\r
833         }\r
834         else\r
835         {\r
836                 tmp = getmousepos() * 0.1;\r
837                 if(vlen(tmp)>cvar("camera_mouse_treshold"))\r
838                 {\r
839                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));\r
840                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));\r
841                 }\r
842         }\r
843 \r
844         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;\r
845         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;\r
846         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;\r
847         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;\r
848 \r
849         // Fix difference when angles don't have the same sign\r
850         delta = '0 0 0';\r
851         if(mouse_angles_y < -60 && current_angles_y > 60)\r
852                 delta = '0 360 0';\r
853         if(mouse_angles_y > 60 && current_angles_y < -60)\r
854                 delta = '0 -360 0';\r
855 \r
856         if(cvar("camera_look_player"))\r
857                 attenuation = cvar("camera_look_attenuation");\r
858         else\r
859                 attenuation = cvar("camera_speed_attenuation");\r
860 \r
861         attenuation = 1 / max(1, attenuation);\r
862         current_angles += (mouse_angles - current_angles + delta) * attenuation;\r
863 \r
864         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;\r
865         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;\r
866         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;\r
867         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;\r
868 \r
869         // Camera position\r
870         tmp = '0 0 0';\r
871         dimensions = 0;\r
872 \r
873         if( camera_direction_x )\r
874         {\r
875                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);\r
876                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);\r
877                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )\r
878                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);\r
879                 ++dimensions;\r
880         }\r
881 \r
882         if( camera_direction_y )\r
883         {\r
884                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);\r
885                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);\r
886                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);\r
887                 ++dimensions;\r
888         }\r
889 \r
890         if( camera_direction_z )\r
891         {\r
892                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);\r
893                 ++dimensions;\r
894         }\r
895 \r
896         if(cvar("camera_free"))\r
897                 speed = cvar("camera_speed_free");\r
898         else\r
899                 speed = cvar("camera_speed_chase");\r
900 \r
901         if(dimensions)\r
902         {\r
903                 speed = speed * sqrt(1 / dimensions);\r
904                 camera_offset += tmp * speed;\r
905         }\r
906 \r
907         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;\r
908 \r
909         // Camera modes\r
910         if( cvar("camera_free") )\r
911         {\r
912                 if ( camera_mode == CAMERA_CHASE )\r
913                 {\r
914                         current_camera_offset = current_origin + current_camera_offset;\r
915                         camera_offset = current_origin + camera_offset;\r
916                 }\r
917 \r
918                 camera_mode = CAMERA_FREE;\r
919                 current_position = current_camera_offset;\r
920         }\r
921         else\r
922         {\r
923                 if ( camera_mode == CAMERA_FREE )\r
924                 {\r
925                         current_origin = view_origin;\r
926                         camera_offset = camera_offset - current_origin;\r
927                         current_camera_offset = current_camera_offset - current_origin;\r
928                 }\r
929 \r
930                 camera_mode = CAMERA_CHASE;\r
931 \r
932                 if(cvar("camera_chase_smoothly"))\r
933                         current_origin += (view_origin - current_origin) * attenuation;\r
934                 else\r
935                         current_origin = view_origin;\r
936 \r
937                 current_position = current_origin + current_camera_offset;\r
938         }\r
939 \r
940         R_SetView(VF_ANGLES, current_angles);\r
941         R_SetView(VF_ORIGIN, current_position);\r
942 }\r