data/qcsrc/server/bot/aim.qc

   1
   2 // traces multiple trajectories to find one that will impact the target
   3 // 'end' vector is the place it aims for,
   4 // returns TRUE only if it hit targ (don't target non-solid entities)
   5
   6 float findtrajectorywithleading(vector org, vector m1, vector m2, entity targ, float shotspeed, float shotspeedupward, float maxtime, float shotdelay, entity ignore)
   7 {
   8         local float c, savesolid, shottime;
   9         local vector dir, end, v;
  10         if (shotspeed < 1)
  11                 return FALSE; // could cause division by zero if calculated
  12         if (targ.solid < SOLID_BBOX) // SOLID_NOT and SOLID_TRIGGER
  13                 return FALSE; // could never hit it
  14         if (!tracetossent)
  15                 tracetossent = spawn();
  16         tracetossent.owner = ignore;
  17         setsize(tracetossent, m1, m2);
  18         savesolid = targ.solid;
  19         targ.solid = SOLID_NOT;
  20         shottime = ((vlen(targ.origin - org) / shotspeed) + shotdelay);
  21         v = targ.velocity * shottime + targ.origin;
  22         tracebox(targ.origin, targ.mins, targ.maxs, v, FALSE, targ);
  23         v = trace_endpos;
  24         end = v + (targ.mins + targ.maxs) * 0.5;
  25         if ((vlen(end - org) / shotspeed + 0.2) > maxtime)
  26         {
  27                 // out of range
  28                 targ.solid = savesolid;
  29                 return FALSE;
  30         }
  31
  32         if (!tracetossfaketarget)
  33                 tracetossfaketarget = spawn();
  34         tracetossfaketarget.solid = savesolid;
  35         tracetossfaketarget.movetype = targ.movetype;
  36         setmodel(tracetossfaketarget, targ.model); // no low precision
  37         tracetossfaketarget.model = targ.model;
  38         tracetossfaketarget.modelindex = targ.modelindex;
  39         setsize(tracetossfaketarget, targ.mins, targ.maxs);
  40         setorigin(tracetossfaketarget, v);
  41
  42         c = 0;
  43         dir = normalize(end - org);
  44         while (c < 10) // 10 traces
  45         {
  46                 setorigin(tracetossent, org); // reset
  47                 tracetossent.velocity = findtrajectory_velocity = normalize(dir) * shotspeed + shotspeedupward * '0 0 1';
  48                 tracetoss(tracetossent, ignore); // love builtin functions...
  49                 if (trace_ent == tracetossfaketarget) // done
  50                 {
  51                         targ.solid = savesolid;
  52
  53                         // make it disappear
  54                         tracetossfaketarget.solid = SOLID_NOT;
  55                         tracetossfaketarget.movetype = MOVETYPE_NONE;
  56                         tracetossfaketarget.model = "";
  57                         tracetossfaketarget.modelindex = 0;
  58                         // relink to remove it from physics considerations
  59                         setorigin(tracetossfaketarget, v);
  60
  61                         return TRUE;
  62                 }
  63                 dir_z = dir_z + 0.1; // aim up a little more
  64                 c = c + 1;
  65         }
  66         targ.solid = savesolid;
  67
  68         // make it disappear
  69         tracetossfaketarget.solid = SOLID_NOT;
  70         tracetossfaketarget.movetype = MOVETYPE_NONE;
  71         tracetossfaketarget.model = "";
  72         tracetossfaketarget.modelindex = 0;
  73         // relink to remove it from physics considerations
  74         setorigin(tracetossfaketarget, v);
  75
  76         // leave a valid one even if it won't reach
  77         findtrajectory_velocity = normalize(end - org) * shotspeed + shotspeedupward * '0 0 1';
  78         return FALSE;
  79 };
  80
  81 void lag_update()
  82 {
  83         if (self.lag1_time) if (time > self.lag1_time) {self.lag_func(self.lag1_time, self.lag1_float1, self.lag1_float2, self.lag1_entity1, self.lag1_vec1, self.lag1_vec2, self.lag1_vec3, self.lag1_vec4);self.lag1_time = 0;}
  84         if (self.lag2_time) if (time > self.lag2_time) {self.lag_func(self.lag2_time, self.lag2_float1, self.lag2_float2, self.lag2_entity1, self.lag2_vec1, self.lag2_vec2, self.lag2_vec3, self.lag2_vec4);self.lag2_time = 0;}
  85         if (self.lag3_time) if (time > self.lag3_time) {self.lag_func(self.lag3_time, self.lag3_float1, self.lag3_float2, self.lag3_entity1, self.lag3_vec1, self.lag3_vec2, self.lag3_vec3, self.lag3_vec4);self.lag3_time = 0;}
  86         if (self.lag4_time) if (time > self.lag4_time) {self.lag_func(self.lag4_time, self.lag4_float1, self.lag4_float2, self.lag4_entity1, self.lag4_vec1, self.lag4_vec2, self.lag4_vec3, self.lag4_vec4);self.lag4_time = 0;}
  87         if (self.lag5_time) if (time > self.lag5_time) {self.lag_func(self.lag5_time, self.lag5_float1, self.lag5_float2, self.lag5_entity1, self.lag5_vec1, self.lag5_vec2, self.lag5_vec3, self.lag5_vec4);self.lag5_time = 0;}
  88 };
  89
  90 float lag_additem(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
  91 {
  92         if (self.lag1_time == 0) {self.lag1_time = t;self.lag1_float1 = f1;self.lag1_float2 = f2;self.lag1_entity1 = e1;self.lag1_vec1 = v1;self.lag1_vec2 = v2;self.lag1_vec3 = v3;self.lag1_vec4 = v4;return TRUE;}
  93         if (self.lag2_time == 0) {self.lag2_time = t;self.lag2_float1 = f1;self.lag2_float2 = f2;self.lag2_entity1 = e1;self.lag2_vec1 = v1;self.lag2_vec2 = v2;self.lag2_vec3 = v3;self.lag2_vec4 = v4;return TRUE;}
  94         if (self.lag3_time == 0) {self.lag3_time = t;self.lag3_float1 = f1;self.lag3_float2 = f2;self.lag3_entity1 = e1;self.lag3_vec1 = v1;self.lag3_vec2 = v2;self.lag3_vec3 = v3;self.lag3_vec4 = v4;return TRUE;}
  95         if (self.lag4_time == 0) {self.lag4_time = t;self.lag4_float1 = f1;self.lag4_float2 = f2;self.lag4_entity1 = e1;self.lag4_vec1 = v1;self.lag4_vec2 = v2;self.lag4_vec3 = v3;self.lag4_vec4 = v4;return TRUE;}
  96         if (self.lag5_time == 0) {self.lag5_time = t;self.lag5_float1 = f1;self.lag5_float2 = f2;self.lag5_entity1 = e1;self.lag5_vec1 = v1;self.lag5_vec2 = v2;self.lag5_vec3 = v3;self.lag5_vec4 = v4;return TRUE;}
  97         // no room for it (what is the best thing to do here??)
  98         return FALSE;
  99 };
 100
 101 float bot_shouldattack(entity e)
 102 {
 103         if (e.team == self.team)
 104         {
 105                 if (e == self)
 106                         return FALSE;
 107                 if (teams_matter)
 108                 if (e.team != 0)
 109                         return FALSE;
 110         }
 111
 112         if(teams_matter)
 113         {
 114                 if(e.team==0)
 115                         return FALSE;
 116         }
 117         else if(bot_ignore_bots)
 118                 if(clienttype(e) == CLIENTTYPE_BOT)
 119                         return FALSE;
 120
 121         if (!e.takedamage)
 122                 return FALSE;
 123         if (e.deadflag)
 124                 return FALSE;
 125         if (e.BUTTON_CHAT)
 126                 return FALSE;
 127         if(e.flags & FL_NOTARGET)
 128                 return FALSE;
 129         return TRUE;
 130 };
 131
 132 void bot_lagfunc(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
 133 {
 134         if(self.flags & FL_INWATER)
 135         {
 136                 self.bot_aimtarg = world;
 137                 return;
 138         }
 139         self.bot_aimtarg = e1;
 140         self.bot_aimlatency = self.ping; // FIXME?  Shouldn't this be in the lag item?
 141         self.bot_aimselforigin = v1;
 142         self.bot_aimselfvelocity = v2;
 143         self.bot_aimtargorigin = v3;
 144         self.bot_aimtargvelocity = v4;
 145         if(skill <= 0)
 146                 self.bot_canfire = (random() < 0.8);
 147         else if(skill <= 1)
 148                 self.bot_canfire = (random() < 0.9);
 149         else if(skill <= 2)
 150                 self.bot_canfire = (random() < 0.95);
 151         else
 152                 self.bot_canfire = 1;
 153 };
 154
 155 float bot_aimdir(vector v, float maxfiredeviation)
 156 {
 157         local float dist, delta_t, blend;
 158         local vector desiredang, diffang;
 159
 160         //dprint("aim ", self.netname, ": old:", vtos(self.v_angle));
 161         // make sure v_angle is sane first
 162         self.v_angle_y = self.v_angle_y - floor(self.v_angle_y / 360) * 360;
 163         self.v_angle_z = 0;
 164
 165         // get the desired angles to aim at
 166         //dprint(" at:", vtos(v));
 167         v = normalize(v);
 168         //te_lightning2(world, self.origin + self.view_ofs, self.origin + self.view_ofs + v * 200);
 169         if (time >= self.bot_badaimtime)
 170         {
 171                 self.bot_badaimtime = max(self.bot_badaimtime + 0.3, time);
 172                 self.bot_badaimoffset = randomvec() * bound(0, 5 - 0.5 * (skill+self.bot_offsetskill), 5) * cvar("bot_ai_aimskill_offset");
 173         }
 174         desiredang = vectoangles(v) + self.bot_badaimoffset;
 175         //dprint(" desired:", vtos(desiredang));
 176         if (desiredang_x >= 180)
 177                 desiredang_x = desiredang_x - 360;
 178         desiredang_x = bound(-90, 0 - desiredang_x, 90);
 179         desiredang_z = self.v_angle_z;
 180         //dprint(" / ", vtos(desiredang));
 181
 182         //// pain throws off aim
 183         //if (self.bot_painintensity)
 184         //{
 185         //      // shake from pain
 186         //      desiredang = desiredang + randomvec() * self.bot_painintensity * 0.2;
 187         //}
 188
 189         // calculate turn angles
 190         diffang = (desiredang - self.bot_olddesiredang);
 191         // wrap yaw turn
 192         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
 193         if (diffang_y >= 180)
 194                 diffang_y = diffang_y - 360;
 195         self.bot_olddesiredang = desiredang;
 196         //dprint(" diff:", vtos(diffang));
 197
 198         delta_t = time-self.bot_prevaimtime;
 199         self.bot_prevaimtime = time;
 200         // Here we will try to anticipate the comming aiming direction
 201         self.bot_1st_order_aimfilter= self.bot_1st_order_aimfilter
 202                 + (diffang * (1 / delta_t)    - self.bot_1st_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_1st"),1);
 203         self.bot_2nd_order_aimfilter= self.bot_2nd_order_aimfilter
 204                 + (self.bot_1st_order_aimfilter - self.bot_2nd_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_2nd"),1);
 205         self.bot_3th_order_aimfilter= self.bot_3th_order_aimfilter
 206                 + (self.bot_2nd_order_aimfilter - self.bot_3th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_3th"),1);
 207         self.bot_4th_order_aimfilter= self.bot_4th_order_aimfilter
 208                 + (self.bot_3th_order_aimfilter - self.bot_4th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_4th"),1);
 209         self.bot_5th_order_aimfilter= self.bot_5th_order_aimfilter
 210                 + (self.bot_4th_order_aimfilter - self.bot_5th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_5th"),1);
 211
 212         //blend = (bound(0,skill,10)*0.1)*pow(1-bound(0,skill,10)*0.05,2.5)*5.656854249; //Plot formule before changing !
 213         blend = bound(0,skill+self.bot_aimskill,10)*0.1;
 214         desiredang = desiredang + blend *
 215         (
 216                   self.bot_1st_order_aimfilter * cvar("bot_ai_aimskill_order_mix_1st")
 217                 + self.bot_2nd_order_aimfilter * cvar("bot_ai_aimskill_order_mix_2nd")
 218                 + self.bot_3th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_3th")
 219                 + self.bot_4th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_4th")
 220                 + self.bot_5th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_5th")
 221         );
 222
 223         // calculate turn angles
 224         diffang = desiredang - self.bot_mouseaim;
 225         // wrap yaw turn
 226         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
 227         if (diffang_y >= 180)
 228                 diffang_y = diffang_y - 360;
 229         //dprint(" diff:", vtos(diffang));
 230
 231         if (time >= self.bot_aimthinktime)
 232         {
 233                 self.bot_aimthinktime = max(self.bot_aimthinktime + 0.5 - 0.05*(skill+self.bot_thinkskill), time);
 234                 self.bot_mouseaim = self.bot_mouseaim + diffang * (1-random()*0.1*bound(1,10-(skill+self.bot_thinkskill),10));
 235         }
 236
 237         //self.v_angle = self.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
 238
 239         diffang = self.bot_mouseaim - desiredang;
 240         // wrap yaw turn
 241         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
 242         if (diffang_y >= 180)
 243                 diffang_y = diffang_y - 360;
 244         desiredang = desiredang + diffang * bound(0,cvar("bot_ai_aimskill_think"),1);
 245
 246         // calculate turn angles
 247         diffang = desiredang - self.v_angle;
 248         // wrap yaw turn
 249         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
 250         if (diffang_y >= 180)
 251                 diffang_y = diffang_y - 360;
 252         //dprint(" diff:", vtos(diffang));
 253
 254         // jitter tracking
 255         dist = vlen(diffang);
 256         //diffang = diffang + randomvec() * (dist * 0.05 * (3.5 - bound(0, skill, 3)));
 257
 258         // turn
 259         local float r, fixedrate, blendrate;
 260         fixedrate = cvar("bot_ai_aimskill_fixedrate") / bound(1,dist,1000);
 261         blendrate = cvar("bot_ai_aimskill_blendrate");
 262         r = max(fixedrate, blendrate);
 263         //self.v_angle = self.v_angle + diffang * bound(frametime, r * frametime * (2+skill*skill*0.05-random()*0.05*(10-skill)), 1);
 264         self.v_angle = self.v_angle + diffang * bound(delta_t, r * delta_t * (2+pow(skill+self.bot_mouseskill,3)*0.005-random()), 1);
 265         self.v_angle = self.v_angle * bound(0,cvar("bot_ai_aimskill_mouse"),1) + desiredang * bound(0,(1-cvar("bot_ai_aimskill_mouse")),1);
 266         //self.v_angle = self.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
 267         //self.v_angle = self.v_angle + diffang * (1/ blendrate);
 268         self.v_angle_z = 0;
 269         self.v_angle_y = self.v_angle_y - floor(self.v_angle_y / 360) * 360;
 270         //dprint(" turn:", vtos(self.v_angle));
 271
 272         makevectors(self.v_angle);
 273         shotorg = self.origin + self.view_ofs;
 274         shotdir = v_forward;
 275
 276         //dprint(" dir:", vtos(v_forward));
 277         //te_lightning2(world, shotorg, shotorg + shotdir * 100);
 278
 279         // calculate turn angles again
 280         //diffang = desiredang - self.v_angle;
 281         //diffang_y = diffang_y - floor(diffang_y / 360) * 360;
 282         //if (diffang_y >= 180)
 283         //      diffang_y = diffang_y - 360;
 284
 285         //dprint("e ", vtos(diffang), " < ", ftos(maxfiredeviation), "\n");
 286
 287         // decide whether to fire this time
 288         // note the maxfiredeviation is in degrees so this has to convert to radians first
 289         //if ((normalize(v) * shotdir) >= cos(maxfiredeviation * (3.14159265358979323846 / 180)))
 290         if ((normalize(v) * shotdir) >= cos(maxfiredeviation * (3.14159265358979323846 / 180)))
 291         if (vlen(trace_endpos-shotorg) < 500+500*bound(0, skill+self.bot_aggresskill, 10) || random()*random()>bound(0,(skill+self.bot_aggresskill)*0.05,1))
 292                 self.bot_firetimer = time + bound(0.1, 0.5-(skill+self.bot_aggresskill)*0.05, 0.5);
 293         //traceline(shotorg,shotorg+shotdir*1000,FALSE,world);
 294         //dprint(ftos(maxfiredeviation),"\n");
 295         //dprint(" diff:", vtos(diffang), "\n");
 296
 297         return self.bot_canfire && (time < self.bot_firetimer);
 298 };
 299
 300 vector bot_shotlead(vector targorigin, vector targvelocity, float shotspeed, float shotdelay)
 301 {
 302         // Try to add code here that predicts gravity effect here, no clue HOW to though ... well not yet atleast...
 303         return targorigin + targvelocity * (shotdelay + vlen(targorigin - shotorg) / shotspeed);
 304 };
 305
 306 float bot_aim(float shotspeed, float shotspeedupward, float maxshottime, float applygravity)
 307 {
 308         local float f, r;
 309         local vector v;
 310         /*
 311         eprint(self);
 312         dprint("bot_aim(", ftos(shotspeed));
 313         dprint(", ", ftos(shotspeedupward));
 314         dprint(", ", ftos(maxshottime));
 315         dprint(", ", ftos(applygravity));
 316         dprint(");\n");
 317         */
 318         shotspeed *= g_weaponspeedfactor;
 319         shotspeedupward *= g_weaponspeedfactor;
 320         if (!shotspeed)
 321         {
 322                 dprint("bot_aim: WARNING: weapon ", W_Name(self.weapon), " shotspeed is zero!\n");
 323                 shotspeed = 1000000;
 324         }
 325         if (!maxshottime)
 326         {
 327                 dprint("bot_aim: WARNING: weapon ", W_Name(self.weapon), " maxshottime is zero!\n");
 328                 maxshottime = 1;
 329         }
 330         makevectors(self.v_angle);
 331         shotorg = self.origin + self.view_ofs;
 332         shotdir = v_forward;
 333         v = bot_shotlead(self.bot_aimtargorigin, self.bot_aimtargvelocity, shotspeed, self.bot_aimlatency);
 334         local float distanceratio;
 335         distanceratio =sqrt(bound(0,skill,10000))*0.3*(vlen(v-shotorg)-100)/cvar("bot_ai_aimskill_firetolerance_distdegrees");
 336         distanceratio = bound(0,distanceratio,1);
 337         r =  (cvar("bot_ai_aimskill_firetolerance_maxdegrees")-cvar("bot_ai_aimskill_firetolerance_mindegrees"))
 338                 * (1-distanceratio) + cvar("bot_ai_aimskill_firetolerance_mindegrees");
 339         if (applygravity && self.bot_aimtarg)
 340         {
 341                 if (!findtrajectorywithleading(shotorg, '0 0 0', '0 0 0', self.bot_aimtarg, shotspeed, shotspeedupward, maxshottime, 0, self))
 342                         return FALSE;
 343                 f = bot_aimdir(findtrajectory_velocity - shotspeedupward * '0 0 1', r);
 344         }
 345         else
 346         {
 347                 f = bot_aimdir(v - shotorg, r);
 348                 //dprint("AIM: ");dprint(vtos(self.bot_aimtargorigin));dprint(" + ");dprint(vtos(self.bot_aimtargvelocity));dprint(" * ");dprint(ftos(self.bot_aimlatency + vlen(self.bot_aimtargorigin - shotorg) / shotspeed));dprint(" = ");dprint(vtos(v));dprint(" : aimdir = ");dprint(vtos(normalize(v - shotorg)));dprint(" : ");dprint(vtos(shotdir));dprint("\n");
 349                 traceline(shotorg, shotorg + shotdir * 10000, FALSE, self);
 350                 if (trace_ent.takedamage)
 351                 if (trace_fraction < 1)
 352                 if (!bot_shouldattack(trace_ent))
 353                         return FALSE;
 354                 traceline(shotorg, self.bot_aimtargorigin, FALSE, self);
 355                 if (trace_fraction < 1)
 356                 if (trace_ent != self.enemy)
 357                 if (!bot_shouldattack(trace_ent))
 358                         return FALSE;
 359         }
 360         if (r > maxshottime * shotspeed)
 361                 return FALSE;
 362         return f;
 363 };