data/qcsrc/server/bot/havocbot/vore_ai.qc

   1 .float status_teamhealing; // 0 = can't team heal, 1 = can team heal, 2 = team healing right now
   2
   3 float Swallow_condition_check_bot(entity prey)
   4 {
   5         // checks the necessary conditions for a bot to swallow a player
   6
   7         if(Swallow_condition_check(prey)) // check the normal conditions of the vore system
   8         if not(prey.BUTTON_CHAT) // don't eat players who are chatting
   9         if(self.health > cvar("g_balance_vore_kick_damage_max")) // explained below
  10                 return TRUE;
  11         return FALSE;
  12 }
  13
  14 void Vore_AI_Teamheal(entity prey)
  15 {
  16         // allows bots to use the teamheal feature and heal damaged team mates
  17         // the prey entity is only used when it's available (a player is detected in range)
  18
  19         entity head;
  20
  21         if not(teams_matter && cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))
  22                 return;
  23         if(self.deadflag != DEAD_NO || self.predator.classname == "player" || self.flagcarried || self.digesting) // a flag carrier can't waste time on team healing
  24         {
  25                 self.status_teamhealing = 0;
  26                 return;
  27         }
  28
  29         // if a teamheal is ongoing, decide whether or not to abandon it when seeing a foe we can attack
  30         // this only causes the bot to regurgitate their team mate when seeing an enemy, with the hope that our enemy will still be there once we can swallow
  31         // the higher the skill, the greater the chance a bot will abandon a team heal for an enemy
  32         if(self.status_teamhealing > 1)
  33         if(Swallow_condition_check_bot(prey))
  34         if(prey.team != self.team)
  35         if(random() * 10 < cvar("bot_ai_vore_teamhealabandon") * skill / self.bot_voreteamheal) // there are 10 bot skill steps
  36                 self.BUTTON_REGURGITATE = TRUE; // release the team mate
  37
  38         // decide if we can teamheal or not
  39         if(self.stomach_load)
  40         {
  41                 self.status_teamhealing = 2; // consider a team mate is in our stomach and we are teamhealing, until proven otherwise below
  42
  43                 FOR_EACH_PLAYER(head)
  44                 {
  45                         if(head.predator == self)
  46                         if(head.team != self.team)
  47                         {
  48                                 self.status_teamhealing = 0; // there's a foe in our stomach, we can't teamheal now
  49                                 return;
  50                         }
  51                 }
  52         }
  53         else
  54                 self.status_teamhealing = 1; // if our stomach is empty, it means we can decide to teamheal
  55
  56         // now that we're decided if we can teamheal or not, lets go ahead and do so
  57
  58         // if we are holding a team mate that's been healed to the limit, we can release them
  59         FOR_EACH_PLAYER(head)
  60         {
  61                 if(head.predator == self) // head is automatically a team mate, or we wouldn't be reaching this part of the code
  62                 if(head.health >= cvar("g_balance_vore_teamheal_stable"))
  63                         self.BUTTON_REGURGITATE = TRUE; // release the team mate
  64         }
  65
  66         // check if we can heal a team mate we come across, and if so swallow them
  67         if(prey.team == self.team)
  68         if(Swallow_condition_check_bot(prey))
  69         if(prey.health < cvar("g_balance_vore_teamheal_stable"))
  70         if not(prey.digesting) // if our team mate is digesting someone, he likely wouldn't want us ruining his frag
  71         if not(prey.flagcarried) // don't eat the flag carrier and ruin his job
  72                 self.BUTTON_ATCK = TRUE; // swallow the team mate
  73 }
  74
  75 .float decide_swallow, decide_pred, decide_prey;
  76 void Vore_AI()
  77 {
  78         // main vore AI code
  79
  80         if(!cvar("g_vore"))
  81                 return;
  82         if(cvar("bot_nofire") || !skill || (g_rpg && cvar("g_rpg_botattack") < 1))
  83                 return;
  84
  85 // --------------------------------
  86 // Predator bot behavior:
  87 // --------------------------------
  88
  89         // finding and swallowing a player
  90
  91         // aim toward the nearest possible victim. The greater the skill, the quicker the aim
  92         // this only does the aiming, checking and swallowing is handled below
  93         entity scan;
  94         scan = findradius(self.origin, cvar("g_balance_vore_swallow_range"));
  95         if(Swallow_condition_check_bot(scan))
  96                 bot_aimdir(scan.origin + scan.view_ofs - self.origin - self.view_ofs, -1);
  97
  98         // now do the actual checking and swallowing
  99         entity prey;
 100         float randomtry_pred, randomtry_prey;
 101         float decide_pred_time, decide_prey_time;
 102
 103         prey = Swallow_player_check();
 104
 105         // check if we should run the Teamhealing AI rather than continuing with the normal vore AI
 106         Vore_AI_Teamheal(prey);
 107         if(self.status_teamhealing > 1) // if we are teamhealing, there's nothing to do from here on
 108                 return;
 109
 110         randomtry_pred = randomtry_prey = random() * 10; // there are 10 bot skill steps
 111         if(prey.items & IT_STRENGTH) // avoid eating bots that have the Strenght powerup
 112                 randomtry_pred /= cvar("bot_ai_vore_fear") * self.bot_vorefear;
 113         if(prey.items & IT_INVINCIBLE) // avoid eating bots that have the Invincible powerup
 114                 randomtry_pred /= cvar("bot_ai_vore_fear") * self.bot_vorefear;
 115         decide_pred_time = cvar("bot_ai_vore_decide_pred") / (skill * 2 + 1) / self.bot_vorethinkpred;
 116         decide_prey_time = cvar("bot_ai_vore_decide_prey") / (skill * 2 + 1) / self.bot_vorethinkprey;
 117
 118         if(time > self.decide_swallow)
 119         if(Swallow_condition_check_bot(prey))
 120         {
 121                 // the greater the skill, the higher the chance bots will swallow someone each attempt
 122                 if(skill >= randomtry_pred)
 123                 if not(teams_matter && prey.team == self.team)
 124                 {
 125                         self.BUTTON_ATCK = TRUE; // swallow
 126                         self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with their prey
 127                 }
 128                 self.decide_swallow = time + cvar("bot_ai_vore_decide_swallow"); // this is needed to take a proper decision, otherwise the code would execute each frame and return TRUE pretty soon
 129         }
 130
 131         // deciding what to do with a victim:
 132
 133         if(self.stomach_load && time > self.decide_pred)
 134         {
 135                 // if the predator's health is smaller than the maximum damage a stomach kick can do, regurgitate the player(s)
 136                 // otherwise the predator is putting himself at risk by keeping you inside
 137                 if(self.health <= cvar("g_balance_vore_kick_damage_max"))
 138                         self.BUTTON_REGURGITATE = TRUE;
 139
 140                 else if(!self.digesting)
 141                 {
 142                         // the higher the skill, the faster bots will start to digest you
 143                         if not(g_rpg && cvar("g_rpg_botattack") < 2)
 144                         if(skill >= randomtry_pred)
 145                                 self.BUTTON_DIGEST = TRUE; // digest
 146
 147                         self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with their prey
 148                 }
 149         }
 150
 151 // --------------------------------
 152 // Prey bot behavior:
 153 // --------------------------------
 154
 155         // all we can do in the stomach is kick and do some damage / try to escape, or leave if the circumstances allow it and we should
 156
 157         if(self.predator.classname == "player" && time > self.decide_prey)
 158         {
 159                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
 160                 if not(teams_matter && self.team == self.predator.team)
 161                 {
 162                         // the higher the skill, the more the bot will kick in your stomack
 163                         if(skill >= randomtry_prey)
 164                         if not(teams_matter && self.team == self.predator.team) // if someone from the same team is in the belly, don't kick the predator
 165                                 self.BUTTON_ATCK = TRUE; // kick
 166                 }
 167
 168                 // if a bot can willingly leave the predator, do so unless there's a reason not to
 169                 if(self.stat_canleave)
 170                 {
 171                         if(self.predator.digesting) // our predator is digesting, so get out of him regardless of who he is
 172                                 self.BUTTON_JUMP = TRUE; // leave
 173                         else if not(g_rpg && cvar("g_rpg_botattack") < 2)
 174                         {
 175                                 if not(teams_matter && self.team == self.predator.team && cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable")) // we are being team healed, don't leave
 176                                         self.BUTTON_JUMP = TRUE; // leave
 177                         }
 178                 }
 179
 180                 self.decide_prey = time + decide_prey_time; // time before the bot decides what to do with their predator
 181         }
 182 }