keepinstomach - same thing on the predator's end. When enabled, a team mate will...
[voretournament/voretournament.git] / data / qcsrc / server / bot / havocbot / vore_ai.qc
1 .float status_teamhealing; // 0 = can't team heal, 1 = can team heal, 2 = team healing right now
2
3 float Swallow_condition_check_bot(entity prey)
4 {
5         // checks the necessary conditions for a bot to swallow a player
6
7         if(Swallow_condition_check(prey)) // check the normal conditions of the vore system
8         if not(prey.BUTTON_CHAT) // don't eat players who are chatting
9         if(self.health > cvar("g_balance_vore_kick_damage_max")) // explained below
10                 return TRUE;
11         return FALSE;
12 }
13
14 void Vore_AI_Teamheal(entity prey)
15 {
16         // allows bots to use the teamheal feature and heal damaged team mates
17         // the prey entity is only used when it's available (a player is detected in range)
18
19         entity head;
20
21         if not(teams_matter && cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))
22                 return;
23         if(self.deadflag != DEAD_NO || self.predator.classname == "player" || self.flagcarried || self.digesting) // a flag carrier can't waste time on team healing
24         {
25                 self.status_teamhealing = 0;
26                 return;
27         }
28
29         // if a teamheal is ongoing, decide whether or not to abandon it when seeing a foe we can attack
30         // this only causes the bot to regurgitate their team mate when seeing an enemy, with the hope that our enemy will still be there once we can swallow
31         // the higher the skill, the greater the chance a bot will abandon a team heal for an enemy
32         if(self.status_teamhealing > 1)
33         if(Swallow_condition_check_bot(prey))
34         if(prey.team != self.team)
35         if(random() * 10 < cvar("bot_ai_vore_teamhealabandon") * skill / self.bot_voreteamheal) // there are 10 bot skill steps
36                 self.BUTTON_REGURGITATE = TRUE; // release the team mate
37
38         // decide if we can teamheal or not
39         if(self.stomach_load)
40         {
41                 self.status_teamhealing = 2; // consider a team mate is in our stomach and we are teamhealing, until proven otherwise below
42
43                 FOR_EACH_PLAYER(head)
44                 {
45                         if(head.predator == self)
46                         if(head.team != self.team)
47                         {
48                                 self.status_teamhealing = 0; // there's a foe in our stomach, we can't teamheal now
49                                 return;
50                         }
51                 }
52         }
53         else
54                 self.status_teamhealing = 1; // if our stomach is empty, it means we can decide to teamheal
55
56         // now that we're decided if we can teamheal or not, lets go ahead and do so
57
58         // if we are holding a team mate that's been healed to the limit, we can release them
59         if not(cvar("bot_ai_vore_keepinstomach"))
60         FOR_EACH_PLAYER(head)
61         {
62                 if(head.predator == self) // head is automatically a team mate, or we wouldn't be reaching this part of the code
63                 if(head.health >= cvar("g_balance_vore_teamheal_stable"))
64                         self.BUTTON_REGURGITATE = TRUE; // release the team mate
65         }
66
67         // check if we can heal a team mate we come across, and if so swallow them
68         if(prey.team == self.team)
69         if(Swallow_condition_check_bot(prey))
70         if(prey.health < cvar("g_balance_vore_teamheal_stable"))
71         if not(prey.digesting) // if our team mate is digesting someone, he likely wouldn't want us ruining his frag
72         if not(prey.flagcarried) // don't eat the flag carrier and ruin his job
73         if not(prey.BUTTON_ATCK || prey.BUTTON_ATCK2) // our team mate wouldn't want us eating him while he's firing
74                 self.BUTTON_ATCK = TRUE; // swallow the team mate
75 }
76
77 .float decide_swallow, decide_pred, decide_prey;
78 void Vore_AI()
79 {
80         // main vore AI code
81
82         if(!cvar("g_vore")) // the vore system is disabled
83                 return;
84         if(cvar("bot_nofire") || !skill || (g_rpg && cvar("g_rpg_botattack") < 1))
85                 return;
86
87 // --------------------------------
88 // Predator bot behavior:
89 // --------------------------------
90
91         if(self.predator.classname != "player")
92         {
93                 // finding and swallowing a player
94
95                 // aim toward the nearest possible victim. The greater the skill, the quicker the aim
96                 // this only does the aiming, checking and swallowing is handled below
97                 entity head;
98                 head = findradius(self.origin, cvar("g_balance_vore_swallow_range"));
99                 while(head)
100                 {
101                         if(Swallow_condition_check_bot(head))
102                                 bot_aimdir(head.origin + head.view_ofs - self.origin - self.view_ofs, -1);
103                         head = head.chain;
104                 }
105
106                 // now do the actual checking and swallowing
107                 entity prey;
108                 float randomtry, fear;
109                 float decide_pred_time, decide_prey_time;
110
111                 prey = Swallow_player_check();
112                 fear = 1;
113
114                 // check if we should run the Teamhealing AI rather than continuing with the normal vore AI
115                 Vore_AI_Teamheal(prey);
116                 if(self.status_teamhealing > 1) // if we are teamhealing, there's nothing to do from here on
117                         return;
118
119                 randomtry = random() * 10; // there are 10 bot skill steps
120                 if(prey.items & IT_STRENGTH) // avoid eating bots that have the Strenght powerup
121                         fear += cvar("bot_ai_vore_fear") * self.bot_vorefear;
122                 if(prey.items & IT_INVINCIBLE) // avoid eating bots that have the Invincible powerup
123                         fear += cvar("bot_ai_vore_fear") * self.bot_vorefear;
124                 fear += self.stomach_load; // the bigger our stomach, the less we want to put someone else in there
125                 decide_pred_time = cvar("bot_ai_vore_decide_pred") / skill / self.bot_vorethinkpred;
126                 decide_prey_time = cvar("bot_ai_vore_decide_prey") / skill / self.bot_vorethinkprey;
127
128                 if(time > self.decide_swallow)
129                 if(Swallow_condition_check_bot(prey))
130                 {
131                         // the greater the skill, the higher the chance bots will swallow someone each attempt
132                         if(skill / fear >= randomtry)
133                         if not(teams_matter && prey.team == self.team)
134                         {
135                                 self.BUTTON_ATCK = TRUE; // swallow
136                                 self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with their prey
137                         }
138                         self.decide_swallow = time + cvar("bot_ai_vore_decide_swallow"); // this is needed to take a proper decision, otherwise the code would execute each frame and return TRUE pretty soon
139                 }
140
141                 // deciding what to do with a victim:
142
143                 if(self.stomach_load && time > self.decide_pred)
144                 {
145                         // if the predator's health is smaller than the maximum damage a stomach kick can do, regurgitate the player(s)
146                         // otherwise the predator is putting himself at risk by keeping you inside
147                         if(self.health <= cvar("g_balance_vore_kick_damage_max"))
148                                 self.BUTTON_REGURGITATE = TRUE;
149
150                         else if(!self.digesting)
151                         {
152                                 // the higher the skill, the faster bots will start to digest you
153                                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
154                                 if(skill >= randomtry)
155                                         self.BUTTON_DIGEST = TRUE; // digest
156
157                                 self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with their prey
158                         }
159                 }
160         }
161
162 // --------------------------------
163 // Prey bot behavior:
164 // --------------------------------
165
166         if(self.predator.classname == "player" && time > self.decide_prey)
167         {
168                 // all we can do in the stomach is kick and do some damage / try to escape, or leave if the circumstances allow it and we should
169
170                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
171                 if not(teams_matter && self.team == self.predator.team)
172                 {
173                         // the higher the skill, the more the bot will kick in your stomack
174                         if(skill >= randomtry)
175                         if not(teams_matter && self.team == self.predator.team) // if someone from the same team is in the belly, don't kick the predator
176                                 self.BUTTON_ATCK = TRUE; // kick
177                 }
178
179                 // if a bot can willingly leave the predator, do so unless there's a reason not to
180                 if(self.stat_canleave)
181                 {
182                         if(self.predator.digesting) // our predator is digesting, so get out of him regardless of who he is
183                                 self.BUTTON_JUMP = TRUE; // leave
184                         else if not(g_rpg && cvar("g_rpg_botattack") < 2)
185                         {
186                                 if not(teams_matter && self.team == self.predator.team && cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable")) // we are being team healed, don't leave
187                                 if not(teams_matter && self.team == self.predator.team && cvar("bot_ai_vore_stayinstomach")) // bots are not supposed to leave a team mate's stomach automatically
188                                         self.BUTTON_JUMP = TRUE; // leave
189                         }
190                 }
191
192                 self.decide_prey = time + decide_prey_time; // time before the bot decides what to do with their predator
193         }
194 }