8a18c2e7823af3f91a2b5d63a3e13848a5b68ec6
[voretournament/voretournament.git] / data / qcsrc / server / bot / havocbot / vore_ai.qc
1 .float status_teamhealing; // 0 = can't team heal, 1 = can team heal, 2 = team healing right now
2
3 float Swallow_condition_check_bot(entity prey)
4 {
5         // checks the necessary conditions for a bot to swallow a player
6
7         if(Swallow_condition_check(prey)) // check the normal conditions of the vore system
8         if(time >= prey.spawnshieldtime)
9         if not(prey.BUTTON_CHAT) // don't eat players who are chatting
10         if(self.health > cvar("g_balance_vore_kick_damage_max")) // explained below
11                 return TRUE;
12         return FALSE;
13 }
14
15 void Vore_AI_Teamheal(entity prey)
16 {
17         // allows bots to use the teamheal feature and heal damaged team mates
18         // the prey entity is only used when it's available (a player is detected in range)
19
20         entity head;
21
22         if not(teams_matter && cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))
23                 return;
24         if(self.deadflag != DEAD_NO || self.predator.classname == "player" || self.flagcarried || self.digesting) // a flag carrier can't waste time on team healing
25         {
26                 self.status_teamhealing = 0;
27                 return;
28         }
29
30         // if a teamheal is ongoing, decide whether or not to abandon it when seeing a foe we can attack
31         // this only causes the bot to regurgitate their team mate when seeing an enemy, with the hope that our enemy will still be there once we can swallow
32         // the higher the skill, the greater the chance a bot will abandon a team heal for an enemy
33         if(self.status_teamhealing > 1)
34         if(Swallow_condition_check_bot(prey))
35         if(prey.team != self.team)
36         if(random() * 10 < cvar("bot_ai_vore_teamhealabandon") * skill / self.bot_voreteamheal) // there are 10 bot skill steps
37                 self.BUTTON_REGURGITATE = TRUE; // release the team mate
38
39         // decide if we can teamheal or not
40         if(self.stomach_load)
41         {
42                 self.status_teamhealing = 2; // consider a team mate is in our stomach and we are teamhealing, until proven otherwise below
43
44                 FOR_EACH_PLAYER(head)
45                 {
46                         if(head.predator == self)
47                         if(head.team != self.team)
48                         {
49                                 self.status_teamhealing = 0; // there's a foe in our stomach, we can't teamheal now
50                                 return;
51                         }
52                 }
53         }
54         else
55                 self.status_teamhealing = 1; // if our stomach is empty, it means we can decide to teamheal
56
57         // now that we're decided if we can teamheal or not, lets go ahead and do so
58
59         // if we are holding a team mate that's been healed to the limit, we can release them
60         if not(cvar("bot_ai_vore_keepinstomach"))
61         FOR_EACH_PLAYER(head)
62         {
63                 if(head.predator == self) // head is automatically a team mate, or we wouldn't be reaching this part of the code
64                 if(head.health >= cvar("g_balance_vore_teamheal_stable"))
65                         self.BUTTON_REGURGITATE = TRUE; // release the team mate
66         }
67
68         // check if we can heal a team mate we come across, and if so swallow them
69         if(prey.team == self.team)
70         if(Swallow_condition_check_bot(prey))
71         if(prey.health < cvar("g_balance_vore_teamheal_stable"))
72         if not(prey.digesting) // if our team mate is digesting someone, he likely wouldn't want us ruining his frag
73         if not(prey.flagcarried) // don't eat the flag carrier and ruin his job
74         if not(prey.BUTTON_ATCK || prey.BUTTON_ATCK2) // our team mate wouldn't want us eating him while he's firing
75                 self.BUTTON_ATCK = TRUE; // swallow the team mate
76 }
77
78 .float decide_swallow, decide_pred, decide_prey;
79 void Vore_AI()
80 {
81         // main vore AI code
82
83         if(!cvar("g_vore")) // the vore system is disabled
84                 return;
85         if(cvar("bot_nofire") || !skill || (g_rpg && cvar("g_rpg_botattack") < 1))
86                 return;
87
88 // --------------------------------
89 // Predator bot behavior:
90 // --------------------------------
91
92         if(self.predator.classname != "player")
93         {
94                 // finding and swallowing a player
95
96                 // aim toward the nearest possible victim. The greater the skill, the quicker the aim
97                 // this only does the aiming, checking and swallowing is handled below
98                 entity head;
99                 head = findradius(self.origin, cvar("g_balance_vore_swallow_range"));
100                 while(head)
101                 {
102                         if(Swallow_condition_check_bot(head))
103                                 bot_aimdir(head.origin + head.view_ofs - self.origin - self.view_ofs, -1);
104                         head = head.chain;
105                 }
106
107                 // now do the actual checking and swallowing
108                 entity prey;
109                 float randomtry, fear;
110                 float decide_pred_time, decide_prey_time;
111
112                 prey = Swallow_player_check();
113                 fear = 1;
114
115                 // check if we should run the Teamhealing AI rather than continuing with the normal vore AI
116                 Vore_AI_Teamheal(prey);
117                 if(self.status_teamhealing > 1) // if we are teamhealing, there's nothing to do from here on
118                         return;
119
120                 randomtry = random() * 10; // there are 10 bot skill steps
121                 if(prey.items & IT_STRENGTH) // avoid eating bots that have the Strenght powerup
122                         fear += cvar("bot_ai_vore_fear") * self.bot_vorefear;
123                 if(prey.items & IT_INVINCIBLE) // avoid eating bots that have the Invincible powerup
124                         fear += cvar("bot_ai_vore_fear") * self.bot_vorefear;
125                 fear += self.stomach_load; // the bigger our stomach, the less we want to put someone else in there
126                 decide_pred_time = cvar("bot_ai_vore_decide_pred") / skill / self.bot_vorethinkpred;
127                 decide_prey_time = cvar("bot_ai_vore_decide_prey") / skill / self.bot_vorethinkprey;
128
129                 if(time > self.decide_swallow)
130                 if(Swallow_condition_check_bot(prey))
131                 {
132                         // the greater the skill, the higher the chance bots will swallow someone each attempt
133                         if(skill / fear >= randomtry)
134                         if not(teams_matter && prey.team == self.team)
135                         {
136                                 self.BUTTON_ATCK = TRUE; // swallow
137                                 self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with their prey
138                         }
139                         self.decide_swallow = time + cvar("bot_ai_vore_decide_swallow"); // this is needed to take a proper decision, otherwise the code would execute each frame and return TRUE pretty soon
140                 }
141
142                 // deciding what to do with a victim:
143
144                 if(self.stomach_load && time > self.decide_pred)
145                 {
146                         // if the predator's health is smaller than the maximum damage a stomach kick can do, regurgitate the player(s)
147                         // otherwise the predator is putting himself at risk by keeping you inside
148                         if(self.health <= cvar("g_balance_vore_kick_damage_max"))
149                                 self.BUTTON_REGURGITATE = TRUE;
150
151                         else if(!self.digesting)
152                         {
153                                 // the higher the skill, the faster bots will start to digest you
154                                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
155                                 if(skill >= randomtry)
156                                         self.BUTTON_DIGEST = TRUE; // digest
157
158                                 self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with their prey
159                         }
160                 }
161         }
162
163 // --------------------------------
164 // Prey bot behavior:
165 // --------------------------------
166
167         if(self.predator.classname == "player" && time > self.decide_prey)
168         {
169                 // all we can do in the stomach is kick and do some damage / try to escape, or leave if the circumstances allow it and we should
170
171                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
172                 if not(teams_matter && self.team == self.predator.team)
173                 {
174                         // the higher the skill, the more the bot will kick in your stomack
175                         if(skill >= randomtry)
176                         if not(teams_matter && self.team == self.predator.team) // if someone from the same team is in the belly, don't kick the predator
177                                 self.BUTTON_ATCK = TRUE; // kick
178                 }
179
180                 // if a bot can willingly leave the predator, do so unless there's a reason not to
181                 if(self.stat_canleave)
182                 {
183                         if(self.predator.digesting) // our predator is digesting, so get out of him regardless of who he is
184                                 self.BUTTON_JUMP = TRUE; // leave
185                         else if not(g_rpg && cvar("g_rpg_botattack") < 2)
186                         {
187                                 if not(teams_matter && self.team == self.predator.team && cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable")) // we are being team healed, don't leave
188                                 if not(teams_matter && self.team == self.predator.team && cvar("bot_ai_vore_stayinstomach")) // bots are not supposed to leave a team mate's stomach automatically
189                                         self.BUTTON_JUMP = TRUE; // leave
190                         }
191                 }
192
193                 self.decide_prey = time + decide_prey_time; // time before the bot decides what to do with their predator
194         }
195 }