data/qcsrc/server/bot/havocbot/vore_ai.qc

   1 .float status_teamhealing; // 0 = can't team heal, 1 = can team heal, 2 = team healing right now
   2
   3 float Swallow_condition_check_bot(entity prey)
   4 {
   5         // checks the necessary conditions for a bot to swallow a player
   6
   7         if(Swallow_condition_check(prey)) // check the normal conditions of the vore system
   8         if not(prey.BUTTON_CHAT) // don't eat players who are chatting
   9         if(self.health > cvar("g_balance_vore_kick_damage_max")) // explained below
  10                 return TRUE;
  11         return FALSE;
  12 }
  13
  14 void Vore_AI_Teamheal(entity prey)
  15 {
  16         // allows bots to use the teamheal feature and heal damaged team mates
  17         // the prey entity is only used when it's available (a player is detected in range)
  18
  19         entity head;
  20
  21         if not(teams_matter && cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))
  22                 return;
  23         if(self.deadflag != DEAD_NO || self.predator.classname == "player" || self.flagcarried || self.digesting) // a flag carrier can't waste time on team healing
  24         {
  25                 self.status_teamhealing = 0;
  26                 return;
  27         }
  28
  29         // if a teamheal is ongoing, decide whether or not to abandon it when seeing a foe we can attack
  30         // this only causes the bot to regurgitate their team mate when seeing an enemy, with the hope that our enemy will still be there once we can swallow
  31         // the higher the skill, the greater the chance a bot will abandon a team heal for an enemy
  32         if(self.status_teamhealing > 1)
  33         if(Swallow_condition_check_bot(prey))
  34         if(prey.team != self.team)
  35         if(random() * 10 < cvar("bot_ai_vore_teamhealabandon") * skill / self.bot_voreteamheal) // there are 10 bot skill steps
  36                 self.BUTTON_REGURGITATE = TRUE; // release the team mate
  37
  38         // decide if we can teamheal or not
  39         if(self.stomach_load)
  40         {
  41                 self.status_teamhealing = 2; // consider a team mate is in our stomach and we are teamhealing, until proven otherwise below
  42
  43                 FOR_EACH_PLAYER(head)
  44                 {
  45                         if(head.predator == self)
  46                         if(head.team != self.team)
  47                         {
  48                                 self.status_teamhealing = 0; // there's a foe in our stomach, we can't teamheal now
  49                                 return;
  50                         }
  51                 }
  52         }
  53         else
  54                 self.status_teamhealing = 1; // if our stomach is empty, it means we can decide to teamheal
  55
  56         // now that we're decided if we can teamheal or not, lets go ahead and do so
  57
  58         // if we are holding a team mate that's been healed to the limit, we can release them
  59         FOR_EACH_PLAYER(head)
  60         {
  61                 if(head.predator == self) // head is automatically a team mate, or we wouldn't be reaching this part of the code
  62                 if(head.health >= cvar("g_balance_vore_teamheal_stable"))
  63                         self.BUTTON_REGURGITATE = TRUE; // release the team mate
  64         }
  65
  66         // check if we can heal a team mate we come across, and if so swallow them
  67         if(prey.team == self.team)
  68         if(Swallow_condition_check_bot(prey))
  69         if(prey.health < cvar("g_balance_vore_teamheal_stable"))
  70         if not(prey.digesting) // if our team mate is digesting someone, he likely wouldn't want us ruining his frag
  71         if not(prey.flagcarried) // don't eat the flag carrier and ruin his job
  72         if not(prey.BUTTON_ATCK || prey.BUTTON_ATCK2) // our team mate wouldn't want us eating him while he's firing
  73                 self.BUTTON_ATCK = TRUE; // swallow the team mate
  74 }
  75
  76 .float decide_swallow, decide_pred, decide_prey;
  77 void Vore_AI()
  78 {
  79         // main vore AI code
  80
  81         if(!cvar("g_vore")) // the vore system is disabled
  82                 return;
  83         if(cvar("bot_nofire") || !skill || (g_rpg && cvar("g_rpg_botattack") < 1))
  84                 return;
  85
  86 // --------------------------------
  87 // Predator bot behavior:
  88 // --------------------------------
  89
  90         // finding and swallowing a player
  91
  92         // aim toward the nearest possible victim. The greater the skill, the quicker the aim
  93         // this only does the aiming, checking and swallowing is handled below
  94         entity head;
  95         head = findradius(self.origin, cvar("g_balance_vore_swallow_range"));
  96         while(head)
  97         {
  98                 if(Swallow_condition_check_bot(head))
  99                         bot_aimdir(head.origin + head.view_ofs - self.origin - self.view_ofs, -1);
 100                 head = head.chain;
 101         }
 102
 103         // now do the actual checking and swallowing
 104         entity prey;
 105         float randomtry_pred, randomtry_prey;
 106         float decide_pred_time, decide_prey_time;
 107
 108         prey = Swallow_player_check();
 109
 110         // check if we should run the Teamhealing AI rather than continuing with the normal vore AI
 111         Vore_AI_Teamheal(prey);
 112         if(self.status_teamhealing > 1) // if we are teamhealing, there's nothing to do from here on
 113                 return;
 114
 115         randomtry_pred = randomtry_prey = random() * 10; // there are 10 bot skill steps
 116         if(prey.items & IT_STRENGTH) // avoid eating bots that have the Strenght powerup
 117                 randomtry_pred /= cvar("bot_ai_vore_fear") * self.bot_vorefear;
 118         if(prey.items & IT_INVINCIBLE) // avoid eating bots that have the Invincible powerup
 119                 randomtry_pred /= cvar("bot_ai_vore_fear") * self.bot_vorefear;
 120         decide_pred_time = cvar("bot_ai_vore_decide_pred") / skill / self.bot_vorethinkpred;
 121         decide_prey_time = cvar("bot_ai_vore_decide_prey") / skill / self.bot_vorethinkprey;
 122
 123         if(time > self.decide_swallow)
 124         if(Swallow_condition_check_bot(prey))
 125         {
 126                 // the greater the skill, the higher the chance bots will swallow someone each attempt
 127                 if(skill >= randomtry_pred)
 128                 if not(teams_matter && prey.team == self.team)
 129                 {
 130                         self.BUTTON_ATCK = TRUE; // swallow
 131                         self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with their prey
 132                 }
 133                 self.decide_swallow = time + cvar("bot_ai_vore_decide_swallow"); // this is needed to take a proper decision, otherwise the code would execute each frame and return TRUE pretty soon
 134         }
 135
 136         // deciding what to do with a victim:
 137
 138         if(self.stomach_load && time > self.decide_pred)
 139         {
 140                 // if the predator's health is smaller than the maximum damage a stomach kick can do, regurgitate the player(s)
 141                 // otherwise the predator is putting himself at risk by keeping you inside
 142                 if(self.health <= cvar("g_balance_vore_kick_damage_max"))
 143                         self.BUTTON_REGURGITATE = TRUE;
 144
 145                 else if(!self.digesting)
 146                 {
 147                         // the higher the skill, the faster bots will start to digest you
 148                         if not(g_rpg && cvar("g_rpg_botattack") < 2)
 149                         if(skill >= randomtry_pred)
 150                                 self.BUTTON_DIGEST = TRUE; // digest
 151
 152                         self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with their prey
 153                 }
 154         }
 155
 156 // --------------------------------
 157 // Prey bot behavior:
 158 // --------------------------------
 159
 160         // all we can do in the stomach is kick and do some damage / try to escape, or leave if the circumstances allow it and we should
 161
 162         if(self.predator.classname == "player" && time > self.decide_prey)
 163         {
 164                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
 165                 if not(teams_matter && self.team == self.predator.team)
 166                 {
 167                         // the higher the skill, the more the bot will kick in your stomack
 168                         if(skill >= randomtry_prey)
 169                         if not(teams_matter && self.team == self.predator.team) // if someone from the same team is in the belly, don't kick the predator
 170                                 self.BUTTON_ATCK = TRUE; // kick
 171                 }
 172
 173                 // if a bot can willingly leave the predator, do so unless there's a reason not to
 174                 if(self.stat_canleave)
 175                 {
 176                         if(self.predator.digesting) // our predator is digesting, so get out of him regardless of who he is
 177                                 self.BUTTON_JUMP = TRUE; // leave
 178                         else if not(g_rpg && cvar("g_rpg_botattack") < 2)
 179                         {
 180                                 if not(teams_matter && self.team == self.predator.team && cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable")) // we are being team healed, don't leave
 181                                         self.BUTTON_JUMP = TRUE; // leave
 182                         }
 183                 }
 184
 185                 self.decide_prey = time + decide_prey_time; // time before the bot decides what to do with their predator
 186         }
 187 }