Don't allow kicking immediately after being swallowed. Increase escape probability...
[voretournament/voretournament.git] / data / qcsrc / server / vore.qc
1 .float regurgitate_prepare;\r
2 .float stomachkick_delay, system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
3 .float complain_vore;\r
4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
5 \r
6 const float system_delay_time = 0.1;\r
7 const float complain_delay_time = 1;\r
8 const float button_delay_time = 0.5;\r
9 const float steptime = 0.1;\r
10 \r
11 entity Swallow_player_check()\r
12 {\r
13         // check if we can swallow a player instead of firing our weapon\r
14 \r
15         float swallow_range;\r
16         vector vore_w_shotorg, vore_w_shotdir;\r
17 \r
18         swallow_range = cvar("g_balance_vore_swallow_range");\r
19         if(self.scale) // we can swallow from further or closer based on our size\r
20                 swallow_range *= self.scale;\r
21         vore_w_shotorg = self.origin;\r
22         vore_w_shotdir = v_forward;\r
23 \r
24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
25         if(trace_fraction < 1)\r
26         if(trace_ent.classname == "player")\r
27                 return trace_ent;\r
28         return world;\r
29 }\r
30 \r
31 float Swallow_condition_check(entity prey)\r
32 {\r
33         // checks the necessary conditions for swallowing a player\r
34 \r
35         if(prey != self)\r
36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
38         if(!self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
40         {\r
41                 string swallow_complain;\r
42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
43                         swallow_complain = "You cannot swallow your team mates\n";\r
44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
46                 else if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
47                         swallow_complain = strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n");\r
48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
52 \r
53                 if(swallow_complain != "")\r
54                 {\r
55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
56                         {\r
57                                 play2(self, "misc/forbidden.wav");\r
58                                 sprint(self, swallow_complain);\r
59                                 self.complain_vore = time + complain_delay_time;\r
60                         }\r
61                         return FALSE;\r
62                 }\r
63                 return TRUE;\r
64         }\r
65         return FALSE;\r
66 }\r
67 \r
68 float Stomach_TeamMates_check(entity pred)\r
69 {\r
70         // checks if a player's stomach contains any team mates\r
71 \r
72         entity head;\r
73         if(teams_matter)\r
74         {\r
75                 FOR_EACH_PLAYER(head)\r
76                 {\r
77                         if(head.predator == pred && head.team == pred.team)\r
78                                 return TRUE;\r
79                 }\r
80         }\r
81         return FALSE;\r
82 }\r
83 \r
84 float Vore_CanLeave()\r
85 {\r
86         if(self.stat_eaten)\r
87         {\r
88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
89                         return TRUE;\r
90                 if(teams_matter && self.team == self.predator.team)\r
91                         return TRUE;\r
92                 if(g_rpg && cvar("g_rpg_canleave"))\r
93                         return TRUE;\r
94         }\r
95         return FALSE;\r
96 }\r
97 \r
98 // position the camera properly for prey\r
99 void Vore_SetCamera()\r
100 {\r
101         if not(self.stat_eaten)\r
102                 return;\r
103 \r
104         self.view_ofs = PL_PREY_VIEW_OFS;\r
105 \r
106         float prey_height;\r
107         if(self.fakeprey)\r
108                 prey_height = (self.scale - self.fakepredator.scale) * cvar("g_healthsize_vore_pos");\r
109         else\r
110                 prey_height = (self.scale - self.predator.scale) * cvar("g_healthsize_vore_pos");\r
111         self.view_ofs_z += prey_height;\r
112 }\r
113 \r
114 .float gurgle_oldstomachload;\r
115 void Vore_GurgleSound()\r
116 {\r
117         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
118         {\r
119                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
120 \r
121                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
122                 self.gurgle_oldstomachload = self.stomach_load;\r
123         }\r
124 }\r
125 \r
126 void Vore_WeightApply(entity e)\r
127 {\r
128         // apply stomach weight that makes you heavier the more you eat\r
129         // slowing the player is done in cl_physics.qc\r
130 \r
131         if(e.stomach_load != e.vore_oldstomachload)\r
132                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
133         if(e.gravity == 0)\r
134                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
135         e.vore_oldstomachload = e.stomach_load;\r
136 }\r
137 \r
138 void Vore_AutoDigest(entity e)\r
139 {\r
140         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
141 \r
142         if(!cvar("g_vore_digestion") || e.digesting)\r
143                 return;\r
144         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
145                 return; // this feature is only for players, not bots\r
146         if(e.stomach_load > 1)\r
147                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
148         if(Stomach_TeamMates_check(e))\r
149                 return; // never begin automatic digestion if we've swallowed a team mate\r
150 \r
151         e.digesting = TRUE;\r
152 }\r
153 \r
154 .entity pusher;\r
155 .float pushltime;\r
156 void Vore_Swallow(entity e)\r
157 {\r
158         // this player is being swallowed by another player, apply the proper changes\r
159 \r
160         e.vore_oldmovetype = e.movetype;\r
161         e.vore_oldsolid = e.solid;\r
162 \r
163         e.predator = self;\r
164         setorigin(e, e.predator.origin);\r
165         e.velocity = '0 0 0';\r
166         e.movetype = MOVETYPE_FOLLOW;\r
167         e.solid = SOLID_NOT;\r
168         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
169 \r
170         // drop keys (KH) and flags (CTF) when we get swallowed\r
171         kh_Key_DropAll(e, FALSE);\r
172         if(e.flagcarried)\r
173                 DropFlag(e.flagcarried, world, e.predator);\r
174 \r
175         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
176                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
177 \r
178         if(teams_matter && e.team == e.predator.team)\r
179         {\r
180                 if(cvar("g_vore_kick"))\r
181                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
182                 if(cvar("g_vore_digestion"))\r
183                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
184         }\r
185 \r
186         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
187         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
188         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
189         e.predator.stomach_load += 1;\r
190         e.predator.regurgitate_prepare = 0;\r
191         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
192         Vore_WeightApply(e.predator);\r
193         Vore_AutoDigest(e.predator);\r
194 \r
195         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
196         e.predator.weapon_delay = time + button_delay_time;\r
197         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
198         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
199         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
200 }\r
201 \r
202 void Vore_Regurgitate(entity e)\r
203 {\r
204         // this player is being regurgitated by their predator, apply the proper changes\r
205 \r
206         e.movetype = e.vore_oldmovetype;\r
207         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
208                 e.solid = e.vore_oldsolid;\r
209         e.view_ofs_z = PL_VIEW_OFS_z;\r
210 \r
211         // apply velocities\r
212         local vector oldforward, oldright, oldup;\r
213         oldforward = v_forward;\r
214         oldright = v_right;\r
215         oldup = v_up;\r
216         makevectors(e.predator.v_angle);\r
217         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
218         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
219         v_forward = oldforward;\r
220         v_right = oldright;\r
221         v_up = oldup;\r
222 \r
223         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
224         e.pushltime = time + cvar("g_maxpushtime");\r
225 \r
226         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
227         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
228         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
229         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
230         e.predator.stomach_load -= 1;\r
231         e.predator.regurgitate_prepare = 0;\r
232         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
233         Vore_WeightApply(e.predator);\r
234 \r
235         // block firing for a small amount of time, or we'll be firing the next frame\r
236         e.weapon_delay = time + button_delay_time;\r
237         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
238         e.predator = world;\r
239 }\r
240 \r
241 void Vore_DeadPrey_Configure(entity e)\r
242 {\r
243         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
244 \r
245         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
246                 return;\r
247 \r
248         // this entity is like e.predator but for dead prey, to avoid conflicts\r
249         e.fakepredator = e.predator;\r
250         e.fakeprey = TRUE;\r
251 \r
252         // first release the prey from the predator, as dead prey needs to be attached differently\r
253         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
254         e.predator.stomach_load -= 1;\r
255         Vore_WeightApply(e.predator);\r
256         e.predator = world;\r
257 \r
258         // now put our dead prey inside the predator's stomach, but only as an effect\r
259         e.movetype = MOVETYPE_FOLLOW;\r
260         e.takedamage = DAMAGE_NO;\r
261         e.solid = SOLID_NOT;\r
262         e.aiment = e.fakepredator;\r
263 }\r
264 \r
265 void Vore_DeadPrey_Detach(entity e)\r
266 {\r
267         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
268         // should only execute after Vore_DeadPrey_Configure has ran first\r
269 \r
270         if not(cvar("g_vore_keepdeadprey"))\r
271                 return;\r
272 \r
273         e.fakepredator = world;\r
274         e.fakeprey = TRUE; // keep fakeprey status\r
275         e.stat_eaten = 0;\r
276         e.aiment = world;\r
277         e.movetype = MOVETYPE_TOSS;\r
278 }\r
279 \r
280 void Vore_PreyRelease(entity e, float pred_disconnect)\r
281 {\r
282         if(pred_disconnect)\r
283         {\r
284                 if(e.fakeprey)\r
285                         Vore_DeadPrey_Detach(e);\r
286                 else\r
287                         Vore_Regurgitate(e);\r
288         }\r
289         else if(self.stat_eaten && !self.fakeprey)\r
290         {\r
291                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
292                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
293                         Vore_DeadPrey_Configure(e);\r
294                 else\r
295                         Vore_Regurgitate(e);\r
296         }\r
297 }\r
298 \r
299 void Vore_Disconnect()\r
300 {\r
301         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
302 \r
303         // prey disconnects or goes spectating while inside someone's belly\r
304         if(self.stat_eaten)\r
305                 Vore_PreyRelease(self, TRUE);\r
306 \r
307         // pred disconnects or goes spectating with players in their belly\r
308         entity head;\r
309         FOR_EACH_PLAYER(head)\r
310         {\r
311                 if(head.predator == self || head.fakepredator == self)\r
312                         Vore_PreyRelease(head, TRUE);\r
313         }\r
314         Vore_GurgleSound(); // stop the gurgling sound\r
315 \r
316         self.stomach_load = self.gravity = 0; // prevents a bug\r
317 }\r
318 \r
319 .float digestion_step;\r
320 void Vore_Digest()\r
321 {\r
322         // apply digestion to prey\r
323 \r
324         if(time > self.predator.digestion_step)\r
325         {\r
326                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
327                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
328                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
329 \r
330                 if (self.predator.digestsound_finished < time)\r
331                 {\r
332                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
333                         self.predator.digestsound_finished = time + 0.5;\r
334                 }\r
335                 self.predator.digestion_step = time + steptime;\r
336         }\r
337 \r
338         if(self.deadflag != DEAD_NO)\r
339         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
340                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
341 }\r
342 \r
343 .float teamheal_step;\r
344 void Vore_Teamheal()\r
345 {\r
346         // apply teamheal\r
347 \r
348         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
349         if(time > self.teamheal_step)\r
350         {\r
351                 self.health += cvar("g_balance_vore_teamheal");\r
352                 self.teamheal_step = time + steptime;\r
353 \r
354                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
355                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
356                 {\r
357                         play2(self, "misc/beep.wav");\r
358                         play2(self.predator, "misc/beep.wav");\r
359                 }\r
360         }\r
361 }\r
362 \r
363 void Vore_StomachKick()\r
364 {\r
365         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
366 \r
367         if(time > self.stomachkick_delay)\r
368         {\r
369                 float damage;\r
370                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
371 \r
372                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
373                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.wav", VOL_BASE, ATTN_NORM);\r
374                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
375                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
376 \r
377                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
378                         Vore_Regurgitate(self);\r
379 \r
380                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
381         }\r
382 }\r
383 \r
384 void Vore_StomachLeave()\r
385 {\r
386         // allows players to get out of their predator at will in some circumstances, such as team mates\r
387 \r
388         if(Vore_CanLeave())\r
389                 Vore_Regurgitate(self);\r
390         else if(time > self.complain_vore)\r
391         {\r
392                 play2(self, "misc/forbidden.wav");\r
393                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
394                 self.complain_vore = time + complain_delay_time;\r
395         }\r
396 }\r
397 \r
398 void Vore_AutoTaunt()\r
399 {\r
400         // triggers ambient vore taunts, for both pred and prey\r
401 \r
402         float taunt_time;\r
403 \r
404         // predator taunts\r
405         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
406         {\r
407                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
408                 {\r
409                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
410                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
411                 }\r
412         }\r
413         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
414         {\r
415                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
416                 SetAutoTaunt(self, 0, 0);\r
417         }\r
418 \r
419         // prey taunts\r
420         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
421         {\r
422                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
423                 {\r
424                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
425                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
426                 }\r
427         }\r
428         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
429         {\r
430                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
431                 SetAutoTaunt(self, 0, 0);\r
432         }\r
433 }\r
434 \r
435 void Vore()\r
436 {\r
437         // main vore code, this is where it all happens\r
438 \r
439         if(!cvar("g_vore")) // the vore system is disabled\r
440         {\r
441                 Vore_Disconnect();\r
442                 return;\r
443         }\r
444 \r
445         Vore_AutoTaunt();\r
446 \r
447         // wash the goo away from players once they leave the stomach\r
448         if(!self.stat_eaten)\r
449         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
450         if(self.colormod)\r
451         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
452         {\r
453                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
454                 if(self.colormod_x > 1)\r
455                         self.colormod_x = 1;\r
456                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
457                 if(self.colormod_y > 1)\r
458                         self.colormod_y = 1;\r
459                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
460                 if(self.colormod_z > 1)\r
461                         self.colormod_z = 1;\r
462         }\r
463 \r
464         // set all vore stats\r
465         if(self.fakepredator.classname == "player")\r
466                 self.stat_eaten = num_for_edict(self.fakepredator);\r
467         else if(self.predator.classname == "player")\r
468         {\r
469                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
470                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
471                 self.stat_eaten = num_for_edict(self.predator);\r
472         }\r
473         else\r
474         {\r
475                 self.stat_stomachload = self.stomach_load;\r
476                 self.stat_digesting = self.digesting;\r
477                 self.stat_eaten = 0;\r
478         }\r
479         self.stat_canleave = Vore_CanLeave();\r
480 \r
481         // don't allow a player inside a player inside another player :)\r
482         // prevent this by checking if such has happened, and taking the proper measures\r
483         // this code has a high priority and must not be stopped by any delay, so run it here\r
484         if(self.predator.stat_eaten)\r
485         {\r
486                 entity target_predator, target_predator_predator, oldself;\r
487                 target_predator = self.predator;\r
488                 target_predator_predator = self.predator.predator;\r
489 \r
490                 Vore_Regurgitate(self);\r
491 \r
492                 // now steal our prey's prey if this probability applies\r
493                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
494                 {\r
495                         oldself = self;\r
496                         self = target_predator_predator;\r
497                         if(Swallow_condition_check(oldself))\r
498                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
499                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
500                                 Vore_Swallow(oldself);\r
501                         self = oldself;\r
502                 }\r
503         }\r
504 \r
505         // apply delays and skip the vore system under some circumstances\r
506         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
507         {\r
508                 Vore_Disconnect();\r
509                 return;\r
510         }\r
511         if(self.spectatee_status)\r
512                 return;\r
513         if(time < self.system_delay)\r
514                 return;\r
515 \r
516 // --------------------------------\r
517 // Code that addresses predators:\r
518 // --------------------------------\r
519 \r
520         entity prey;\r
521         prey = Swallow_player_check();\r
522 \r
523         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
524         self.stat_canswallow = 0;\r
525         if(Swallow_condition_check(prey))\r
526         {\r
527                 // canswallow stat, used by the HUD\r
528                 if(teams_matter && prey.team == self.team)\r
529                         self.stat_canswallow = 2;\r
530                 else\r
531                         self.stat_canswallow = 1;\r
532 \r
533                 if(self.BUTTON_ATCK)\r
534                         Vore_Swallow(prey);\r
535         }\r
536         else if(prey != world)\r
537                 self.stat_canswallow = -1;\r
538 \r
539         // toggle digestion, if the player has someone in their stomach\r
540         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
541         {\r
542                 if(self.stomach_load)\r
543                 {\r
544                         if(time > self.digest_button_delay_time)\r
545                         {\r
546                                 self.digesting = !self.digesting;\r
547                                 self.digest_button_delay_time = time + button_delay_time;\r
548                         }\r
549                 }\r
550                 else if(time > self.complain_vore)\r
551                 {\r
552                         play2(self, "misc/forbidden.wav");\r
553                         sprint(self, "There is nothing to digest\n");\r
554                         self.complain_vore = time + complain_delay_time;\r
555                 }\r
556         }\r
557         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
558                 self.digesting = FALSE;\r
559 \r
560         // predator wishes to regurgitate his prey\r
561         if(self.BUTTON_REGURGITATE)\r
562         {\r
563                 if(self.stomach_load)\r
564                 {\r
565                         if(time > self.regurgitate_button_delay_time)\r
566                         {\r
567                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
568                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
569                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
570                         }\r
571                 }\r
572                 else if(time > self.complain_vore)\r
573                 {\r
574                         play2(self, "misc/forbidden.wav");\r
575                         sprint(self, "There is nothing to regurgitate\n");\r
576                         self.complain_vore = time + complain_delay_time;\r
577                 }\r
578         }\r
579 \r
580         if(cvar("g_vore_gurglesound"))\r
581                 Vore_GurgleSound();\r
582 \r
583 // --------------------------------\r
584 // Code that addresses the prey:\r
585 // --------------------------------\r
586 \r
587         Vore_SetCamera();\r
588 \r
589         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
590         if(self.fakeprey)\r
591         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
592                 Vore_DeadPrey_Detach(self);\r
593 \r
594         if(!self.stat_eaten)\r
595                 return;\r
596 \r
597         if(self.deadflag != DEAD_NO)\r
598         {\r
599                 Vore_PreyRelease(self, FALSE);\r
600                 return;\r
601         }\r
602 \r
603         if(self.predator.deadflag != DEAD_NO)\r
604                 Vore_Regurgitate(self);\r
605         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
606                 Vore_Regurgitate(self);\r
607 \r
608         // apply delayed regurgitating if it was scheduled\r
609         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
610         {\r
611                 self.predator.regurgitate_prepare = 0;\r
612                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
613                 Vore_Regurgitate(self);\r
614         }\r
615 \r
616         // execute digesting and team healing\r
617         if(self.predator.digesting == TRUE)\r
618                 Vore_Digest();\r
619         if(teams_matter && self.team == self.predator.team)\r
620         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
621                 Vore_Teamheal();\r
622 \r
623         // execute prey commands\r
624         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
625                 Vore_StomachKick();\r
626         if(self.BUTTON_JUMP)\r
627                 Vore_StomachLeave();\r
628 \r
629         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
630         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
631         kh_Key_DropAll(self, FALSE);\r
632 }